data/qcsrc/server/cl_player.qc

   1
   2 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
   3 // merged player_run and player_stand to player_anim
   4 // added death animations to player_anim
   5 // can now spawn thrown weapons from anywhere, not just from players
   6 // thrown weapons now fade out after 20 seconds
   7 // created PlayerGib function
   8 // PlayerDie no longer uses hitloc or damage
   9 // PlayerDie now supports dying animations as well as gibbing
  10 // cleaned up PlayerDie a lot
  11 // added CopyBody
  12
  13 .entity pusher;
  14 .float pushltime;
  15
  16 void CopyBody(float keepvelocity)
  17 {
  18         local entity oldself;
  19         if (self.effects & EF_NODRAW)
  20                 return;
  21         oldself = self;
  22         self = spawn();
  23         self.enemy = oldself;
  24         self.lip = oldself.lip;
  25         self.colormap = oldself.colormap;
  26         self.iscreature = oldself.iscreature;
  27         self.angles = oldself.angles;
  28         self.avelocity = oldself.avelocity;
  29         self.classname = "body";
  30         self.damageforcescale = oldself.damageforcescale;
  31         self.effects = oldself.effects;
  32         self.event_damage = oldself.event_damage;
  33         self.animstate_startframe = oldself.animstate_startframe;
  34         self.animstate_numframes = oldself.animstate_numframes;
  35         self.animstate_framerate = oldself.animstate_framerate;
  36         self.animstate_starttime = oldself.animstate_starttime;
  37         self.animstate_endtime = oldself.animstate_endtime;
  38         self.animstate_override = oldself.animstate_override;
  39         self.animstate_looping = oldself.animstate_looping;
  40         self.frame = oldself.frame;
  41         self.dead_frame = oldself.dead_frame;
  42         self.pain_finished = oldself.pain_finished;
  43         self.health = oldself.health;
  44         self.armorvalue = oldself.armorvalue;
  45         self.armortype = oldself.armortype;
  46         self.model = oldself.model;
  47         self.modelindex = oldself.modelindex;
  48         self.movetype = oldself.movetype;
  49         self.nextthink = oldself.nextthink;
  50         self.skin = oldself.skin;
  51         self.solid = oldself.solid;
  52         self.takedamage = oldself.takedamage;
  53         self.think = oldself.think;
  54         self.gibrandom = oldself.gibrandom;
  55         self.customizeentityforclient = oldself.customizeentityforclient;
  56         if (keepvelocity == 1)
  57                 self.velocity = oldself.velocity;
  58         self.oldvelocity = self.velocity;
  59         self.fade_time = oldself.fade_time;
  60         self.fade_rate = oldself.fade_rate;
  61         //self.weapon = oldself.weapon;
  62         setorigin(self, oldself.origin);
  63         setsize(self, oldself.mins, oldself.maxs);
  64         self.oldorigin = oldself.origin;
  65         self = oldself;
  66 }
  67
  68 float animparseerror;
  69 vector(float animfile) animparseline =
  70 {
  71         local string line;
  72         local float c;
  73         local vector anim;
  74         if (animfile < 0)
  75                 return '0 1 2';
  76         line = fgets(animfile);
  77         c = tokenize(line);
  78         if (c != 3)
  79         {
  80                 animparseerror = TRUE;
  81                 return '0 1 2';
  82         }
  83         anim_x = stof(argv(0));
  84         anim_y = stof(argv(1));
  85         anim_z = stof(argv(2));
  86         // don't allow completely bogus values
  87         if (anim_x < 0 || anim_y < 1 || anim_z < 0.001)
  88                 anim = '0 1 2';
  89         return anim;
  90 };
  91
  92 void() player_setupanimsformodel =
  93 {
  94         local string animfilename;
  95         local float animfile;
  96         // defaults for legacy .zym models without animinfo files
  97         self.anim_die1 = '0 1 0.5'; // 2 seconds
  98         self.anim_die2 = '1 1 0.5'; // 2 seconds
  99         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 100         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 101         self.anim_duckwalk = '4 1 1';
 102         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 103         self.anim_duckidle = '6 1 1';
 104         self.anim_idle = '7 1 1';
 105         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 106         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 107         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 108         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 109         self.anim_taunt = '12 1 1'; // FIXME?  there is no code using this anim
 110         self.anim_run = '13 1 1';
 111         self.anim_runbackwards = '14 1 1';
 112         self.anim_strafeleft = '15 1 1';
 113         self.anim_straferight = '16 1 1';
 114         self.anim_dead1 = '17 1 1';
 115         self.anim_dead2 = '18 1 1';
 116         self.anim_forwardright = '19 1 1';
 117         self.anim_forwardleft = '20 1 1';
 118         self.anim_backright = '21 1 1';
 119         self.anim_backleft  = '22 1 1';
 120         animparseerror = FALSE;
 121         animfilename = strcat(self.model, ".animinfo");
 122         animfile = fopen(animfilename, FILE_READ);
 123         if (animfile >= 0)
 124         {
 125                 self.anim_die1         = animparseline(animfile);
 126                 self.anim_die2         = animparseline(animfile);
 127                 self.anim_draw         = animparseline(animfile);
 128                 self.anim_duck         = animparseline(animfile);
 129                 self.anim_duckwalk     = animparseline(animfile);
 130                 self.anim_duckjump     = animparseline(animfile);
 131                 self.anim_duckidle     = animparseline(animfile);
 132                 self.anim_idle         = animparseline(animfile);
 133                 self.anim_jump         = animparseline(animfile);
 134                 self.anim_pain1        = animparseline(animfile);
 135                 self.anim_pain2        = animparseline(animfile);
 136                 self.anim_shoot        = animparseline(animfile);
 137                 self.anim_taunt        = animparseline(animfile);
 138                 self.anim_run          = animparseline(animfile);
 139                 self.anim_runbackwards = animparseline(animfile);
 140                 self.anim_strafeleft   = animparseline(animfile);
 141                 self.anim_straferight  = animparseline(animfile);
 142                 self.anim_forwardright = animparseline(animfile);
 143                 self.anim_forwardleft  = animparseline(animfile);
 144                 self.anim_backright    = animparseline(animfile);
 145                 self.anim_backleft     = animparseline(animfile);
 146                 fclose(animfile);
 147
 148                 // derived anims
 149                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 150                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 151
 152                 if (animparseerror)
 153                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 154         }
 155         else
 156                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 157         // reset animstate now
 158         player_setanim(self.anim_idle, TRUE, FALSE, TRUE);
 159 };
 160
 161 void(vector anim, float looping, float override, float restart) player_setanim =
 162 {
 163         if (!restart)
 164         if (anim_x == self.animstate_startframe)
 165         if (anim_y == self.animstate_numframes)
 166         if (anim_z == self.animstate_framerate)
 167                 return;
 168         self.animstate_startframe = anim_x;
 169         self.animstate_numframes = anim_y;
 170         self.animstate_framerate = anim_z;
 171         self.animstate_starttime = time;
 172         self.animstate_endtime = time + self.animstate_numframes / self.animstate_framerate;
 173         self.animstate_looping = looping;
 174         self.animstate_override = override;
 175         self.frame = self.animstate_startframe;
 176 };
 177
 178 void() player_updateframe =
 179 {
 180         if (time >= self.animstate_endtime)
 181         {
 182                 if (self.animstate_looping)
 183                 {
 184                         self.animstate_starttime = self.animstate_endtime;
 185                         self.animstate_endtime = self.animstate_endtime + self.animstate_numframes / self.animstate_framerate;
 186                 }
 187                 self.animstate_override = FALSE;
 188         }
 189         self.frame = self.animstate_startframe + bound(0, (time - self.animstate_starttime) * self.animstate_framerate, self.animstate_numframes - 1);
 190 };
 191
 192 void player_anim (void)
 193 {
 194         player_updateframe();
 195
 196         if (self.deadflag != DEAD_NO)
 197         {
 198                 if (time > self.animstate_endtime)
 199                 {
 200                         if (self.maxs_z > 5)
 201                         {
 202                                 self.maxs_z = 5;
 203                                 setsize(self, self.mins, self.maxs);
 204                         }
 205                         self.frame = self.dead_frame;
 206                 }
 207                 return;
 208         }
 209
 210         if (!self.animstate_override)
 211         {
 212                 if (!(self.flags & FL_ONGROUND))
 213                 {
 214                         if (self.crouch)
 215                                 player_setanim(self.anim_duckjump, FALSE, TRUE, FALSE);
 216                         else
 217                                 player_setanim(self.anim_jump, FALSE, TRUE, FALSE);
 218                 }
 219                 else if (self.crouch)
 220                 {
 221                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 222                                 player_setanim(self.anim_duckwalk, TRUE, FALSE, FALSE);
 223                         else
 224                                 player_setanim(self.anim_duckidle, TRUE, FALSE, FALSE);
 225                 }
 226                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 227                 {
 228                         if (self.movement_x > 0 && self.movement_y == 0)
 229                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 230                         else if (self.movement_x < 0 && self.movement_y == 0)
 231                                 player_setanim(self.anim_runbackwards, TRUE, FALSE, FALSE);
 232                         else if (self.movement_x == 0 && self.movement_y > 0)
 233                                 player_setanim(self.anim_straferight, TRUE, FALSE, FALSE);
 234                         else if (self.movement_x == 0 && self.movement_y < 0)
 235                                 player_setanim(self.anim_strafeleft, TRUE, FALSE, FALSE);
 236                         else if (self.movement_x > 0 && self.movement_y > 0)
 237                                 player_setanim(self.anim_forwardright, TRUE, FALSE, FALSE);
 238                         else if (self.movement_x > 0 && self.movement_y < 0)
 239                                 player_setanim(self.anim_forwardleft, TRUE, FALSE, FALSE);
 240                         else if (self.movement_x < 0 && self.movement_y > 0)
 241                                 player_setanim(self.anim_backright, TRUE, FALSE, FALSE);
 242                         else if (self.movement_x < 0 && self.movement_y < 0)
 243                                 player_setanim(self.anim_backleft, TRUE, FALSE, FALSE);
 244                         else
 245                                 player_setanim(self.anim_run, TRUE, FALSE, FALSE);
 246                 }
 247                 else
 248                         player_setanim(self.anim_idle, TRUE, FALSE, FALSE);
 249         }
 250 }
 251 //End change by Supajoe on 11:44 PM EST 11/16/03 (Subject: Player animations)
 252
 253 void SpawnThrownWeapon (vector org, float w)
 254 {
 255         W_ThrowWeapon(randomvec() * 100 + '0 0 200', org - self.origin, FALSE);
 256 }
 257
 258 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 259 {
 260         local float take, save, gentle;
 261         gentle = cvar("sv_gentle");
 262         if(gentle < 1)
 263                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 264         // damage resistance (ignore most of the damage from a bullet or similar)
 265         damage = max(damage - 5, 1);
 266
 267         save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 268         take = bound(0, damage - save, damage);
 269
 270         if (save > 10)
 271                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 272         else if (take > 30)
 273                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 274         else if (take > 10)
 275                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 276
 277         if(gentle < 1) {
 278                 if (take > 50)
 279                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 280                 if (take > 100)
 281                         TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 282         }
 283
 284         if (!(self.flags & FL_GODMODE))
 285         {
 286                 self.armorvalue = self.armorvalue - save;
 287                 self.health = self.health - take;
 288                 // pause regeneration for 5 seconds
 289                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 290         }
 291         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 292         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 293         self.dmg_inflictor = inflictor;
 294
 295         if (self.health <= -50)
 296         {
 297                 // don't use any animations as a gib
 298                 self.frame = 0;
 299                 self.dead_frame = 0;
 300                 // view just above the floor
 301                 self.view_ofs = '0 0 4';
 302
 303                 // make a juicy mess
 304                 local float multiplier;
 305                 multiplier = 1;
 306                 if (cvar("ekg"))
 307                         multiplier = 5;
 308
 309
 310                 // make a meaty mess
 311                 TossGib (self, "models/gibs/eye.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 312
 313                 if(gentle < 1) {
 314                         te_bloodshower (self.origin + self.mins, self.origin + self.maxs, 1200 * multiplier, 1000);
 315                         TossGib (world, "models/gibs/bloodyskull.md3", self.origin + self.view_ofs, self.velocity,0);
 316
 317                         local float c;
 318                         c = 0;
 319
 320                         while (c < multiplier)
 321                         {
 322                                 c = c + 1;
 323                                 //TossGib (world, "models/gibs/gib1.md3", self.origin, self.velocity + randomvec() * 450,0);
 324                                 //TossGib (world, "models/gibs/gib2.md3", self.origin, self.velocity + randomvec() * 450,0);
 325                                 //TossGib (world, "models/gibs/gib3.md3", self.origin, self.velocity + randomvec() * 450,0);
 326                                 //TossGib (world, "models/gibs/gib4.md3", self.origin, self.velocity + randomvec() * 450,0);
 327                                 //TossGib (world, "models/gibs/gib5.md3", self.origin, self.velocity + randomvec() * 450,0);
 328                                 //TossGib (world, "models/gibs/gib6.md3", self.origin, self.velocity + randomvec() * 450,0);
 329
 330                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 331                                 TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 90),0);
 332                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 333                                 //TossGib (world, "models/gibs/arm.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 334                                 TossGib (world, "models/gibs/chest.md3", self.origin + self.view_ofs * 0.5, self.velocity + randomvec() * (random() * 120 + 80),0);
 335                                 //TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * 150,0);
 336                                 TossGib (world, "models/gibs/smallchest.md3", self.origin + self.view_ofs, self.velocity + randomvec() * (random() * 120 + 80),0);
 337                                 TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * (random() * 120 + 85),0);
 338                                 TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * (random() * 120 + 85),0);
 339                                 //TossGib (world, "models/gibs/leg1.md3", self.origin + self.view_ofs * -0.2, self.velocity + randomvec() * 150,0);
 340                                 //TossGib (world, "models/gibs/leg2.md3", self.origin + self.view_ofs * -0.4, self.velocity + randomvec() * 150,0);
 341
 342                                 // these splat on impact
 343                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 344                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 345                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 346                                 TossGib (world, "models/gibs/chunk.mdl", self.origin, self.velocity + randomvec() * 450,1);
 347                         }
 348                         sound (self, CHAN_VOICE, "misc/gib.wav", 1, ATTN_NORM);
 349                 }
 350         }
 351 }
 352
 353 void ClientKill_Now_TeamChange();
 354
 355 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 356 {
 357         local float take, save, waves, sdelay;
 358
 359         damage = damage * bound(1.0, self.cvar_cl_handicap, 100.0);
 360         if(cvar("sv_gentle")) {
 361                 pointparticles(particleeffectnum("damage_hit"), hitloc, force, bound(0, damage, 200));
 362         } else {
 363                 pointparticles(particleeffectnum("blood"), hitloc, force, bound(0, damage, 200));
 364         }
 365
 366         if (self.pain_finished < time)          //Don't switch pain sequences like crazy
 367         {
 368                 if(!cvar("sv_gentle")) {
 369                         if (random() > 0.5)
 370                                 player_setanim(self.anim_pain1, FALSE, TRUE, TRUE);
 371                         else
 372                                 player_setanim(self.anim_pain2, FALSE, TRUE, TRUE);
 373                 }
 374                 self.pain_finished = time + 0.5;        //Supajoe
 375
 376                 // throw off bot aim temporarily
 377                 local float shake;
 378                 shake = damage * 5 / (bound(0,skill,100) + 1);
 379                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 380                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 381         }
 382
 383         if(g_arena)
 384         if(numspawned < 2)
 385                 return;
 386
 387         if (!g_minstagib)
 388         {
 389                 save = bound(0, damage * cvar("g_balance_armor_blockpercent"), self.armorvalue);
 390                 take = bound(0, damage - save, damage);
 391         }
 392         else
 393         {
 394                 save = 0;
 395                 take = damage;
 396         }
 397
 398         if (save > 10)
 399                 sound (self, CHAN_IMPACT, "misc/armorimpact.wav", 1, ATTN_NORM);
 400         else if (take > 30)
 401                 sound (self, CHAN_IMPACT, "misc/bodyimpact2.wav", 1, ATTN_NORM);
 402         else if (take > 10)
 403                 sound (self, CHAN_IMPACT, "misc/bodyimpact1.wav", 1, ATTN_NORM);
 404
 405         if (take > 50)
 406                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.1,1);
 407         if (take > 100)
 408                 TossGib (world, "models/gibs/chunk.mdl", hitloc, force * -0.2,1);
 409
 410         if (time > self.spawnshieldtime)
 411         {
 412                 if (!(self.flags & FL_GODMODE))
 413                 {
 414                         self.armorvalue = self.armorvalue - save;
 415                         self.health = self.health - take;
 416                         // pause regeneration for 5 seconds
 417                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 418                 }
 419                 else
 420                         self.max_armorvalue += (save + take);
 421         }
 422         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 423         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 424         self.dmg_inflictor = inflictor;
 425
 426         if(attacker == self)
 427         {
 428                 // don't reset pushltime for self damage as it may be an attempt to
 429                 // escape a lava pit or similar
 430                 //self.pushltime = 0;
 431         }
 432         else if(attacker.classname == "player" || attacker.classname == "gib")
 433         {
 434                 self.pusher = attacker;
 435                 self.pushltime = time + cvar("g_maxpushtime");
 436         }
 437         else if(time < self.pushltime)
 438         {
 439                 attacker = self.pusher;
 440                 self.pushltime = max(self.pushltime, time + 0.6);
 441         }
 442         else
 443                 self.pushltime = 0;
 444
 445         if (self.health < 1)
 446         {
 447                 float defer_ClientKill_Now_TeamChange;
 448                 defer_ClientKill_Now_TeamChange = FALSE;
 449
 450                 self.deaths += 1;
 451
 452                 // get rid of kill indicator
 453                 if(self.killindicator)
 454                 {
 455                         remove(self.killindicator);
 456                         self.killindicator = world;
 457                         if(self.killindicator_teamchange)
 458                                 defer_ClientKill_Now_TeamChange = TRUE;
 459
 460                         if(self.classname == "body")
 461                         if(deathtype == DEATH_KILL)
 462                         {
 463                                 // for the lemmings fans, a small harmless explosion
 464                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 465                         }
 466                 }
 467
 468                 // become fully visible
 469                 self.alpha = 1;
 470                 // clear selected player display
 471                 ClearSelectedPlayer();
 472                 // throw a weapon
 473                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 474                 // print an obituary message
 475                 Obituary (attacker, self, deathtype);
 476                 DropAllRunes(self);
 477                 if(self == attacker)
 478                         kh_Key_DropAll(self, TRUE);
 479                 else if(attacker.classname == "player" || attacker.classname == "gib")
 480                         kh_Key_DropAll(self, FALSE);
 481                 else
 482                         kh_Key_DropAll(self, TRUE);
 483                 if(self.flagcarried)
 484                         DropFlag(self.flagcarried);
 485                 // clear waypoints
 486                 WaypointSprite_PlayerDead();
 487                 // make the corpse upright (not tilted)
 488                 self.angles_x = 0;
 489                 self.angles_z = 0;
 490                 // don't spin
 491                 self.avelocity = '0 0 0';
 492                 // view from the floor
 493                 self.view_ofs = '0 0 -8';
 494                 // toss the corpse
 495                 self.movetype = MOVETYPE_TOSS;
 496                 // shootable corpse
 497                 self.solid = SOLID_CORPSE;
 498                 // don't stick to the floor
 499                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 500                 // dying animation
 501                 self.deadflag = DEAD_DYING;
 502                 // when to allow respawn
 503                 sdelay = 0;
 504                 waves = 0;
 505                 if(cvar("g_respawn_mapsettings"))
 506                 {
 507                         sdelay = cvar("g_respawn_mapsettings_delay");
 508                         waves = cvar("g_respawn_mapsettings_waves");
 509                 }
 510                 if(!sdelay)
 511                         sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 512                 if(!sdelay)
 513                         sdelay = cvar("g_respawn_delay");
 514                 if(!waves)
 515                         waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 516                 if(!waves)
 517                         waves = cvar("g_respawn_waves");
 518                 if(waves)
 519                         self.death_time = ceil((time + sdelay) / waves) * waves;
 520                 else
 521                         self.death_time = time + sdelay;
 522                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 523                         self.respawn_countdown = 10; // first number to count down from is 10
 524                 else
 525                         self.respawn_countdown = -1; // do not count down
 526                 if (random() < 0.5)
 527                 {
 528                         player_setanim(self.anim_die1, FALSE, TRUE, TRUE);
 529                         self.dead_frame = self.anim_dead1_x;
 530                 }
 531                 else
 532                 {
 533                         player_setanim(self.anim_die2, FALSE, TRUE, TRUE);
 534                         self.dead_frame = self.anim_dead2_x;
 535                 }
 536                 // set damage function to corpse damage
 537                 self.event_damage = PlayerCorpseDamage;
 538                 // call the corpse damage function just in case it wants to gib
 539                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 540                 // set up to fade out later
 541                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 542
 543                 // remove laserdot
 544                 if(self.weaponentity)
 545                         if(self.weaponentity.lasertarget)
 546                                 remove(self.weaponentity.lasertarget);
 547
 548                 if(clienttype(self) == CLIENTTYPE_REAL)
 549                 {
 550                         self.fixangle = TRUE;
 551                         //msg_entity = self;
 552                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 553                         //WriteAngle (MSG_ONE, self.v_angle_x);
 554                         //WriteAngle (MSG_ONE, self.v_angle_y);
 555                         //WriteAngle (MSG_ONE, 80);
 556                 }
 557
 558                 if(g_arena)
 559                         Spawnqueue_Unmark(self);
 560
 561                 if(defer_ClientKill_Now_TeamChange)
 562                         ClientKill_Now_TeamChange();
 563
 564                 if(cvar("sv_gentle")) {
 565                         // remove corpse
 566                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 567                         pointparticles(particleeffectnum("damage_dissolve"), self.origin, force, 1);
 568                 }
 569         }
 570 }
 571
 572 float UpdateSelectedPlayer_countvalue(float v)
 573 {
 574         return max(0, (v - 1.0) / 0.5);
 575 }
 576
 577 // returns: -2 if no hit, otherwise cos of the angle
 578 // uses the global v_angle
 579 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 580 {
 581         vector so, d;
 582         float c;
 583
 584         if(p == self)
 585                 return -2;
 586
 587         if(p.deadflag)
 588                 return -2;
 589
 590         so = self.origin + self.view_ofs;
 591         d = p.origin - so;
 592
 593         // misaimed?
 594         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 595                 return -2;
 596
 597         // now find the cos of the angle...
 598         c = normalize(d) * v_forward;
 599
 600         if(c <= mincosangle)
 601                 return -2;
 602
 603         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 604         if(trace_fraction < 1)
 605                 return -2;
 606
 607         return c;
 608 }
 609
 610 void ClearSelectedPlayer()
 611 {
 612         if(self.selected_player)
 613         {
 614                 centerprint_expire(self, CENTERPRIO_POINT);
 615                 self.selected_player = world;
 616                 self.selected_player_display_needs_update = FALSE;
 617         }
 618 }
 619
 620 void UpdateSelectedPlayer()
 621 {
 622         entity selected;
 623         float selected_score;
 624         selected = world;
 625         selected_score = 0.95; // 18 degrees
 626
 627         if(!cvar("sv_allow_shownames"))
 628                 return;
 629
 630         if(clienttype(self) != CLIENTTYPE_REAL)
 631                 return;
 632
 633         if(self.cvar_cl_shownames == 0)
 634                 return;
 635
 636         if(self.cvar_cl_shownames == 1 && !teams_matter)
 637                 return;
 638
 639         makevectors(self.v_angle); // sets v_forward
 640
 641         // 1. cursor trace is always right
 642         if(self.cursor_trace_ent && self.cursor_trace_ent.classname == "player" && !self.cursor_trace_ent.deadflag)
 643         {
 644                 selected = self.cursor_trace_ent;
 645         }
 646         else
 647         {
 648                 // 2. if we don't have a cursor trace, find the player which is least
 649                 //    mis-aimed at
 650                 entity p;
 651                 FOR_EACH_PLAYER(p)
 652                 {
 653                         float c;
 654                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 655                         if(c >= -1)
 656                         {
 657                                 selected = p;
 658                                 selected_score = c;
 659                         }
 660                 }
 661         }
 662
 663         if(selected)
 664         {
 665                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 666         }
 667         else
 668         {
 669                 if(time < self.selected_player_display_timeout)
 670                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 671                                 selected = self.selected_player;
 672         }
 673
 674         if(selected)
 675         {
 676                 if(selected == self.selected_player)
 677                 {
 678                         float save;
 679                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 680                         self.selected_player_count = self.selected_player_count + frametime;
 681                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 682                         {
 683                                 string namestr, healthstr;
 684                                 namestr = playername(selected);
 685                                 if(teams_matter)
 686                                 {
 687                                         healthstr = ftos(floor(selected.health));
 688                                         if(self.team == selected.team)
 689                                         {
 690                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 691                                                 self.selected_player_display_needs_update = TRUE;
 692                                         }
 693                                 }
 694                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 695                         }
 696                 }
 697                 else
 698                 {
 699                         ClearSelectedPlayer();
 700                         self.selected_player = selected;
 701                         self.selected_player_time = time;
 702                         self.selected_player_count = 0;
 703                         self.selected_player_display_needs_update = FALSE;
 704                 }
 705         }
 706         else
 707         {
 708                 ClearSelectedPlayer();
 709         }
 710
 711         if(self.selected_player)
 712                 self.last_selected_player = self.selected_player;
 713 }
 714
 715 float precache_sound_index (string s) = #19;
 716 void soundto(entity e, entity sounddest, float chan, string samp, float vol, float atten)
 717 {
 718         vector o;
 719         if(clienttype(sounddest) != CLIENTTYPE_REAL)
 720                 return;
 721         o = e.origin + 0.5 * (e.mins + e.maxs);
 722         msg_entity = sounddest;
 723         WriteByte(MSG_ONE, 6);
 724         WriteByte(MSG_ONE, 27); // all bits except SND_LOOPING
 725         WriteByte(MSG_ONE, vol * 255);
 726         WriteByte(MSG_ONE, atten * 64);
 727         WriteEntity(MSG_ONE, e);
 728         WriteByte(MSG_ONE, chan);
 729         WriteShort(MSG_ONE, precache_sound_index(samp));
 730         WriteCoord(MSG_ONE, o_x);
 731         WriteCoord(MSG_ONE, o_y);
 732         WriteCoord(MSG_ONE, o_z);
 733 }
 734
 735 #if 0
 736 .string playersound_attack;
 737 .string playersound_attackinfive;
 738 .string playersound_coverme;
 739 .string playersound_defend;
 740 .string playersound_freelance;
 741 .string playersound_incoming;
 742 .string playersound_meet;
 743 .string playersound_needhelp;
 744 .string playersound_seenflag;
 745 .string playersound_taunt;
 746 .string playersound_teamshoot;
 747 .float modelindex_for_playersound;
 748
 749 float GetVoiceMessageTeamsayType(string type)
 750 {
 751         if(type == "taunt")
 752                 return 0;
 753         if(type == "teamshoot")
 754                 return 2;
 755         return 1;
 756 }
 757
 758 string allvoicesamples = "attack attackinfive coverme defend freelance incoming meet needhelp seenflag taunt teamshoot";
 759 float GetPlayerSoundSampleField_notFound;
 760 .string GetVoiceMessageSampleField(string type)
 761 {
 762         GetPlayerSoundSampleField_notFound = 0;
 763         switch(type)
 764         {
 765                 case "attack":       return playersound_attack;
 766                 case "attackinfive": return playersound_attackinfive;
 767                 case "coverme":      return playersound_coverme;
 768                 case "defend":       return playersound_defend;
 769                 case "freelance":    return playersound_freelance;
 770                 case "incoming":     return playersound_incoming;
 771                 case "meet":         return playersound_meet;
 772                 case "needhelp":     return playersound_needhelp;
 773                 case "seenflag":     return playersound_seenflag;
 774                 case "taunt":        return playersound_taunt;
 775                 case "teamshoot":    return playersound_teamshoot;
 776         }
 777         GetPlayerSoundSampleField_notFound = 1;
 778         return playersound_taunt;
 779 }
 780
 781 .string GetPlayerSoundSampleField(string type)
 782 {
 783         GetPlayerSoundSampleField_notFound = 0;
 784         switch(type)
 785         {
 786                 case "attack":       return playersound_attack;
 787                 default:             return GetVoiceMessageSampleField(type);
 788         }
 789 }
 790
 791 void PrecachePlayerSounds(string f)
 792 {
 793         float fh;
 794         float i, n;
 795         string s;
 796         fh = fopen(f, FILE_READ);
 797         if(fh < 0)
 798                 return;
 799         while((s = fgets(fh)))
 800         {
 801                 if(tokenize(s) != 3)
 802                 {
 803                         dprint("Invalid sound info line: ", s, "\n");
 804                         continue;
 805                 }
 806                 n = stof(argv(2));
 807                 for(i = 1; i <= n; ++i)
 808                         precache_sound(strcat(argv(1), ftos(i), ".wav"));
 809         }
 810         fclose(fh);
 811 }
 812
 813 void LoadPlayerSounds(string f)
 814 {
 815         float fh;
 816         string s;
 817         var .string field;
 818         fh = fopen(f, FILE_READ);
 819         if(fh < 0)
 820                 return;
 821         while((s = fgets(fh)))
 822         {
 823                 if(tokenize(s) != 3)
 824                         continue;
 825                 field = GetPlayerSoundSampleField(argv(0));
 826                 if(GetPlayerSoundSampleField_notFound)
 827                         continue;
 828                 if(self.field)
 829                         strunzone(self.field);
 830                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 831         }
 832         fclose(fh);
 833 }
 834
 835 void UpdatePlayerSounds()
 836 {
 837         if(self.modelindex == self.modelindex_for_playersound)
 838                 return;
 839         self.modelindex_for_playersound = self.modelindex;
 840         LoadPlayerSounds("sound/player/default.sounds");
 841         LoadPlayerSounds(strcat(self.model, ".sounds"));
 842 }
 843
 844 void VoiceMessage(string type)
 845 {
 846         // TODO precache voice messages?
 847         var string sample;
 848         var float teamsay;
 849         sample = self.(GetPlayerSoundSampleField(type));
 850
 851         if(GetPlayerSoundSampleField_notFound)
 852         {
 853                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
 854                 return;
 855         }
 856
 857         if(!sample)
 858                 return;
 859
 860         teamsay = GetVoiceMessageTeamsayType(type);
 861
 862         tokenize(sample);
 863         sample = strcat(argv(0), ftos(ceil(random() * stof(argv(1)))), ".wav"); // randomization
 864
 865         if(teamsay == 2)
 866         {
 867                 if(teams_matter)
 868                         if(self.pusher)
 869                                 if(self.pusher.team == self.team)
 870                                 {
 871                                         soundto(self, self.pusher, CHAN_VOICE, sample, 1, ATTN_NONE);
 872                                         soundto(self, self, CHAN_VOICE, sample, 1, ATTN_NONE);
 873                                 }
 874         }
 875         else if(teamsay == 0 || !teams_matter)
 876         {
 877                 // broadcast the sound, but it's directional
 878                 sound(self, CHAN_VOICE, sample, 1, ATTN_NORM);
 879         }
 880         else if(teamsay == 1)
 881         {
 882                 entity e;
 883                 FOR_EACH_REALCLIENT(e)
 884                         if(e.team == self.team)
 885                                 soundto(self, e, CHAN_VOICE, sample, 1, ATTN_NONE);
 886         }
 887 }
 888 #else
 889 void PrecachePlayerSounds(string f) { }
 890 void UpdatePlayerSounds() { }
 891 void VoiceMessage(string type) { sprint(self, "Sorry, voice command support is not done yet. Maybe later.\n"); }
 892 #endif