data/qcsrc/menu-div0test/item/label.c

   1 #ifdef INTERFACE
   2 CLASS(Label) EXTENDS(Item)
   3         METHOD(Label, configureLabel, void(entity, string, float, float))
   4         METHOD(Label, draw, void(entity))
   5         METHOD(Label, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(Label, setText, void(entity, string))
   7         METHOD(Label, toString, string(entity))
   8         ATTRIB(Label, text, string, string_null)
   9         ATTRIB(Label, fontSize, float, 8)
  10         ATTRIB(Label, align, float, 0.5)
  11         ATTRIB(Label, allowCut, float, 0)
  12         ATTRIB(Label, keepspaceLeft, float, 0) // for use by subclasses (radiobuttons for example)
  13         ATTRIB(Label, keepspaceRight, float, 0)
  14         ATTRIB(Label, realFontSize, vector, '0 0 0')
  15         ATTRIB(Label, realOrigin, vector, '0 0 0')
  16         ATTRIB(Label, alpha, float, 0.7)
  17         ATTRIB(Label, colorL, vector, '1 1 1')
  18         ATTRIB(Label, disabled, float, 0)
  19         ATTRIB(Label, disabledAlpha, float, 0.3)
  20 ENDCLASS(Label)
  21 #endif
  22
  23 #ifdef IMPLEMENTATION
  24 string toStringLabel(entity me)
  25 {
  26         return me.text;
  27 }
  28 void setTextLabel(entity me, string txt)
  29 {
  30         me.text = txt;
  31         me.realOrigin_x = me.align * (1 - me.keepspaceLeft - me.keepspaceRight - me.realFontSize_x * draw_TextWidth(me.text, 0)) + me.keepspaceLeft;
  32 }
  33 void resizeNotifyLabel(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  34 {
  35         // absSize_y is height of label
  36         me.realFontSize_y = me.fontSize / absSize_y;
  37         me.realFontSize_x = me.fontSize / absSize_x;
  38         me.realOrigin_x = me.align * (1 - me.keepspaceLeft - me.keepspaceRight - me.realFontSize_x * draw_TextWidth(me.text, 0)) + me.keepspaceLeft;
  39         me.realOrigin_y = 0.5 * (1 - me.realFontSize_y);
  40 }
  41 void configureLabelLabel(entity me, string txt, float sz, float algn)
  42 {
  43         me.fontSize = sz;
  44         me.align = algn;
  45         me.setText(me, txt);
  46 }
  47 void drawLabel(entity me)
  48 {
  49         if(me.disabled)
  50                 draw_alpha *= me.disabledAlpha;
  51         if(me.fontSize)
  52                 if(me.text)
  53                 {
  54                         if(me.allowCut)
  55                                 draw_Text(me.realOrigin, draw_TextShortenToWidth(me.text, 1 / me.realFontSize_x, 0), me.realFontSize, me.colorL, me.alpha, 0);
  56                         else
  57                                 draw_Text(me.realOrigin, me.text, me.realFontSize, me.colorL, me.alpha, 0);
  58                 }
  59 }
  60 #endif