data/qcsrc/client/teamradar.qc

   1 float teamradar_angle; // player yaw angle
   2 vector teamradar_origin3d_in_texcoord; // player origin
   3 vector teamradar_origin2d; // 2D origin
   4 vector teamradar_size2d; // 2D size
   5 float teamradar_size; // 2D scale factor
   6 float cl_teamradar_scale; // window size = ...qu
   7 float v_flipped;
   8
   9 float vlen_maxnorm2d(vector v)
  10 {
  11         return max4(v_x, v_y, -v_x, -v_y);
  12 }
  13
  14 float vlen_minnorm2d(vector v)
  15 {
  16         return min(max(v_x, -v_x), max(v_y, -v_y));
  17 }
  18
  19 vector teamradar_3dcoord_to_texcoord(vector in)
  20 {
  21         vector out;
  22         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
  23         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
  24         out_z = 0;
  25         return out;
  26 }
  27
  28 vector teamradar_texcoord_to_2dcoord(vector in)
  29 {
  30         vector out;
  31         in -= teamradar_origin3d_in_texcoord;
  32
  33         out = rotate(in, teamradar_angle * DEG2RAD);
  34         out_y = - out_y; // screen space is reversed
  35
  36         out = out * teamradar_size;
  37         if(v_flipped)
  38                 out_x = -out_x;
  39         out += teamradar_origin2d;
  40         return out;
  41 }
  42
  43 vector yinvert(vector v)
  44 {
  45         v_y = 1 - v_y;
  46         return v;
  47 }
  48
  49 void draw_teamradar_background(float bg, float fg)
  50 {
  51         if(bg > 0)
  52         {
  53                 R_BeginPolygon("", 0);
  54                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  55                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  56                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  57                 R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', bg);
  58                 R_EndPolygon();
  59         }
  60
  61         if(fg > 0 && minimapname != "")
  62         {
  63                 if(csqc_flags & CSQC_FLAG_READPICTURE) // not 2.4.2
  64                         R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  65                 else
  66                         R_BeginPolygon(minimapname, DRAWFLAG_ADDITIVE);
  67                 if(v_flipped)
  68                 {
  69                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), '1 1 1', fg);
  70                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), '1 1 1', fg);
  71                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), '1 1 1', fg);
  72                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), '1 1 1', fg);
  73                 }
  74                 else
  75                 {
  76                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), '1 1 1', fg);
  77                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), '1 1 1', fg);
  78                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), '1 1 1', fg);
  79                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), '1 1 1', fg);
  80                 }
  81                 R_EndPolygon();
  82         }
  83 }
  84
  85 void(vector coord3d, vector pangles, vector rgb) draw_teamradar_player =
  86 {
  87         vector coord, rgb2;
  88
  89         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  90
  91         makevectors(pangles - '0 1 0' * teamradar_angle);
  92         if(v_flipped)
  93         {
  94                 v_forward_x = -v_forward_x;
  95                 v_right_x = -v_right_x;
  96                 v_up_x = -v_up_x;
  97         }
  98         v_forward_z = 0;
  99         v_forward = normalize(v_forward);
 100         v_forward_y *= -1.0;
 101         v_right_x = -v_forward_y;
 102         v_right_y = v_forward_x;
 103
 104         if(rgb == '1 1 1')
 105                 rgb2 = '0 0 0';
 106         else
 107                 rgb2 = '1 1 1';
 108
 109         R_BeginPolygon("", 0);
 110         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, 1);
 111         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, 1);
 112         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, 1);
 113         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, 1);
 114         R_EndPolygon();
 115
 116         R_BeginPolygon("", 0);
 117         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, 1);
 118         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, 1);
 119         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, 1);
 120         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, 1);
 121         R_EndPolygon();
 122 };
 123
 124 void draw_teamradar_icon(vector coord, float icon, float pingtime, vector rgb, float a)
 125 {
 126         float dt;
 127         vector v;
 128
 129         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 130         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
 131         if(pingtime != 0)
 132         {
 133                 dt = time - pingtime;
 134                 if(dt > 1)
 135                         return;
 136                 v = '2 2 0' * teamradar_size * dt;
 137                 drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', 1 - dt, DRAWFLAG_ADDITIVE);
 138         }
 139 }
 140
 141 void draw_teamradar_link(vector start, vector end, float colors)
 142 {
 143         vector c0, c1, norm;
 144
 145         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 146         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 147         norm = normalize(start - end);
 148         norm_z = norm_x;
 149         norm_x = -norm_y;
 150         norm_y = norm_z;
 151         norm_z = 0;
 152
 153         c0 = colormapPaletteColor(colors & 0x0F, FALSE);
 154         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, FALSE);
 155
 156         R_BeginPolygon("", 0);
 157         R_PolygonVertex(start - norm, '0 0 0', c0, 1);
 158         R_PolygonVertex(start + norm, '0 1 0', c0, 1);
 159         R_PolygonVertex(end + norm, '1 1 0', c1, 1);
 160         R_PolygonVertex(end - norm, '1 0 0', c1, 1);
 161         R_EndPolygon();
 162 }
 163
 164 float cl_teamradar_scale;
 165 float cl_teamradar_background_alpha;
 166 float cl_teamradar_foreground_alpha;
 167 float cl_teamradar_rotation;
 168 vector cl_teamradar_size;
 169 vector cl_teamradar_position;
 170 float cl_teamradar_zoommode;
 171
 172 void teamradar_loadcvars()
 173 {
 174         v_flipped = cvar("v_flipped");
 175         if(ons_showmap)
 176         {
 177                 cl_teamradar_scale = 42; // dummy, not used (see zoommode)
 178                 cl_teamradar_background_alpha = 1;
 179                 cl_teamradar_foreground_alpha = 1;
 180                 cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 181                 if(!cl_teamradar_rotation)
 182                         cl_teamradar_rotation = 4;
 183                 cl_teamradar_size = '256 256 0'; // TODO make somewhat variable?
 184                 cl_teamradar_position = '0.5 0.5 0';
 185                 cl_teamradar_zoommode = 3;
 186         }
 187         else
 188         {
 189                 cl_teamradar_scale = cvar("cl_teamradar_scale");
 190                 cl_teamradar_background_alpha = cvar("cl_teamradar_background_alpha");
 191                 cl_teamradar_foreground_alpha = cvar("cl_teamradar_foreground_alpha");
 192                 cl_teamradar_rotation = cvar("cl_teamradar_rotation");
 193                 cl_teamradar_size = stov(cvar_string("cl_teamradar_size"));
 194                 cl_teamradar_position = stov(cvar_string("cl_teamradar_position"));
 195                 cl_teamradar_zoommode = cvar("cl_teamradar_zoommode");
 196
 197                 // others default to 0
 198                 // match this to defaultNexuiz.cfg!
 199                 if(!cl_teamradar_scale) cl_teamradar_scale = 4096;
 200                 if(!cl_teamradar_background_alpha) cl_teamradar_background_alpha = 0.4;
 201                 if(!cl_teamradar_foreground_alpha) cl_teamradar_foreground_alpha = 0.8;
 202                 if(!cl_teamradar_size_x) cl_teamradar_size_x = 128;
 203                 if(!cl_teamradar_size_y) cl_teamradar_size_y = cl_teamradar_size_x;
 204
 205                 cl_teamradar_size_z = 0;
 206                 cl_teamradar_position_z = 0;
 207         }
 208 }
 209
 210 void() teamradar_view =
 211 {
 212         local float color, color2;
 213         local vector rgb;
 214         local entity tm;
 215         float scale2d, normalsize, bigsize;
 216         float f;
 217
 218         if(minimapname == "" && !ons_showmap)
 219                 return;
 220
 221         teamradar_loadcvars();
 222
 223         switch(cl_teamradar_zoommode)
 224         {
 225                 default:
 226                 case 0:
 227                         f = current_zoomfraction;
 228                         break;
 229                 case 1:
 230                         f = 1 - current_zoomfraction;
 231                         break;
 232                 case 2:
 233                         f = 0;
 234                         break;
 235                 case 3:
 236                         f = 1;
 237                         break;
 238         }
 239
 240         switch(cl_teamradar_rotation)
 241         {
 242                 case 0:
 243                         teamradar_angle = input_angles_y - 90;
 244                         break;
 245                 default:
 246                         teamradar_angle = 90 * cl_teamradar_rotation;
 247                         break;
 248         }
 249
 250         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
 251         teamradar_size2d = cl_teamradar_size;
 252         teamradar_origin2d =
 253                   '1 0 0' * (0.5 * teamradar_size2d_x + cl_teamradar_position_x * (vid_conwidth - teamradar_size2d_x))
 254                 + '0 1 0' * (0.5 * teamradar_size2d_y + cl_teamradar_position_y * (vid_conheight - teamradar_size2d_y));
 255
 256         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
 257         if(cl_teamradar_rotation == 0)
 258         {
 259                 // max-min distance must fit the radar in any rotation
 260                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen(mi_max - mi_min));
 261         }
 262         else
 263         {
 264                 vector c0, c1, c2, c3, span;
 265                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
 266                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
 267                 c2 = rotate('1 0 0' * mi_min_x + '0 1 0' * mi_max_y, teamradar_angle * DEG2RAD);
 268                 c3 = rotate('1 0 0' * mi_max_x + '0 1 0' * mi_min_y, teamradar_angle * DEG2RAD);
 269                 span = '0 0 0';
 270                 span_x = max4(c0_x, c1_x, c2_x, c3_x) - min4(c0_x, c1_x, c2_x, c3_x);
 271                 span_y = max4(c0_y, c1_y, c2_y, c3_y) - min4(c0_y, c1_y, c2_y, c3_y);
 272
 273                 // max-min distance must fit the radar in x=x, y=y
 274                 bigsize = min(
 275                         teamradar_size2d_x * scale2d / (1.05 * span_x),
 276                         teamradar_size2d_y * scale2d / (1.05 * span_y)
 277                 );
 278         }
 279
 280         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / cl_teamradar_scale;
 281         if(bigsize > normalsize)
 282                 normalsize = bigsize;
 283
 284         teamradar_size =
 285                   f * bigsize
 286                 + (1 - f) * normalsize;
 287         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 288                   f * (mi_min + mi_max) * 0.5
 289                 + (1 - f) * pmove_org);
 290
 291         color = GetPlayerColor(player_localentnum-1);
 292         rgb = GetTeamRGB(color);
 293
 294         drawsetcliparea(
 295                 teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 296                 teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 297                 teamradar_size2d_x,
 298                 teamradar_size2d_y
 299         );
 300
 301         draw_teamradar_background(cl_teamradar_background_alpha, cl_teamradar_foreground_alpha);
 302
 303         if(ons_showmap)
 304         {
 305                 drawresetcliparea();
 306
 307                 vector frame_origin, frame_size;
 308                 frame_origin = frame_size = '0 0 0';
 309
 310                 frame_origin_x = teamradar_origin2d_x - teamradar_size2d_x * 0.55859375;
 311                 frame_origin_y = teamradar_origin2d_y - teamradar_size2d_y * 0.55859375;
 312                 frame_size_x = teamradar_size2d_x * 1.1171875;
 313                 frame_size_y = teamradar_size2d_y * 1.1171875;
 314                 drawpic(frame_origin, "gfx/ons-frame.tga", frame_size, '1 1 1', 1, 0);
 315                 drawpic(frame_origin, "gfx/ons-frame-team.tga", frame_size, rgb, 1, 0);
 316
 317                 drawsetcliparea(
 318                         teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 319                         teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 320                         teamradar_size2d_x,
 321                         teamradar_size2d_y
 322                 );
 323         }
 324
 325         for(tm = world; (tm = find(tm, classname, "radarlink")); )
 326                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
 327         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
 328                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm.teamradar_time, tm.teamradar_color, tm.alpha);
 329         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
 330         {
 331                 color2 = GetPlayerColor(tm.sv_entnum);
 332                 //if(color == COLOR_SPECTATOR || color == color2)
 333                         draw_teamradar_player(tm.origin, tm.angles, GetTeamRGB(color2));
 334         }
 335         draw_teamradar_player(pmove_org, input_angles, '1 1 1');
 336
 337         drawresetcliparea();
 338 };
 339
 340
 341
 342 // radar links
 343
 344 void Ent_RadarLink()
 345 {
 346         float sendflags;
 347         sendflags = ReadByte();
 348
 349         InterpolateOrigin_Undo();
 350
 351         self.iflags = IFLAG_VELOCITY;
 352         self.classname = "radarlink";
 353
 354         if(sendflags & 1)
 355         {
 356                 self.origin_x = ReadCoord();
 357                 self.origin_y = ReadCoord();
 358                 self.origin_z = ReadCoord();
 359         }
 360
 361         if(sendflags & 2)
 362         {
 363                 self.velocity_x = ReadCoord();
 364                 self.velocity_y = ReadCoord();
 365                 self.velocity_z = ReadCoord();
 366         }
 367
 368         if(sendflags & 4)
 369         {
 370                 self.team = ReadByte();
 371         }
 372
 373         InterpolateOrigin_Note();
 374 }