data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4         relocate_spawnpoint();
   5 }
   6
   7 void info_player_deathmatch (void)
   8 {
   9         relocate_spawnpoint();
  10 }
  11
  12 float spawn_allbad;
  13 float spawn_allgood;
  14 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  15 {
  16         local entity spot, player, nextspot, previousspot, newfirstspot;
  17         local float pcount;
  18         spot = firstspot;
  19         newfirstspot = world;
  20         previousspot = world;
  21         spawn_allgood = TRUE;
  22         spawn_allbad = TRUE;
  23         while (spot)
  24         {
  25                 nextspot = spot.chain;
  26                 // count team mismatches as bad spots
  27                 if (spot.team == teamcheck)
  28                 {
  29                         pcount = 0;
  30                         player = playerlist;
  31                         while (player)
  32                         {
  33                                 if (player != self)
  34                                 if (vlen(player.origin - spot.origin) < mindist)
  35                                         pcount = pcount + 1;
  36                                 player = player.chain;
  37                         }
  38                         if (!pcount)
  39                         {
  40                                 spawn_allbad = FALSE;
  41                                 if (newfirstspot)
  42                                         previousspot.chain = spot;
  43                                 else
  44                                         newfirstspot = spot;
  45                                 previousspot = spot;
  46                                 spot.chain = world;
  47                         }
  48                         else
  49                                 spawn_allgood = FALSE;
  50                 }
  51                 spot = nextspot;
  52         }
  53         // if we couldn't find ANY good points, return the original list
  54         if (!newfirstspot)
  55                 newfirstspot = firstspot;
  56         return newfirstspot;
  57 }
  58
  59 entity Spawn_RandomPoint(entity firstspot)
  60 {
  61         local entity spot;
  62         local float numspots;
  63         // count number of spots
  64         numspots = 0;
  65         spot = firstspot;
  66         while (spot)
  67         {
  68                 numspots = numspots + 1;
  69                 spot = spot.chain;
  70         }
  71         // pick a random one
  72         numspots = numspots * random();
  73         spot = firstspot;
  74         while (spot.chain && numspots >= 1)
  75         {
  76                 numspots = numspots - 1;
  77                 spot = spot.chain;
  78         }
  79         return spot;
  80 }
  81
  82 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  83 {
  84         local entity best, spot, player;
  85         local float bestrating, rating;
  86         best = world;
  87         bestrating = -1000000;
  88         spot = firstspot;
  89         while (spot)
  90         {
  91                 rating = 1000000000;
  92                 player = playerlist;
  93                 while (player)
  94                 {
  95                         if (player != self)
  96                                 rating = min(rating, vlen(player.origin - spot.origin));
  97                         player = player.chain;
  98                 }
  99                 rating = rating + random() * 16;
 100                 if (bestrating < rating)
 101                 {
 102                         best = spot;
 103                         bestrating = rating;
 104                 }
 105                 spot = spot.chain;
 106         }
 107         return best;
 108 }
 109
 110 /*
 111 =============
 112 SelectSpawnPoint
 113
 114 Finds a point to respawn
 115 =============
 116 */
 117 entity SelectSpawnPoint (float anypoint)
 118 {
 119         local float teamcheck;
 120         local entity spot, firstspot, playerlist;
 121         string spotname;
 122
 123         spot = find (world, classname, "testplayerstart");
 124         if (spot)
 125                 return spot;
 126
 127         spotname = "info_player_deathmatch";
 128         teamcheck = 0;
 129
 130         if(!anypoint && cvar("g_ctf") )
 131                 teamcheck = self.team;
 132
 133         // get the list of players
 134         playerlist = findchain(classname, "player");
 135         // get the entire list of spots
 136         firstspot = findchain(classname, "info_player_deathmatch");
 137         // filter out the bad ones
 138         // (note this returns the original list if none survived)
 139         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 140
 141         // there is 50/50 chance of choosing a random spot or the furthest spot
 142         // (this means that roughly every other spawn will be furthest, so you
 143         // usually won't get fragged at spawn twice in a row)
 144         if (random() > 0.5 || spawn_allbad || spawn_allgood)
 145                 spot = Spawn_RandomPoint(firstspot);
 146         else
 147                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 148
 149         if (!spot)
 150         {
 151                 if(cvar("spawn_debug"))
 152                         GotoNextMap();
 153                 else
 154                         error ("PutClientInServer: no start points on level");
 155         }
 156
 157         return spot;
 158 }
 159
 160 /*
 161 =============
 162 CheckPlayerModel
 163
 164 Checks if the argument string can be a valid playermodel.
 165 Returns a valid one in doubt.
 166 =============
 167 */
 168 string CheckPlayerModel(string plyermodel) {
 169         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 170
 171         /* Possible Fixme: Check if server can open the model?
 172            This would kill custom models, however. */
 173
 174         return plyermodel;
 175 }
 176
 177 /*
 178 =============
 179 Client_customizeentityforclient
 180
 181 LOD reduction
 182 =============
 183 */
 184 float Client_customizeentityforclient()
 185 {
 186 #ifdef ALLOW_VARIABLE_LOD
 187         // self: me
 188         // other: the player viewing me
 189         float distance;
 190         float f;
 191
 192         distance = vlen(self.origin - other.origin);
 193         f = (distance + 100.0) * other.cvar_cl_playerdetailreduction;
 194         if(f > 10000)
 195         {
 196                 self.modelindex = self.modelindex_lod2;
 197         }
 198         else if(f > 5000)
 199         {
 200                 self.modelindex = self.modelindex_lod1;
 201         }
 202         else
 203         {
 204                 self.modelindex = self.modelindex_lod0;
 205         }
 206 #endif
 207
 208         return TRUE;
 209 }
 210
 211 float fexists(string f)
 212 {
 213         float fh;
 214         fh = fopen(f, FILE_READ);
 215         if(fh < 0)
 216                 return FALSE;
 217         fclose(fh);
 218         return TRUE;
 219 }
 220
 221 void setmodel_lod(entity e, string modelname)
 222 {
 223 #ifdef ALLOW_VARIABLE_LOD
 224         string s;
 225
 226         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_1.zym");
 227         if(fexists(s))
 228         {
 229                 precache_model(s);
 230                 setmodel(e, s);
 231                 self.modelindex_lod1 = self.modelindex;
 232         }
 233         else
 234                 self.modelindex_lod1 = -1;
 235
 236         s = strcat(substring(modelname, 0, strlen(modelname) - 4), "_2.zym");
 237         if(fexists(s))
 238         {
 239                 precache_model(s);
 240                 setmodel(e, s);
 241                 self.modelindex_lod2 = self.modelindex;
 242         }
 243         else
 244                 self.modelindex_lod2 = -1;
 245
 246         precache_model(modelname);
 247         setmodel(e, modelname);
 248         self.modelindex_lod0 = self.modelindex;
 249
 250         if(self.modelindex_lod1 < 0)
 251                 self.modelindex_lod1 = self.modelindex;
 252
 253         if(self.modelindex_lod2 < 0)
 254                 self.modelindex_lod2 = self.modelindex;
 255 #else
 256         precache_model(modelname);
 257         setmodel(e, modelname);
 258 #endif
 259 }
 260
 261 /*
 262 =============
 263 PutObserverInServer
 264
 265 putting a client as observer in the server
 266 =============
 267 */
 268 void PutObserverInServer (void)
 269 {
 270         entity  spot;
 271         spot = SelectSpawnPoint (FALSE);
 272         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 273
 274         if(clienttype(self) == CLIENTTYPE_REAL)
 275         {
 276                 msg_entity = self;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, self);
 279         }
 280
 281         if (cvar("g_runematch"))
 282                 DropAllRunes(self);
 283
 284         if(self.frags <= 0 && self.frags > -666 && cvar("g_lms") && self.killcount != -666)
 285                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 286         else if(self.killcount != -666)
 287                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 288
 289         self.classname = "observer";
 290         self.health = -666;
 291         self.takedamage = DAMAGE_NO;
 292         self.solid = SOLID_NOT;
 293         self.movetype = MOVETYPE_NOCLIP;
 294         self.flags = FL_CLIENT | FL_NOTARGET;
 295         self.armorvalue = 666;
 296         self.effects = 0;
 297         self.armorvalue = cvar("g_balance_armor_start");
 298         self.pauserotarmor_finished = 0;
 299         self.pauserothealth_finished = 0;
 300         self.pauseregen_finished = 0;
 301         self.damageforcescale = 0;
 302         self.death_time = 0;
 303         self.dead_time = 0;
 304         self.dead_frame = 0;
 305         self.die_frame = 0;
 306         self.deaths = 0;
 307         self.alpha = 0;
 308         self.scale = 0;
 309         self.fade_time = 0;
 310         self.pain_frame = 0;
 311         self.pain_finished = 0;
 312         self.strength_finished = 0;
 313         self.invincible_finished = 0;
 314         self.pushltime = 0;
 315         self.think = SUB_Null;
 316         self.nextthink = 0;
 317         self.hook_time = 0;
 318         self.runes = 0;
 319         self.deadflag = DEAD_NO;
 320         self.angles = spot.angles;
 321         self.angles_z = 0;
 322         self.fixangle = TRUE;
 323         self.crouch = FALSE;
 324         self.view_ofs = PL_VIEW_OFS;
 325         setorigin (self, spot.origin);
 326         setsize (self, '0 0 0', '0 0 0');
 327         self.oldorigin = self.origin;
 328         self.items = 0;
 329         self.model = "";
 330         self.modelindex = 0;
 331         self.weapon = 0;
 332         self.weaponmodel = "";
 333         self.weaponframe = 0;
 334         self.weaponentity = world;
 335         self.killcount = -666;
 336         self.velocity = '0 0 0';
 337         self.avelocity = '0 0 0';
 338         self.punchangle = '0 0 0';
 339         self.punchvector = '0 0 0';
 340         self.oldvelocity = self.velocity;
 341
 342         if(cvar("g_arena"))
 343         {
 344                 if(self.frags != -2)
 345                 {
 346                         Spawnqueue_Insert(self);
 347                 }
 348                 else
 349                 {
 350                         Spawnqueue_Unmark(self);
 351                         Spawnqueue_Remove(self);
 352                 }
 353         }
 354         else if(!cvar("g_lms"))
 355                 self.frags = -666;
 356 }
 357
 358
 359 /*
 360 =============
 361 PutClientInServer
 362
 363 Called when a client spawns in the server
 364 =============
 365 */
 366 void PutClientInServer (void)
 367 {
 368         if(clienttype(self) == CLIENTTYPE_BOT)
 369         {
 370                 self.classname = "player";
 371         }
 372         else if(clienttype(self) == CLIENTTYPE_REAL)
 373         {
 374                 msg_entity = self;
 375                 WriteByte(MSG_ONE, SVC_SETVIEW);
 376                 WriteEntity(MSG_ONE, self);
 377         }
 378
 379         // player is dead and becomes observer
 380         if(cvar("g_lms") && self.frags < 1)
 381                 self.classname = "observer";
 382
 383         if(cvar("g_arena"))
 384         if(!self.spawned)
 385                 self.classname = "observer";
 386
 387         if(self.classname == "player") {
 388                 entity  spot;
 389
 390                 spot = SelectSpawnPoint (FALSE);
 391
 392                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 393
 394                 self.classname = "player";
 395                 self.iscreature = TRUE;
 396                 self.movetype = MOVETYPE_WALK;
 397                 self.solid = SOLID_SLIDEBOX;
 398                 self.flags = FL_CLIENT;
 399                 self.takedamage = DAMAGE_AIM;
 400                 self.effects = 0;
 401                 self.health = cvar("g_balance_health_start");
 402                 self.armorvalue = cvar("g_balance_armor_start");
 403                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 404                 self.pauserotarmor_finished = time + cvar("g_balance_pause_armor_rot_spawn");
 405                 self.pauserothealth_finished = time + cvar("g_balance_pause_health_rot_spawn");
 406                 self.pauseregen_finished = time + cvar("g_balance_pause_health_regen_spawn");
 407                 self.damageforcescale = 2;
 408                 self.death_time = 0;
 409                 self.dead_time = 0;
 410                 self.dead_frame = 0;
 411                 self.die_frame = 0;
 412                 self.alpha = 0;
 413                 self.scale = 0;
 414                 self.fade_time = 0;
 415                 self.pain_frame = 0;
 416                 self.pain_finished = 0;
 417                 self.strength_finished = 0;
 418                 self.invincible_finished = 0;
 419                 self.pushltime = 0;
 420                 //self.speed_finished = 0;
 421                 //self.slowmo_finished = 0;
 422                 // players have no think function
 423                 self.think = SUB_Null;
 424                 self.nextthink = 0;
 425                 self.weapon = 0;
 426                 self.switchweapon = 0;
 427                 self.hook_time = 0;
 428
 429                 self.runes = 0;
 430
 431                 self.deadflag = DEAD_NO;
 432
 433                 self.angles = spot.angles;
 434
 435                 self.angles_z = 0; // never spawn tilted even if the spot says to
 436                 self.fixangle = TRUE; // turn this way immediately
 437                 self.velocity = '0 0 0';
 438                 self.avelocity = '0 0 0';
 439                 self.punchangle = '0 0 0';
 440                 self.punchvector = '0 0 0';
 441                 self.oldvelocity = self.velocity;
 442
 443                 self.viewzoom = 0.6;
 444
 445                 self.customizeentityforclient = Client_customizeentityforclient;
 446
 447                 if(cvar("sv_defaultcharacter") == 1) {
 448                         local string defaultmodel;
 449                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 450                         setmodel_lod (self, defaultmodel);
 451                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 452                 } else {
 453                         self.playermodel = CheckPlayerModel(self.playermodel);
 454                         setmodel_lod (self, self.playermodel);
 455                         self.skin = stof(self.playerskin);
 456
 457                 }
 458
 459                 self.crouch = FALSE;
 460                 self.view_ofs = PL_VIEW_OFS;
 461                 setsize (self, PL_MIN, PL_MAX);
 462                 self.spawnorigin = spot.origin;
 463                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 464                 // don't reset back to last position, even if new position is stuck in solid
 465                 self.oldorigin = self.origin;
 466
 467                 if(cvar("g_lms"))
 468                 {
 469                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 470                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 471                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 472                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 473                         self.health = cvar("g_lms_start_health");
 474                         self.armorvalue = cvar("g_lms_start_armor");
 475                 }
 476                 else if (cvar("g_use_ammunition")) {
 477                         self.ammo_shells = cvar("g_start_ammo_shells");
 478                         self.ammo_nails = cvar("g_start_ammo_nails");
 479                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 480                         self.ammo_cells = cvar("g_start_ammo_cells");
 481                 } else {
 482                         self.ammo_shells = 999;
 483                         self.ammo_nails = 999;
 484                         self.ammo_rockets = 999;
 485                         self.ammo_cells = 999;
 486                 }
 487
 488                 self.items = 0;
 489                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 490                 {
 491                         self.items = self.items | IT_LASER;
 492                         self.switchweapon = WEP_LASER;
 493                 }
 494                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 495                 {
 496                         self.items = self.items | IT_SHOTGUN;
 497                         self.switchweapon = WEP_SHOTGUN;
 498                 }
 499                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 500                 {
 501                         self.items = self.items | IT_UZI;
 502                         self.switchweapon = WEP_UZI;
 503                 }
 504                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 505                 {
 506                         self.items = self.items | IT_GRENADE_LAUNCHER;
 507                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 508                 }
 509                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 510                 {
 511                         self.items = self.items | IT_ELECTRO;
 512                         self.switchweapon = WEP_ELECTRO;
 513                 }
 514                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 515                 {
 516                         self.items = self.items | IT_CRYLINK;
 517                         self.switchweapon = WEP_CRYLINK;
 518                 }
 519                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 520                 {
 521                         self.items = self.items | IT_NEX;
 522                         self.switchweapon = WEP_NEX;
 523                 }
 524                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 525                 {
 526                         self.items = self.items | IT_HAGAR;
 527                         self.switchweapon = WEP_HAGAR;
 528                 }
 529                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 530                 {
 531                         self.items = self.items | IT_ROCKET_LAUNCHER;
 532                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 533                 }
 534
 535                 if(cvar("g_instagib"))
 536                 {
 537                         self.items = IT_NEX;
 538                         self.switchweapon = WEP_NEX;
 539                         self.ammo_cells = 999;
 540                 }
 541
 542                 if(cvar("g_rocketarena"))
 543                 {
 544                         self.items = IT_ROCKET_LAUNCHER;
 545                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 546                         self.ammo_rockets = 999;
 547                 }
 548
 549                 if(cvar("g_nixnex"))
 550                 {
 551                         self.items = 0;
 552                         // will be done later
 553                 }
 554
 555                 if(cvar("g_minstagib"))
 556                 {
 557                         self.health = 100;
 558                         self.armorvalue = 0;
 559                         self.items = IT_NEX;
 560                         self.switchweapon = WEP_NEX;
 561                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 562                         self.extralives = 0;
 563                         self.jump_interval = time;
 564                 }
 565
 566                 if(cvar("g_arena"))
 567                         Spawnqueue_Remove(self);
 568
 569                 self.event_damage = PlayerDamage;
 570
 571                 self.bot_attack = TRUE;
 572
 573                 self.statdraintime = time + 5;
 574                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 575
 576                 if(self.killcount == -666) {
 577                         self.killcount = 0;
 578                         if(!cvar("g_arena"))
 579                                 self.frags = 0;
 580                 }
 581
 582                 self.cnt = WEP_LASER;
 583                 self.nixnex_lastchange_id = -1;
 584
 585                 /*
 586                 W_UpdateWeapon();
 587                 W_UpdateAmmo();
 588                 */
 589                 CL_SpawnWeaponentity();
 590                 self.alpha = default_player_alpha;
 591                 self.exteriorweaponentity.alpha = default_player_alpha;
 592
 593                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval")*2;
 594                 self.lms_traveled_distance = 0;
 595
 596                 if(cvar("spawn_debug"))
 597                 {
 598                                 sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 599                                 remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 600                 }
 601
 602                 //stuffcmd(self, "chase_active 0");
 603                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 604         } else if(self.classname == "observer") {
 605                 PutObserverInServer ();
 606         }
 607 }
 608
 609 /*
 610 =============
 611 SetNewParms
 612 =============
 613 */
 614 void SetNewParms (void)
 615 {
 616
 617 }
 618
 619 /*
 620 =============
 621 SetChangeParms
 622 =============
 623 */
 624 void SetChangeParms (void)
 625 {
 626
 627 }
 628
 629 /*
 630 =============
 631 ClientKill
 632
 633 Called when a client types 'kill' in the console
 634 =============
 635 */
 636 void ClientKill (void)
 637 {
 638         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 639 }
 640
 641 /*
 642 =============
 643 ClientConnect
 644
 645 Called when a client connects to the server
 646 =============
 647 */
 648 string ColoredTeamName(float t);
 649 //void dom_player_join_team(entity pl);
 650 void ClientConnect (void)
 651 {
 652         self.classname = "player_joining";
 653         self.flags = self.flags | FL_CLIENT;
 654
 655         if(player_count<0) player_count = 0;
 656
 657         bot_clientconnect();
 658
 659         //if(cvar("g_domination"))
 660         //      dom_player_join_team(self);
 661
 662         //JoinBestTeam(self, FALSE);
 663
 664         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 665                 self.classname = "observer";
 666         } else {
 667                 self.classname = "player";
 668                 campaign_bots_may_start = 1;
 669         }
 670
 671         self.playerid = (playerid_last = playerid_last + 1);
 672         if(cvar("sv_eventlog"))
 673         {
 674                 string s;
 675                 if(clienttype(self) == CLIENTTYPE_REAL)
 676                         s = "player";
 677                 else
 678                         s = "bot";
 679                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", s, ":", self.netname), TRUE);
 680                 s = strcat(":team:", ftos(self.playerid), ":");
 681                 s = strcat(s, ftos(self.team));
 682                 GameLogEcho(s, FALSE);
 683         }
 684
 685         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 686
 687         bprint ("^4",self.netname);
 688         bprint ("^4 connected");
 689
 690         if(cvar("g_domination") || cvar("g_ctf"))
 691         {
 692                 bprint(" and joined the ");
 693                 bprint(ColoredTeamName(self.team));
 694         }
 695
 696         bprint("\n");
 697
 698         self.welcomemessage_time = time + cvar("welcome_message_time");
 699         self.welcomemessage_time2 = 0;
 700
 701         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 702         // send prediction settings to the client
 703         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 704         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 705         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 706         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 707         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 708         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 709         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 710         stuffcmd(self, strcat("set cl_movement_friction_on_land ", ftos(cvar("sv_friction_on_land")), "\n"));
 711         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 712         // Wazat's grappling hook
 713         SetGrappleHookBindings();
 714
 715         // get autoswitch state from player
 716         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 717         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 718
 719         // get version info from player
 720         stuffcmd(self, "cmd clientversion $gameversion\n");
 721
 722         // get other cvars from player
 723         GetCvars(0);
 724
 725         // set cvar for team scoreboard
 726         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 727
 728         if(cvar("g_lms"))
 729         {
 730                 self.frags = cvar("fraglimit");
 731                 // no fraglimit was set, so player gets 999 lives
 732                 if(self.frags < 1)
 733                         self.frags = 999;
 734
 735                 // disallow player to join after the worst player has lost g_lms_last_join lives
 736                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 737                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 738                 {
 739                         self.frags = -666;
 740                         lms_dead_count += 1;
 741                 }
 742                 else if(cvar("fraglimit") > lms_lowest_lives)
 743                 {
 744                         self.frags = lms_lowest_lives;
 745                 }
 746         }
 747         else if(cvar("g_arena"))
 748         {
 749                 self.classname = "observer";
 750                 Spawnqueue_Insert(self);
 751         }
 752
 753         bot_relinkplayerlist();
 754
 755         self.jointime = time;
 756 }
 757
 758 /*
 759 =============
 760 ClientDisconnect
 761
 762 Called when a client disconnects from the server
 763 =============
 764 */
 765 void(entity e) DropFlag;
 766 .entity chatbubbleentity;
 767 .entity teambubbleentity;
 768 void ClientDisconnect (void)
 769 {
 770         float save;
 771         if(cvar("sv_eventlog"))
 772                 GameLogEcho(strcat(":part:", ftos(self.playerid)), FALSE);
 773         bprint ("^4",self.netname);
 774         bprint ("^4 disconnected\n");
 775
 776         if (self.chatbubbleentity)
 777         {
 778                 remove (self.chatbubbleentity);
 779                 self.chatbubbleentity = world;
 780         }
 781
 782         if (self.teambubbleentity)
 783         {
 784                 remove (self.teambubbleentity);
 785                 self.teambubbleentity = world;
 786         }
 787
 788         DropAllRunes(self);
 789
 790         if(self.flagcarried)
 791                 DropFlag(self.flagcarried);
 792
 793         save = self.flags;
 794         self.flags = self.flags - (self.flags & FL_CLIENT);
 795         bot_relinkplayerlist();
 796         self.flags = save;
 797
 798         // player was dead, decrease dead count
 799         if(cvar("g_lms") && self.frags < 1)
 800                 lms_dead_count -= 1;
 801         else if(cvar("g_arena"))
 802         {
 803                 Spawnqueue_Unmark(self);
 804                 Spawnqueue_Remove(self);
 805         }
 806 }
 807
 808 .float buttonchat;
 809 void() ChatBubbleThink =
 810 {
 811         self.nextthink = time;
 812         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 813         {
 814                 remove(self);
 815                 return;
 816         }
 817         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 818         if (self.owner.buttonchat && !self.owner.deadflag)
 819                 self.model = self.mdl;
 820         else
 821                 self.model = "";
 822 };
 823
 824 void() UpdateChatBubble =
 825 {
 826         if (!self.modelindex)
 827                 return;
 828         // spawn a chatbubble entity if needed
 829         if (!self.chatbubbleentity)
 830         {
 831                 self.chatbubbleentity = spawn();
 832                 self.chatbubbleentity.owner = self;
 833                 self.chatbubbleentity.exteriormodeltoclient = self;
 834                 self.chatbubbleentity.think = ChatBubbleThink;
 835                 self.chatbubbleentity.nextthink = time;
 836                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 837                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 838                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 839                 self.chatbubbleentity.model = "";
 840         }
 841 }
 842
 843
 844 void() TeamBubbleThink =
 845 {
 846         self.nextthink = time;
 847         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 848         {
 849                 remove(self);
 850                 return;
 851         }
 852 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 853         if (self.owner.buttonchat || self.owner.deadflag)
 854                 self.model = "";
 855         else
 856                 self.model = self.mdl;
 857
 858 };
 859
 860 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 861
 862 void() UpdateTeamBubble =
 863 {
 864         if (!self.modelindex || !cvar("teamplay"))
 865                 return;
 866         // spawn a teambubble entity if needed
 867         if (!self.teambubbleentity && cvar("teamplay"))
 868         {
 869                 self.teambubbleentity = spawn();
 870                 self.teambubbleentity.owner = self;
 871                 self.teambubbleentity.exteriormodeltoclient = self;
 872                 self.teambubbleentity.think = TeamBubbleThink;
 873                 self.teambubbleentity.nextthink = time;
 874                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 875 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 876                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 877                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 878                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 879                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 880                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 881         }
 882 }
 883
 884 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 885 // added to the model skins
 886 /*void() UpdateColorModHack =
 887 {
 888         local float c;
 889         c = self.clientcolors & 15;
 890         // LordHavoc: only bothering to support white, green, red, yellow, blue
 891              if (teamplay == 0) self.colormod = '0 0 0';
 892         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 893         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 894         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 895         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 896         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 897         else self.colormod = '1 1 1';
 898 };*/
 899
 900 void UpdatePlayerColors () {
 901         if(self.weaponentity) {
 902                 self.weaponentity.colormap = self.colormap;
 903                 self.exteriorweaponentity.colormap = self.colormap;
 904         }
 905 }
 906 /*
 907 =============
 908 PlayerJump
 909
 910 When you press the jump key
 911 =============
 912 */
 913 void PlayerJump (void)
 914 {
 915         float mjumpheight;
 916
 917         mjumpheight = cvar("g_balance_jumpheight");
 918         if (self.waterlevel >= 2)
 919         {
 920                 if (self.watertype == CONTENT_WATER)
 921                         self.velocity_z = 200;
 922                 else if (self.watertype == CONTENT_SLIME)
 923                         self.velocity_z = 80;
 924                 else
 925                         self.velocity_z = 50;
 926
 927                 return;
 928         }
 929
 930
 931         if (!(self.flags & FL_ONGROUND))
 932                 return;
 933
 934         if (!(self.flags & FL_JUMPRELEASED))
 935                 return;
 936
 937         if(cvar("g_runematch"))
 938         {
 939                 if(self.runes & RUNE_SPEED)
 940                 {
 941                         if(self.runes & CURSE_SLOW)
 942                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 943                         else
 944                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 945                 }
 946                 else if(self.runes & CURSE_SLOW)
 947                 {
 948                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 949                 }
 950         }
 951
 952         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 953         {
 954                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 955         }
 956
 957         self.velocity_z = self.velocity_z + mjumpheight;
 958         self.oldvelocity_z = self.velocity_z;
 959
 960         self.flags = self.flags - FL_ONGROUND;
 961         self.flags = self.flags - FL_JUMPRELEASED;
 962 }
 963
 964 void() CheckWaterJump =
 965 {
 966         local vector start, end;
 967
 968 // check for a jump-out-of-water
 969         makevectors (self.angles);
 970         start = self.origin;
 971         start_z = start_z + 8;
 972         v_forward_z = 0;
 973         normalize(v_forward);
 974         end = start + v_forward*24;
 975         traceline (start, end, TRUE, self);
 976         if (trace_fraction < 1)
 977         {       // solid at waist
 978                 start_z = start_z + self.maxs_z - 8;
 979                 end = start + v_forward*24;
 980                 self.movedir = trace_plane_normal * -50;
 981                 traceline (start, end, TRUE, self);
 982                 if (trace_fraction == 1)
 983                 {       // open at eye level
 984                         self.flags = self.flags | FL_WATERJUMP;
 985                         self.velocity_z = 225;
 986                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 987                         self.teleport_time = time + 2;  // safety net
 988                         return;
 989                 }
 990         }
 991 };
 992
 993
 994 void respawn(void)
 995 {
 996         CopyBody(1);
 997         PutClientInServer();
 998 }
 999
1000 void player_powerups (void)
1001 {
1002         if (cvar("g_minstagib"))
1003         {
1004                 self.effects = EF_FULLBRIGHT;
1005                 if (self.items & IT_STRENGTH)
1006                 {
1007                         if (time > self.strength_finished)
1008                         {
1009                                 self.alpha = default_player_alpha;
1010                                 self.exteriorweaponentity.alpha = default_player_alpha;
1011                                 self.items = self.items - (self.items & IT_STRENGTH);
1012                                 sprint(self, "^3Invisibility has worn off\n");
1013                         }
1014                 }
1015                 else
1016                 {
1017                         if (time < self.strength_finished)
1018                         {
1019                                 self.alpha = cvar("g_minstagib_invis_alpha");
1020                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
1021                                 self.items = self.items | IT_STRENGTH;
1022                                 sprint(self, "^3You are invisible\n");
1023                         }
1024                 }
1025
1026                 if (self.items & IT_INVINCIBLE)
1027                 {
1028                         if (time > self.invincible_finished)
1029                         {
1030                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1031                                 sprint(self, "^3Speed has worn off\n");
1032                         }
1033                 }
1034                 else
1035                 {
1036                         if (time < self.invincible_finished)
1037                         {
1038                                 self.items = self.items | IT_INVINCIBLE;
1039                                 sprint(self, "^3You are on speed\n");
1040                         }
1041                 }
1042                 return;
1043         }
1044
1045         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
1046         if (self.items & IT_STRENGTH)
1047         {
1048                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1049                 if (time > self.strength_finished)
1050                 {
1051                         self.items = self.items - (self.items & IT_STRENGTH);
1052                         sprint(self, "^3Strength has worn off\n");
1053                 }
1054         }
1055         else
1056         {
1057                 if (time < self.strength_finished)
1058                 {
1059                         self.items = self.items | IT_STRENGTH;
1060                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
1061                 }
1062         }
1063         if (self.items & IT_INVINCIBLE)
1064         {
1065                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1066                 if (time > self.invincible_finished)
1067                 {
1068                         self.items = self.items - (self.items & IT_INVINCIBLE);
1069                         sprint(self, "^3Shield has worn off\n");
1070                 }
1071         }
1072         else
1073         {
1074                 if (time < self.invincible_finished)
1075                 {
1076                         self.items = self.items | IT_INVINCIBLE;
1077                         sprint(self, "^3Shield surrounds you\n");
1078                 }
1079         }
1080
1081         if (cvar("g_fullbrightplayers"))
1082                 self.effects = self.effects | EF_FULLBRIGHT;
1083
1084         // midair gamemode: damage only while in the air
1085         // if in midair mode, being on ground grants temporary invulnerability
1086         // (this is so that multishot weapon don't clear the ground flag on the
1087         // first damage in the frame, leaving the player vulnerable to the
1088         // remaining hits in the same frame)
1089         if (self.flags & FL_ONGROUND)
1090         if (cvar("g_midair"))
1091                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
1092
1093         if (time < self.spawnshieldtime)
1094                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1095 }
1096
1097 void player_regen (void)
1098 {
1099         float maxh, maxa, limith, limita, max_mod, regen_mod, rot_mod, limit_mod;
1100         maxh = cvar("g_balance_health_stable");
1101         maxa = cvar("g_balance_armor_stable");
1102         limith = cvar("g_balance_health_limit");
1103         limita = cvar("g_balance_armor_limit");
1104
1105         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
1106                 return;
1107
1108         if(cvar("g_runematch"))
1109         {
1110                 max_mod = regen_mod = rot_mod = limit_mod = 1;
1111                 if (self.runes & RUNE_REGEN)
1112                 {
1113                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
1114                         {
1115                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
1116                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
1117                                 limit_mod = cvar("g_balance_rune_regen_combo_limitmod");
1118                         }
1119                         else
1120                         {
1121                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
1122                                 max_mod = cvar("g_balance_rune_regen_hpmod");
1123                                 limit_mod = cvar("g_balance_rune_regen_limitmod");
1124                         }
1125                 }
1126                 else if (self.runes & CURSE_VENOM)
1127                 {
1128                         max_mod = cvar("g_balance_curse_venom_hpmod");
1129                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
1130                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
1131                         else
1132                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
1133                         limit_mod = cvar("g_balance_curse_venom_limitmod");
1134                         //if (!self.runes & RUNE_REGEN)
1135                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
1136                 }
1137                 maxh = maxh * max_mod;
1138                 //maxa = maxa * max_mod;
1139
1140                 if (time > self.pauserotarmor_finished)
1141                 {
1142                         if (self.armorvalue > maxa)
1143                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1144                 }
1145                 if (time > self.pauserothealth_finished)
1146                 {
1147                         if (self.health > maxh)
1148                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
1149                 }
1150                 if (time > self.pauseregen_finished)
1151                 {
1152                         if (self.health < maxh)
1153                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime  + 0.001, 1000);
1154                         if (self.armorvalue < maxa)
1155                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime  + 0.001, 1000);
1156                 }
1157         }
1158         else
1159         {
1160                 if (time > self.pauserothealth_finished)
1161                 if (self.health > maxh)
1162                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
1163                 if (time > self.pauserotarmor_finished)
1164                 if (self.armorvalue > maxa)
1165                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
1166                 if (time > self.pauseregen_finished)
1167                 {
1168                         if (self.health < maxh)
1169                                  self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_regen") * frametime + 0.001, 1000);
1170                         if (self.armorvalue < maxa)
1171                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime + 0.001, 1000);
1172                 }
1173         }
1174
1175         if (self.health > limith)
1176                 self.health = limith;
1177         if(self.health < 1)
1178                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1179         if (self.armorvalue > limita)
1180                 self.armorvalue = limita;
1181 }
1182
1183 /*
1184 ======================
1185 spectate mode routines
1186 ======================
1187 */
1188 void SpectateCopy(entity spectatee) {
1189         self.armortype = spectatee.armortype;
1190         self.armorvalue = spectatee.armorvalue;
1191         self.currentammo = spectatee.currentammo;
1192         self.effects = spectatee.effects;
1193         self.health = spectatee.health;
1194         self.impulse = 0;
1195         self.items = spectatee.items;
1196         self.punchangle = spectatee.punchangle;
1197         self.view_ofs = spectatee.view_ofs;
1198         self.v_angle = spectatee.v_angle;
1199         self.viewzoom = spectatee.viewzoom;
1200         setorigin(self, spectatee.origin);
1201         setsize(self, spectatee.mins, spectatee.maxs);
1202 }
1203
1204 void SpectateUpdate() {
1205         if (self != self.enemy) {
1206                 if(self.enemy.flags & FL_NOTARGET)
1207                         PutObserverInServer();
1208                 SpectateCopy(self.enemy);
1209                 self.dmg_take = self.enemy.dmg_take;
1210                 self.dmg_save = self.enemy.dmg_save;
1211                 self.dmg_inflictor = self.enemy.dmg_inflictor;
1212                 self.fixangle = TRUE;
1213                 self.angles = self.enemy.v_angle;
1214                 //msg_entity = self;
1215                 //WriteByte(MSG_ONE, SVC_SETANGLE);
1216                 //WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1217                 //WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1218                 //WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1219         }
1220 }
1221
1222 float SpectateNext() {
1223         other = find(self.enemy, classname, "player");
1224         if (!other) {
1225                 other = find(other, classname, "player");
1226         }
1227         if (other) {
1228                 self.enemy = other;
1229         }
1230         if(self.enemy.classname == "player") {
1231                 msg_entity = self;
1232                 WriteByte(MSG_ONE, SVC_SETVIEW);
1233                 WriteEntity(MSG_ONE, self.enemy);
1234                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1235                 SpectateUpdate();
1236                 return 1;
1237         } else {
1238                 return 0;
1239         }
1240 }
1241
1242 /*
1243 =============
1244 PlayerPreThink
1245
1246 Called every frame for each client before the physics are run
1247 =============
1248 */
1249 void PlayerPreThink (void)
1250 {
1251         if(self.classname == "player") {
1252                 local vector m1, m2;
1253
1254 //              if(self.netname == "Wazat")
1255 //                      bprint(strcat(self.classname, "\n"));
1256
1257                 CheckRules_Player();
1258
1259                 if(self.button7)
1260                         PrintWelcomeMessage(self);
1261
1262                 if(cvar("g_lms") || !cvar("sv_spectate"))
1263                 if((time - self.jointime) <= cvar("welcome_message_time"))
1264                         PrintWelcomeMessage(self);
1265
1266                 if (intermission_running)
1267                 {
1268                         IntermissionThink ();   // otherwise a button could be missed between
1269                         return;                                 // the think tics
1270                 }
1271
1272                 if (self.deadflag != DEAD_NO)
1273                 {
1274                         player_anim();
1275                         weapon_freeze();
1276                         if (self.deadflag == DEAD_DYING)
1277                         {
1278                                 if (time > self.dead_time)
1279                                         self.deadflag = DEAD_DEAD;
1280                         }
1281                         else if (self.deadflag == DEAD_DEAD)
1282                         {
1283                                 if (cvar("g_lms") || cvar("g_arena") || cvar("g_forced_respawn"))
1284                                         self.deadflag = DEAD_RESPAWNABLE;
1285                                 else if (!self.button0 && !self.button2 && !self.button3)
1286                                         self.deadflag = DEAD_RESPAWNABLE;
1287                         }
1288                         else if (self.deadflag == DEAD_RESPAWNABLE)
1289                         {
1290                                 if (self.button0  ||
1291                                     self.button2  ||
1292                                     self.button3  ||
1293                                     self.button4  ||
1294                                     self.button5  ||
1295                                     self.button6  ||
1296                                     self.button7  ||
1297                                     self.button8  ||
1298                                     self.buttonuse ||
1299                                     cvar("g_lms") ||
1300                                     cvar("g_forced_respawn"))
1301                                         respawn();
1302                         }
1303                         return;
1304                 }
1305
1306                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1307                 {
1308                         vector dist;
1309
1310                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1311                         dist = self.oldorigin - self.origin;
1312                         dist_z = 0;
1313                         self.lms_traveled_distance += fabs(vlen(dist));
1314
1315                         if(time > self.lms_nextcheck)
1316                         {
1317                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1318                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1319                                 {
1320                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1321                                         // FIXME KadaverJack: gibbing player here causes playermodel to bounce around, instead of eye.md3
1322                                         // I wasn't able to find out WHY that happens, so I put a workaround in place that shall prevent players from being gibbed :(
1323                                         Damage(self, self, self, bound(0, cvar("g_lms_campcheck_damage"), self.health + self.armorvalue * cvar("g_balance_armor_blockpercent") + 5), DEATH_CAMP, self.origin, '0 0 0');
1324                                 }
1325                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1326                                 self.lms_traveled_distance = 0;
1327                         }
1328                 }
1329
1330                 if (self.button5 && !self.hook.state)
1331                 {
1332                         if (!self.crouch)
1333                         {
1334                                 self.crouch = TRUE;
1335                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1336                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1337                         }
1338                 }
1339                 else
1340                 {
1341                         if (self.crouch)
1342                         {
1343                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1344                                 if (!trace_startsolid)
1345                                 {
1346                                         self.crouch = FALSE;
1347                                         self.view_ofs = PL_VIEW_OFS;
1348                                         setsize (self, PL_MIN, PL_MAX);
1349                                 }
1350                         }
1351                 }
1352
1353                 if(cvar("sv_defaultcharacter") == 1) {
1354                         local string defaultmodel;
1355                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1356
1357                         if (defaultmodel != self.model)
1358                         {
1359                                 m1 = self.mins;
1360                                 m2 = self.maxs;
1361                                 setmodel_lod (self, defaultmodel);
1362                                 setsize (self, m1, m2);
1363                         }
1364
1365                         if (self.skin != cvar("sv_defaultplayerskin"))
1366                                 self.skin = cvar("sv_defaultplayerskin");
1367                 } else {
1368                         if (self.playermodel != self.model)
1369                         {
1370                                 self.playermodel = CheckPlayerModel(self.playermodel);
1371                                 m1 = self.mins;
1372                                 m2 = self.maxs;
1373                                 setmodel_lod (self, self.playermodel);
1374                                 setsize (self, m1, m2);
1375                         }
1376
1377                         if (self.skin != stof(self.playerskin))
1378                                 self.skin = stof(self.playerskin);
1379                 }
1380                 // Savage: Check for nameless players
1381                 if (strlen(self.netname) < 1) {
1382                         self.netname = "Player";
1383                         stuffcmd(self, "name Player\n");
1384                 }
1385
1386                 GrapplingHookFrame();
1387
1388                 W_WeaponFrame();
1389
1390                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1391                 {
1392                         if (cvar("g_minstagib") && self.button3)
1393                         {
1394                                 if (self.jump_interval <= (time + 0.1))
1395                                 {
1396                                         self.jump_interval = time + 1;
1397                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1398                                 }
1399                         }
1400                         else if (self.viewzoom > 0.4)
1401                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1402                 }
1403                 else if (self.viewzoom < 1.0)
1404                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1405
1406
1407                 if (self.button2)
1408                         PlayerJump ();
1409                 else
1410                         self.flags = self.flags | FL_JUMPRELEASED;
1411
1412                 player_powerups();
1413                 player_regen();
1414                 player_anim();
1415
1416                 //self.angles_y=self.v_angle_y + 90;   // temp
1417
1418                 if (self.waterlevel == 2)
1419                         CheckWaterJump ();
1420
1421                 //if (TetrisPreFrame()) return;
1422         } else if(gameover) {
1423                 if (intermission_running)
1424                         IntermissionThink ();   // otherwise a button could be missed between
1425                 return;
1426         } else if(self.classname == "observer") {
1427
1428                 if (self.flags & FL_JUMPRELEASED) {
1429                         if (self.button2 && self.version == cvar("gameversion")) {
1430                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1431                                         self.flags = self.flags & !FL_JUMPRELEASED;
1432                                         self.classname = "player";
1433                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1434                                                 JoinBestTeam(self, 0);
1435                                         if(cvar("g_campaign"))
1436                                                 campaign_bots_may_start = 1;
1437                                         PutClientInServer();
1438                                         if(self.flags & !FL_NOTARGET)
1439                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1440                                         centerprint(self,"");
1441                                         return;
1442                                 } else {
1443                                         self.flags = self.flags & !FL_JUMPRELEASED;
1444                                         stuffcmd(self,"menu_showteamselect\n");
1445                                         return;
1446                                 }
1447                         } else if(self.button0 && self.version == cvar("gameversion")) {
1448                                 self.flags = self.flags & !FL_JUMPRELEASED;
1449                                 if(SpectateNext() == 1) {
1450                                         self.classname = "spectator";
1451                                 }
1452                         }
1453                 } else {
1454                         if (!(self.button0 || self.button2)) {
1455                                 self.flags = self.flags | FL_JUMPRELEASED;
1456                         }
1457                 }
1458                 PrintWelcomeMessage(self);
1459         } else if(self.classname == "spectator") {
1460
1461                 if (self.flags & FL_JUMPRELEASED) {
1462                         if (self.button2 && self.version == cvar("gameversion")) {
1463                                 if(!cvar("teamplay") || cvar("g_campaign") || cvar("g_balance_teams")) {
1464                                         self.flags = self.flags & !FL_JUMPRELEASED;
1465                                         self.classname = "player";
1466                                         if(!cvar("g_lms"))
1467                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1468
1469                                         if(cvar("g_campaign") || cvar("g_balance_teams"))
1470                                                 JoinBestTeam(self, 0);
1471                                         if(cvar("g_campaign"))
1472                                                 campaign_bots_may_start = 1;
1473                                         PutClientInServer();
1474                                         centerprint(self,"");
1475                                         return;
1476                                 } else {
1477                                         self.flags = self.flags & !FL_JUMPRELEASED;
1478                                         stuffcmd(self,"menu_showteamselect\n");
1479                                         return;
1480                                 }
1481                         } else if(self.button0) {
1482                                 self.flags = self.flags & !FL_JUMPRELEASED;
1483                                 if(SpectateNext() == 1) {
1484                                         self.classname = "spectator";
1485                                 } else {
1486                                         self.classname = "observer";
1487                                         PutClientInServer();
1488                                 }
1489                         } else if (self.button3) {
1490                                 self.flags = self.flags & !FL_JUMPRELEASED;
1491                                 self.classname = "observer";
1492                                 PutClientInServer();
1493                         } else {
1494                                 SpectateUpdate();
1495                         }
1496         } else {
1497                 if (!(self.button0 || self.button3)) {
1498                         self.flags = self.flags | FL_JUMPRELEASED;
1499                 }
1500                 }
1501                 PrintWelcomeMessage(self);
1502         }
1503 }
1504
1505
1506 /*
1507 =============
1508 PlayerPostThink
1509
1510 Called every frame for each client after the physics are run
1511 =============
1512 */
1513 void PlayerPostThink (void)
1514 {
1515         if(self.classname == "player") {
1516                 CheckRules_Player();
1517                 UpdateChatBubble();
1518                 UpdateTeamBubble();
1519                 UpdatePlayerColors();
1520                 if (self.deadflag == DEAD_NO)
1521                 if (self.impulse)
1522                         ImpulseCommands ();
1523                 if (intermission_running)
1524                         return;         // intermission or finale
1525
1526                 //PrintWelcomeMessage(self);
1527                 //if (TetrisPostFrame()) return;
1528         } else if (self.classname == "observer") {
1529                 //do nothing
1530         } else if (self.classname == "spectator") {
1531                 //do nothing
1532         }
1533         Arena_Warmup();
1534 }