data/qcsrc/client/sbar.qc

   1
   2 float last_weapon;
   3 float activeweapon;
   4 float weapontime;
   5
   6 float sb_lines; // still don't know what to do with that NOTE: check dp's sbar.c to see what that should be
   7
   8 vector sbar;
   9 float sbar_alpha_fg;
  10 float sbar_hudselector;
  11
  12 float ps_primary, ps_secondary;
  13 float ts_primary, ts_secondary;
  14
  15 void CSQC_kh_hud();
  16 void CSQC_ctf_hud();
  17 void MapVote_Draw();
  18 void Sbar_FinaleOverlay()
  19 {
  20         /*vector pos;
  21         pos_x = (vid_conwidth - 1)/2;
  22         pos_y = 16;
  23         pos_z = 0;*/
  24
  25         //drawpic(pos, "gfx/finale", '0 0 0', '1 1 1', sbar_alpha_fg, DRAWFLAG_NORMAL);
  26
  27         //drawstring(pos, "END", sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
  28         MapVote_Draw();
  29 }
  30
  31 void Sbar_DrawWeapon(float nr, float fade, float active)
  32 {
  33         vector pos, vsize, color;
  34         float value;
  35
  36         value = (active) ? 1 : 0.6;
  37         color_x = color_y = color_z = value;
  38
  39         if(sbar_hudselector == 1)
  40         {
  41                 // width = 300, height = 100
  42                 const float w_width = 32, w_height = 12, w_space = 2, font_size = 8;
  43
  44                 pos_x = (vid_conwidth - w_width * 9) * 0.5 + w_width * nr;
  45                 pos_y = (vid_conheight - w_height);
  46                 pos_z = 0;
  47                 vsize_x = w_width;
  48                 vsize_y = w_height;
  49                 vsize_z = 0;
  50                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  51                 pos_x += w_space;
  52                 pos_y += w_space;
  53                 vsize_x = font_size;
  54                 vsize_y = font_size;
  55                 vsize_z = 0;
  56                 drawstring(pos, ftos(nr+1), vsize, '1 1 0', sbar_alpha_fg, 0);
  57
  58         }
  59         else
  60         {
  61                 // width = 300, height = 100
  62                 const float w2_width = 300, w2_height = 100, w2_space = 10;
  63                 const float w2_scale = 0.4;
  64
  65                 pos_x = vid_conwidth - (w2_width + w2_space) * w2_scale;
  66                 pos_y = (w2_height + w2_space) * w2_scale * nr + w2_space;
  67                 pos_z = 0;
  68                 vsize_x = w2_width * w2_scale;
  69                 vsize_y = w2_height * w2_scale;
  70                 vsize_z = 0;
  71
  72                 drawpic(pos, strcat("gfx/inv_weapon", ftos(nr)), vsize, color, value * fade * sbar_alpha_fg, 0);
  73         }
  74 }
  75 void Sbar_DrawXNum (vector pos, float num, float digits, float lettersize, vector rgb, float a, float dflags)
  76 {
  77         float l, i;
  78         string str, tmp;
  79         float minus;
  80         vector vsize;
  81
  82         vsize_x = vsize_y = lettersize;
  83         vsize_z = 0;
  84
  85         if(num < 0)
  86         {
  87                 minus = true;
  88                 num = -num;
  89                 pos_x -= lettersize;
  90         } else
  91                 minus = false;
  92
  93         if(digits < 0)
  94         {
  95                 tmp = ftos(num);
  96                 digits = -digits;
  97                 str = strcat(substring("0000000000", 0, digits - strlen(tmp)), tmp);
  98         } else
  99                 str = ftos(num);
 100
 101         l = strlen(str);
 102
 103         if(l > digits)
 104         {
 105                 str = substring(str, l-digits, 999);
 106                 l = strlen(str);
 107         } else if(l < digits)
 108                 pos_x += (digits-l) * lettersize;
 109
 110         if(minus)
 111         {
 112                 drawpic(sbar + pos, "gfx/num_minus", vsize, rgb, a * sbar_alpha_fg, dflags);
 113                 pos_x += lettersize;
 114         }
 115
 116         for(i = 0; i < l; ++i)
 117         {
 118                 drawpic(sbar + pos, strcat("gfx/num_", substring(str, i, 1)), vsize, rgb, a * sbar_alpha_fg, dflags);
 119                 pos_x += lettersize;
 120         }
 121 }
 122
 123 void Cmd_Sbar_SetFields(float argc);
 124 void Sbar_InitScores()
 125 {
 126         float i, f;
 127
 128         ps_primary = ps_secondary = ts_primary = ts_secondary = -1;
 129         for(i = 0; i < MAX_SCORE; ++i)
 130         {
 131                 f = (scores_flags[i] & SFL_SORT_PRIO_MASK);
 132                 if(f == SFL_SORT_PRIO_PRIMARY)
 133                         ps_primary = i;
 134                 if(f == SFL_SORT_PRIO_SECONDARY)
 135                         ps_secondary = i;
 136         }
 137         if(ps_secondary == -1)
 138                 ps_secondary = ps_primary;
 139
 140         for(i = 0; i < MAX_TEAMSCORE; ++i)
 141         {
 142                 f = (teamscores_flags[i] & SFL_SORT_PRIO_MASK);
 143                 if(f == SFL_SORT_PRIO_PRIMARY)
 144                         ts_primary = i;
 145                 if(f == SFL_SORT_PRIO_SECONDARY)
 146                         ts_secondary = i;
 147         }
 148         if(ts_secondary == -1)
 149                 ts_secondary = ts_primary;
 150
 151         Cmd_Sbar_SetFields(0);
 152 }
 153
 154 void Sbar_UpdatePlayerPos(entity pl);
 155 float SetTeam(entity pl, float Team);
 156 //float lastpnum;
 157 void Sbar_UpdatePlayerTeams()
 158 {
 159         float Team;
 160         entity pl, tmp;
 161         float num;
 162
 163         num = 0;
 164         for(pl = players.sort_next; pl; pl = pl.sort_next)
 165         {
 166                 num += 1;
 167                 Team = GetPlayerColor(pl.sv_entnum);
 168                 if(SetTeam(pl, Team))
 169                 {
 170                         tmp = pl.sort_prev;
 171                         Sbar_UpdatePlayerPos(pl);
 172                         if(tmp)
 173                                 pl = tmp;
 174                         else
 175                                 pl = players.sort_next;
 176                 }
 177         }
 178         /*
 179         if(num != lastpnum)
 180                 print(strcat("PNUM: ", ftos(num), "\n"));
 181         lastpnum = num;
 182         */
 183 }
 184
 185 float Sbar_ComparePlayerScores(entity left, entity right)
 186 {
 187         float vl, vr;
 188         vl = GetPlayerColor(left.sv_entnum);
 189         vr = GetPlayerColor(right.sv_entnum);
 190
 191         if(vl > vr)
 192                 return true;
 193         if(vl < vr)
 194                 return false;
 195
 196         if(vl == COLOR_SPECTATOR)
 197         {
 198                 // FIRST the one with scores (spectators), THEN the ones without (downloaders)
 199                 // no other sorting
 200                 if(!left.gotscores && right.gotscores)
 201                         return true;
 202                 return false;
 203         }
 204
 205         vl = left.scores[ps_primary];
 206         vr = right.scores[ps_primary];
 207         if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
 208         {
 209                 if(vl == 0 && vr != 0)
 210                         return 1;
 211                 if(vl != 0 && vr == 0)
 212                         return 0;
 213         }
 214         if(vl > vr)
 215                 return IS_INCREASING(scores_flags[ps_primary]);
 216         if(vl < vr)
 217                 return IS_DECREASING(scores_flags[ps_primary]);
 218
 219         vl = left.scores[ps_secondary];
 220         vr = right.scores[ps_secondary];
 221         if(scores_flags[ps_secondary] & SFL_ZERO_IS_WORST)
 222         {
 223                 if(vl == 0 && vr != 0)
 224                         return 1;
 225                 if(vl != 0 && vr == 0)
 226                         return 0;
 227         }
 228         if(vl > vr)
 229                 return IS_INCREASING(scores_flags[ps_secondary]);
 230         if(vl < vr)
 231                 return IS_DECREASING(scores_flags[ps_secondary]);
 232
 233         return false;
 234 }
 235
 236 void Sbar_UpdatePlayerPos(entity player)
 237 {
 238         for(other = player.sort_next; other && Sbar_ComparePlayerScores(player, other); other = player.sort_next)
 239         {
 240                 SORT_SWAP(player, other);
 241         }
 242         for(other = player.sort_prev; other != players && Sbar_ComparePlayerScores(other, player); other = player.sort_prev)
 243         {
 244                 SORT_SWAP(other, player);
 245         }
 246 }
 247
 248 float Sbar_CompareTeamScores(entity left, entity right)
 249 {
 250         float vl, vr;
 251
 252         if(left.team == COLOR_SPECTATOR)
 253                 return 1;
 254         if(right.team == COLOR_SPECTATOR)
 255                 return 0;
 256
 257         vl = left.teamscores[ts_primary];
 258         vr = right.teamscores[ts_primary];
 259         if(vl > vr)
 260                 return IS_INCREASING(teamscores_flags[ts_primary]);
 261         if(vl < vr)
 262                 return IS_DECREASING(teamscores_flags[ts_primary]);
 263
 264         vl = left.teamscores[ts_secondary];
 265         vr = right.teamscores[ts_secondary];
 266         if(vl > vr)
 267                 return IS_INCREASING(teamscores_flags[ts_secondary]);
 268         if(vl < vr)
 269                 return IS_DECREASING(teamscores_flags[ts_secondary]);
 270
 271         return false;
 272 }
 273
 274 void Sbar_UpdateTeamPos(entity Team)
 275 {
 276         for(other = Team.sort_next; other && Sbar_CompareTeamScores(Team, other); other = Team.sort_next)
 277         {
 278                 SORT_SWAP(Team, other);
 279         }
 280         for(other = Team.sort_prev; other != teams && Sbar_CompareTeamScores(other, Team); other = Team.sort_prev)
 281         {
 282                 SORT_SWAP(other, Team);
 283         }
 284 }
 285
 286 void Cmd_Sbar_Help(float argc)
 287 {
 288         print("You can modify the scoreboard using the\n");
 289         print("^3|---------------------------------------------------------------|\n");
 290         print("^1 TO BE DONE\n");
 291         print("Usage:\n");
 292         print("^2sbar_columns_set default\n");
 293         print("^2sbar_columns_set ^7filed1 field2 ...\n");
 294         print("The following field names are recognized (case INsensitive):\n");
 295         print("You can use a ^3|^7 to start the right-aligned fields.\n");
 296
 297         print("^3name^7 or ^3nick^7             Name of a player\n");
 298         print("^3ping^7                     Ping time\n\n");
 299         print("^3kd^7 or ^3kdr^7 or ^3kdratio^7 or ^3k/d\n");
 300         print("                         The kill-death ratio\n");
 301
 302         print("Before a field you can put a + or - sign, then a comma separated list\n");
 303         print("of game types, then a slash, to make the field show up only in these\n");
 304         print("or in all but these game types.\n");
 305
 306         local float i;
 307         print("Additional columns:\n");
 308         for(i = 0; i < MAX_SCORE; ++i)
 309         {
 310                 if(scores_label[i] != "")
 311                         print(strcat(scores_label[i], "\n"));
 312         }
 313 }
 314
 315 #define MIN_NAMELEN 24
 316 #define MAX_NAMELEN 24
 317
 318 string Sbar_DefaultColumnLayout()
 319 {
 320         return "ping pl name | -ctf,kh/kills -ctf,kh/deaths +lms/lives +lms/rank +kh,ctf/caps +kh/pushes +kh/destroyed -lms/score";
 321 }
 322
 323 void Cmd_Sbar_SetFields(float argc)
 324 {
 325         float i, j, slash;
 326         string str, pattern, subpattern;
 327         float digit;
 328         float have_name, have_primary, have_secondary, have_separator;
 329         float missing;
 330
 331         // TODO: re enable with gametype dependant cvars?
 332         if(argc < 2) // no arguments provided
 333                 argc = tokenizebyseparator(strcat("x ", cvar_string("sbar_columns")), " ");
 334
 335         if(argc < 2)
 336                 argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 337
 338         if(argc == 2)
 339         {
 340                 if(argv(1) == "default")
 341                         argc = tokenizebyseparator(strcat("x ", Sbar_DefaultColumnLayout()), " ");
 342                 else if(argv(1) == "all")
 343                 {
 344                         string s;
 345                         s = "ping name |";
 346                         for(i = 0; i < MAX_SCORE; ++i)
 347                         {
 348                                 if(i != ps_primary)
 349                                 if(i != ps_secondary)
 350                                 if(scores_label[i] != "")
 351                                         s = strcat(s, " ", scores_label[i]);
 352                         }
 353                         if(ps_secondary != ps_primary)
 354                                 s = strcat(s, " ", scores_label[ps_secondary]);
 355                         s = strcat(s, " ", scores_label[ps_primary]);
 356                         argc = tokenizebyseparator(strcat("x ", s), " ");
 357                 }
 358         }
 359
 360
 361         argc = min(MAX_SBAR_FIELDS, argc);
 362         sbar_num_fields = 0;
 363
 364         drawfont = sbar_font;
 365         digit = stringwidth("0123456789", FALSE) / 10;
 366
 367         subpattern = strcat(",", GametypeNameFromType(gametype), ",");
 368
 369         argc = min(argc-1, MAX_SBAR_FIELDS-1);
 370         for(i = 0; i < argc; ++i)
 371         {
 372                 str = argv(i+1);
 373
 374                 slash = strstrofs(str, "/", 0);
 375                 if(slash >= 0)
 376                 {
 377                         pattern = substring(str, 0, slash);
 378                         str = substring(str, slash + 1, strlen(str) - (slash + 1));
 379
 380                         if(substring(pattern, 0, 1) == "-")
 381                         {
 382                                 pattern = substring(pattern, 1, strlen(pattern) - 1);
 383                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
 384                                         continue;
 385                         }
 386                         else
 387                         {
 388                                 if(substring(pattern, 0, 1) == "+")
 389                                         pattern = substring(pattern, 1, strlen(pattern) - 1);
 390                                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
 391                                         continue;
 392                         }
 393                 }
 394
 395                 strunzone(sbar_title[sbar_num_fields]);
 396                 sbar_title[sbar_num_fields] = strzone(str);
 397                 sbar_size[sbar_num_fields] = stringwidth(str, FALSE);
 398                 str = strtolower(str);
 399
 400                 if(str == "ping") {
 401                         sbar_field[sbar_num_fields] = SP_PING;
 402                 } else if(str == "pl") {
 403                         sbar_field[sbar_num_fields] = SP_PL;
 404                 } else if(str == "kd" || str == "kdr" || str == "kdratio" || str == "k/d") {
 405                         sbar_field[sbar_num_fields] = SP_KDRATIO;
 406                 } else if(str == "name" || str == "nick") {
 407                         sbar_field[sbar_num_fields] = SP_NAME;
 408                         sbar_size[sbar_num_fields] = MIN_NAMELEN; // minimum size? any use?
 409                         have_name = 1;
 410                 } else if(str == "|") {
 411                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 412                         have_separator = 1;
 413                 } else {
 414                         for(j = 0; j < MAX_SCORE; ++j)
 415                                 if(str == strtolower(scores_label[j]))
 416                                         goto found; // sorry, but otherwise fteqcc -O3 miscompiles this and warns about "unreachable code"
 417 :notfound
 418                         print(strcat("^1Error:^7 Unknown score field: '", str, "'\n"));
 419                         continue;
 420 :found
 421                         sbar_field[sbar_num_fields] = j;
 422                         if(j == ps_primary)
 423                                 have_primary = 1;
 424                         if(j == ps_secondary)
 425                                 have_secondary = 1;
 426                 }
 427                 ++sbar_num_fields;
 428         }
 429
 430         if(scores_flags[ps_primary] & SFL_ALLOW_HIDE)
 431                 have_primary = 1;
 432         if(scores_flags[ps_secondary] & SFL_ALLOW_HIDE)
 433                 have_secondary = 1;
 434         if(ps_primary == ps_secondary)
 435                 have_secondary = 1;
 436         missing = !have_primary + !have_secondary + !have_separator + !have_name;
 437
 438         if(sbar_num_fields+missing < MAX_SBAR_FIELDS)
 439         {
 440                 if(!have_name)
 441                 {
 442                         strunzone(sbar_title[sbar_num_fields]);
 443                         for(i = sbar_num_fields; i > 0; --i)
 444                         {
 445                                 sbar_title[i] = sbar_title[i-1];
 446                                 sbar_size[i] = sbar_size[i-1];
 447                                 sbar_field[i] = sbar_field[i-1];
 448                         }
 449                         sbar_title[0] = strzone("name");
 450                         sbar_field[0] = SP_NAME;
 451                         sbar_size[0] = MIN_NAMELEN; // minimum size? any use?
 452                         ++sbar_num_fields;
 453                         print("fixed missing field 'name'\n");
 454
 455                         if(!have_separator)
 456                         {
 457                                 strunzone(sbar_title[sbar_num_fields]);
 458                                 for(i = sbar_num_fields; i > 1; --i)
 459                                 {
 460                                         sbar_title[i] = sbar_title[i-1];
 461                                         sbar_size[i] = sbar_size[i-1];
 462                                         sbar_field[i] = sbar_field[i-1];
 463                                 }
 464                                 sbar_title[1] = strzone("|");
 465                                 sbar_field[1] = SP_SEPARATOR;
 466                                 sbar_size[1] = stringwidth("|", FALSE);
 467                                 ++sbar_num_fields;
 468                                 print("fixed missing field '|'\n");
 469                         }
 470                 }
 471                 else if(!have_separator)
 472                 {
 473                         strunzone(sbar_title[sbar_num_fields]);
 474                         sbar_title[sbar_num_fields] = strzone("|");
 475                         sbar_size[sbar_num_fields] = stringwidth("|", FALSE);
 476                         sbar_field[sbar_num_fields] = SP_SEPARATOR;
 477                         ++sbar_num_fields;
 478                         print("fixed missing field '|'\n");
 479                 }
 480
 481                 if(!have_secondary)
 482                 {
 483                         strunzone(sbar_title[sbar_num_fields]);
 484                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_secondary]);
 485                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 486                         sbar_field[sbar_num_fields] = ps_secondary;
 487                         ++sbar_num_fields;
 488                         print("fixed missing field '", scores_label[ps_secondary], "'\n");
 489                 }
 490
 491                 if(!have_primary)
 492                 {
 493                         strunzone(sbar_title[sbar_num_fields]);
 494                         sbar_title[sbar_num_fields] = strzone(scores_label[ps_primary]);
 495                         sbar_size[sbar_num_fields] = stringwidth(sbar_title[sbar_num_fields], FALSE);
 496                         sbar_field[sbar_num_fields] = ps_primary;
 497                         ++sbar_num_fields;
 498                         print("fixed missing field '", scores_label[ps_primary], "'\n");
 499                 }
 500         }
 501
 502         sbar_field[sbar_num_fields] = SP_END;
 503 }
 504
 505 // MOVEUP::
 506 vector sbar_field_rgb;
 507 string Sbar_GetField(entity pl, float field)
 508 {
 509         float tmp, num, denom, f;
 510         string str;
 511         sbar_field_rgb = '1 1 1';
 512         switch(field)
 513         {
 514                 case SP_PING:
 515                         if not(pl.gotscores)
 516                                 return "\x8D\x8D\x8D"; // >>> sign
 517                         str = getplayerkey(pl.sv_entnum, "ping");
 518                         if(str == "0")
 519                                 return "N/A";
 520                         tmp = max(0, min(220, stof(str)-80)) / 220;
 521                         sbar_field_rgb = '1 1 1' - '0 1 1'*tmp;
 522                         return str;
 523
 524                 case SP_PL:
 525                         if not(pl.gotscores)
 526                                 return "N/A";
 527                         str = getplayerkey(pl.sv_entnum, "pl");
 528                         if(str == "0")
 529                                 return "";
 530                         tmp = bound(0, stof(str), 20) / 20; // 20% is REALLY BAD pl
 531                         sbar_field_rgb = '1 0.5 0.5' - '0 0.5 0.5'*tmp;
 532                         return str;
 533
 534                 case SP_NAME:
 535                         return getplayerkey(pl.sv_entnum, "name");
 536
 537                 case SP_KDRATIO:
 538                         num = pl.(scores[SP_KILLS]);
 539                         denom = pl.(scores[SP_DEATHS]);
 540
 541                         if(denom == 0) {
 542                                 sbar_field_rgb = '0 1 0';
 543                                 str = ftos(num);
 544                         } else if(num <= 0) {
 545                                 sbar_field_rgb = '1 0 0';
 546                                 str = ftos(num/denom);
 547                         } else
 548                                 str = ftos(num/denom);
 549
 550                         tmp = strstrofs(str, ".", 0);
 551                         if(tmp > 0)
 552                                 str = substring(str, 0, tmp+2);
 553                         return str;
 554
 555                 default:
 556                         tmp = pl.(scores[field]);
 557                         f = scores_flags[field];
 558                         if(field == ps_primary)
 559                                 sbar_field_rgb = '1 1 0';
 560                         else if(field == ps_secondary)
 561                                 sbar_field_rgb = '0 1 1';
 562                         else
 563                                 sbar_field_rgb = '1 1 1';
 564                         if(!tmp)
 565                                 if(f & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME))
 566                                         return "";
 567                         if(f & SFL_RANK)
 568                         {
 569                                 str = ftos(floor(tmp + 0.5));
 570                                 num = strlen(str);
 571                                 if((num >= 2) && (substring(str, num - 2, 1) == "1"))
 572                                         return strcat(str, "th");
 573                                 else if(substring(str, num - 1, 1) == "1")
 574                                         return strcat(str, "st");
 575                                 else if(substring(str, num - 1, 1) == "2")
 576                                         return strcat(str, "nd");
 577                                 else if(substring(str, num - 1, 1) == "3")
 578                                         return strcat(str, "rd");
 579                                 else
 580                                         return strcat(str, "th");
 581                         }
 582                         else if(f & SFL_TIME)
 583                         {
 584                                 return mmsss(tmp);
 585                         }
 586                         return ftos(tmp);
 587         }
 588         //return "error";
 589 }
 590
 591 // shamelessly stolen from menu QC :P <- as if I would steal YOUR code pfft ;)
 592 float textLengthUpToWidth(string theText, float maxWidth, float handleColors)
 593 {
 594         // STOP.
 595         // The following function is SLOW.
 596         // For your safety and for the protection of those around you...
 597         // DO NOT CALL THIS AT HOME.
 598         // No really, don't.
 599         if(stringwidth(theText, handleColors) <= maxWidth)
 600                 return strlen(theText); // yeah!
 601
 602         // binary search for right place to cut string
 603         float left, right, middle; // this always works
 604         left = 0;
 605         right = strlen(theText); // this always fails
 606         do
 607         {
 608                 middle = floor((left + right) / 2);
 609                 if(stringwidth(substring(theText, 0, middle), handleColors) <= maxWidth)
 610                         left = middle;
 611                 else
 612                         right = middle;
 613         }
 614         while(left < right - 1);
 615
 616         // NOTE: when color codes are involved, this binary search is,
 617         // mathematically, BROKEN. However, it is obviously guaranteed to
 618         // terminate, as the range still halves each time - but nevertheless, it is
 619         // guaranteed that it finds ONE valid cutoff place (where "left" is in
 620         // range, and "right" is outside).
 621
 622         return left;
 623 }
 624 string textShortenToWidth(string theText, float maxWidth, float handleColors)
 625 {
 626         if(stringwidth(theText, handleColors) <= maxWidth)
 627                 return theText;
 628         else
 629                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - stringwidth("...", handleColors), handleColors)), "...");
 630 }
 631
 632 float xmin, xmax, ymin, ymax, sbwidth, sbheight;
 633
 634 void Sbar_PrintScoreboardItem(vector pos, entity pl, float is_self)
 635 {
 636         vector tmp;
 637         string str;
 638         float i, field, len;
 639         float is_spec;
 640         is_spec = (GetPlayerColor(pl.sv_entnum) == COLOR_SPECTATOR);
 641
 642         // Layout:
 643         tmp_z = 0;
 644         if(is_self)
 645         {
 646                 tmp_x = sbwidth;
 647                 tmp_y = sbar_fontsize_y;
 648                 drawfill(pos - '1 1 0', tmp + '2 2 0', '1 1 1', 0.3, DRAWFLAG_NORMAL);
 649         }
 650         tmp_y = 0;
 651
 652         for(i = 0; i < sbar_num_fields; ++i)
 653         {
 654                 field = sbar_field[i];
 655                 if(field == SP_SEPARATOR)
 656                         break;
 657
 658                 if(is_spec && field != SP_NAME && field != SP_PING) {
 659                         pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 660                         continue;
 661                 }
 662                 str = Sbar_GetField(pl, field);
 663
 664                 if(field == SP_NAME)
 665                 {
 666                         float realsize;
 667                         float j;
 668                         realsize = sbar_size[i];
 669                         if(i+1 < sbar_num_fields)
 670                                 if(sbar_field[i+1] == SP_SEPARATOR)
 671                                 {
 672                                         realsize = (xmax - xmin) / sbar_fontsize_x;
 673                                         for(j = 0; j < sbar_num_fields; ++j) if(j != i) if(sbar_field[j] != SP_SEPARATOR)
 674                                                 realsize -= sbar_size[j] + 1;
 675                                         realsize += 1;
 676                                 }
 677                         str = textShortenToWidth(str, realsize, TRUE);
 678                 }
 679                 len = stringwidth(str, TRUE);
 680
 681                 if(sbar_size[i] < len)
 682                         sbar_size[i] = len;
 683
 684                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 685
 686                 if(field == SP_NAME) {
 687                         tmp_x = sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 688                         drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 689                 } else {
 690                         tmp_x = len*sbar_fontsize_x + sbar_fontsize_x;
 691                         drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 692                 }
 693         }
 694
 695         if(sbar_field[i] == SP_SEPARATOR)
 696         {
 697                 pos_x = xmax;
 698                 for(i = sbar_num_fields-1; i > 0; --i)
 699                 {
 700                         field = sbar_field[i];
 701                         if(field == SP_SEPARATOR)
 702                                 break;
 703
 704                         if(is_spec && field != SP_NAME && field != SP_PING) {
 705                                 pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 706                                 continue;
 707                         }
 708
 709                         str = Sbar_GetField(pl, field);
 710
 711                         if(field == SP_NAME)
 712                                 str = textShortenToWidth(str, sbar_size[i], TRUE);
 713                         len = stringwidth(str, TRUE);
 714
 715                         if(sbar_size[i] < len)
 716                                 sbar_size[i] = len;
 717
 718                         if(field == SP_NAME) {
 719                                 tmp_x = sbar_fontsize_x*len; // left or right aligned? let's put it right...
 720                                 drawcolorcodedstring(pos - tmp, str, sbar_fontsize, 1, DRAWFLAG_NORMAL);
 721                         } else {
 722                                 tmp_x = sbar_fontsize_x*len; //strlen(str);
 723                                 drawstring(pos - tmp, str, sbar_fontsize, sbar_field_rgb, 1, DRAWFLAG_NORMAL);
 724                         }
 725                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 726                 }
 727         }
 728 }
 729
 730 float lastpingstime;
 731 void Sbar_DrawScoreboard()
 732 {
 733         //float xmin, ymin, xmax, ymax;
 734         vector rgb, pos, tmp, sbar_save;
 735         entity pl, tm;
 736         float specs, i;
 737         float center_x;
 738
 739         if(time > lastpingstime + 10)
 740         {
 741                 localcmd("pings\n");
 742                 lastpingstime = time;
 743         }
 744
 745         xmin = vid_conwidth / 5;
 746         ymin = 20;
 747
 748         xmax = vid_conwidth - xmin;
 749         ymax = vid_conheight - 0.2*vid_conheight;
 750
 751         sbwidth = xmax - xmin;
 752         sbheight = ymax - ymin;
 753
 754         center_x = xmin + 0.5*sbwidth;
 755
 756         //Sbar_UpdateFields();
 757
 758         // Initializes position
 759         //pos_x = xmin;
 760         pos_y = ymin;
 761         pos_z = 0;
 762
 763         // Heading
 764         drawfont = sbar_bigfont;
 765         pos_x = center_x - stringwidth("Scoreboard", TRUE)*0.5*24;
 766         drawstring(pos, "Scoreboard", '24 24 0', '1 1 1', 1, DRAWFLAG_NORMAL);
 767         pos_x = xmin;
 768         pos_y += 24 + 4;
 769
 770         // Titlebar background:
 771         tmp_x = sbwidth;
 772         tmp_y = sbar_fontsize_y;
 773         drawfill(pos - '1 1 0', tmp + '2 2 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
 774
 775         drawfont = sbar_font;
 776
 777         for(i = 0; i < sbar_num_fields; ++i)
 778         {
 779                 if(sbar_field[i] == SP_SEPARATOR)
 780                         break;
 781                 drawstring(pos, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 782                 pos_x += sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 783         }
 784
 785         if(sbar_field[i] == SP_SEPARATOR)
 786         {
 787                 pos_x = xmax + sbar_fontsize_x;
 788                 tmp_y = tmp_z = 0;
 789                 for(i = sbar_num_fields-1; i > 0; --i)
 790                 {
 791                         if(sbar_field[i] == SP_SEPARATOR)
 792                                 break;
 793
 794                         pos_x -= sbar_fontsize_x*sbar_size[i] + sbar_fontsize_x;
 795                         /**
 796                          * FTEQCC BUG!
 797                          * Using the following line will fuck it all up:
 798                          **
 799                          * tmp_x = sbar_size[i] - strlen(sbar_title[i])*8;
 800                          */
 801                         tmp_x = sbar_fontsize_x*sbar_size[i];
 802                         tmp_x -= stringwidth(sbar_title[i], FALSE)*sbar_fontsize_x;
 803                         drawstring(pos + tmp, sbar_title[i], sbar_fontsize, '1 1 1', 1, DRAWFLAG_NORMAL);
 804                 }
 805         }
 806
 807         pos_x = xmin;
 808         pos_y += 1.5 * sbar_fontsize_y;
 809
 810         sbar_save = sbar;
 811         sbar = '0 0 0';
 812
 813         if(teamplay)
 814         {
 815                 //for(tm = sortedTeams.sort_next; tm; tm = tm.sort_next)
 816                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 817                 {
 818                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
 819                                 continue;
 820
 821                         rgb = GetTeamRGB(tm.team);
 822
 823                         pos_x = xmin;
 824
 825                         Sbar_DrawXNum(
 826                                 pos - '6.5 0 0' * sbar_fontsize_y,
 827                                 tm.(teamscores[ts_primary]),
 828                                 4, sbar_fontsize_y * 1.5, rgb, 1, DRAWFLAG_NORMAL);
 829
 830                         if(ts_primary != ts_secondary)
 831                         Sbar_DrawXNum(
 832                                 pos - '4.5 0 0' * sbar_fontsize_y + '0 1.5 0' * sbar_fontsize_y,
 833                                 tm.(teamscores[ts_secondary]),
 834                                 4, sbar_fontsize_y * 1, rgb, 1, DRAWFLAG_NORMAL);
 835
 836                         specs = tm.team_size;
 837
 838                         if(specs < 2)
 839                                 specs = 2;
 840
 841                         tmp_x = sbwidth;
 842                         tmp_y = 1.25 * sbar_fontsize_y * specs;
 843                         drawfill(pos - '1 1 0', tmp + '2 0 0', rgb, 0.2, DRAWFLAG_NORMAL);
 844
 845                         for(pl = players.sort_next; pl; pl = pl.sort_next)
 846                         {
 847                                 if(pl.team != tm.team)
 848                                         continue;
 849                                 Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 850                                 pos_y += 1.25 * sbar_fontsize_y;
 851                                 tmp_y -= 1.25 * sbar_fontsize_y;
 852                         }
 853                         pos_y += tmp_y + 1.5 * sbar_fontsize_y;
 854                 }
 855                 // rgb := tempvector :)
 856                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 857                 pos_y += 3 * sbar_fontsize_y;
 858                 specs = 0;
 859                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 860                 {
 861                         if(pl.team != COLOR_SPECTATOR)
 862                                 continue;
 863                         //drawcolorcodedstring(pos, getplayerkey(pl.sb_player, "name"), '8 8 0', 1, 0);
 864                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 865                         pos += '0 1.25 0' * sbar_fontsize_y;
 866                         ++specs;
 867                 }
 868
 869                 if(specs)
 870                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 871         } else {
 872                 pos_x = xmin;
 873                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 874                 {
 875                         if(pl.team == COLOR_SPECTATOR)
 876                                 continue;
 877                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 878                         pos_y += 1.25 * sbar_fontsize_y;
 879                         tmp_y -= 1.25 * sbar_fontsize_y;
 880                 }
 881
 882                 // rgb := tempvector :)
 883                 rgb = pos + '0 1.5 0' * sbar_fontsize_y;
 884                 pos_y += 3 * sbar_fontsize_y;
 885                 specs = 0;
 886                 for(pl = players.sort_next; pl; pl = pl.sort_next)
 887                 {
 888                         if(pl.team != COLOR_SPECTATOR)
 889                                 continue;
 890                         Sbar_PrintScoreboardItem(pos, pl, (pl.sv_entnum == player_localentnum - 1));
 891                         pos += '0 1.25 0' * sbar_fontsize_y;
 892                         ++specs;
 893                 }
 894
 895                 if(specs)
 896                         drawstring(rgb, "Spectators", sbar_fontsize, '1 1 1', 1, 0);
 897         }
 898
 899         string str;
 900         float tl, fl;
 901         str = strcat("playing on ^2", shortmapname, "^7");
 902         tl = getstatf(STAT_TIMELIMIT);
 903         fl = getstatf(STAT_FRAGLIMIT);
 904         if(gametype == GAME_LMS)
 905         {
 906                 if(tl > 0)
 907                         str = strcat(str, " for up to ^1", ftos(tl), " minutes^7");
 908         }
 909         else
 910         {
 911                 if(tl > 0)
 912                         str = strcat(str, " for ^1", ftos(tl), " minutes^7");
 913                 if(fl > 0)
 914                 {
 915                         if(tl > 0)
 916                                 str = strcat(str, " or");
 917                         str = strcat(str, " until ^3", ftos(fl));
 918                         if(scores_label[ps_primary] == "score")
 919                                 str = strcat(str, " points^7");
 920                         else
 921                                 str = strcat(str, " ", scores_label[ps_primary]);
 922                 }
 923         }
 924
 925         pos_y += 1.5 * sbar_fontsize_y;
 926         drawcolorcodedstring(pos + '0.5 0 0' * (sbwidth - sbar_fontsize_x * stringwidth(str, TRUE)), str, sbar_fontsize, 0.8, 0);
 927
 928         sbar = sbar_save;
 929 }
 930
 931 string MakeRaceString(float cp, float mytime, float histime, float lapdelta, string hisname)
 932 {
 933         string col;
 934         string timestr;
 935         string cpname;
 936         string lapstr;
 937         lapstr = "";
 938
 939         if(histime == 0) // goal hit
 940         {
 941                 if(mytime > 0)
 942                 {
 943                         timestr = strcat("+", ftos_decimals(+mytime, 1));
 944                         col = "^1";
 945                 }
 946                 else if(mytime == 0)
 947                 {
 948                         timestr = "+0.0";
 949                         col = "^3";
 950                 }
 951                 else
 952                 {
 953                         timestr = strcat("-", ftos_decimals(-mytime, 1));
 954                         col = "^2";
 955                 }
 956
 957                 if(lapdelta > 0)
 958                 {
 959                         lapstr = strcat(" (-", ftos(lapdelta), "L)");
 960                         col = "^2";
 961                 }
 962                 else if(lapdelta < 0)
 963                 {
 964                         lapstr = strcat(" (+", ftos(-lapdelta), "L)");
 965                         col = "^1";
 966                 }
 967         }
 968         else if(histime > 0) // anticipation
 969         {
 970                 if(mytime >= histime)
 971                         timestr = strcat("+", ftos_decimals(mytime - histime, 1));
 972                 else
 973                         timestr = mmsss(histime * 10);
 974                 col = "^3";
 975         }
 976         else
 977                 col = "^7";
 978
 979         if(cp)
 980                 cpname = strcat("Intermediate ", ftos(cp));
 981         else
 982                 cpname = "Finish line";
 983
 984         if(histime < 0)
 985                 return strcat(col, cpname);
 986         else if(hisname == "")
 987                 return strcat(col, cpname, " (", timestr, ")");
 988         else
 989                 return strcat(col, cpname, " (", timestr, " ", strcat(hisname, col, lapstr), ")");
 990 }
 991
 992 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
 993 {
 994 }
 995
 996 void Sbar_Score(float margin)
 997 {
 998         float timelimit, timeleft, minutes, seconds, distribution, myplace, score;
 999         vector sbar_save, place;
1000         entity tm, pl, me;
1001         sbar_save = sbar;
1002
1003         myteam = GetPlayerColor(player_localentnum - 1);
1004
1005         sbar_y = vid_conheight - (32+12);
1006         sbar_x -= margin;
1007
1008         place = '-48 -12 0';
1009         if(teamplay)
1010         {
1011                 // Layout:
1012                 //
1013                 //   team1 team3 team4
1014                 //
1015                 //         TEAM2
1016                 //for(i = 0; i < 4; ++i)
1017                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
1018                 {
1019                         if(tm.team == COLOR_SPECTATOR || !tm.team_size) // no players? don't display
1020                                 continue;
1021                         // -32*4 = -128
1022                         score = tm.(teamscores[ts_primary]);
1023                         if(tm.team == myteam)
1024                                 Sbar_DrawXNum('-128 0 0', score, 4, 32, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1025                         else
1026                         {
1027                                 Sbar_DrawXNum(place, score, 4, 12, GetTeamRGB(tm.team), 1, DRAWFLAG_NORMAL);
1028                                 place_x -= 4*12;
1029                         }
1030                 }
1031         } else {
1032                 // me vector := [team/connected frags id]
1033                 myplace = 0;
1034                 for(me = players.sort_next; me; me = me.sort_next)
1035                 {
1036                         if(me.team != COLOR_SPECTATOR)
1037                                 ++myplace;
1038                         if(me.sv_entnum == player_localentnum - 1)
1039                                 break;
1040                 }
1041                 pl = players;
1042                 if(pl == me)
1043                         pl = pl.sort_next;
1044
1045                 if(pl) {
1046                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
1047                 } else
1048                         distribution = 0;
1049
1050                 if(myplace == 1)
1051                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1052                 else if(myplace == 2)
1053                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1054                 else
1055                         Sbar_DrawXNum('-36 -12 0', myplace, 3, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1056
1057                 score = me.(scores[ps_primary]);
1058                 if(distribution >= 0)
1059                 {
1060                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 1', 1, DRAWFLAG_NORMAL);
1061                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 1', 1, DRAWFLAG_NORMAL);
1062                 } else if(distribution >= -5)
1063                 {
1064                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 1 0', 1, DRAWFLAG_NORMAL);
1065                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 1 0', 1, DRAWFLAG_NORMAL);
1066                 } else {
1067                         Sbar_DrawXNum('-84 -12 0', distribution, 4, 12, ' 1 0 0', 1, DRAWFLAG_NORMAL);
1068                         Sbar_DrawXNum('-128 0 0', score, 4, 32, '1 0 0', 1, DRAWFLAG_NORMAL);
1069                 }
1070         }
1071         timelimit = getstatf(STAT_TIMELIMIT);
1072         if(timelimit)
1073         {
1074                 timeleft = max(0, timelimit * 60 - time);
1075                 minutes = floor(timeleft / 60);
1076                 seconds = floor(timeleft - minutes*60);
1077                 if(minutes >= 5)
1078                 {
1079                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1080                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1081                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1082                 } else if(minutes >= 1)
1083                 {
1084                         Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1085                         drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 0', sbar_alpha_fg, 0);
1086                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 0', 1, DRAWFLAG_NORMAL);
1087                 } else {
1088                         Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 0 0', 1, DRAWFLAG_NORMAL);
1089                 }
1090         } else {
1091                 minutes = floor(time / 60);
1092                 seconds = floor(time - minutes*60);
1093                 Sbar_DrawXNum('-72 32 0', minutes, 3, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1094                 drawpic(sbar + '-36 32 0', "gfx/num_colon", '12 12 0', '1 1 1', sbar_alpha_fg, 0);
1095                 Sbar_DrawXNum('-24 32 0', seconds, -2, 12, '1 1 1', 1, DRAWFLAG_NORMAL);
1096         }
1097
1098         if(gametype == GAME_RACE)
1099         {
1100                 drawfont = sbar_bigfont;
1101                 float a;
1102                 vector m;
1103                 string s, forcetime;
1104
1105                 m = '0.5 0 0' * vid_conwidth + '0 0.25 0' * vid_conheight;
1106
1107                 if(race_checkpointtime)
1108                 {
1109
1110                         a = bound(0, 2 - (time - race_checkpointtime), 1);
1111                         s = "";
1112                         forcetime = "";
1113                         if(a > 0) // just hit a checkpoint?
1114                         {
1115                                 if(race_time && race_previousbesttime)
1116                                         s = MakeRaceString(race_checkpoint, race_time / 10 - race_previousbesttime / 10, 0, 0, race_previousbestname);
1117                                 else
1118                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
1119                                 if(race_time)
1120                                         forcetime = mmsss(race_time);
1121                         }
1122                         else
1123                         {
1124                                 if(race_laptime && race_nextbesttime)
1125                                 {
1126                                         a = bound(0, 2 - ((race_laptime + race_nextbesttime/10) - time), 1);
1127                                         if(a > 0) // next one?
1128                                         {
1129                                                 s = MakeRaceString(race_nextcheckpoint, time - race_laptime, race_nextbesttime / 10, 0, race_nextbestname);
1130                                         }
1131                                 }
1132                         }
1133
1134                         if(s != "" && a > 0)
1135                         {
1136                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1137                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1138                         }
1139
1140                         if(forcetime != "")
1141                         {
1142                                 float sz;
1143                                 a = bound(0, 1 - 2 * (time - race_checkpointtime), 1);
1144                                 sz = 1.2 / (a + 0.2);
1145                                 drawstring(m - '0 0 0' - '0 16 0' * (sz - 1) - '16 0 0' * sz * stringwidth(forcetime, FALSE), forcetime, '32 32 0' * sz, '1 1 1', sbar_alpha_fg * a, 0);
1146                                 a = 1 - a;
1147                         }
1148                         else
1149                                 a = 1;
1150
1151                         if(race_laptime)
1152                         {
1153                                 s = mmsss(10*(time - race_laptime));
1154                                 drawstring(m - '0 0 0' - '16 0 0' * stringwidth(s, FALSE), s, '32 32 0', '1 1 1', sbar_alpha_fg * a, 0);
1155                         }
1156                 }
1157                 else
1158                 {
1159                         if(race_mycheckpointtime)
1160                         {
1161                                 a = bound(0, 2 - (time - race_mycheckpointtime), 1);
1162                                 s = MakeRaceString(race_mycheckpoint, race_mycheckpointdelta / 10, -!race_mycheckpointenemy, race_mycheckpointlapsdelta, race_mycheckpointenemy);
1163                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1164                                 drawcolorcodedstring(m - '0 16 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1165                         }
1166                         if(race_othercheckpointtime && race_othercheckpointenemy != "")
1167                         {
1168                                 a = bound(0, 2 - (time - race_othercheckpointtime), 1);
1169                                 s = MakeRaceString(race_othercheckpoint, -race_othercheckpointdelta / 10, -!race_othercheckpointenemy, race_othercheckpointlapsdelta, race_othercheckpointenemy);
1170                                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1171                                 drawcolorcodedstring(m - '0 0 0' - '8 0 0' * stringwidth(s, TRUE), s, '16 16 0', sbar_alpha_fg * a, 0);
1172                         }
1173                 }
1174
1175                 drawfont = sbar_font;
1176         }
1177
1178         sbar = sbar_save;
1179 }
1180
1181 void Sbar_MiniscoreItem(vector pos, entity pl, float is_self)
1182 {
1183         float x, score;
1184         pos_x += 72;
1185
1186         if(teamplay)
1187                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(pl.team)*0.5, 1, DRAWFLAG_NORMAL);
1188         else
1189                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1190         x = pos_x;
1191         pos_x += 5*8;
1192         score = pl.(scores[ps_primary]);
1193         pos_x -= stringwidth(ftos(score), FALSE)*8;
1194         drawstring(pos, ftos(score), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1195         pos_x = x;
1196         if(is_self)
1197         {
1198                 pos_x += 48;
1199                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1200                 pos_x += 8;
1201         } else
1202                 pos_x += 56;
1203         drawcolorcodedstring(pos, getplayerkey(pl.sv_entnum, "name"), '8 8 0', 1, 0);
1204 }
1205
1206 void Sbar_MiniscoreTeamItem(vector pos, float color, float frags, float is_self)
1207 {
1208         float x;
1209         pos_x += 72;
1210
1211         if(teamplay)
1212                 drawfill(pos + '0 1 0', '40 6 0', GetTeamRGB(color)*0.5, 1, DRAWFLAG_NORMAL);
1213         else
1214                 drawfill(pos + '0 1 0', '40 6 0', '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
1215         x = pos_x;
1216         pos_x += 5*8;
1217         pos_x -= stringwidth(ftos(frags), FALSE)*8;
1218         drawstring(pos, ftos(frags), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1219         pos_x = x;
1220         if(is_self)
1221         {
1222                 pos_x += 48;
1223                 drawstring(pos, "\x0D", '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1224                 pos_x += 8;
1225         } else
1226                 pos_x += 56;
1227         drawstring(pos, GetTeamName(color), '8 8 0', '1 1 1', 1, DRAWFLAG_NORMAL);
1228 }
1229
1230 void Sbar_MiniDeathmatchOverlay(vector pos)
1231 {
1232         float numlines, up, down, score;
1233         entity me, tm, pl;
1234         float miniscoreboard_size;
1235         miniscoreboard_size = cvar("sbar_miniscoreboard_size");
1236
1237         if(miniscoreboard_size == 0)
1238                 return;
1239         pos_y = vid_conheight - 8;
1240
1241         if(miniscoreboard_size < 0)
1242                 numlines = (vid_conheight - sbar_y + 7) / 8;
1243         else
1244                 numlines = miniscoreboard_size;
1245
1246         // give up if there isn't enough room
1247         if(pos_x >= vid_conwidth || pos_y >= vid_conheight || numlines < 1)
1248                 return;
1249
1250         // me vector := [team/connected frags id]
1251         for(me = players.sort_next; me; me = me.sort_next)
1252         {
1253                 if(me.sv_entnum == player_localentnum - 1)
1254                         break;
1255         }
1256
1257         if(teamplay)
1258                 numlines -= numteams;
1259
1260         // figure out how many players above and below we can show
1261         up = floor(numlines/2);
1262         down = up;
1263         if((up + down) > numlines)
1264                 down = numlines - up;
1265
1266         // render bottom-up
1267         for(pl = me.sort_next; pl && down > 0; pl = pl.sort_next)
1268         {
1269                 if(pl.team == COLOR_SPECTATOR)
1270                         continue;
1271                 Sbar_MiniscoreItem(pos, pl, false);
1272                 pos_y -= 9;
1273                 --down;
1274         }
1275         Sbar_MiniscoreItem(pos, me, true);
1276         pos_y -= 9;
1277         up += down; // if there weren't enough lines below... add them
1278         for(pl = me.sort_prev; pl && up > 0; pl = pl.sort_prev)
1279         {
1280                 if(pl.team == COLOR_SPECTATOR)
1281                         continue;
1282                 Sbar_MiniscoreItem(pos, pl, false);
1283                 pos_y -= 9;
1284                 --up;
1285         }
1286
1287         if(teamplay)
1288         {
1289                 for(tm = teams.sort_next; tm.sort_next; tm = tm.sort_next);
1290                 for(; tm; tm = tm.sort_prev)
1291                 {
1292                         if(!tm.team_size || tm.team == COLOR_SPECTATOR)
1293                                 continue;
1294                         score = tm.(teamscores[ts_primary]);
1295                         Sbar_MiniscoreTeamItem(pos, tm.team, score, (tm.team == me.team));
1296                         pos_y -= 9;
1297                 }
1298         }
1299 }
1300
1301 float Sbar_WouldDrawScoreboard ()
1302 {
1303         if (sb_showscores)
1304                 return 1;
1305         else if (intermission == 1)
1306                 return 1;
1307         else if (intermission == 2)
1308                 return 1;
1309         else if (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard"))
1310                 return 1;
1311         else if(sb_showscores_force)
1312                 return 1;
1313         return 0;
1314 }
1315
1316 void Sbar_Draw (void)
1317 {
1318         float i;
1319         float x, fade;
1320         float stat_items;
1321
1322         sbar_fontsize = Sbar_GetFontsize();
1323
1324         if(spectatee_status)
1325         {
1326                 string s;
1327                 vector o;
1328                 o = '1 0 0' * vid_conwidth;
1329                 if(spectatee_status == -1)
1330                         s = "^1Observing";
1331                 else
1332                         s = strcat("^1Spectating ^7", getplayerkey(spectatee_status - 1, "name"));
1333                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1334                 drawcolorcodedstring(
1335                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1336                         s,
1337                         sbar_fontsize,
1338                         sbar_alpha_fg,
1339                         0
1340                 );
1341                 o += sbar_fontsize_y * '0 1 0';
1342
1343                 if(spectatee_status == -1)
1344                         s = "^1Press ^3primary fire^1 to spectate";
1345                 else
1346                         s = "^1Press ^3primary fire^1 for another player";
1347                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1348                 drawcolorcodedstring(
1349                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1350                         s,
1351                         sbar_fontsize,
1352                         sbar_alpha_fg,
1353                         0
1354                 );
1355                 o += sbar_fontsize_y * '0 1 0';
1356
1357                 if(spectatee_status != -1)
1358                         s = "^1Use ^3weapon switching^1 to change the speed";
1359                 else
1360                         s = "^1Press ^3secondary fire^1 to observe";
1361                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1362                 drawcolorcodedstring(
1363                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1364                         s,
1365                         sbar_fontsize,
1366                         sbar_alpha_fg,
1367                         0
1368                 );
1369                 o += sbar_fontsize_y * '0 1 0';
1370
1371                 if(gametype == GAME_ARENA)
1372                         s = "^1Wait for your turn to join";
1373                 else if(gametype == GAME_LMS)
1374                 {
1375                         entity sk;
1376                         sk = playerslots[player_localentnum - 1];
1377                         if(sk.(scores[ps_primary]) >= 666)
1378                                 s = "^1Match has already begun";
1379                         else if(sk.(scores[ps_primary]) > 0)
1380                                 s = "^1You have no more lives left";
1381                         else
1382                                 s = "^1Press ^7jump^1 to join";
1383                 }
1384                 else
1385                         s = "^1Press ^7jump^1 to join";
1386                 dummyfunction(0, 0, 0, 0, 0, 0, 0, 0); // work around DP bug (set OFS_PARAM5 to 0)
1387                 drawcolorcodedstring(
1388                         o - sbar_fontsize_x * '1 0 0' * stringwidth(s, TRUE),
1389                         s,
1390                         sbar_fontsize,
1391                         sbar_alpha_fg,
1392                         0
1393                 );
1394                 o += sbar_fontsize_y * '0 1 0';
1395         }
1396
1397         //Sbar_SortFrags();
1398         Sbar_UpdatePlayerTeams();
1399
1400         sb_lines = 24;
1401
1402         if (sb_showscores)
1403                 Sbar_DrawScoreboard();
1404         else if (intermission == 1)
1405         {
1406                 Sbar_DrawScoreboard();
1407                 return;
1408         }
1409         else if (intermission == 2)
1410                 Sbar_FinaleOverlay();
1411         else
1412         {
1413                 if (sb_showscores || sb_showscores_force || (getstati(STAT_HEALTH) <= 0 && cvar("cl_deathscoreboard")))
1414                 {
1415                         sbar_x = (vid_conwidth - 640.0)*0.5;
1416                         sbar_y = vid_conheight - 47;
1417                         //Sbar_DrawAlphaPic (sbar_x, sbar_y, sb_scorebar, sbar_alpha_bg.value);
1418                         //drawpic('0 0 0', "gfx/scorebar", '0 0 0', '1 1 1', cvar("sbar_alpha_bg"), 0);
1419                         Sbar_DrawScoreboard ();
1420                 }
1421                 else
1422                 {
1423                         if (sb_lines && sbar_hudselector == 1)
1424                         {
1425                                 stat_items = getstati(STAT_ITEMS);
1426
1427                                 sbar_x = (vid_conwidth - 320.0)*0.5;
1428                                 sbar_y = vid_conheight - 24.0 - 16.0;
1429                                 sbar_z = 0;
1430
1431                                 fade = 3.2 - 2 * (time - weapontime);
1432                                 fade = bound(0.7, fade, 1);
1433
1434                                 x = 1.0;
1435                                 for(i = 0; i < 8; ++i)
1436                                 {
1437                                         if(stat_items & x)
1438                                         {
1439                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1440                                         }
1441                                         x *= 2;
1442                                 }
1443                                 x *= 2*2*2*2;
1444                                 if(stat_items & x)
1445                                 {
1446                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1447                                 }
1448
1449                                 // armor
1450                                 x = getstati(STAT_ARMOR);
1451                                 if (x > 0)
1452                                 {
1453                                         // "gfx/sb_armor"
1454                                         //Sbar_DrawStretchPic (72, 0, sb_armor[0], sbar_alpha_fg.value, 24, 24);
1455                                         drawpic(sbar + '72 0 0', "gfx/sb_armor", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1456                                         if(x > 200)
1457                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0 1 0', 1, 0);
1458                                         else if(x > 100)
1459                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1460                                         else if(x > 50)
1461                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1462                                         else if(x > 25)
1463                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1464                                         else
1465                                                 Sbar_DrawXNum('0 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1466                                 }
1467
1468                                 // health
1469                                 x = getstati(STAT_HEALTH);
1470                                 if (x != 0)
1471                                 {
1472                                         // "gfx/sb_health"
1473                                         //Sbar_DrawStretchPic (184, 0, sb_health, sbar_alpha_fg.value, 24, 24);
1474                                         drawpic(sbar + '184 0 0', "gfx/sb_health", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1475                                         if(x > 200)
1476                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0 1 0', 1, 0);
1477                                         else if(x > 100)
1478                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.2 1 0', 1, 0);
1479                                         else if(x > 50)
1480                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1481                                         else if(x > 25)
1482                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '1 1 0.2', 1, 0);
1483                                         else
1484                                                 Sbar_DrawXNum('112 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1485                                 }
1486
1487                                 // ammo
1488                                 x = getstati(STAT_AMMO);
1489                                 if ((stat_items & (NEX_IT_SHELLS | NEX_IT_BULLETS | NEX_IT_ROCKETS | NEX_IT_CELLS)) || x != 0)
1490                                 {
1491                                         if (stat_items & NEX_IT_SHELLS)
1492                                                 drawpic(sbar + '296 0 0', "gfx/sb_shells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1493                                         else if (stat_items & NEX_IT_BULLETS)
1494                                                 drawpic(sbar + '296 0 0', "gfx/sb_bullets", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1495                                         else if (stat_items & NEX_IT_ROCKETS)
1496                                                 drawpic(sbar + '296 0 0', "gfx/sb_rocket", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1497                                         else if (stat_items & NEX_IT_CELLS)
1498                                                 drawpic(sbar + '296 0 0', "gfx/sb_cells", '24 24 0', '1 1 1', sbar_alpha_fg, 0);
1499                                         if(x > 10)
1500                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1501                                         else
1502                                                 Sbar_DrawXNum('224 0 0', x, 3, 24, '0.7 0 0', 1, 0);
1503                                 }
1504
1505                                 if (sbar_x + 320 + 160 <= vid_conwidth)
1506                                         Sbar_MiniDeathmatchOverlay(sbar + '320 0 0');
1507                                 if (sbar_x > 0)
1508                                         Sbar_Score(16);
1509                                 // The margin can be at most 8 to support 640x480 console size:
1510                                 //   320 + 2 * (144 + 16) = 640
1511                         }
1512                         else if (sb_lines)
1513                         {
1514
1515                                 stat_items = getstati(STAT_ITEMS);
1516
1517                                 sbar_x = (vid_conwidth - 640.0)*0.5;
1518                                 sbar_y = vid_conheight - 47;
1519                                 sbar_z = 0;
1520
1521                                 fade = 3 - 2 * (time - weapontime);
1522
1523                                 x = 1.0;
1524                                 for(i = 0; i < 8; ++i)
1525                                 {
1526                                         if(stat_items & x)
1527                                         {
1528                                                 Sbar_DrawWeapon(i+1, fade, (i + 2 == activeweapon));
1529                                         }
1530                                         x *= 2;
1531                                 }
1532                                 x *= 2*2*2*2;
1533                                 if(stat_items & x)
1534                                 {
1535                                         Sbar_DrawWeapon(0, fade, (activeweapon == 1));
1536                                 }
1537
1538                                 if (sb_lines > 24)
1539                                         drawpic(sbar, "gfx/sbar", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1540                                 else
1541                                         drawpic(sbar, "gfx/sbar_minimal", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1542
1543                                 // armor
1544                                 // (340-3*24) = 268
1545                                 Sbar_DrawXNum('268 12 0', getstati(STAT_ARMOR), 3, 24, '0.6 0.7 0.8', 1, 0);
1546
1547                                 // health
1548                                 // (154-3*24) = 82
1549                                 x = getstati(STAT_HEALTH);
1550                                 if(x > 100)
1551                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '1 1 1', 1, 0);
1552                                 else if(x <= 25 && time - floor(time) > 0.5)
1553                                         Sbar_DrawXNum('82 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1554                                 else
1555                                         Sbar_DrawXNum('81 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1556
1557                                 // AK dont draw ammo for the laser
1558                                 x = getstati(STAT_AMMO);
1559                                 if(activeweapon != 12)
1560                                 {
1561                                         // (519-3*24) = 447
1562                                         if (stat_items & NEX_IT_SHELLS)
1563                                                 drawpic(sbar + '519 0 0', "gfx/sb_shells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1564                                         else if (stat_items & NEX_IT_BULLETS)
1565                                                 drawpic(sbar + '519 0 0', "gfx/sb_bullets", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1566                                         else if (stat_items & NEX_IT_ROCKETS)
1567                                                 drawpic(sbar + '519 0 0', "gfx/sb_rocket", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1568                                         else if (stat_items & NEX_IT_CELLS)
1569                                                 drawpic(sbar + '519 0 0', "gfx/sb_cells", '0 0 0', '1 1 1', sbar_alpha_fg, 0);
1570                                         if(x > 10)
1571                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.6 0.7 0.8', 1, 0);
1572                                         else
1573                                                 Sbar_DrawXNum('447 12 0', x, 3, 24, '0.7 0 0', 1, 0);
1574                                 }
1575
1576                                 if (sb_lines > 24)
1577                                         drawpic(sbar, "gfx/sbar_overlay", '0 0 0', '1 1 1', 1, DRAWFLAG_MODULATE);
1578
1579                                 if (sbar_x + 600 + 160 <= vid_conwidth)
1580                                         Sbar_MiniDeathmatchOverlay (sbar + '600 0 0');
1581
1582                                 if (sbar_x > 0)
1583                                         Sbar_Score(-16);
1584                                 // Because:
1585                                 //   Mini scoreboard uses 12*4 per other team, that is, 144
1586                                 //   pixels when there are four teams...
1587                                 //   Nexuiz by default sets vid_conwidth to 800... makes
1588                                 //   sbar_x == 80...
1589                                 //   so we need to shift it by 64 pixels to the right to fit
1590                                 //   BUT: then it overlaps with the image that gets drawn
1591                                 //   for viewsize 100! Therefore, just account for 3 teams,
1592                                 //   that is, 96 pixels mini scoreboard size, needing 16 pixels
1593                                 //   to the right!
1594                         }
1595
1596
1597                         if(gametype == GAME_KEYHUNT)
1598                         {
1599                                 CSQC_kh_hud();
1600                         } else if(gametype == GAME_CTF)
1601                         {
1602                                 CSQC_ctf_hud();
1603                         }
1604                 }
1605         }
1606 }
1607
1608 void CSQC_ctf_hud(void)
1609 {
1610         // cvar("sbar_flagstatus_right") move the flag icons right
1611         // cvar("sbar_flagstatus_pos") pixel position of the nexuiz flagstatus icons
1612         float redflag, blueflag;
1613         float stat_items;
1614         vector pos;
1615
1616         stat_items = getstati(STAT_ITEMS);
1617         redflag = (stat_items/32768) & 3;
1618         blueflag = (stat_items/131072) & 3;
1619
1620         /**
1621          * FTEQCC BUG!
1622          * For some reason now not even THAT works there...
1623          * Maybe the minus' precedence screws it up? The last one there, maybe I should use brackets
1624          **
1625          * pos_x = (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - sbar_x - 64 : 10 - sbar_x;
1626          ** Should try those later:
1627          * pos_x = (cvar("sbar_flagstatus_right")) ? (vid_conwidth - 10 - sbar_x - 64) : (10 - sbar_x);
1628          * pos_x = ( (cvar("sbar_flagstatus_right")) ? vid_conwidth - 10 - 64 : 10 ) - sbar_x;
1629          */
1630
1631         if(cvar("sbar_flagstatus_right"))
1632                 pos_x = vid_conwidth - 10 - sbar_x - 64;
1633         else
1634                 pos_x = 10 - sbar_x;
1635
1636         pos_z = 0;
1637
1638         if(sbar_hudselector == 1)
1639                 pos_y = (vid_conheight - sbar_y) - cvar("sbar_flagstatus_pos") - 64;
1640         else
1641                 pos_y = -117;
1642
1643         pos += sbar;
1644
1645         switch(redflag)
1646         {
1647         case 1: drawpic(pos, "gfx/sb_flag_red_taken", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1648         case 2: drawpic(pos, "gfx/sb_flag_red_lost", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1649         case 3: drawpic(pos, "gfx/sb_flag_red_carrying", '0 0 0', '1 1 1', 1, DRAWFLAG_NORMAL); break;
1650         }
1651
1652         pos_y -= 64;
1653
1654         switch(blueflag)
1655         {
1656         case 1: drawpic(pos, "gfx/sb_flag_blue_taken", '0 0 0', '1 1 1', 1, 0); break;
1657         case 2: drawpic(pos, "gfx/sb_flag_blue_lost", '0 0 0', '1 1 1', 1, 0); break;
1658         case 3: drawpic(pos, "gfx/sb_flag_blue_carrying", '0 0 0', '1 1 1', 1, 0); break;
1659         }
1660 }