data/qcsrc/client/projectile.qc

   1 .float spawntime;
   2 .vector trail_oldorigin;
   3
   4 void SUB_Null()
   5 {
   6 }
   7
   8 void SUB_Stop()
   9 {
  10         self.move_velocity = self.move_avelocity = '0 0 0';
  11         self.move_movetype = MOVETYPE_NONE;
  12 }
  13
  14 .float count; // set if clientside projectile
  15 .float cnt; // sound index
  16 .float gravity;
  17 .float snd_looping;
  18
  19 void Projectile_DrawTrail(vector to)
  20 {
  21         vector from;
  22         from = self.trail_oldorigin;
  23         self.trail_oldorigin = to;
  24         switch(self.cnt)
  25         {
  26                 case PROJECTILE_ROCKET:
  27                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  28                         break;
  29                 case PROJECTILE_TAG:
  30                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  31                         break;
  32                 case PROJECTILE_CRYLINK:
  33                         trailparticles(self, particleeffectnum("TR_CRYLINKPLASMA"), from, to);
  34                         break;
  35                 case PROJECTILE_CRYLINK_BOUNCING:
  36                         trailparticles(self, particleeffectnum("TR_CRYLINKPLASMA"), from, to);
  37                         break;
  38                 case PROJECTILE_ELECTRO_BEAM:
  39                         trailparticles(self, particleeffectnum("TR_NEXUIZPLASMA"), from, to);
  40                         break;
  41                 case PROJECTILE_GRENADE:
  42                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  43                         break;
  44                 case PROJECTILE_GRENADE_BOUNCING:
  45                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  46                         break;
  47                 case PROJECTILE_PORTO_RED:
  48                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  49                         break;
  50                 case PROJECTILE_PORTO_BLUE:
  51                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  52                         break;
  53                 case PROJECTILE_FLAC:
  54                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  55                         break;
  56                 case PROJECTILE_SEEKER:
  57                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  58                         break;
  59                 case PROJECTILE_HOOKBOMB:
  60                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  61                         break;
  62                 case PROJECTILE_HAGAR:
  63                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  64                         break;
  65                 case PROJECTILE_HAGAR_BOUNCING:
  66                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  67                         break;
  68                 case PROJECTILE_BULLET:
  69                 case PROJECTILE_BULLET_GLOWING:
  70                         trailparticles(self, particleeffectnum("tr_bullet"), from, to);
  71                         break;
  72                 default:
  73                         break;
  74         }
  75
  76 }
  77
  78 void Projectile_Draw()
  79 {
  80         vector rot;
  81         vector trailorigin;
  82         float f;
  83         float drawn;
  84         float t;
  85
  86         f = self.move_flags;
  87
  88         if(self.count & 0x80)
  89         {
  90                 //self.move_flags &~= FL_ONGROUND;
  91                 Movetype_Physics(TRUE);
  92                 if(!(self.move_flags & FL_ONGROUND))
  93                         self.angles = vectoangles(self.velocity);
  94         }
  95         else
  96         {
  97                 InterpolateOrigin_Do();
  98         }
  99
 100         if(self.count & 0x80)
 101         {
 102                 drawn = (time >= self.spawntime - 0.02);
 103                 t = max(time, self.spawntime);
 104         }
 105         else
 106         {
 107                 drawn = (self.iflags & IFLAG_VALID);
 108                 t = time;
 109         }
 110
 111         if(!(f & FL_ONGROUND))
 112         {
 113                 rot = '0 0 0';
 114                 switch(self.cnt)
 115                 {
 116                         /*
 117                         case PROJECTILE_GRENADE:
 118                                 rot = '-2000 0 0'; // forward
 119                                 break;
 120                         */
 121                         case PROJECTILE_GRENADE_BOUNCING:
 122                                 rot = '0 -1000 0'; // sideways
 123                                 break;
 124                         case PROJECTILE_HOOKBOMB:
 125                                 rot = '1000 0 0'; // forward
 126                                 break;
 127                         default:
 128                                 break;
 129                 }
 130                 self.angles = AnglesTransform_Multiply(self.angles, rot * (t - self.spawntime));
 131
 132                 fixedmakevectors(self.angles);
 133
 134                 trailorigin = self.origin;
 135                 switch(self.cnt)
 136                 {
 137                         case PROJECTILE_GRENADE:
 138                         case PROJECTILE_GRENADE_BOUNCING:
 139                                 trailorigin += v_right * 1 + v_forward * -10;
 140                                 break;
 141                         default:
 142                                 break;
 143                 }
 144                 if(drawn)
 145                         Projectile_DrawTrail(trailorigin);
 146                 else
 147                         self.trail_oldorigin = trailorigin;
 148         }
 149
 150         if(!drawn)
 151                 return;
 152
 153         switch(self.cnt)
 154         {
 155                 case PROJECTILE_BULLET_GLOWING:
 156                         R_AddDynamicLight(self.origin, 50, '1 1 0');
 157                         break;
 158                 default:
 159                         break;
 160         }
 161
 162         self.renderflags = 0;
 163
 164         R_AddEntity(self);
 165 }
 166
 167 void loopsound(entity e, float ch, string samp, float vol, float attn)
 168 {
 169         if(csqc_flags & CSQC_FLAG_COLORCODES)
 170         {
 171                 sound(e, ch, samp, vol, attn);
 172                 e.snd_looping = 1;
 173         }
 174 }
 175
 176 void Ent_RemoveProjectile()
 177 {
 178         if(self.snd_looping)
 179                 sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
 180
 181         if(self.count & 0x80)
 182         {
 183                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 184                 Projectile_DrawTrail(trace_endpos);
 185         }
 186 }
 187
 188 void Ent_Projectile()
 189 {
 190         float f;
 191
 192         // projectile properties:
 193         //   kind (interpolated, or clientside)
 194         //
 195         //   modelindex
 196         //   origin
 197         //   scale
 198         //   if clientside:
 199         //     velocity
 200         //     gravity
 201         //   soundindex (hardcoded list)
 202         //   effects
 203         //
 204         // projectiles don't send angles, because they always follow the velocity
 205
 206         f = ReadByte();
 207         self.count = (f & 0x80);
 208         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES;
 209         self.solid = SOLID_TRIGGER;
 210         //self.effects = EF_NOMODELFLAGS;
 211
 212         // this should make collisions with bmodels more exact, but it leads to
 213         // projectiles no longer being able to lie on a bmodel
 214         self.move_nomonsters = MOVE_WORLDONLY;
 215         if(f & 0x40)
 216                 self.move_flags |= FL_ONGROUND;
 217         else
 218                 self.move_flags &~= FL_ONGROUND;
 219
 220         if(!self.move_time)
 221         {
 222                 // for some unknown reason, we don't need to care for
 223                 // sv_gameplayfix_delayprojectiles here.
 224                 self.move_time = time;
 225                 self.spawntime = time;
 226         }
 227         else
 228                 self.move_time = max(self.move_time, time);
 229
 230         if(!(self.count & 0x80))
 231                 InterpolateOrigin_Undo();
 232
 233         if(f & 1)
 234         {
 235                 self.origin_x = ReadCoord();
 236                 self.origin_y = ReadCoord();
 237                 self.origin_z = ReadCoord();
 238                 if(self.count & 0x80)
 239                 {
 240                         self.velocity_x = ReadCoord();
 241                         self.velocity_y = ReadCoord();
 242                         self.velocity_z = ReadCoord();
 243                         self.gravity = ReadCoord();
 244
 245                         self.move_origin = self.origin;
 246                         self.move_velocity = self.velocity;
 247                 }
 248
 249                 self.trail_oldorigin = self.origin;
 250         }
 251
 252         if(f & 2)
 253         {
 254                 self.cnt = ReadByte();
 255
 256                 self.scale = 1;
 257                 switch(self.cnt)
 258                 {
 259                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl"); break;
 260                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3"); self.scale = 2; break;
 261                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); break;
 262                         case PROJECTILE_BULLET: setmodel(self, "models/tracer.mdl"); break;
 263                         case PROJECTILE_BULLET_GLOWING: setmodel(self, "models/tracer.mdl"); break;
 264                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl"); break;
 265                         case PROJECTILE_CRYLINK_BOUNCING: setmodel(self, "models/plasmatrail.mdl"); break;
 266                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl"); break;
 267                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3"); break;
 268                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3"); break;
 269                         case PROJECTILE_LASER: setmodel(self, "models/laser.mdl"); break;
 270                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3"); break;
 271                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.scale = 2; break;
 272                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 273                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 274                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 275                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3"); break;
 276                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 277                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 278                         default:
 279                                 error("Received invalid CSQC projectile, can't work with this!");
 280                                 break;
 281                 }
 282
 283                 self.mins = '0 0 0';
 284                 self.maxs = '0 0 0';
 285                 self.colormod = '0 0 0';
 286                 self.move_touch = SUB_Stop;
 287                 self.move_movetype = MOVETYPE_TOSS;
 288
 289                 switch(self.cnt)
 290                 {
 291                         case PROJECTILE_ELECTRO:
 292                                 // only new engines support sound moving with object
 293                                 loopsound(self, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 294                                 self.mins = '0 0 -3';
 295                                 self.maxs = '0 0 -3';
 296                                 self.move_movetype = MOVETYPE_BOUNCE;
 297                                 self.move_touch = SUB_Null;
 298                                 break;
 299                         case PROJECTILE_ROCKET:
 300                                 loopsound(self, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 301                                 self.mins = '-3 -3 -3';
 302                                 self.maxs = '3 3 3';
 303                                 break;
 304                         case PROJECTILE_TAG:
 305                                 loopsound(self, CHAN_PROJECTILE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTN_NORM);
 306                                 self.mins = '-2 -2 -2';
 307                                 self.maxs = '2 2 2';
 308                                 break;
 309                         case PROJECTILE_GRENADE_BOUNCING:
 310                                 self.mins = '0 0 -3';
 311                                 self.maxs = '0 0 -3';
 312                                 self.move_movetype = MOVETYPE_BOUNCE;
 313                                 self.move_touch = SUB_Null;
 314                                 break;
 315                         case PROJECTILE_SEEKER:
 316                                 self.mins = '-2 -2 -2';
 317                                 self.maxs = '2 2 2';
 318                                 break;
 319                         case PROJECTILE_PORTO_RED:
 320                                 self.colormod = '2 1 1';
 321                                 self.alpha = 0.5;
 322                                 self.move_movetype = MOVETYPE_BOUNCE;
 323                                 self.move_touch = SUB_Null;
 324                                 break;
 325                         case PROJECTILE_PORTO_BLUE:
 326                                 self.colormod = '1 1 2';
 327                                 self.alpha = 0.5;
 328                                 self.move_movetype = MOVETYPE_BOUNCE;
 329                                 self.move_touch = SUB_Null;
 330                                 break;
 331                         case PROJECTILE_HAGAR_BOUNCING:
 332                                 self.move_movetype = MOVETYPE_BOUNCE;
 333                                 self.move_touch = SUB_Null;
 334                                 break;
 335                         case PROJECTILE_CRYLINK_BOUNCING:
 336                                 self.move_movetype = MOVETYPE_BOUNCE;
 337                                 self.move_touch = SUB_Null;
 338                                 break;
 339                         default:
 340                                 break;
 341                 }
 342         }
 343
 344         if(self.gravity)
 345         {
 346                 if(self.move_movetype == MOVETYPE_FLY)
 347                         self.move_movetype = MOVETYPE_TOSS;
 348                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 349                         self.move_movetype = MOVETYPE_BOUNCE;
 350         }
 351         else
 352         {
 353                 if(self.move_movetype == MOVETYPE_TOSS)
 354                         self.move_movetype = MOVETYPE_FLY;
 355                 if(self.move_movetype == MOVETYPE_BOUNCE)
 356                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 357         }
 358
 359         if(!(self.count & 0x80))
 360                 InterpolateOrigin_Note();
 361
 362         self.draw = Projectile_Draw;
 363         self.entremove = Ent_RemoveProjectile;
 364 }
 365
 366 void Projectile_Precache()
 367 {
 368         precache_model("models/ebomb.mdl");
 369         precache_model("models/elaser.mdl");
 370         precache_model("models/grenademodel.md3");
 371         precache_model("models/hagarmissile.mdl");
 372         precache_model("models/hlac_bullet.md3");
 373         precache_model("models/laser.mdl");
 374         precache_model("models/plasmatrail.mdl");
 375         precache_model("models/rocket.md3");
 376         precache_model("models/tagrocket.md3");
 377         precache_model("models/tracer.mdl");
 378         precache_sound("weapons/electro_fly.wav");
 379         precache_sound("weapons/rocket_fly.wav");
 380         precache_sound("weapons/tag_rocket_fly.wav");
 381 }