data/qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------\r
   2 // BEGIN REQUIRED CSQC FUNCTIONS\r
   3 //include "main.qh"\r
   4 \r
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
   6 \r
   7 void() menu_show_error =\r
   8 {\r
   9         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);\r
  10 };\r
  11 \r
  12 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)\r
  13 // Useful for precaching things\r
  14 \r
  15 void() menu_sub_null =\r
  16 {\r
  17 };\r
  18 \r
  19 // let's make this a general data buffer...\r
  20 float using_gps;\r
  21 \r
  22 #ifdef USE_FTE\r
  23 float __engine_check;\r
  24 #endif\r
  25 \r
  26 string config_get(string key, string defaultvalue)\r
  27 {\r
  28         string s;\r
  29         s = db_get(configdb, strcat("/s/", key));\r
  30         if(s == "")\r
  31                 return defaultvalue;\r
  32         else\r
  33                 return db_get(configdb, strcat("/v/", key));\r
  34 }\r
  35 \r
  36 void CSQC_Init(void)\r
  37 {\r
  38 #ifdef USE_FTE\r
  39 #pragma target ID\r
  40         __engine_check = checkextension("DP_SV_WRITEPICTURE");\r
  41         if(!__engine_check)\r
  42         {\r
  43                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");\r
  44                 localcmd("\ndisconnect\n");\r
  45                 return;\r
  46         }\r
  47 #pragma target FTE\r
  48 #endif\r
  49         \r
  50         float i;\r
  51         CSQC_CheckEngine();\r
  52 \r
  53         configdb = db_create();\r
  54 \r
  55         drawfont = 0;\r
  56         menu_visible = FALSE;\r
  57         menu_show = menu_show_error;\r
  58         menu_action = menu_sub_null;\r
  59         using_gps = false;\r
  60         maxclients = 255; // we later get the real maxclients to speed up stuff\r
  61         //ctf_temp_1 = "";\r
  62         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used\r
  63         //registercmd("ctf_menu");\r
  64         registercmd("ons_map");\r
  65         //registercmd("menu_action");\r
  66         registercmd("sbar_columns_set");\r
  67         registercmd("sbar_columns_help");\r
  68 \r
  69         registercvar("sbar_usecsqc", "1");\r
  70         registercvar("sbar_columns", "default", CVAR_SAVE);\r
  71 \r
  72         gametype = 0;\r
  73 \r
  74         gps_start = world;\r
  75 \r
  76         // sbar_fields uses strunzone on the titles!\r
  77         for(i = 0; i < MAX_SBAR_FIELDS; ++i)\r
  78                 sbar_title[i] = strzone("(null)");\r
  79 \r
  80         postinit = false;\r
  81 \r
  82         teams = Sort_Spawn();\r
  83         players = Sort_Spawn();\r
  84         \r
  85         GetTeam(COLOR_SPECTATOR, true); // add specs first\r
  86 }\r
  87 \r
  88 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)\r
  89 void CSQC_Shutdown(void)\r
  90 {\r
  91 #ifdef USE_FTE\r
  92 #pragma TARGET id\r
  93         if(!__engine_check)\r
  94                 return 0;\r
  95 #pragma TARGET fte\r
  96 #endif\r
  97 \r
  98         remove(teams);\r
  99         remove(players);\r
 100         db_close(configdb);\r
 101 \r
 102         entity e;\r
 103         for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
 104                         cvar_set(e.netname, e.message);\r
 105 }\r
 106 \r
 107 .float has_team;\r
 108 float SetTeam(entity o, float Team)\r
 109 {\r
 110         entity tm;\r
 111         if(Team == -1) // leave\r
 112         {\r
 113                 if(o.has_team)\r
 114                 {\r
 115                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");\r
 116                         tm = GetTeam(o.team, false);\r
 117                         tm.team_size -= 1;\r
 118                         o.has_team = 0;\r
 119                         return TRUE;\r
 120                 }\r
 121         }\r
 122         else\r
 123         {\r
 124                 if not(o.has_team)\r
 125                 {\r
 126                         //print("(CONNECT) enter team ", ftos(o.team), "\n");\r
 127                         o.team = Team;\r
 128                         tm = GetTeam(Team, true);\r
 129                         tm.team_size += 1;\r
 130                         o.has_team = 1;\r
 131                         return TRUE;\r
 132                 }\r
 133                 else if(Team != o.team)\r
 134                 {\r
 135                         //print("(CHANGE) leave team ", ftos(o.team), "\n");\r
 136                         tm = GetTeam(o.team, false);\r
 137                         tm.team_size -= 1;\r
 138                         o.team = Team;\r
 139                         //print("(CHANGE) enter team ", ftos(o.team), "\n");\r
 140                         tm = GetTeam(Team, true);\r
 141                         tm.team_size += 1;\r
 142                         return TRUE;\r
 143                 }\r
 144         }\r
 145         return FALSE;\r
 146 }\r
 147 \r
 148 void Playerchecker_Think()\r
 149 {\r
 150         float i;\r
 151         for(i = 0; i < maxclients; ++i)\r
 152         {\r
 153                 if(getplayerkey(i, "name") == "")\r
 154                 {\r
 155                         if(playerslots[i].sort_prev)\r
 156                         {\r
 157                                 //print("playerchecker: KILL KILL KILL\n");\r
 158                                 // player disconnected\r
 159                                 SetTeam(playerslots[i], -1);\r
 160                                 RemovePlayer(playerslots[i]);\r
 161                                 playerslots[i].sort_prev = world;\r
 162                                 playerslots[i].gotscores = 0;\r
 163                         }\r
 164                 }\r
 165                 else\r
 166                 {\r
 167                         if not(playerslots[i].sort_prev)\r
 168                         {\r
 169                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");\r
 170                                 // player connected\r
 171                                 if not(playerslots[i])\r
 172                                         playerslots[i] = spawn();\r
 173                                 playerslots[i].sv_entnum = i;\r
 174                                 playerslots[i].gotscores = 0;\r
 175                                 SetTeam(playerslots[i], COLOR_SPECTATOR);\r
 176                                 RegisterPlayer(playerslots[i]);\r
 177                                 Sbar_UpdatePlayerPos(playerslots[i]);\r
 178                         }\r
 179                 }\r
 180         }\r
 181         self.nextthink = time + 0.2;\r
 182 }\r
 183 \r
 184 void PostInit(void)\r
 185 {\r
 186         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));\r
 187         localcmd(strcat("\nsbar_columns_set ", cvar_string("sbar_columns"), ";\n"));\r
 188 \r
 189         entity playerchecker;\r
 190         playerchecker = spawn();\r
 191         playerchecker.think = Playerchecker_Think;\r
 192         playerchecker.nextthink = time + 0.2;\r
 193 \r
 194         postinit = true;\r
 195 }\r
 196 \r
 197 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function\r
 198 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.\r
 199 void Cmd_Sbar_SetFields(float);\r
 200 void Cmd_Sbar_Help(float);\r
 201 float CSQC_ConsoleCommand(string strMessage)\r
 202 {\r
 203         float argc;\r
 204         // Tokenize String\r
 205         //argc = tokenize(strMessage);\r
 206         argc = tokenizebyseparator(strMessage, " ");\r
 207         \r
 208         // Acquire Command\r
 209         local string strCmd;\r
 210         strCmd = argv(0);\r
 211 \r
 212         /*if(strCmd == "ctf_menu") {\r
 213                 ctf_menu_show();\r
 214                 nReturn = true;\r
 215                 } else*/\r
 216         if(strCmd == "ons_map") {\r
 217                 Cmd_ons_map();\r
 218                 return true;\r
 219         } else if(strCmd == "sbar_columns_set") {\r
 220                 Cmd_Sbar_SetFields(argc);\r
 221                 return true;\r
 222         } else if(strCmd == "sbar_columns_help") {\r
 223                 Cmd_Sbar_Help(argc);\r
 224                 return true;\r
 225         } else if(strCmd == "+showscores") {\r
 226                 sb_showscores = true;\r
 227                 return true;\r
 228         } else if(strCmd == "-showscores") {\r
 229                 sb_showscores = false;\r
 230                 return true;\r
 231         }\r
 232         \r
 233         return false;\r
 234 }\r
 235 \r
 236 float GameCommand(string msg)\r
 237 {\r
 238         float argc;\r
 239         argc = tokenize(msg);\r
 240         string cmd;\r
 241         cmd = argv(0);\r
 242         if(cmd == "mv_download") {\r
 243                 Cmd_MapVote_MapDownload(argc);\r
 244                 return true;\r
 245         }\r
 246         else if(cmd == "settemp") {\r
 247                 entity e;\r
 248                 for(e = world; (e = find(e, classname, "saved_cvar_value")); )\r
 249                         if(e.netname == argv(1))\r
 250                                 goto saved;\r
 251                 e = spawn();\r
 252                 e.classname = "saved_cvar_value";\r
 253                 e.netname = strzone(argv(1));\r
 254                 e.message = strzone(cvar_string(argv(1)));\r
 255 :saved\r
 256                 cvar_set(argv(1), argv(2));\r
 257         }\r
 258         \r
 259         return false;\r
 260 }\r
 261 \r
 262 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.\r
 263 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.\r
 264 // All keys are in ascii.\r
 265 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.\r
 266 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.\r
 267 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.\r
 268 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)\r
 269 {\r
 270         local float bSkipKey;\r
 271         bSkipKey = false;\r
 272         \r
 273         if(menu_visible)\r
 274                 if(menu_action(bInputType, nPrimary, nSecondary))\r
 275                         return TRUE;\r
 276         return bSkipKey;\r
 277 }\r
 278 \r
 279 // END REQUIRED CSQC FUNCTIONS\r
 280 // --------------------------------------------------------------------------\r
 281 \r
 282 // --------------------------------------------------------------------------\r
 283 // BEGIN OPTIONAL CSQC FUNCTIONS\r
 284 void Ent_ReadONS()\r
 285 {\r
 286         entity gps;\r
 287         using_gps = true;\r
 288 \r
 289         self.origin_x = ReadCoord();\r
 290         self.origin_y = ReadCoord();\r
 291         self.angles_y = ReadCoord();\r
 292         self.origin_z = self.angles_x = self.angles_z = 0;\r
 293 \r
 294         for(gps = gps_start; gps; gps = gps.chain)\r
 295         {\r
 296                 if(gps == self)\r
 297                         break;\r
 298         }\r
 299         if(!gps)\r
 300         {\r
 301                 self.chain = gps_start;\r
 302                 gps_start = self;\r
 303         }\r
 304 }\r
 305 \r
 306 void Ent_RemoveONS()\r
 307 {\r
 308         if(gps_start == self)\r
 309                 gps_start = self.chain;\r
 310         else\r
 311         {\r
 312                 local entity ent;\r
 313                 ent = gps_start;\r
 314                         \r
 315                 while(ent.chain != self && ent.chain != world)\r
 316                         ent = ent.chain;\r
 317                 if(ent.chain == self)\r
 318                         ent.chain = self.chain;\r
 319         }\r
 320 }\r
 321 \r
 322 void Ent_Remove();\r
 323 void Ent_ReadPlayerScore()\r
 324 {\r
 325         float i, Team, n;\r
 326         float isNew;\r
 327         entity o;\r
 328 \r
 329         // damnit -.- don't want to go change every single .sv_entnum in sbar.qc AGAIN\r
 330         // (no I've never heard of M-x replace-string, sed, or anything like that)\r
 331         isNew = !self.owner; // workaround for DP bug\r
 332         n = ReadByte()-1;\r
 333 \r
 334 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 335         if(!isNew && n != self.sv_entnum)\r
 336         {\r
 337                 print("A CSQC entity changed its owner!\n");\r
 338                 isNew = true;\r
 339                 Ent_Remove();\r
 340                 self.enttype = ENT_CLIENT_SCORES;\r
 341         }\r
 342 #endif\r
 343 \r
 344         self.sv_entnum = n;\r
 345         Team = GetPlayerColor(self.sv_entnum);\r
 346 \r
 347         if not(playerslots[self.sv_entnum])\r
 348                 playerslots[self.sv_entnum] = spawn();\r
 349         o = self.owner = playerslots[self.sv_entnum];\r
 350         o.sv_entnum = self.sv_entnum;\r
 351         o.gotscores = 1;\r
 352         if not(o.sort_prev)\r
 353                 RegisterPlayer(o);\r
 354 \r
 355         SetTeam(o, Team);\r
 356 \r
 357 #if MAX_SCORE <= 3\r
 358         for(i = 0; i < MAX_SCORE; ++i)\r
 359                 o.(scores[i]) = ReadShort();\r
 360 #else\r
 361         float sf;\r
 362 #if MAX_SCORE <= 8\r
 363         sf = ReadByte();\r
 364 #else\r
 365         sf = ReadShort();\r
 366 #endif\r
 367         float p;\r
 368         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)\r
 369                 if(sf & p)\r
 370                         o.(scores[i]) = ReadShort();\r
 371 #endif\r
 372 \r
 373         Sbar_UpdatePlayerPos(o);\r
 374 }\r
 375 \r
 376 void Ent_ReadTeamScore()\r
 377 {\r
 378         float i;\r
 379         entity o;\r
 380         \r
 381         self.team = ReadByte();\r
 382         o = self.owner = GetTeam(self.team, true);\r
 383 \r
 384 #if MAX_TEAMSCORE <= 3\r
 385         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 386                 o.(teamscores[i]) = ReadShort();\r
 387 #else\r
 388         float sf;\r
 389 #if MAX_TEAMSCORE <= 8\r
 390         sf = ReadByte();\r
 391 #else\r
 392         sf = ReadShort();\r
 393 #endif\r
 394         float p;\r
 395         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)\r
 396                 if(sf & p)\r
 397                         o.(teamscores[i]) = ReadShort();\r
 398 #endif\r
 399 \r
 400         Sbar_UpdateTeamPos(o);\r
 401 }\r
 402 \r
 403 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.\r
 404 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.\r
 405 void(float bIsNewEntity) CSQC_Ent_Update =\r
 406 {\r
 407         float msg, t;\r
 408         t = ReadByte();\r
 409 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED\r
 410         if(self.enttype)\r
 411                 if(t != self.enttype)\r
 412                 {\r
 413                         print("A CSQC entity changed its type!\n");\r
 414                         Ent_Remove();\r
 415                 }\r
 416 #endif\r
 417         self.enttype = t;\r
 418         if(self.enttype == ENT_CLIENT_ENTCS)\r
 419         {\r
 420                 self.sv_entnum = ReadByte()-1;\r
 421 \r
 422                 for(msg = ReadByte(); msg != ENTCS_MSG_END; msg = ReadByte())\r
 423                 {\r
 424                         switch(msg)\r
 425                         {\r
 426                         case ENTCS_MSG_ONS_GPS: Ent_ReadONS(); break;\r
 427                         case ENTCS_MSG_ONS_REMOVE: Ent_RemoveONS(); break;\r
 428                         default:\r
 429                                 error("unknown ENTCS_MSG type\n");\r
 430                         }\r
 431                 }\r
 432         }\r
 433         else if(self.enttype == ENT_CLIENT_SCORES)\r
 434                 Ent_ReadPlayerScore();\r
 435         else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 436                 Ent_ReadTeamScore();\r
 437         else\r
 438                 error("unknown entity type in CSQC_Ent_Update\n");\r
 439         \r
 440 };\r
 441 // Destructor, but does NOT deallocate the entity by calling remove(). Also\r
 442 // used when an entity changes its type. For an entity that someone interacts\r
 443 // with others, make sure it can no longer do so.\r
 444 void Ent_Remove()\r
 445 {\r
 446         if(self.enttype == ENT_CLIENT_ENTCS)\r
 447         {\r
 448                 if(using_gps) //gametype == GAME_ONSLAUGHT)\r
 449                 {\r
 450                         if(gps_start == self)\r
 451                                 gps_start = self.chain;\r
 452                         else\r
 453                         {\r
 454                                 local entity ent;\r
 455                                 ent = gps_start;\r
 456                         \r
 457                                 while(ent.chain != self && ent.chain != world)\r
 458                                         ent = ent.chain;\r
 459                                 if(ent.chain == self)\r
 460                                         ent.chain = self.chain;\r
 461                         }\r
 462                 }\r
 463         } else if(self.enttype == ENT_CLIENT_SCORES)\r
 464         {\r
 465                 if(self.owner)\r
 466                 {\r
 467                         SetTeam(self.owner, -1);\r
 468                         if(self.owner.sort_prev)\r
 469                                 RemovePlayer(self.owner);\r
 470                         self.owner.sort_prev = NULL;\r
 471                 }\r
 472         } else if(self.enttype == ENT_CLIENT_TEAMSCORES)\r
 473         {\r
 474                 /*\r
 475                 if(self.owner)\r
 476                         RemoveTeam(self.owner);\r
 477                 */\r
 478                 // we don't NEED to remove them... they won't display anyway\r
 479                 // plus, svqc never does this anyway\r
 480         }\r
 481 \r
 482         self.enttype = 0;\r
 483         self.classname = "";\r
 484         // TODO possibly set more stuff to defaults\r
 485 }\r
 486 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.\r
 487 void CSQC_Ent_Remove()\r
 488 {\r
 489         if(self.enttype)\r
 490                 Ent_Remove();\r
 491         remove(self);\r
 492 }\r
 493 \r
 494 void Gamemode_Init()\r
 495 {\r
 496         local string mapinfo, infoline;\r
 497         local float len;\r
 498         local float file;\r
 499         local vector mi_min, mi_max;\r
 500 \r
 501         if(!strcasecmp(substring(mapname, 0, 5), "maps/"))\r
 502                 shortmapname = substring(mapname, 5, 999);\r
 503         else\r
 504                 shortmapname = mapname;\r
 505         len = strlen(shortmapname);\r
 506         if(!strcasecmp(substring(shortmapname, len-4, 4), ".bsp"))\r
 507                 shortmapname = substring(shortmapname, 0, len-4);\r
 508         shortmapname = strzone(shortmapname);\r
 509 \r
 510         if(gametype == GAME_ONSLAUGHT) {\r
 511                 mapinfo = strcat("maps/", minimapname, ".info");\r
 512                 minimapname = strzone(strcat("gfx/", shortmapname, "_mini.tga"));\r
 513 \r
 514                 mi_min = world.mins;\r
 515                 mi_max = world.maxs;\r
 516                 \r
 517                 file = fopen(mapinfo, FILE_READ);\r
 518                 if(file >= 0) {\r
 519                         while((infoline = fgets(file))) {\r
 520                                 if(!strncasecmp(infoline, "mins", 4)) {\r
 521                                         mi_min = stov(substring(infoline, 5, 999));\r
 522                                 } else if(!strncasecmp(infoline, "maxs", 4)) {\r
 523                                         mi_max = stov(substring(infoline, 5, 999));\r
 524                                 } else if(strncasecmp(infoline, "//", 2)) { // don't print comment-style lines\r
 525                                         print(strcat("mapinfo: ", infoline, "\n"));\r
 526                                 }\r
 527                         }\r
 528                 } else {\r
 529                         print(strcat("Map has no .info file (", mapinfo, ").\n"));\r
 530                 }\r
 531                 fclose(file);\r
 532 \r
 533                 print(strcat("Mins: ", vtos(mi_min), "    Maxs: ", vtos(mi_max), "\n"));\r
 534                 \r
 535                 mi_center = (mi_min + mi_max) * 0.5;\r
 536                 mi_scale = mi_max - mi_min;\r
 537                 \r
 538                 \r
 539                 print(strcat("Using ", minimapname, " as minimap.\n"));\r
 540                 precache_pic(minimapname);\r
 541                 precache_pic("gfx/ons-cp-neutral.tga");\r
 542                 precache_pic("gfx/ons-cp-red.tga");\r
 543                 precache_pic("gfx/ons-cp-blue.tga");\r
 544                 precache_pic("gfx/ons-frame.tga");\r
 545                 precache_pic("gfx/ons-frame-team.tga");\r
 546         } else if(gametype == GAME_KEYHUNT) {\r
 547                 precache_pic("gfx/sb_key_carrying");\r
 548                 precache_pic("gfx/sb_key_carrying_outline");\r
 549         }\r
 550 }\r
 551 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.\r
 552 void CSQC_Parse_StuffCmd(string strMessage)\r
 553 {\r
 554         localcmd(strMessage);\r
 555 }\r
 556 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.\r
 557 void CSQC_Parse_Print(string strMessage)\r
 558 {\r
 559         print(strMessage);\r
 560 }\r
 561 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.  To execute standard behavior, simply execute cprint with the string.\r
 562 void CSQC_Parse_CenterPrint(string strMessage)\r
 563 {\r
 564         cprint(strMessage);\r
 565 }\r
 566 \r
 567 void CSQC_CheckRevision();\r
 568 \r
 569 void Gamemode_Init();\r
 570 void Net_ReadScoresInfo()\r
 571 {\r
 572         float i;\r
 573         gametype = ReadByte();\r
 574         for(i = 0; i < MAX_SCORE; ++i)\r
 575         {\r
 576                 scores_label[i] = strzone(ReadString());\r
 577                 scores_flags[i] = ReadByte();\r
 578         }\r
 579         for(i = 0; i < MAX_TEAMSCORE; ++i)\r
 580         {\r
 581                 teamscores_label[i] = strzone(ReadString());\r
 582                 teamscores_flags[i] = ReadByte();\r
 583         }\r
 584         Sbar_InitScores();\r
 585         Gamemode_Init();\r
 586 }\r
 587 \r
 588 void Net_ReadInit()\r
 589 {\r
 590         csqc_revision = ReadShort();\r
 591         maxclients = ReadByte();\r
 592 \r
 593         CSQC_CheckRevision();\r
 594 }\r
 595 \r
 596 string Net_ReadPicture()\r
 597 {\r
 598         string img;\r
 599         if(csqc_flags & CSQC_FLAG_READPICTURE)\r
 600         {\r
 601                 img = ReadPicture();\r
 602                 print(strcat("Got Picture: ", img, "\n"));\r
 603         } else {\r
 604                 img = ReadString();\r
 605                 print(strcat("^3Warning: ^7Couldn't download ", img, ". This is probably because your engine build is outdated.\n"));\r
 606                 float psize, i;\r
 607                 psize = ReadShort();\r
 608                 // Can I be sure that ReadShort is 2 bytes and ReadLong is 4 bytes?\r
 609                 // Because then this could be optimized to first get all 4-byte-groups,\r
 610                 // then the remaining 2, then the remaining 1\r
 611                 for(i = 0; i < psize; ++i)\r
 612                         ReadByte();\r
 613         }\r
 614         return img;\r
 615 }\r
 616 \r
 617 void Net_Config()\r
 618 {\r
 619         string key, value;\r
 620         key = ReadString();\r
 621         value = ReadString();\r
 622         db_put(configdb, strcat("/v/", key), value);\r
 623         db_put(configdb, strcat("/s/", key), "1");\r
 624 }\r
 625 \r
 626 void Net_ReadRace()\r
 627 {\r
 628         float b;\r
 629 \r
 630         b = ReadByte();\r
 631 \r
 632         switch(b)\r
 633         {\r
 634                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:\r
 635                         race_checkpoint = ReadByte();\r
 636                         race_time = ReadShort();\r
 637                         race_previousbesttime = ReadShort();\r
 638                         if(race_previousbestname)\r
 639                                 strunzone(race_previousbestname);\r
 640                         race_previousbestname = strzone(ReadString());\r
 641 \r
 642                         race_checkpointtime = time;\r
 643 \r
 644                         if(race_checkpoint == 0)\r
 645                                 race_laptime = time; // valid\r
 646 \r
 647                         break;\r
 648 \r
 649                 case RACE_NET_CHECKPOINT_CLEAR:\r
 650                         race_laptime = 0;\r
 651                         race_checkpointtime = 0;\r
 652                         break;\r
 653 \r
 654                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:\r
 655                         race_laptime = ReadCoord();\r
 656                         race_checkpointtime = -99999;\r
 657                         // fall through\r
 658                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:\r
 659                         race_nextcheckpoint = ReadByte();\r
 660 \r
 661                         race_nextbesttime = ReadShort();\r
 662                         if(race_nextbestname)\r
 663                                 strunzone(race_nextbestname);\r
 664                         race_nextbestname = strzone(ReadString());\r
 665                         break;\r
 666 \r
 667                 case RACE_NET_CHECKPOINT_HIT_RACE:\r
 668                         race_mycheckpoint = ReadByte();\r
 669                         race_mycheckpointtime = time;\r
 670                         race_mycheckpointdelta = ReadShort();\r
 671                         race_mycheckpointlapsdelta = ReadByte();\r
 672                         if(race_mycheckpointlapsdelta >= 128)\r
 673                                 race_mycheckpointlapsdelta -= 256;\r
 674                         if(race_mycheckpointenemy)\r
 675                                 strunzone(race_mycheckpointenemy);\r
 676                         race_mycheckpointenemy = strzone(ReadString());\r
 677                         break;\r
 678 \r
 679                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:\r
 680                         race_othercheckpoint = ReadByte();\r
 681                         race_othercheckpointtime = time;\r
 682                         race_othercheckpointdelta = ReadShort();\r
 683                         race_othercheckpointlapsdelta = ReadByte();\r
 684                         if(race_othercheckpointlapsdelta >= 128)\r
 685                                 race_othercheckpointlapsdelta -= 256;\r
 686                         if(race_othercheckpointenemy)\r
 687                                 strunzone(race_othercheckpointenemy);\r
 688                         race_othercheckpointenemy = strzone(ReadString());\r
 689                         break;\r
 690         }\r
 691 }\r
 692 \r
 693 void Net_ReadForceScoreboard()\r
 694 {\r
 695         sb_showscores_force = ReadByte();\r
 696 }\r
 697 \r
 698 void Net_Reset()\r
 699 {\r
 700         race_laptime = 0;\r
 701         race_checkpointtime = 0;\r
 702 }\r
 703 \r
 704 void Net_ReadSpectating()\r
 705 {\r
 706         float newspectatee_status;\r
 707         newspectatee_status = ReadByte();\r
 708         if(newspectatee_status == player_localentnum)\r
 709                 newspectatee_status = -1; // observing\r
 710         if(newspectatee_status != spectatee_status)\r
 711                 Net_Reset();\r
 712         spectatee_status = newspectatee_status;\r
 713 }\r
 714 \r
 715 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.\r
 716 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.\r
 717 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.\r
 718 float CSQC_Parse_TempEntity()\r
 719 {\r
 720         local float bHandled;\r
 721                 bHandled  = true;\r
 722         // Acquire TE ID\r
 723         local float nTEID;\r
 724                 nTEID = ReadByte();\r
 725 \r
 726                 // NOTE: Could just do return instead of break...\r
 727         switch(nTEID)\r
 728         {\r
 729                 case TE_CSQC_INIT:\r
 730                         Net_ReadInit();\r
 731                         bHandled = true;\r
 732                         break;\r
 733                 case TE_CSQC_MAPVOTE:\r
 734                         Net_Mapvote();\r
 735                         bHandled = true;\r
 736                         break;\r
 737                 case TE_CSQC_CONFIG:\r
 738                         Net_Config();\r
 739                         bHandled = true;\r
 740                         break;\r
 741                 case TE_CSQC_SCORESINFO:\r
 742                         Net_ReadScoresInfo();\r
 743                         bHandled = true;\r
 744                         break;\r
 745                 case TE_CSQC_RACE:\r
 746                         Net_ReadRace();\r
 747                         bHandled = true;\r
 748                         break;\r
 749                 case TE_CSQC_FORCESCOREBOARD:\r
 750                         Net_ReadForceScoreboard();\r
 751                         bHandled = true;\r
 752                         break;\r
 753                 case TE_CSQC_SPECTATING:\r
 754                         Net_ReadSpectating();\r
 755                         bHandled = true;\r
 756                         break;\r
 757                 case 13: // TE_BEAM\r
 758                         Net_GrapplingHook();\r
 759                         bHandled = true;\r
 760                         break;\r
 761                 default:\r
 762                         // No special logic for this temporary entity; return 0 so the engine can handle it\r
 763                         bHandled = false;\r
 764                         break;\r
 765         }\r
 766         \r
 767         if(!postinit)\r
 768                 PostInit();\r
 769                 \r
 770         return bHandled;\r
 771 }\r
 772 \r
 773 // COMMIT-TODO: Update if necessare, before committing\r
 774 void CSQC_CheckRevision()\r
 775 {\r
 776         if(csqc_revision == CSQC_REVISION)\r
 777         {\r
 778                 print("^2SVQC and CSQC revisions are compatible.\n");\r
 779         } else if(csqc_revision < CSQC_REVISION) {\r
 780                 print("^1Your csprogs.dat (CSQC) version is newer than the one on the server.\n");\r
 781         } else if(csqc_revision > CSQC_REVISION) {\r
 782                 print("^1Your csprogs.dat (CSQC) is too old for this server.\n");\r
 783                 print("^1Please update to a newer version.\n");\r
 784         }\r
 785 }\r