data/qcsrc/client/teamradar.qc

   1 float teamradar_angle; // player yaw angle
   2 vector teamradar_origin3d_in_texcoord; // player origin
   3 vector teamradar_origin2d; // 2D origin
   4 vector teamradar_size2d; // 2D size
   5 float teamradar_size; // 2D scale factor
   6 float teamradar_scale; // window size = ...qu
   7
   8 vector teamradar_3dcoord_to_texcoord(vector in)
   9 {
  10         vector out;
  11         out_x = (in_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
  12         out_y = (in_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
  13         out_z = 0;
  14         return out;
  15 }
  16
  17 vector teamradar_texcoord_to_2dcoord(vector in)
  18 {
  19         vector out;
  20         in -= teamradar_origin3d_in_texcoord;
  21
  22         out = rotate(in, teamradar_angle * DEG2RAD);
  23         out_y = - out_y; // screen space is reversed
  24
  25         out = out * teamradar_size;
  26         out += teamradar_origin2d;
  27         return out;
  28 }
  29
  30 vector yinvert(vector v)
  31 {
  32         v_y = -v_y;
  33         return v;
  34 }
  35
  36 void draw_teamradar_background(float a)
  37 {
  38         if(a <= 0)
  39                 return;
  40
  41         R_BeginPolygon(minimapname, 0);
  42         R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', a);
  43         R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y - teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', a);
  44         R_PolygonVertex('1 0 0' * (teamradar_origin2d_x + teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', a);
  45         R_PolygonVertex('1 0 0' * (teamradar_origin2d_x - teamradar_size2d_x * 0.5) + '0 1 0' * (teamradar_origin2d_y + teamradar_size2d_y * 0.5), '0 0 0', '0 0 0', a);
  46         R_EndPolygon();
  47         R_BeginPolygon(minimapname, DRAWFLAG_ADDITIVE);
  48         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), '1 1 1', 1);
  49         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), '1 1 1', 1);
  50         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), '1 1 1', 1);
  51         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), '1 1 1', 1);
  52         R_EndPolygon();
  53 }
  54
  55 void(vector coord3d, vector pangles, vector rgb) draw_teamradar_player =
  56 {
  57         vector coord, rgb2;
  58
  59         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  60
  61         makevectors(pangles - '0 1 0' * teamradar_angle);
  62         v_forward_z = 0;
  63         v_forward = normalize(v_forward);
  64         v_forward_y *= -1.0;
  65         v_right_x = -v_forward_y;
  66         v_right_y = v_forward_x;
  67
  68         if(rgb == '1 1 1')
  69                 rgb2 = '0 0 0';
  70         else
  71                 rgb2 = '1 1 1';
  72
  73         R_BeginPolygon("", 0);
  74         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, 1);
  75         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, 1);
  76         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, 1);
  77         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, 1);
  78         R_EndPolygon();
  79
  80         R_BeginPolygon("", 0);
  81         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, 1);
  82         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, 1);
  83         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, 1);
  84         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, 1);
  85         R_EndPolygon();
  86 };
  87
  88 void draw_teamradar_icon(vector coord, float icon, float pingtime, vector rgb, float a)
  89 {
  90         float dt;
  91         vector v;
  92
  93         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
  94         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
  95         if(pingtime != 0)
  96         {
  97                 dt = time - pingtime;
  98                 if(dt > 1)
  99                         return;
 100                 v = '2 2 0' * teamradar_size * dt;
 101                 drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', 1 - dt, DRAWFLAG_ADDITIVE);
 102         }
 103 }
 104
 105 void() teamradar_view =
 106 {
 107         local float color;
 108         local vector rgb;
 109         local entity tm;
 110         float scale2d, normalsize, bigsize;
 111         float a;
 112
 113         if(!cvar("cl_teamradar"))
 114                 return;
 115
 116         color = GetPlayerColor(player_localentnum-1);
 117         rgb = GetTeamRGB(color);
 118
 119         scale2d = max(
 120                 mi_picmax_x - mi_picmin_x,
 121                 mi_picmax_y - mi_picmin_y
 122         );
 123
 124         teamradar_scale = cvar("cl_teamradar_scale");
 125         a = cvar("cl_teamradar_background_alpha");
 126         teamradar_angle = cvar("cl_teamradar_rotation") * 90;
 127
 128         // fix undefined cvars first
 129         if(!teamradar_scale)
 130                 teamradar_scale = 2048;
 131         if(!a)
 132                 a = 0.75;
 133
 134         if(!teamradar_angle)
 135                 teamradar_angle = input_angles_y - 90;
 136         teamradar_origin2d = '64 64 0';
 137         teamradar_size2d = '128 128 0';
 138
 139         normalsize = teamradar_size2d_x * scale2d / teamradar_scale;
 140         bigsize = teamradar_size2d_x * scale2d / vlen(mi_min - mi_max);
 141         if(bigsize > normalsize)
 142                 normalsize = bigsize;
 143         teamradar_size =
 144                   current_zoomfraction * bigsize
 145                 + (1 - current_zoomfraction) * normalsize;
 146         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
 147                   current_zoomfraction * (mi_min + mi_max) * 0.5
 148                 + (1 - current_zoomfraction) * pmove_org);
 149
 150         drawsetcliparea(
 151                 teamradar_origin2d_x - teamradar_size2d_x * 0.5,
 152                 teamradar_origin2d_y - teamradar_size2d_y * 0.5,
 153                 teamradar_size2d_x,
 154                 teamradar_size2d_y
 155         );
 156
 157         draw_teamradar_background(a);
 158         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
 159                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm.teamradar_time, tm.teamradar_color, tm.alpha);
 160         for(tm = gps_start; tm != world; tm = tm.chain)
 161                 draw_teamradar_player(tm.origin, tm.angles, rgb);
 162         draw_teamradar_player(pmove_org, input_angles, '1 1 1');
 163
 164         drawresetcliparea();
 165 };