data/qcsrc/client/projectile.qc

   1 void SUB_Null()
   2 {
   3 }
   4
   5 void SUB_Stop()
   6 {
   7         self.move_velocity = self.move_avelocity = '0 0 0';
   8         self.move_movetype = MOVETYPE_NONE;
   9 }
  10
  11 .float count; // set if clientside projectile
  12 .float cnt; // sound index
  13 .float gravity;
  14
  15 void Projectile_Draw()
  16 {
  17         vector oldorg;
  18
  19         oldorg = self.origin;
  20
  21         if(self.count & 0x80)
  22         {
  23                 //self.move_flags &~= FL_ONGROUND;
  24                 Movetype_Physics(TRUE);
  25                 self.angles = vectoangles(self.velocity);
  26         }
  27         else
  28         {
  29                 InterpolateOrigin_Do();
  30         }
  31
  32         switch(self.cnt)
  33         {
  34                 case PROJECTILE_ROCKET:
  35                         trailparticles(self, particleeffectnum("TR_ROCKET"), oldorg, self.origin);
  36                         break;
  37                 case PROJECTILE_TAG:
  38                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), oldorg, self.origin);
  39                         break;
  40                 case PROJECTILE_ELECTRO_BEAM:
  41                         trailparticles(self, particleeffectnum("TR_NEXUIZPLASMA"), oldorg, self.origin);
  42                         break;
  43                 case PROJECTILE_GRENADE:
  44                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), oldorg, self.origin);
  45                         self.angles -= '750 0 0' * time;
  46                         break;
  47                 case PROJECTILE_GRENADE_BOUNCING:
  48                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), oldorg, self.origin);
  49                         if(!(self.move_flags & FL_ONGROUND))
  50                                 self.angles += '100 150 100' * time;
  51                         break;
  52                 case PROJECTILE_PORTO_RED:
  53                         // TODO add red dynamic light
  54                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), oldorg, self.origin);
  55                         break;
  56                 case PROJECTILE_PORTO_BLUE:
  57                         // TODO add blue dynamic light
  58                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), oldorg, self.origin);
  59                         break;
  60                 case PROJECTILE_FLAC:
  61                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), oldorg, self.origin);
  62                         break;
  63                 case PROJECTILE_SEEKER:
  64                         trailparticles(self, particleeffectnum("TR_ROCKET"), oldorg, self.origin);
  65                         break;
  66                 case PROJECTILE_HOOKBOMB:
  67                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), oldorg, self.origin);
  68                         self.angles = '0 500 0' * time;
  69                         break;
  70                 case PROJECTILE_HAGAR:
  71                         trailparticles(self, particleeffectnum("TR_GRENADE"), oldorg, self.origin);
  72                         break;
  73                 case PROJECTILE_HAGAR_BOUNCING:
  74                         trailparticles(self, particleeffectnum("TR_GRENADE"), oldorg, self.origin);
  75                         break;
  76                 case PROJECTILE_BULLET_GLOWING:
  77                         R_AddDynamicLight(self.origin, 50, '1 1 0');
  78                         break;
  79                 default:
  80                         break;
  81         }
  82
  83         self.renderflags = 0;
  84
  85         if((self.count & 0x80) || (self.iflags & IFLAG_VALID))
  86                 R_AddEntity(self);
  87 }
  88
  89 void loopsound(entity e, float ch, string samp, float vol, float attn)
  90 {
  91         if(csqc_flags & CSQC_FLAG_COLORCODES)
  92                 sound(e, ch, samp, vol, attn);
  93 }
  94
  95 void Ent_RemoveProjectile()
  96 {
  97         if(self.cnt)
  98                 loopsound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
  99 }
 100
 101 void Ent_Projectile()
 102 {
 103         float f;
 104
 105         InterpolateOrigin_Undo();
 106
 107         // projectile properties:
 108         //   kind (interpolated, or clientside)
 109         //
 110         //   modelindex
 111         //   origin
 112         //   scale
 113         //   if clientside:
 114         //     velocity
 115         //     gravity
 116         //   soundindex (hardcoded list)
 117         //   effects
 118         //
 119         // projectiles don't send angles, because they always follow the velocity
 120
 121         f = ReadByte();
 122         self.count = (f & 0x80);
 123         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES;
 124         self.move_flags &~= FL_ONGROUND;
 125         self.solid = SOLID_TRIGGER;
 126         //self.effects = EF_NOMODELFLAGS;
 127
 128         // sv_gameplayfix_delayprojectiles
 129         if(!self.move_time)
 130                 self.move_time = time + ticrate;
 131         else
 132                 self.move_time = max(self.move_time, time);
 133
 134         if(!(self.count & 0x80))
 135                 InterpolateOrigin_Undo();
 136
 137         if(f & 1)
 138         {
 139                 self.origin_x = ReadCoord();
 140                 self.origin_y = ReadCoord();
 141                 self.origin_z = ReadCoord();
 142                 if(self.count & 0x80)
 143                 {
 144                         self.velocity_x = ReadCoord();
 145                         self.velocity_y = ReadCoord();
 146                         self.velocity_z = ReadCoord();
 147                         self.gravity = ReadCoord();
 148
 149                         self.move_origin = self.origin;
 150                         self.move_velocity = self.velocity;
 151                 }
 152         }
 153
 154         if(f & 2)
 155         {
 156                 self.cnt = ReadByte();
 157
 158                 self.scale = 1;
 159                 switch(self.cnt)
 160                 {
 161                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl"); break;
 162                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3"); break;
 163                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); break;
 164                         case PROJECTILE_BULLET: setmodel(self, "models/tracer.mdl"); break;
 165                         case PROJECTILE_BULLET_GLOWING: setmodel(self, "models/tracer.mdl"); break;
 166                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl"); break;
 167                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl"); break;
 168                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3"); break;
 169                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3"); break;
 170                         case PROJECTILE_LASER: setmodel(self, "models/laser.mdl"); break;
 171                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3"); break;
 172                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.scale = 2; break;
 173                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 174                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 175                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 176                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3"); break;
 177                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 178                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 179                         default:
 180                                 error("Received invalid CSQC projectile, can't work with this!");
 181                                 break;
 182                 }
 183
 184                 self.mins = '0 0 0';
 185                 self.maxs = '0 0 0';
 186                 self.colormod = '0 0 0';
 187                 self.move_touch = SUB_Stop;
 188                 self.move_movetype = MOVETYPE_TOSS;
 189
 190                 switch(self.cnt)
 191                 {
 192                         case PROJECTILE_ELECTRO:
 193                                 // only new engines support sound moving with object
 194                                 loopsound(self, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 195                                 self.mins = '0 0 -3';
 196                                 self.maxs = '0 0 -3';
 197                                 self.move_movetype = MOVETYPE_BOUNCE;
 198                                 self.move_touch = SUB_Null;
 199                                 break;
 200                         case PROJECTILE_ROCKET:
 201                                 loopsound(self, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 202                                 self.mins = '-3 -3 -3';
 203                                 self.maxs = '3 3 3';
 204                                 break;
 205                         case PROJECTILE_TAG:
 206                                 loopsound(self, CHAN_PROJECTILE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTN_NORM);
 207                                 self.mins = '-2 -2 -2';
 208                                 self.maxs = '2 2 2';
 209                                 break;
 210                         case PROJECTILE_GRENADE_BOUNCING:
 211                                 self.mins = '0 0 -3';
 212                                 self.maxs = '0 0 -3';
 213                                 self.move_movetype = MOVETYPE_BOUNCE;
 214                                 self.move_touch = SUB_Null;
 215                                 break;
 216                         case PROJECTILE_SEEKER:
 217                                 self.mins = '-2 -2 -2';
 218                                 self.maxs = '2 2 2';
 219                                 break;
 220                         case PROJECTILE_PORTO_RED:
 221                                 self.colormod = '2 1 1';
 222                                 self.alpha = 0.5;
 223                                 break;
 224                         case PROJECTILE_PORTO_BLUE:
 225                                 self.colormod = '1 1 2';
 226                                 self.alpha = 0.5;
 227                                 break;
 228                         case PROJECTILE_HAGAR_BOUNCING:
 229                                 self.move_movetype = MOVETYPE_BOUNCE;
 230                                 self.move_touch = SUB_Null;
 231                                 break;
 232                         default:
 233                                 break;
 234                 }
 235         }
 236
 237         if(self.gravity)
 238         {
 239                 if(self.move_movetype == MOVETYPE_FLY)
 240                         self.move_movetype = MOVETYPE_TOSS;
 241                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 242                         self.move_movetype = MOVETYPE_BOUNCE;
 243         }
 244         else
 245         {
 246                 if(self.move_movetype == MOVETYPE_TOSS)
 247                         self.move_movetype = MOVETYPE_FLY;
 248                 if(self.move_movetype == MOVETYPE_BOUNCE)
 249                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 250         }
 251
 252         if(!(self.count & 0x80))
 253                 InterpolateOrigin_Note();
 254
 255         self.draw = Projectile_Draw;
 256 }
 257
 258 void Projectile_Precache()
 259 {
 260         precache_model("models/ebomb.mdl");
 261         precache_model("models/elaser.mdl");
 262         precache_model("models/grenademodel.md3");
 263         precache_model("models/hagarmissile.mdl");
 264         precache_model("models/hlac_bullet.md3");
 265         precache_model("models/laser.mdl");
 266         precache_model("models/plasmatrail.mdl");
 267         precache_model("models/rocket.md3");
 268         precache_model("models/tagrocket.md3");
 269         precache_model("models/tracer.mdl");
 270         precache_sound("weapons/electro_fly.wav");
 271         precache_sound("weapons/rocket_fly.wav");
 272         precache_sound("weapons/tag_rocket_fly.wav");
 273 }