data/qcsrc/client/projectile.qc

   1 .float spawntime;
   2 .vector trail_oldorigin;
   3
   4 void SUB_Null()
   5 {
   6 }
   7
   8 void SUB_Stop()
   9 {
  10         self.move_velocity = self.move_avelocity = '0 0 0';
  11         self.move_movetype = MOVETYPE_NONE;
  12 }
  13
  14 .float count; // set if clientside projectile
  15 .float cnt; // sound index
  16 .float gravity;
  17 .float snd_looping;
  18
  19 void Projectile_DrawTrail(vector to)
  20 {
  21         vector from;
  22         from = self.trail_oldorigin;
  23         self.trail_oldorigin = to;
  24         switch(self.cnt)
  25         {
  26                 case PROJECTILE_ROCKET:
  27                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  28                         break;
  29                 case PROJECTILE_TAG:
  30                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  31                         break;
  32                 case PROJECTILE_ELECTRO_BEAM:
  33                         trailparticles(self, particleeffectnum("TR_NEXUIZPLASMA"), from, to);
  34                         break;
  35                 case PROJECTILE_GRENADE:
  36                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  37                         break;
  38                 case PROJECTILE_GRENADE_BOUNCING:
  39                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  40                         break;
  41                 case PROJECTILE_PORTO_RED:
  42                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  43                         break;
  44                 case PROJECTILE_PORTO_BLUE:
  45                         trailparticles(self, particleeffectnum("TR_WIZSPIKE"), from, to);
  46                         break;
  47                 case PROJECTILE_FLAC:
  48                         trailparticles(self, particleeffectnum("TR_VORESPIKE"), from, to);
  49                         break;
  50                 case PROJECTILE_SEEKER:
  51                         trailparticles(self, particleeffectnum("TR_ROCKET"), from, to);
  52                         break;
  53                 case PROJECTILE_HOOKBOMB:
  54                         trailparticles(self, particleeffectnum("TR_KNIGHTSPIKE"), from, to);
  55                         break;
  56                 case PROJECTILE_HAGAR:
  57                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  58                         break;
  59                 case PROJECTILE_HAGAR_BOUNCING:
  60                         trailparticles(self, particleeffectnum("TR_GRENADE"), from, to);
  61                         break;
  62                 default:
  63                         break;
  64         }
  65
  66 }
  67
  68 void Projectile_Draw()
  69 {
  70         vector rot;
  71         vector trailorigin;
  72         float f;
  73         float drawn;
  74         float t;
  75
  76         f = self.move_flags;
  77
  78         if(self.count & 0x80)
  79         {
  80                 //self.move_flags &~= FL_ONGROUND;
  81                 Movetype_Physics(TRUE);
  82                 if(!(self.move_flags & FL_ONGROUND))
  83                         self.angles = vectoangles(self.velocity);
  84         }
  85         else
  86         {
  87                 InterpolateOrigin_Do();
  88         }
  89
  90         if(self.count & 0x80)
  91         {
  92                 drawn = (time >= self.spawntime - 0.02);
  93                 t = max(time, self.spawntime);
  94         }
  95         else
  96         {
  97                 drawn = (self.iflags & IFLAG_VALID);
  98                 t = time;
  99         }
 100
 101         if(!(f & FL_ONGROUND))
 102         {
 103                 rot = '0 0 0';
 104                 switch(self.cnt)
 105                 {
 106                         /*
 107                         case PROJECTILE_GRENADE:
 108                                 rot = '-2000 0 0'; // forward
 109                                 break;
 110                         */
 111                         case PROJECTILE_GRENADE_BOUNCING:
 112                                 rot = '0 -1000 0'; // sideways
 113                                 break;
 114                         case PROJECTILE_HOOKBOMB:
 115                                 rot = '1000 0 0'; // forward
 116                                 break;
 117                         default:
 118                                 break;
 119                 }
 120                 self.angles = AnglesTransform_Multiply(self.angles, rot * (t - self.spawntime));
 121
 122                 fixedmakevectors(self.angles);
 123
 124                 trailorigin = self.origin;
 125                 switch(self.cnt)
 126                 {
 127                         case PROJECTILE_GRENADE:
 128                         case PROJECTILE_GRENADE_BOUNCING:
 129                                 trailorigin += v_right * 1 + v_forward * -10;
 130                                 break;
 131                         default:
 132                                 break;
 133                 }
 134                 if(drawn)
 135                         Projectile_DrawTrail(trailorigin);
 136                 else
 137                         self.trail_oldorigin = trailorigin;
 138         }
 139
 140         if(!drawn)
 141                 return;
 142
 143         switch(self.cnt)
 144         {
 145                 case PROJECTILE_BULLET_GLOWING:
 146                         R_AddDynamicLight(self.origin, 50, '1 1 0');
 147                         break;
 148                 default:
 149                         break;
 150         }
 151
 152         self.renderflags = 0;
 153
 154         R_AddEntity(self);
 155 }
 156
 157 void loopsound(entity e, float ch, string samp, float vol, float attn)
 158 {
 159         if(csqc_flags & CSQC_FLAG_COLORCODES)
 160         {
 161                 sound(e, ch, samp, vol, attn);
 162                 e.snd_looping = 1;
 163         }
 164 }
 165
 166 void Ent_RemoveProjectile()
 167 {
 168         if(self.snd_looping)
 169                 sound(self, CHAN_PROJECTILE, "misc/null.wav", VOL_BASE, ATTN_NORM);
 170
 171         if(self.count & 0x80)
 172         {
 173                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 174                 Projectile_DrawTrail(trace_endpos);
 175         }
 176 }
 177
 178 void Ent_Projectile()
 179 {
 180         float f;
 181
 182         // projectile properties:
 183         //   kind (interpolated, or clientside)
 184         //
 185         //   modelindex
 186         //   origin
 187         //   scale
 188         //   if clientside:
 189         //     velocity
 190         //     gravity
 191         //   soundindex (hardcoded list)
 192         //   effects
 193         //
 194         // projectiles don't send angles, because they always follow the velocity
 195
 196         f = ReadByte();
 197         self.count = (f & 0x80);
 198         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES;
 199         self.move_flags &~= FL_ONGROUND;
 200         self.solid = SOLID_TRIGGER;
 201         //self.effects = EF_NOMODELFLAGS;
 202
 203         // sv_gameplayfix_delayprojectiles
 204         if(!self.move_time)
 205         {
 206                 self.move_time = time + ticrate;
 207                 self.spawntime = time + ticrate;
 208         }
 209         else
 210                 self.move_time = max(self.move_time, time);
 211
 212         if(!(self.count & 0x80))
 213                 InterpolateOrigin_Undo();
 214
 215         if(f & 1)
 216         {
 217                 self.origin_x = ReadCoord();
 218                 self.origin_y = ReadCoord();
 219                 self.origin_z = ReadCoord();
 220                 if(self.count & 0x80)
 221                 {
 222                         self.velocity_x = ReadCoord();
 223                         self.velocity_y = ReadCoord();
 224                         self.velocity_z = ReadCoord();
 225                         self.gravity = ReadCoord();
 226
 227                         self.move_origin = self.origin;
 228                         self.move_velocity = self.velocity;
 229                 }
 230
 231                 self.trail_oldorigin = self.origin;
 232         }
 233
 234         if(f & 2)
 235         {
 236                 self.cnt = ReadByte();
 237
 238                 self.scale = 1;
 239                 switch(self.cnt)
 240                 {
 241                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl"); break;
 242                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3"); self.scale = 3; break;
 243                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); break;
 244                         case PROJECTILE_BULLET: setmodel(self, "models/tracer.mdl"); break;
 245                         case PROJECTILE_BULLET_GLOWING: setmodel(self, "models/tracer.mdl"); break;
 246                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl"); break;
 247                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl"); break;
 248                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3"); break;
 249                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3"); break;
 250                         case PROJECTILE_LASER: setmodel(self, "models/laser.mdl"); break;
 251                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3"); break;
 252                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.scale = 2; break;
 253                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 254                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 255                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3"); self.scale = 4; break;
 256                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3"); break;
 257                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 258                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; break;
 259                         default:
 260                                 error("Received invalid CSQC projectile, can't work with this!");
 261                                 break;
 262                 }
 263
 264                 self.mins = '0 0 0';
 265                 self.maxs = '0 0 0';
 266                 self.colormod = '0 0 0';
 267                 self.move_touch = SUB_Stop;
 268                 self.move_movetype = MOVETYPE_TOSS;
 269
 270                 switch(self.cnt)
 271                 {
 272                         case PROJECTILE_ELECTRO:
 273                                 // only new engines support sound moving with object
 274                                 loopsound(self, CHAN_PROJECTILE, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 275                                 self.mins = '0 0 -3';
 276                                 self.maxs = '0 0 -3';
 277                                 self.move_movetype = MOVETYPE_BOUNCE;
 278                                 self.move_touch = SUB_Null;
 279                                 break;
 280                         case PROJECTILE_ROCKET:
 281                                 loopsound(self, CHAN_PROJECTILE, "weapons/rocket_fly.wav", VOL_BASE, ATTN_NORM);
 282                                 self.mins = '-3 -3 -3';
 283                                 self.maxs = '3 3 3';
 284                                 break;
 285                         case PROJECTILE_TAG:
 286                                 loopsound(self, CHAN_PROJECTILE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTN_NORM);
 287                                 self.mins = '-2 -2 -2';
 288                                 self.maxs = '2 2 2';
 289                                 break;
 290                         case PROJECTILE_GRENADE_BOUNCING:
 291                                 self.mins = '0 0 -3';
 292                                 self.maxs = '0 0 -3';
 293                                 self.move_movetype = MOVETYPE_BOUNCE;
 294                                 self.move_touch = SUB_Null;
 295                                 break;
 296                         case PROJECTILE_SEEKER:
 297                                 self.mins = '-2 -2 -2';
 298                                 self.maxs = '2 2 2';
 299                                 break;
 300                         case PROJECTILE_PORTO_RED:
 301                                 self.colormod = '2 1 1';
 302                                 self.alpha = 0.5;
 303                                 self.move_movetype = MOVETYPE_BOUNCE;
 304                                 self.move_touch = SUB_Null;
 305                                 break;
 306                         case PROJECTILE_PORTO_BLUE:
 307                                 self.colormod = '1 1 2';
 308                                 self.alpha = 0.5;
 309                                 self.move_movetype = MOVETYPE_BOUNCE;
 310                                 self.move_touch = SUB_Null;
 311                                 break;
 312                         case PROJECTILE_HAGAR_BOUNCING:
 313                                 self.move_movetype = MOVETYPE_BOUNCE;
 314                                 self.move_touch = SUB_Null;
 315                                 break;
 316                         default:
 317                                 break;
 318                 }
 319         }
 320
 321         if(self.gravity)
 322         {
 323                 if(self.move_movetype == MOVETYPE_FLY)
 324                         self.move_movetype = MOVETYPE_TOSS;
 325                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 326                         self.move_movetype = MOVETYPE_BOUNCE;
 327         }
 328         else
 329         {
 330                 if(self.move_movetype == MOVETYPE_TOSS)
 331                         self.move_movetype = MOVETYPE_FLY;
 332                 if(self.move_movetype == MOVETYPE_BOUNCE)
 333                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 334         }
 335
 336         if(!(self.count & 0x80))
 337                 InterpolateOrigin_Note();
 338
 339         self.draw = Projectile_Draw;
 340         self.entremove = Ent_RemoveProjectile;
 341 }
 342
 343 void Projectile_Precache()
 344 {
 345         precache_model("models/ebomb.mdl");
 346         precache_model("models/elaser.mdl");
 347         precache_model("models/grenademodel.md3");
 348         precache_model("models/hagarmissile.mdl");
 349         precache_model("models/hlac_bullet.md3");
 350         precache_model("models/laser.mdl");
 351         precache_model("models/plasmatrail.mdl");
 352         precache_model("models/rocket.md3");
 353         precache_model("models/tagrocket.md3");
 354         precache_model("models/tracer.mdl");
 355         precache_sound("weapons/electro_fly.wav");
 356         precache_sound("weapons/rocket_fly.wav");
 357         precache_sound("weapons/tag_rocket_fly.wav");
 358 }