data/qcsrc/common/mapinfo.qc

   1         // internal toy
   2 void cvar_settemp(string pKey, string pValue)
   3 {
   4         //localcmd(strcat("\nsettemp ", t, " \"", s, "\"\n"));
   5
   6         // duplicate what this alias does:
   7         // alias settemp "settemp_list \"1 $1 $settemp_var $settemp_list\"; set $settemp_var \"${$1}\"; settemp_var ${settemp_var}x; $1 \"$2\""
   8
   9         cvar_set("settemp_list", strcat("1 ", pKey, " ", cvar_string("settemp_var"), " ", cvar_string("settemp_list")));
  10 #ifdef MENUQC
  11         registercvar(cvar_string("settemp_var"), "", 0);
  12 #else
  13         registercvar(cvar_string("settemp_var"), "");
  14 #endif
  15         cvar_set(cvar_string("settemp_var"), cvar_string(pKey));
  16         cvar_set("settemp_var", strcat(cvar_string("settemp_var"), "x"));
  17         cvar_set(pKey, pValue);
  18 }
  19
  20 void cvar_settemp_restore()
  21 {
  22         // undo what cvar_settemp did
  23         float n, i;
  24         n = tokenize(cvar_string("settemp_list"));
  25         for(i = 0; i < n - 3; i += 3)
  26                 cvar_set(argv(i + 1), cvar_string(argv(i + 2)));
  27         cvar_set("settemp_list", "0");
  28 }
  29
  30 #ifdef HSOI
  31 // HUGE SET - stored in a string
  32 string HugeSetOfIntegers_empty()
  33 {
  34         return "";
  35 }
  36 float HugeSetOfIntegers_get(string pArr, float i)
  37 {
  38         return stof(substring(pArr, i * 4, 4));
  39 }
  40 float HugeSetOfIntegers_length(string pArr)
  41 {
  42         return strlen(pArr) / 4;
  43 }
  44 string HugeSetOfIntegers_concat(string a1, string a2)
  45 {
  46         return strcat(a1, a2);
  47 }
  48 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  49         // special concat function to build up large lists in less time by binary concatenation
  50 {
  51         string s;
  52         s = strcat("    ", ftos(n));
  53         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  54 }
  55 #endif
  56
  57 // generic string stuff
  58 float startsWith(string haystack, string needle)
  59 {
  60         return substring(haystack, 0, strlen(needle)) == needle;
  61 }
  62 float startsWithNocase(string haystack, string needle)
  63 {
  64         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
  65 }
  66 string extractRestOfLine(string haystack, string needle)
  67 {
  68         if(startsWith(haystack, needle))
  69                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  70         return string_null;
  71 }
  72 string car(string s)
  73 {
  74         float o;
  75         o = strstrofs(s, " ", 0);
  76         if(o < 0)
  77                 return s;
  78         return substring(s, 0, o);
  79 }
  80 string cdr(string s)
  81 {
  82         float o;
  83         o = strstrofs(s, " ", 0);
  84         if(o < 0)
  85                 return string_null;
  86         return substring(s, o + 1, strlen(s) - (o + 1));
  87 }
  88
  89 float _MapInfo_Cache_Active;
  90 float _MapInfo_Cache_DB_NameToIndex;
  91 float _MapInfo_Cache_Buf_IndexToMapData;
  92
  93 void MapInfo_Cache_Destroy()
  94 {
  95         if(!_MapInfo_Cache_Active)
  96                 return;
  97
  98         db_close(_MapInfo_Cache_DB_NameToIndex);
  99         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
 100         _MapInfo_Cache_Active = 0;
 101 }
 102
 103 void MapInfo_Cache_Create()
 104 {
 105         MapInfo_Cache_Destroy();
 106         _MapInfo_Cache_DB_NameToIndex = db_create();
 107         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
 108         _MapInfo_Cache_Active = 1;
 109 }
 110
 111 void MapInfo_Cache_Invalidate()
 112 {
 113         if(!_MapInfo_Cache_Active)
 114                 return;
 115
 116         MapInfo_Cache_Create();
 117 }
 118
 119 void MapInfo_Cache_Store()
 120 {
 121         float i;
 122         string s;
 123         if(!_MapInfo_Cache_Active)
 124                 return;
 125
 126         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
 127         if(!s) // empty string is NOT valid here!
 128         {
 129                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
 130                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
 131         }
 132         else
 133                 i = stof(s);
 134
 135         // now store all the stuff
 136         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_bspname);
 137         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_title);
 138         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_description);
 139         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, MapInfo_Map_author);
 140         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_supportedGametypes));
 141         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, i++, ftos(MapInfo_Map_supportedFeatures));
 142 }
 143
 144 float MapInfo_Cache_Retrieve(string map)
 145 {
 146         float i;
 147         string s;
 148         if(!_MapInfo_Cache_Active)
 149                 return 0;
 150
 151         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
 152         if(!s)
 153                 return 0;
 154         i = stof(s);
 155
 156         // now retrieve all the stuff
 157         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 158         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 159         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 160         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++);
 161         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 162         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i++));
 163         return 1;
 164 }
 165
 166 // GLOB HANDLING (for all BSP files)
 167 float _MapInfo_globopen;
 168 float _MapInfo_globcount;
 169 float _MapInfo_globhandle;
 170 string _MapInfo_GlobItem(float i)
 171 {
 172         string s;
 173         s = search_getfilename(_MapInfo_globhandle, i);
 174         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 175 }
 176
 177 void MapInfo_Enumerate()
 178 {
 179         if(_MapInfo_globopen)
 180                 search_end(_MapInfo_globhandle);
 181         MapInfo_Cache_Invalidate();
 182         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
 183         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 184         _MapInfo_globopen = 1;
 185 }
 186
 187 // filter the info by game type mask (updates MapInfo_count)
 188 //
 189 #ifdef HSOI
 190 string _MapInfo_filtered;
 191 float MapInfo_FilterList_Lookup(float i)
 192 {
 193         return MapInfo_FilterList_Lookup(i);
 194 }
 195
 196 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pBegin, float pEnd, float pAbortOnGenerate)
 197 {
 198         float m, valid;
 199         string l, r;
 200
 201         if(pBegin == pEnd)
 202                 return HugeSetOfIntegers_empty();
 203
 204         m = floor((pBegin + pEnd) / 2);
 205
 206         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m, pAbortOnGenerate);
 207         if not(l)
 208                 return string_null; // BAIL OUT
 209         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 210                 if(pAbortOnGenerate)
 211                 {
 212                         MapInfo_progress = m / _MapInfo_globcount;
 213                         return string_null; // BAIL OUT
 214                 }
 215         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
 216         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, m + 1, pEnd, pAbortOnGenerate);
 217         if not(r)
 218                 return string_null; // BAIL OUT
 219
 220         if(valid)
 221                 return HugeSetOfIntegers_insert(l, m, r);
 222         else
 223                 return HugeSetOfIntegers_concat(l, r);
 224 }
 225
 226 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 227 {
 228         if(_MapInfo_filtered)
 229                 strunzone(_MapInfo_filtered);
 230         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, 0, _MapInfo_globcount, pAbortOnGenerate);
 231         if not(_MapInfo_filtered)
 232         {
 233                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 234                 return 0;
 235         }
 236         _MapInfo_filtered = strzone(_MapInfo_filtered);
 237         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 238         MapInfo_ClearTemps();
 239         return 1;
 240 }
 241 #else
 242 float _MapInfo_filtered;
 243 float _MapInfo_filtered_allocated;
 244 float MapInfo_FilterList_Lookup(float i)
 245 {
 246         return stof(bufstr_get(_MapInfo_filtered, i));
 247 }
 248
 249 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pAbortOnGenerate)
 250 {
 251         float i, j;
 252         if not(_MapInfo_filtered_allocated)
 253         {
 254                 _MapInfo_filtered_allocated = 1;
 255                 _MapInfo_filtered = buf_create();
 256         }
 257         MapInfo_count = 0;
 258         for(i = 0, j = 0; i < _MapInfo_globcount; ++i)
 259         {
 260                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 261                         if(pAbortOnGenerate)
 262                         {
 263                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 264                                 MapInfo_progress = i / _MapInfo_globcount;
 265                                 return 0;
 266                         }
 267                 if(((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures))
 268                         bufstr_set(_MapInfo_filtered, j++, ftos(i));
 269         }
 270         MapInfo_count = j;
 271         return 1;
 272 }
 273 #endif
 274
 275 // load info about the i-th map into the MapInfo_Map_* globals
 276 string MapInfo_BSPName_ByID(float i)
 277 {
 278         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 279 }
 280
 281 string unquote(string s)
 282 {
 283         float i, j, l;
 284         l = strlen(s);
 285         j = -1;
 286         for(i = 0; i < l; ++i)
 287         {
 288                 string ch;
 289                 ch = substring(s, i, 1);
 290                 if(ch != " ") if(ch != "\"")
 291                 {
 292                         for(j = strlen(s) - i - 1; j > 0; --j)
 293                         {
 294                                 ch = substring(s, i+j, 1);
 295                                 if(ch != " ") if(ch != "\"")
 296                                         return substring(s, i, j+1);
 297                         }
 298                         return substring(s, i, 1);
 299                 }
 300         }
 301         return "";
 302 }
 303
 304 float MapInfo_Get_ByID(float i)
 305 {
 306         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 307                 return 1;
 308         return 0;
 309 }
 310
 311 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 312 {
 313         string fn;
 314         float fh;
 315         string s, k, v;
 316         vector o;
 317         float i;
 318         float inWorldspawn;
 319         float r;
 320         float twoBaseModes;
 321         float diameter, spawnpoints;
 322
 323         vector mapMins, mapMaxs;
 324
 325         r = 1;
 326         fn = strcat("maps/", pFilename, ".ent");
 327         fh = fopen(fn, FILE_READ);
 328         if(fh < 0)
 329         {
 330                 r = 2;
 331                 fn = strcat("maps/", pFilename, ".bsp");
 332                 fh = fopen(fn, FILE_READ);
 333         }
 334         if(fh < 0)
 335                 return 0;
 336         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 337
 338         inWorldspawn = 2;
 339         MapInfo_Map_supportedGametypes = 0;
 340         spawnpoints = 0;
 341
 342         for(;;)
 343         {
 344                 if not((s = fgets(fh)))
 345                         break;
 346                 if(inWorldspawn == 1)
 347                         if(startsWith(s, "}"))
 348                                 inWorldspawn = 0;
 349                 k = unquote(car(s));
 350                 v = unquote(cdr(s));
 351                 if(inWorldspawn)
 352                 {
 353                         if(k == "classname" && v == "worldspawn")
 354                                 inWorldspawn = 1;
 355                         else if(k == "author")
 356                                 MapInfo_Map_author = v;
 357                         else if(k == "_description")
 358                                 MapInfo_Map_description = v;
 359                         else if(k == "message")
 360                         {
 361                                 i = strstrofs(v, " by ", 0);
 362                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 363                                 {
 364                                         MapInfo_Map_title = substring(v, 0, i);
 365                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 366                                 }
 367                                 else
 368                                         MapInfo_Map_title = v;
 369                         }
 370                 }
 371                 else
 372                 {
 373                         if(k == "origin")
 374                         {
 375                                 o = stov(strcat("'", v, "'"));
 376                                 mapMins_x = min(mapMins_x, o_x);
 377                                 mapMins_y = min(mapMins_y, o_y);
 378                                 mapMins_z = min(mapMins_z, o_z);
 379                                 mapMaxs_x = max(mapMaxs_x, o_x);
 380                                 mapMaxs_y = max(mapMaxs_y, o_y);
 381                                 mapMaxs_z = max(mapMaxs_z, o_z);
 382                         }
 383                         else if(k == "classname")
 384                         {
 385                                 if(v == "dom_controlpoint")
 386                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 387                                 else if(v == "item_flag_team2")
 388                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 389                                 else if(v == "team_CTF_blueflag")
 390                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 391                                 else if(v == "runematch_spawn_point")
 392                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 393                                 else if(v == "target_assault_roundend")
 394                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 395                                 else if(v == "onslaught_generator")
 396                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 397                                 else if(v == "info_player_team1")
 398                                         ++spawnpoints;
 399                                 else if(v == "info_player_team2")
 400                                         ++spawnpoints;
 401                                 else if(v == "info_player_start")
 402                                         ++spawnpoints;
 403                                 else if(v == "info_player_deathmatch")
 404                                         ++spawnpoints;
 405                                 else if(v == "weapon_nex")
 406                                         { }
 407                                 else if(v == "weapon_railgun")
 408                                         { }
 409                                 else if(startsWith(v, "weapon_"))
 410                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 411                         }
 412                 }
 413         }
 414         if(inWorldspawn)
 415         {
 416                 print(fn, " ended still in worldspawn, BUG\n");
 417                 return 0;
 418         }
 419         diameter = vlen(mapMaxs - mapMins);
 420
 421         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT);
 422         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 423         {
 424                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 425                 // as the map is too symmetric for them.
 426         }
 427         else
 428         {
 429                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 430                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 431
 432                 if(spawnpoints >= 8  && diameter > 4096)
 433                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 434                 if(                     diameter < 4096)
 435                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 436                 if(spawnpoints >= 12 && diameter > 5120)
 437                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 438         }
 439
 440         dprint("-> diameter ",    ftos(diameter));
 441         dprint(";  spawnpoints ", ftos(spawnpoints));
 442         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
 443
 444         fclose(fh);
 445
 446         return r;
 447 }
 448
 449 void _MapInfo_Map_Reset()
 450 {
 451         MapInfo_Map_title = "<TITLE>";
 452         MapInfo_Map_description = "<DESCRIPTION>";
 453         MapInfo_Map_author = "<AUTHOR>";
 454         MapInfo_Map_supportedGametypes = 0;
 455         MapInfo_Map_supportedFeatures = 0;
 456 }
 457
 458 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 459 {
 460         MapInfo_Map_supportedGametypes |= pThisType;
 461         if(!(pThisType & pWantedType))
 462                 return;
 463
 464         cvar_set("fraglimit", car(s));
 465         s = cdr(s);
 466
 467         cvar_set("timelimit", car(s));
 468         s = cdr(s);
 469
 470         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 471         {
 472                 cvar_set("g_tdm_teams", car(s));
 473                 s = cdr(s);
 474         }
 475
 476         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 477         {
 478                 cvar_set("g_keyhunt_teams", car(s));
 479                 s = cdr(s);
 480         }
 481 }
 482
 483 float MapInfo_Type_FromString(string t)
 484 {
 485         if     (t == "dm")    return MAPINFO_TYPE_DEATHMATCH;
 486         else if(t == "tdm")   return MAPINFO_TYPE_TEAM_DEATHMATCH;
 487         else if(t == "dom")   return MAPINFO_TYPE_DOMINATION;
 488         else if(t == "ctf")   return MAPINFO_TYPE_CTF;
 489         else if(t == "rune")  return MAPINFO_TYPE_RUNEMATCH;
 490         else if(t == "lms")   return MAPINFO_TYPE_LMS;
 491         else if(t == "arena") return MAPINFO_TYPE_ARENA;
 492         else if(t == "kh")    return MAPINFO_TYPE_KEYHUNT;
 493         else if(t == "as")    return MAPINFO_TYPE_ASSAULT;
 494         else if(t == "ons")   return MAPINFO_TYPE_ONSLAUGHT;
 495         else if(t == "all")   return MAPINFO_TYPE_ALL;
 496         else                  return 0;
 497 }
 498
 499 // load info about a map by name into the MapInfo_Map_* globals
 500 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 501 {
 502         string fn;
 503         string s, t;
 504         float fh, fh2;
 505         float r, f;
 506
 507         if(pGametypeToSet == 0)
 508                 if(MapInfo_Cache_Retrieve(pFilename))
 509                         return 1;
 510
 511         r = 1;
 512
 513         MapInfo_Map_bspname = pFilename;
 514
 515         // default all generic fields so they have "good" values in case something fails
 516         fn = strcat("maps/", pFilename, ".mapinfo");
 517         fh = fopen(fn, FILE_READ);
 518         if(fh < 0)
 519         {
 520                 if(!pAllowGenerate)
 521                         return 0;
 522                 _MapInfo_Map_Reset();
 523                 r = _MapInfo_Generate(pFilename);
 524                 if(!r)
 525                         return 0;
 526                 fh = fopen(fn, FILE_WRITE);
 527                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 528                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 529                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 530                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)       fputs(fh, "has weapons\n");
 531                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 532                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 533                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 534                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20\n");
 535                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 536                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 537                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 538                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 539                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 540                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 541
 542                 fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
 543                 if(fh2 >= 0)
 544                 {
 545                         fclose(fh2);
 546                         fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 547                 }
 548
 549                 fclose(fh);
 550                 r = 2;
 551                 // return r;
 552                 fh = fopen(fn, FILE_READ);
 553                 if(fh < 0)
 554                         error("... but I just wrote it!");
 555         }
 556
 557         _MapInfo_Map_Reset();
 558         for(;;)
 559         {
 560                 if not((s = fgets(fh)))
 561                         break;
 562
 563                 // catch different sorts of comments
 564                 if(s == "")                    // empty lines
 565                         continue;
 566                 if(substring(s, 0, 1) == "#")  // UNIX style
 567                         continue;
 568                 if(substring(s, 0, 2) == "//") // C++ style
 569                         continue;
 570                 if(substring(s, 0, 1) == "_")  // q3map style
 571                         continue;
 572
 573                 t = car(s); s = cdr(s);
 574                 if(t == "title")
 575                         MapInfo_Map_title = s;
 576                 else if(t == "description")
 577                         MapInfo_Map_description = s;
 578                 else if(t == "author")
 579                         MapInfo_Map_author = s;
 580                 else if(t == "has")
 581                 {
 582                         t = car(s); s = cdr(s);
 583                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 584                         else
 585                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 586                 }
 587                 else if(t == "type")
 588                 {
 589                         t = car(s); s = cdr(s);
 590                         f = MapInfo_Type_FromString(t);
 591                         if(f)
 592                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 593                         else
 594                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 595                 }
 596                 else if(t == "settemp_for_type")
 597                 {
 598                         t = car(s); s = cdr(s);
 599                         if((f = MapInfo_Type_FromString(t)))
 600                         {
 601                                 if(f & pGametypeToSet)
 602                                 {
 603                                         t = car(s); s = cdr(s);
 604                                         if(strstrofs(t, "\"", 0) >= 0)
 605                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 606                                         else if(strstrofs(t, "\\", 0) >= 0)
 607                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 608                                         else if(strstrofs(t, ";", 0) >= 0)
 609                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 610                                         else if(strstrofs(s, "\"", 0) >= 0)
 611                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 612                                         else if(strstrofs(s, "\\", 0) >= 0)
 613                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 614                                         else if(strstrofs(s, ";", 0) >= 0)
 615                                                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
 616                                         else
 617                                         {
 618                                                 dprint("Applying temporary setting ", t, " := ", s, "\n");
 619                                                 cvar_settemp(t, s);
 620                                         }
 621                                 }
 622                         }
 623                         else
 624                         {
 625                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
 626                         }
 627                 }
 628                 else
 629                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 630         }
 631         fclose(fh);
 632         if(pGametypeToSet)
 633                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 634                         error("Can't select the requested game type. Bailing out.");
 635         MapInfo_Cache_Store();
 636         if(MapInfo_Map_supportedGametypes != 0)
 637                 return r;
 638         dprint("Map ", pFilename, " supports no game types, ignored\n");
 639         return 0;
 640 }
 641
 642 float MapInfo_FindName(string s)
 643 {
 644         // if there is exactly one map of prefix s, return it
 645         // if not, return the null string
 646         // note that DP sorts glob results... so I can use a binary search
 647         float l, r, m, cmp;
 648         l = 0;
 649         r = MapInfo_count;
 650         // invariants: r is behind s, l-1 is equal or before
 651         while(l != r)
 652         {
 653                 m = floor((l + r) / 2);
 654                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
 655                 cmp = strcasecmp(MapInfo_FindName_match, s);
 656                 if(cmp == 0)
 657                         return m; // found and good
 658                 if(cmp < 0)
 659                         l = m + 1; // l-1 is before s
 660                 else
 661                         r = m; // behind s
 662         }
 663         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
 664         MapInfo_FindName_firstResult = l;
 665         // r == l, so: l is behind s, l-1 is before
 666         // SO: if there is any, l is the one with the right prefix
 667         //     and l+1 may be one too
 668         if(l == MapInfo_count)
 669         {
 670                 MapInfo_FindName_match = string_null;
 671                 MapInfo_FindName_firstResult = -1;
 672                 return -1; // no MapInfo_FindName_match, behind last item
 673         }
 674         if(!startsWithNocase(MapInfo_FindName_match, s))
 675         {
 676                 MapInfo_FindName_match = string_null;
 677                 MapInfo_FindName_firstResult = -1;
 678                 return -1; // wrong prefix
 679         }
 680         if(l == MapInfo_count - 1)
 681                 return l; // last one, nothing can follow => unique
 682         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
 683         {
 684                 MapInfo_FindName_match = string_null;
 685                 return -1; // ambigous MapInfo_FindName_match
 686         }
 687         return l;
 688 }
 689
 690 string MapInfo_FixName(string s)
 691 {
 692         MapInfo_FindName(s);
 693         return MapInfo_FindName_match;
 694 }
 695
 696 float MapInfo_CurrentFeatures()
 697 {
 698         float req;
 699         req = 0;
 700         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena")))
 701                 req |= MAPINFO_FEATURE_WEAPONS;
 702         return req;
 703 }
 704
 705 float MapInfo_CurrentGametype()
 706 {
 707         if(cvar("g_domination"))
 708                 return MAPINFO_TYPE_DOMINATION;
 709         else if(cvar("g_ctf"))
 710                 return MAPINFO_TYPE_CTF;
 711         else if(cvar("g_runematch"))
 712                 return MAPINFO_TYPE_RUNEMATCH;
 713         else if(cvar("g_tdm"))
 714                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 715         else if(cvar("g_assault"))
 716                 return MAPINFO_TYPE_ASSAULT;
 717         else if(cvar("g_lms"))
 718                 return MAPINFO_TYPE_LMS;
 719         else if(cvar("g_arena"))
 720                 return MAPINFO_TYPE_ARENA;
 721         else if(cvar("g_keyhunt"))
 722                 return MAPINFO_TYPE_KEYHUNT;
 723         else if(cvar("g_onslaught"))
 724                 return MAPINFO_TYPE_ONSLAUGHT;
 725         else
 726                 return MAPINFO_TYPE_DEATHMATCH;
 727 }
 728
 729 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 730 {
 731         if(!MapInfo_Get_ByName(s, 1, 0))
 732                 return 0;
 733         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 734                 return 0;
 735         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 736                 return 0;
 737         return 1;
 738 }
 739
 740 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 741 {
 742         float r;
 743         r = _MapInfo_CheckMap(s);
 744         MapInfo_ClearTemps();
 745         return r;
 746 }
 747
 748 void MapInfo_SwitchGameType(float t)
 749 {
 750         cvar_set("gamecfg",      "0");
 751         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
 752         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
 753         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
 754         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
 755         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
 756         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
 757         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
 758         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
 759         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
 760         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
 761 }
 762
 763 void MapInfo_LoadMap(string s)
 764 {
 765         MapInfo_Map_supportedGametypes = 0;
 766         if(!MapInfo_CheckMap(s))
 767         {
 768                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
 769                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 770         }
 771         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
 772 }
 773
 774 string MapInfo_ListAllowedMaps()
 775 {
 776         string out;
 777         float i;
 778
 779         // to make absolutely sure:
 780         MapInfo_Enumerate();
 781         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 782
 783         out = "";
 784         for(i = 0; i < MapInfo_count; ++i)
 785                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
 786         return substring(out, 1, strlen(out) - 1);
 787 }
 788
 789 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
 790 {
 791         float t;
 792         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
 793         {
 794                 if(MapInfo_Map_supportedGametypes <= 0)
 795                         error("Mapinfo system is not functional at all. BAILED OUT.\n");
 796
 797                 t = 1;
 798                 while(!(MapInfo_Map_supportedGametypes & 1))
 799                 {
 800                         t *= 2;
 801                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
 802                 }
 803                 // t is now a supported mode!
 804                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
 805                 MapInfo_SwitchGameType(t);
 806         }
 807         cvar_settemp_restore();
 808         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 809         MapInfo_ClearTemps();
 810 }
 811
 812 void MapInfo_ClearTemps()
 813 {
 814         MapInfo_Map_bspname = string_null;
 815         MapInfo_Map_title = string_null;
 816         MapInfo_Map_description = string_null;
 817         MapInfo_Map_author = string_null;
 818         MapInfo_Map_supportedGametypes = 0;
 819         MapInfo_Map_supportedFeatures = 0;
 820 }