data/qcsrc/common/mapinfo.qc

   1 // HUGE SET - stored in a string
   2 string HugeSetOfIntegers_empty()
   3 {
   4         return "";
   5 }
   6 float HugeSetOfIntegers_get(string pArr, float i)
   7 {
   8         return stof(substring(pArr, i * 4, 4));
   9 }
  10 float HugeSetOfIntegers_length(string pArr)
  11 {
  12         return strlen(pArr) / 4;
  13 }
  14 string HugeSetOfIntegers_concat(string a1, string a2)
  15 {
  16         return strcat(a1, a2);
  17 }
  18 string HugeSetOfIntegers_insert(string a1, float n, string a2)
  19         // special concat function to build up large lists in less time by binary concatenation
  20 {
  21         string s;
  22         s = strcat("    ", ftos(n));
  23         return strcat(a1, substring(s, strlen(s) - 4, 4), a2);
  24 }
  25
  26 // generic string stuff
  27 float startsWith(string haystack, string needle)
  28 {
  29         return substring(haystack, 0, strlen(needle)) == needle;
  30 }
  31 string extractRestOfLine(string haystack, string needle)
  32 {
  33         if(startsWith(haystack, needle))
  34                 return substring(haystack, strlen(needle), strlen(haystack) - strlen(needle));
  35         return string_null;
  36 }
  37 string car(string s)
  38 {
  39         float o;
  40         o = strstrofs(s, " ", 0);
  41         if(o < 0)
  42                 return s;
  43         return substring(s, 0, o);
  44 }
  45 string cdr(string s)
  46 {
  47         float o;
  48         o = strstrofs(s, " ", 0);
  49         if(o < 0)
  50                 return string_null;
  51         return substring(s, o + 1, strlen(s) - (o + 1));
  52 }
  53
  54 // GLOB HANDLING (for all BSP files)
  55 float _MapInfo_globopen;
  56 float _MapInfo_globcount;
  57 float _MapInfo_globhandle;
  58 string _MapInfo_GlobItem(float i)
  59 {
  60         string s;
  61         s = search_getfilename(_MapInfo_globhandle, i);
  62         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
  63 }
  64
  65 void MapInfo_Enumerate()
  66 {
  67         if(_MapInfo_globopen)
  68                 search_end(_MapInfo_globhandle);
  69         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
  70         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
  71         _MapInfo_globopen = 1;
  72 }
  73
  74 // filter the info by game type mask (updates MapInfo_count)
  75 string _MapInfo_filtered;
  76 string MapInfo_FilterGametype_Recursive(float pGametype, float pFeatures, float pBegin, float pEnd)
  77 {
  78         float m, valid;
  79         string l, r;
  80
  81         if(pBegin == pEnd)
  82                 return HugeSetOfIntegers_empty();
  83
  84         m = floor((pBegin + pEnd) / 2);
  85
  86         l = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, pBegin, m);
  87         if not(l)
  88                 return string_null; // BAIL OUT
  89         if(MapInfo_Get_ByName(_MapInfo_GlobItem(m), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
  90                 return string_null; // BAIL OUT
  91         valid = (((MapInfo_Map_supportedGametypes & pGametype) != 0) && ((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures));
  92         r = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, m + 1, pEnd);
  93         if not(r)
  94                 return string_null; // BAIL OUT
  95
  96         if(valid)
  97                 return HugeSetOfIntegers_insert(l, m, r);
  98         else
  99                 return HugeSetOfIntegers_concat(l, r);
 100 }
 101 float MapInfo_FilterGametype(float pGametype, float pFeatures)
 102 {
 103         if(_MapInfo_filtered)
 104                 strunzone(_MapInfo_filtered);
 105         _MapInfo_filtered = MapInfo_FilterGametype_Recursive(pGametype, pFeatures, 0, _MapInfo_globcount);
 106         if not(_MapInfo_filtered)
 107         {
 108                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
 109                 return 0;
 110         }
 111         _MapInfo_filtered = strzone(_MapInfo_filtered);
 112         MapInfo_count = HugeSetOfIntegers_length(_MapInfo_filtered);
 113         //print("Filter ", ftos(pGametype), "/", ftos(pFeatures), " has ", ftos(MapInfo_count), "\n");
 114         // TODO clear cache
 115         return 1;
 116 }
 117
 118 // load info about the i-th map into the MapInfo_Map_* globals
 119 string MapInfo_BSPName_ByID(float i)
 120 {
 121         return _MapInfo_GlobItem(HugeSetOfIntegers_get(_MapInfo_filtered, i));
 122 }
 123
 124 float MapInfo_Get_ByID(float i)
 125 {
 126         // TODO check cache
 127         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
 128         {
 129                 // TODO save in cache
 130                 return 1;
 131         }
 132         return 0;
 133 }
 134
 135 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 136 {
 137         string fn;
 138         float fh;
 139         string s, v;
 140         vector o;
 141         float inWorldspawn, l;
 142         float r;
 143         float twoBaseModes;
 144
 145         vector mapMins, mapMaxs;
 146
 147         r = 1;
 148         fn = strcat("maps/", pFilename, ".ent");
 149         fh = fopen(fn, FILE_READ);
 150         if(fh < 0)
 151         {
 152                 r = 2;
 153                 fn = strcat("maps/", pFilename, ".bsp");
 154                 fh = fopen(fn, FILE_READ);
 155         }
 156         if(fh < 0)
 157                 return 0;
 158         print("Analyzing ", fn, " to generate initial mapinfo; please edit that file later\n");
 159
 160         inWorldspawn = 2;
 161         MapInfo_Map_supportedGametypes = 0;
 162
 163         for(;;)
 164         {
 165                 if not((s = fgets(fh)))
 166                         break;
 167                 if(inWorldspawn == 1)
 168                         if(startsWith(s, "}"))
 169                                 inWorldspawn = 0;
 170                 if(inWorldspawn)
 171                 {
 172                         if(startsWith(s, "\"classname\" \"worldspawn\""))
 173                                 inWorldspawn = 1;
 174                         else if((v = extractRestOfLine(s, "\"author\" \"")))
 175                         {
 176                                 for(l = strlen(v) - 1; l > 0; --l)
 177                                         if(substring(v, l, 1) == "\"")
 178                                                 break;
 179                                 MapInfo_Map_author = substring(v, 0, l);
 180                         }
 181                         else if((v = extractRestOfLine(s, "\"message\" \"")))
 182                         {
 183                                 for(l = strlen(v) - 1; l > 0; --l)
 184                                         if(substring(v, l, 1) == "\"")
 185                                                 break;
 186                                 MapInfo_Map_title = substring(v, 0, l);
 187                         }
 188                 }
 189                 else
 190                 {
 191                         if((v = extractRestOfLine(s, "\"origin\" \"")))
 192                         {
 193                                 for(l = strlen(v) - 1; l > 0; --l)
 194                                         if(substring(v, l, 1) == "\"")
 195                                                 break;
 196                                 o = stov(strcat("'", substring(v, 0, l), "'"));
 197                                 mapMins_x = min(mapMins_x, o_x);
 198                                 mapMins_y = min(mapMins_y, o_y);
 199                                 mapMins_z = min(mapMins_z, o_z);
 200                                 mapMaxs_x = max(mapMaxs_x, o_x);
 201                                 mapMaxs_y = max(mapMaxs_y, o_y);
 202                                 mapMaxs_z = max(mapMaxs_z, o_z);
 203                         }
 204                         else if((v = extractRestOfLine(s, "\"classname\" \"")))
 205                         {
 206                                 if(startsWith(v, "dom_controlpoint\""))
 207                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
 208                                 else if(startsWith(v, "item_flag_team2\""))
 209                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
 210                                 else if(startsWith(v, "runematch_spawn_point\""))
 211                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
 212                                 else if(startsWith(v, "target_assault_roundend\""))
 213                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
 214                                 else if(startsWith(v, "onslaught_generator\""))
 215                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
 216                                 else if(startsWith(v, "info_player_team1\""))
 217                                         ++MapInfo_Map_spawnpoints;
 218                                 else if(startsWith(v, "info_player_team2\""))
 219                                         ++MapInfo_Map_spawnpoints;
 220                                 else if(startsWith(v, "info_player_deathmatch\""))
 221                                         ++MapInfo_Map_spawnpoints;
 222                                 else if(startsWith(v, "info_player_start\""))
 223                                         ++MapInfo_Map_spawnpoints;
 224                                 else if(startsWith(v, "weapon_") && !startsWith(v, "weapon_nex\"") && !startsWith(v, "weapon_railgun\""))
 225                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 226                         }
 227                 }
 228         }
 229         if(inWorldspawn)
 230         {
 231                 print(fn, " ended still in worldspawn, BUG\n");
 232                 return 0;
 233         }
 234         MapInfo_Map_diameter = vlen(mapMaxs - mapMins);
 235
 236         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT);
 237         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
 238         {
 239                 // we have a CTF-only or Assault-only map. Don't add other modes then,
 240                 // as the map is too symmetric for them.
 241         }
 242         else
 243         {
 244                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
 245                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
 246
 247                 if(MapInfo_Map_spawnpoints >= 8  && MapInfo_Map_diameter > 4096)
 248                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
 249                 if(                MapInfo_Map_diameter < 4096)
 250                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
 251                 if(MapInfo_Map_spawnpoints >= 12 && MapInfo_Map_diameter > 5120)
 252                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
 253         }
 254
 255         fclose(fh);
 256         return r;
 257 }
 258
 259 void _MapInfo_Map_Reset()
 260 {
 261         MapInfo_Map_title = "Untitled1";
 262         MapInfo_Map_description = "Bleh.";
 263         MapInfo_Map_author = "He-Who-Must-Not-Be-Named";
 264         MapInfo_Map_supportedGametypes = 0;
 265         MapInfo_Map_supportedFeatures = 0;
 266         MapInfo_Map_diameter = 0;
 267         MapInfo_Map_spawnpoints = 0;
 268 }
 269
 270 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType)
 271 {
 272         MapInfo_Map_supportedGametypes |= pThisType;
 273         if(!(pThisType & pWantedType))
 274                 return;
 275
 276         cvar_set("fraglimit", car(s));
 277         s = cdr(s);
 278
 279         cvar_set("timelimit", car(s));
 280         s = cdr(s);
 281
 282         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
 283         {
 284                 cvar_set("g_tdm_teams", car(s));
 285                 s = cdr(s);
 286         }
 287
 288         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
 289         {
 290                 cvar_set("g_keyhunt_teams", car(s));
 291                 s = cdr(s);
 292         }
 293 }
 294
 295 float MapInfo_Type_FromString(string t)
 296 {
 297         if     (t == "dm")    return MAPINFO_TYPE_DEATHMATCH;
 298         else if(t == "tdm")   return MAPINFO_TYPE_TEAM_DEATHMATCH;
 299         else if(t == "dom")   return MAPINFO_TYPE_DOMINATION;
 300         else if(t == "ctf")   return MAPINFO_TYPE_CTF;
 301         else if(t == "rune")  return MAPINFO_TYPE_RUNEMATCH;
 302         else if(t == "lms")   return MAPINFO_TYPE_LMS;
 303         else if(t == "arena") return MAPINFO_TYPE_ARENA;
 304         else if(t == "kh")    return MAPINFO_TYPE_KEYHUNT;
 305         else if(t == "as")    return MAPINFO_TYPE_ASSAULT;
 306         else if(t == "ons")   return MAPINFO_TYPE_ONSLAUGHT;
 307         else                  return 0;
 308 }
 309
 310 // load info about a map by name into the MapInfo_Map_* globals
 311 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
 312 {
 313         string fn;
 314         string s, t;
 315         float fh;
 316         float r, f;
 317
 318         r = 1;
 319
 320         MapInfo_Map_bspname = pFilename;
 321
 322         // default all generic fields so they have "good" values in case something fails
 323         fn = strcat("maps/", pFilename, ".mapinfo");
 324         fh = fopen(fn, FILE_READ);
 325         if(fh < 0)
 326         {
 327                 if(!pAllowGenerate)
 328                         return 0;
 329                 _MapInfo_Map_Reset();
 330                 r = _MapInfo_Generate(pFilename);
 331                 if(!r)
 332                         return 0;
 333                 fh = fopen(fn, FILE_WRITE);
 334                 fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 335                 fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 336                 fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 337                 fputs(fh, strcat("_diameter ", ftos(MapInfo_Map_diameter), "\n"));
 338                 fputs(fh, strcat("_spawnpoints ", ftos(MapInfo_Map_spawnpoints), "\n"));
 339                 if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)       fputs(fh, "has weapons\n");
 340                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DEATHMATCH)      fputs(fh, "type dm 30 20\n");
 341                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_TEAM_DEATHMATCH) fputs(fh, "type tdm 50 20 2\n");
 342                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_DOMINATION)      fputs(fh, "type dom 200 20\n");
 343                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_CTF)             fputs(fh, "type ctf 300 20\n");
 344                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RUNEMATCH)       fputs(fh, "type rune 200 20\n");
 345                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_LMS)             fputs(fh, "type lms 9 20\n");
 346                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ARENA)           fputs(fh, "type arena 10 20\n");
 347                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_KEYHUNT)         fputs(fh, "type kh 1000 20 3\n");
 348                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ASSAULT)         fputs(fh, "type as 20\n");
 349                 if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_ONSLAUGHT)       fputs(fh, "type ons 20\n");
 350                 fclose(fh);
 351                 r = 2;
 352                 // return r;
 353                 fh = fopen(fn, FILE_READ);
 354                 if(fh < 0)
 355                         error("... but I just wrote it!");
 356         }
 357
 358         _MapInfo_Map_Reset();
 359         for(;;)
 360         {
 361                 if not((s = fgets(fh)))
 362                         break;
 363                 t = car(s); s = cdr(s);
 364                 if     (t == "title")
 365                         MapInfo_Map_title = s;
 366                 else if(t == "description")
 367                         MapInfo_Map_description = s;
 368                 else if(t == "author")
 369                         MapInfo_Map_author = s;
 370                 else if(t == "_diameter")
 371                         MapInfo_Map_diameter = stof(s);
 372                 else if(t == "_spawnpoints")
 373                         MapInfo_Map_spawnpoints = stof(s);
 374                 else if(t == "has")
 375                 {
 376                         t = car(s); s = cdr(s);
 377                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 378                         else
 379                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
 380                 }
 381                 else if(t == "type")
 382                 {
 383                         t = car(s); s = cdr(s);
 384                         f = MapInfo_Type_FromString(t);
 385                         if(f)
 386                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f);
 387                         else
 388                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
 389                 }
 390                 else
 391                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
 392         }
 393         fclose(fh);
 394         if(pGametypeToSet)
 395                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
 396                         error("Can't select the requested game type. Bailing out.");
 397         if(MapInfo_Map_supportedGametypes != 0)
 398                 return r;
 399         dprint("Map ", pFilename, " supports no game types, ignored\n");
 400         return 0;
 401 }
 402
 403 string _MapInfo_FindName_match;
 404 float MapInfo_FindName(string s)
 405 {
 406         // if there is exactly one map of prefix s, return it
 407         // if not, return the null string
 408         // note that DP sorts glob results... so I can use a binary search
 409         float l, r, m, cmp;
 410         l = 0;
 411         r = MapInfo_count;
 412         _MapInfo_FindName_match = string_null;
 413         // invariants: r is behind s, l-1 is equal or before
 414         while(l != r)
 415         {
 416                 m = floor((l + r) / 2);
 417                 cmp = strcasecmp(_MapInfo_GlobItem(HugeSetOfIntegers_get(_MapInfo_filtered, m)), s);
 418                 if(cmp == 0)
 419                         return m; // found and good
 420                 if(cmp < 0)
 421                         l = m + 1; // l-1 is before s
 422                 else
 423                         r = m; // behind s
 424         }
 425         // r == l, so: l is behind s, l-1 is before
 426         // SO: if there is any, l is the one with the right prefix
 427         //     and l+1 may be one too
 428         if(l == MapInfo_count)
 429                 return -1; // no _MapInfo_FindName_match, behind last item
 430         _MapInfo_FindName_match = _MapInfo_GlobItem(HugeSetOfIntegers_get(_MapInfo_filtered, l));
 431         if(!startsWith(_MapInfo_FindName_match, s))
 432                 return -1; // wrong prefix
 433         if(l == MapInfo_count - 1)
 434                 return l; // last one, nothing can follow => unique
 435         if(startsWith(_MapInfo_GlobItem(HugeSetOfIntegers_get(_MapInfo_filtered, l + 1)), s))
 436                 return -1; // ambigous _MapInfo_FindName_match
 437         return l;
 438 }
 439
 440 string MapInfo_FixName(string s)
 441 {
 442         MapInfo_FindName(s);
 443         return _MapInfo_FindName_match;
 444 }
 445
 446 float MapInfo_CurrentFeatures()
 447 {
 448         float req;
 449         req = 0;
 450         if(!(cvar("g_instagib") || cvar("g_minstagib") || cvar("g_nixnex") || cvar("g_rocketarena")))
 451                 req |= MAPINFO_FEATURE_WEAPONS;
 452         return req;
 453 }
 454
 455 float MapInfo_CurrentGametype()
 456 {
 457         if(cvar("g_domination"))
 458                 return MAPINFO_TYPE_DOMINATION;
 459         else if(cvar("g_ctf"))
 460                 return MAPINFO_TYPE_CTF;
 461         else if(cvar("g_runematch"))
 462                 return MAPINFO_TYPE_RUNEMATCH;
 463         else if(cvar("g_tdm"))
 464                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
 465         else if(cvar("g_assault"))
 466                 return MAPINFO_TYPE_ASSAULT;
 467         else if(cvar("g_lms"))
 468                 return MAPINFO_TYPE_LMS;
 469         else if(cvar("g_arena"))
 470                 return MAPINFO_TYPE_ARENA;
 471         else if(cvar("g_keyhunt"))
 472                 return MAPINFO_TYPE_KEYHUNT;
 473         else if(cvar("g_onslaught"))
 474                 return MAPINFO_TYPE_ONSLAUGHT;
 475         else
 476                 return MAPINFO_TYPE_DEATHMATCH;
 477 }
 478
 479 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
 480 {
 481         if(!MapInfo_Get_ByName(s, 1, 0))
 482                 return 0;
 483         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
 484                 return 0;
 485         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
 486                 return 0;
 487         return 1;
 488 }
 489
 490 void MapInfo_SwitchGameType(float t)
 491 {
 492         cvar_set("gamecfg",      "0");
 493         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "0" : "1");
 494         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "0" : "1");
 495         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "0" : "1");
 496         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "0" : "1");
 497         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "0" : "1");
 498         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "0" : "1");
 499         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "0" : "1");
 500         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "0" : "1");
 501         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "0" : "1");
 502         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "0" : "1");
 503 }
 504
 505 void MapInfo_LoadMap(string s)
 506 {
 507         if(!MapInfo_CheckMap(s))
 508         {
 509                 print("EMERGENCY: can't play the selected map in the given game mode. Falling back to deathmatch.\n");
 510                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
 511         }
 512         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
 513         localcmd(strcat("\nchangelevel ", s, "\n"));
 514 }
 515
 516 string MapInfo_ListAllowedMaps()
 517 {
 518         string out;
 519         float i;
 520
 521         // to make absolutely sure:
 522         MapInfo_Enumerate();
 523         for(;;)
 524                 if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures()))
 525                         break;
 526
 527         out = "";
 528         for(i = 0; i < MapInfo_count; ++i)
 529                 out = strcat(out, " ", _MapInfo_GlobItem(HugeSetOfIntegers_get(_MapInfo_filtered, i)));
 530         return substring(out, 1, strlen(out) - 1);
 531 }