cmake/FindSDL2.cmake

   1 # - Locate SDL2 library (modified from CMake's FindSDL.cmake)
   2 # This module defines
   3 #  SDL2_LIBRARY, the name of the library to link against
   4 #  SDL2_FOUND, if false, do not try to link to SDL
   5 #  SDL2_INCLUDE_DIR, where to find SDL.h
   6 #  SDL2_VERSION_STRING, human-readable string containing the version of SDL2
   7 #
   8 # This module responds to the the flag:
   9 #  SDL2_BUILDING_LIBRARY
  10 #    If this is defined, then no SDL_main will be linked in because
  11 #    only applications need main().
  12 #    Otherwise, it is assumed you are building an application and this
  13 #    module will attempt to locate and set the the proper link flags
  14 #    as part of the returned SDL2_LIBRARY variable.
  15 #
  16 # Additional Note: If you see an empty SDL2_LIBRARY_TEMP in your configuration
  17 # and no SDL2_LIBRARY, it means CMake did not find your SDL2 library
  18 # (SDL2.dll, libsdl2.so, SDL2.framework, etc).
  19 # Set SDL2_LIBRARY_TEMP to point to your SDL2 library, and configure again.
  20 # Similarly, if you see an empty SDL2MAIN_LIBRARY, you should set this value
  21 # as appropriate. These values are used to generate the final SDL2_LIBRARY
  22 # variable, but when these values are unset, SDL2_LIBRARY does not get created.
  23 #
  24 #
  25 # $SDL2DIR is an environment variable that would
  26 # correspond to the ./configure --prefix=$SDL2DIR
  27 # used in building SDL.
  28 #
  29
  30 #=============================================================================
  31 # Copyright 2014 Justin Jacobs
  32 #
  33 # Distributed under the OSI-approved BSD License (the "License");
  34 # see accompanying file Copyright.txt for details.
  35 #
  36 # This software is distributed WITHOUT ANY WARRANTY; without even the
  37 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  38 # See the License for more information.
  39 #=============================================================================
  40
  41 find_path(SDL2_INCLUDE_DIR SDL.h
  42   HINTS
  43     "${SDL2DIR}"
  44         ENV SDL2DIR
  45         PATH_SUFFIXES include/SDL2 include
  46 )
  47
  48 find_library(SDL2_LIBRARY_TEMP
  49   NAMES SDL2
  50   HINTS
  51     "${SDL2DIR}"
  52         ENV SDL2DIR
  53   PATH_SUFFIXES lib
  54 )
  55
  56 if(NOT SDL2_BUILDING_LIBRARY)
  57   if(NOT ${SDL2_INCLUDE_DIR} MATCHES ".framework")
  58         # Non-OS X framework versions expect you to also dynamically link to
  59         # SDLmain. This is mainly for Windows and OS X. Other (Unix) platforms
  60         # seem to provide SDLmain for compatibility even though they don't
  61         # necessarily need it.
  62         find_library(SDL2MAIN_LIBRARY
  63           NAMES SDL2main
  64           HINTS
  65             "${SDL2DIR}"
  66                 ENV SDL2DIR
  67           PATH_SUFFIXES lib
  68           PATHS
  69           /sw
  70           /opt/local
  71           /opt/csw
  72           /opt
  73         )
  74   endif()
  75 endif()
  76
  77 # SDL2 may require threads on your system.
  78 # The Apple build may not need an explicit flag because one of the
  79 # frameworks may already provide it.
  80 # But for non-OSX systems, I will use the CMake Threads package.
  81 if(NOT APPLE)
  82   find_package(Threads)
  83 endif()
  84
  85 # MinGW needs an additional library, mwindows
  86 # It's total link flags should look like -lmingw32 -lSDLmain -lSDL -lmwindows
  87 # (Actually on second look, I think it only needs one of the m* libraries.)
  88 if(MINGW)
  89   set(MINGW32_LIBRARY mingw32 CACHE STRING "mwindows for MinGW")
  90 endif()
  91
  92 if(SDL2_LIBRARY_TEMP)
  93   # For SDLmain
  94   if(SDL2MAIN_LIBRARY AND NOT SDL2_BUILDING_LIBRARY)
  95         list(FIND SDL2_LIBRARY_TEMP "${SDL2MAIN_LIBRARY}" _SDL2_MAIN_INDEX)
  96         if(_SDL2_MAIN_INDEX EQUAL -1)
  97           set(SDL2_LIBRARY_TEMP "${SDL2MAIN_LIBRARY}" ${SDL2_LIBRARY_TEMP})
  98         endif()
  99         unset(_SDL2_MAIN_INDEX)
 100   endif()
 101
 102   # For OS X, SDL uses Cocoa as a backend so it must link to Cocoa.
 103   # CMake doesn't display the -framework Cocoa string in the UI even
 104   # though it actually is there if I modify a pre-used variable.
 105   # I think it has something to do with the CACHE STRING.
 106   # So I use a temporary variable until the end so I can set the
 107   # "real" variable in one-shot.
 108   if(APPLE)
 109         set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} "-framework Cocoa")
 110   endif()
 111
 112   # For threads, as mentioned Apple doesn't need this.
 113   # In fact, there seems to be a problem if I used the Threads package
 114   # and try using this line, so I'm just skipping it entirely for OS X.
 115   if(NOT APPLE)
 116         set(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} ${CMAKE_THREAD_LIBS_INIT})
 117   endif()
 118
 119   # For MinGW library
 120   if(MINGW)
 121         set(SDL2_LIBRARY_TEMP ${MINGW32_LIBRARY} ${SDL2_LIBRARY_TEMP})
 122   endif()
 123
 124   # Set the final string here so the GUI reflects the final state.
 125   set(SDL2_LIBRARY ${SDL2_LIBRARY_TEMP} CACHE STRING "Where the SDL2 Library can be found")
 126   # Set the temp variable to INTERNAL so it is not seen in the CMake GUI
 127   set(SDL2_LIBRARY_TEMP "${SDL2_LIBRARY_TEMP}" CACHE INTERNAL "")
 128 endif()
 129
 130 if(SDL2_INCLUDE_DIR AND EXISTS "${SDL2_INCLUDE_DIR}/SDL_version.h")
 131   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+[0-9]+$")
 132   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_MINOR_VERSION[ \t]+[0-9]+$")
 133   file(STRINGS "${SDL2_INCLUDE_DIR}/SDL_version.h" SDL2_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_PATCHLEVEL[ \t]+[0-9]+$")
 134   string(REGEX REPLACE "^#define[ \t]+SDL_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MAJOR "${SDL2_VERSION_MAJOR_LINE}")
 135   string(REGEX REPLACE "^#define[ \t]+SDL_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_MINOR "${SDL2_VERSION_MINOR_LINE}")
 136   string(REGEX REPLACE "^#define[ \t]+SDL_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL2_VERSION_PATCH "${SDL2_VERSION_PATCH_LINE}")
 137   set(SDL2_VERSION_STRING ${SDL2_VERSION_MAJOR}.${SDL2_VERSION_MINOR}.${SDL2_VERSION_PATCH})
 138   unset(SDL2_VERSION_MAJOR_LINE)
 139   unset(SDL2_VERSION_MINOR_LINE)
 140   unset(SDL2_VERSION_PATCH_LINE)
 141   unset(SDL2_VERSION_MAJOR)
 142   unset(SDL2_VERSION_MINOR)
 143   unset(SDL2_VERSION_PATCH)
 144 endif()
 145
 146 include(FindPackageHandleStandardArgs)
 147
 148 FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL2
 149                                                                   REQUIRED_VARS SDL2_LIBRARY SDL2_INCLUDE_DIR
 150                                                                   VERSION_VAR SDL2_VERSION_STRING)
 151