configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 #   Copyright (C) 2007 Lasse Collin
   7 #
   8 #   This library is free software; you can redistribute it and/or
   9 #   modify it under the terms of the GNU Lesser General Public
  10 #   License as published by the Free Software Foundation; either
  11 #   version 2.1 of the License, or (at your option) any later version.
  12 #
  13 #   This library is distributed in the hope that it will be useful,
  14 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 #   Lesser General Public License for more details.
  17 #
  18 ###############################################################################
  19
  20 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  21 # let it confuse you. For example, we don't care about checking for behavior
  22 # of malloc(), stat(), or lstat(), since we don't use those functions in
  23 # a way that would cause the problems the autoconf macros check.
  24
  25 AC_PREREQ([2.61])
  26
  27 AC_INIT([XZ Utils], [4.999.8beta], [lasse.collin@tukaani.org], [xz])
  28 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  29 AC_CONFIG_HEADER([config.h])
  30
  31 echo
  32 echo "$PACKAGE_STRING"
  33
  34 echo
  35 echo "System type:"
  36 # This is needed to know if assembler optimizations can be used.
  37 AC_CANONICAL_HOST
  38
  39
  40 echo
  41 echo "Configure options:"
  42
  43
  44 #############
  45 # Debugging #
  46 #############
  47
  48 AC_MSG_CHECKING([if debugging code should be compiled])
  49 AC_ARG_ENABLE([debug], AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  50         [], enable_debug=no)
  51 if test "x$enable_debug" = xyes; then
  52         AC_MSG_RESULT([yes])
  53 else
  54         AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
  55         AC_MSG_RESULT([no])
  56 fi
  57
  58
  59 ###########
  60 # Encoder #
  61 ###########
  62
  63 AC_MSG_CHECKING([if encoder components should be built])
  64 AC_ARG_ENABLE([encoder], AC_HELP_STRING([--disable-encoder],
  65                 [Do not build the encoder components.]),
  66         [], enable_encoder=yes)
  67 if test "x$enable_encoder" = xyes; then
  68         AC_DEFINE([HAVE_ENCODER], [1],
  69                 [Define to 1 if encoder components are enabled.])
  70         AC_MSG_RESULT([yes])
  71 else
  72         AC_MSG_RESULT([no])
  73 fi
  74 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoder" = xyes)
  75
  76
  77 ###########
  78 # Decoder #
  79 ###########
  80
  81 AC_MSG_CHECKING([if decoder components should be built])
  82 AC_ARG_ENABLE([decoder], AC_HELP_STRING([--disable-decoder],
  83                 [Do not build the decoder components.]),
  84         [], enable_decoder=yes)
  85 if test "x$enable_decoder" = xyes; then
  86         AC_DEFINE([HAVE_DECODER], [1],
  87                 [Define to 1 if decoder components are enabled.])
  88         AC_MSG_RESULT([yes])
  89 else
  90         AC_MSG_RESULT([no])
  91         if test "x$enable_encoder" = xno; then
  92                 AC_MSG_ERROR([Do not disable both encoder and decoder.])
  93         fi
  94 fi
  95 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoder" = xyes)
  96
  97
  98 ###########
  99 # Filters #
 100 ###########
 101
 102 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,subblock,delta,x86,powerpc,ia64,arm,armthumb,sparc])dnl
 103 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,sparc])
 104 m4_define([LZ_FILTERS], [lzma1,lzma2])
 105
 106 m4_foreach([NAME], [SUPPORTED_FILTERS],
 107 [enable_filter_[]NAME=no
 108 enable_encoder_[]NAME=no
 109 enable_decoder_[]NAME=no
 110 ])dnl
 111
 112 AC_MSG_CHECKING([which encoders to build])
 113 AC_ARG_ENABLE([encoders], AC_HELP_STRING([--enable-encoders=LIST],
 114                 [Comma-separated list of encoders to build. Default=all.
 115                 Available encoders:]
 116                         m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
 117         [], [enable_encoders=SUPPORTED_FILTERS])
 118 enable_encoders=`echo "$enable_encoders" | sed 's/,subblock//; s/,/ /g'`
 119 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
 120         AC_MSG_RESULT([(none)])
 121 else
 122         for arg in $enable_encoders
 123         do
 124                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 125                         NAME)
 126                                 enable_filter_[]NAME=yes
 127                                 enable_encoder_[]NAME=yes
 128                                 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
 129                                 [Define to 1 if] NAME [encoder is enabled.])
 130                                 ;;])
 131                         *)
 132                                 AC_MSG_RESULT([])
 133                                 AC_MSG_ERROR([unknown filter: $arg])
 134                                 ;;
 135                 esac
 136         done
 137         AC_MSG_RESULT([$enable_encoders])
 138 fi
 139
 140 AC_MSG_CHECKING([which decoders to build])
 141 AC_ARG_ENABLE([decoders], AC_HELP_STRING([--enable-decoders=LIST],
 142                 [Comma-separated list of decoders to build. Default=all.
 143                 Available decoders are the same as available encoders.]),
 144         [], [enable_decoders=SUPPORTED_FILTERS])
 145 enable_decoders=`echo "$enable_decoders" | sed 's/,subblock//; s/,/ /g'`
 146 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
 147         AC_MSG_RESULT([(none)])
 148 else
 149         for arg in $enable_decoders
 150         do
 151                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 152                         NAME)
 153                                 enable_filter_[]NAME=yes
 154                                 enable_decoder_[]NAME=yes
 155                                 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
 156                                 [Define to 1 if] NAME [decoder is enabled.])
 157                                 ;;])
 158                         *)
 159                                 AC_MSG_RESULT([])
 160                                 AC_MSG_ERROR([unknown filter: $arg])
 161                                 ;;
 162                 esac
 163         done
 164
 165         # LZMA2 requires that LZMA1 is enabled.
 166         test "x$enable_encoder_lzma2" = xyes && enable_encoder_lzma1=yes
 167         test "x$enable_decoder_lzma2" = xyes && enable_decoder_lzma1=yes
 168
 169         AC_MSG_RESULT([$enable_decoders])
 170 fi
 171
 172 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
 173                 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
 174         AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
 175 fi
 176
 177 m4_foreach([NAME], [SUPPORTED_FILTERS],
 178 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
 179 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
 180 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
 181 ])dnl
 182
 183 # The so called "simple filters" share common code.
 184 enable_filter_simple=no
 185 enable_encoder_simple=no
 186 enable_decoder_simple=no
 187 m4_foreach([NAME], [SIMPLE_FILTERS],
 188 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
 189 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
 190 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
 191 ])dnl
 192 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
 193 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
 194 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
 195
 196 # LZ-based filters share common code.
 197 enable_filter_lz=no
 198 enable_encoder_lz=no
 199 enable_decoder_lz=no
 200 m4_foreach([NAME], [LZ_FILTERS],
 201 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
 202 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
 203 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
 204 ])dnl
 205 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
 206 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
 207 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
 208
 209
 210 #################
 211 # Match finders #
 212 #################
 213
 214 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
 215
 216 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
 217 [enable_match_finder_[]NAME=no
 218 ])
 219
 220 AC_MSG_CHECKING([which match finders to build])
 221 AC_ARG_ENABLE([match-finders], AC_HELP_STRING([--enable-match-finders=LIST],
 222                 [Comma-separated list of match finders to build. Default=all.
 223                 At least one match finder is required for encoding with
 224                 the LZMA1 and LZMA2 filters. Available match finders:]
 225                 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
 226         [enable_match_finders=SUPPORTED_MATCH_FINDERS])
 227 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 228 if test "x$enable_encoder" = xyes && test "x$enable_encoder_lz" = xyes ; then
 229         for arg in $enable_match_finders
 230                 do
 231                 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
 232                         NAME)
 233                                 enable_match_finder_[]NAME=yes
 234                                 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
 235                                 [Define to 1 to enable] NAME [match finder.])
 236                                 ;;])
 237                         *)
 238                                 AC_MSG_RESULT([])
 239                                 AC_MSG_ERROR([unknown match finder: $arg])
 240                                 ;;
 241                 esac
 242         done
 243         AC_MSG_RESULT([$enable_match_finders])
 244 else
 245         AC_MSG_RESULT([(none because not building any LZ-based encoder)])
 246 fi
 247
 248
 249 ####################
 250 # Integrity checks #
 251 ####################
 252
 253 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
 254
 255 m4_foreach([NAME], [SUPPORTED_FILTERS],
 256 [enable_check_[]NAME=no
 257 ])dnl
 258
 259 AC_MSG_CHECKING([which integrity checks to build])
 260 AC_ARG_ENABLE([checks], AC_HELP_STRING([--enable-checks=LIST],
 261                 [Comma-separated list of integrity checks to build.
 262                 Default=all. Available integrity checks:]
 263                 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
 264         [], [enable_checks=SUPPORTED_CHECKS])
 265 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 266 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 267         AC_MSG_RESULT([(none)])
 268 else
 269         for arg in $enable_checks
 270         do
 271                 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
 272                         NAME)
 273                                 enable_check_[]NAME=yes
 274                                 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
 275                                 [Define to 1 if] NAME
 276                                 [integrity check is enabled.])
 277                                 ;;])
 278                         *)
 279                                 AC_MSG_RESULT([])
 280                                 AC_MSG_ERROR([unknown integrity check: $arg])
 281                                 ;;
 282                 esac
 283         done
 284         AC_MSG_RESULT([$enable_checks])
 285 fi
 286 if test "x$enable_checks_crc32" = xno ; then
 287         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 288 fi
 289
 290 m4_foreach([NAME], [SUPPORTED_CHECKS],
 291 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
 292 ])dnl
 293
 294
 295 ###########################
 296 # Assembler optimizations #
 297 ###########################
 298
 299 AC_MSG_CHECKING([if assembler optimizations should be used])
 300 AC_ARG_ENABLE([assembler], AC_HELP_STRING([--disable-assembler],
 301                 [Do not use assembler optimizations even if such exist
 302                 for the architecture.]),
 303         [], [enable_assembler=yes])
 304 if test "x$enable_assembler" = xyes; then
 305         case $host_cpu in
 306                 i?86)   enable_assembler=x86 ;;
 307                 x86_64) enable_assembler=x86_64 ;;
 308                 *)      enable_assembler=no ;;
 309         esac
 310 fi
 311 case $enable_assembler in
 312         x86)
 313                 AC_DEFINE([HAVE_ASM_X86], [1],
 314                         [Define to 1 if using x86 assembler optimizations.])
 315                 ;;
 316         x86_64)
 317                 AC_DEFINE([HAVE_ASM_X86_64], [1],
 318                         [Define to 1 if using x86_64 assembler optimizations.])
 319                 ;;
 320         no)
 321                 ;;
 322         *)
 323                 AC_MSG_RESULT([])
 324                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', \`x86', or \`x86_64'.])
 325                 ;;
 326 esac
 327 AC_MSG_RESULT([$enable_assembler])
 328 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 329 AM_CONDITIONAL(COND_ASM_X86_64, test "x$enable_assembler" = xx86_64)
 330
 331
 332 ################################
 333 # Fast unaligned memory access #
 334 ################################
 335
 336 AC_MSG_CHECKING([if unaligned memory access should be used])
 337 AC_ARG_ENABLE([unaligned-access], AC_HELP_STRING([--enable-unaligned-access],
 338                 [Enable if the system supports *fast* unaligned memory access
 339                 with 16-bit and 32-bit integers. By default, this is enabled
 340                 only on x86, x86_64, and big endian PowerPC.]),
 341         [], [enable_unaligned_access=auto])
 342 if test "x$enable_unaligned_access" = xauto ; then
 343         case $host_cpu in
 344                 i?86|x86_64|powerpc|powerpc64)
 345                         enable_unaligned_access=yes
 346                         ;;
 347                 *)
 348                         enable_unaligned_access=no
 349                         ;;
 350         esac
 351 fi
 352 if test "x$enable_unaligned_access" = xyes ; then
 353         AC_DEFINE([HAVE_FAST_UNALIGNED_ACCESS], [1], [Define to 1 if
 354                 the system supports fast unaligned memory access.])
 355         AC_MSG_RESULT([yes])
 356 else
 357         AC_MSG_RESULT([no])
 358 fi
 359
 360
 361 #####################
 362 # Size optimization #
 363 #####################
 364
 365 AC_MSG_CHECKING([if small size is preferred over speed])
 366 AC_ARG_ENABLE([small], AC_HELP_STRING([--enable-small],
 367                 [Make liblzma smaller and a little slower.
 368                 This is disabled by default to optimize for speed.]),
 369         [], [enable_small=no])
 370 if test "x$enable_small" = xyes; then
 371         AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
 372 elif test "x$enable_small" != xno; then
 373         AC_MSG_RESULT([])
 374         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 375 fi
 376 AC_MSG_RESULT([$enable_small])
 377 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 378
 379
 380 #############
 381 # Threading #
 382 #############
 383
 384 AC_MSG_CHECKING([if threading support is wanted])
 385 AC_ARG_ENABLE([threads], AC_HELP_STRING([--disable-threads],
 386                 [Disable threading support.
 387                 This makes some things thread-unsafe.]),
 388         [], [enable_threads=yes])
 389 if test "x$enable_threads" != xyes && test "x$enable_threads" != xno; then
 390         AC_MSG_ERROR([--enable-threads accepts only \`yes' or \`no'])
 391 fi
 392 # We use the actual result a little later.
 393
 394
 395 ###############################################################################
 396 # Checks for programs.
 397 ###############################################################################
 398
 399 echo
 400 echo "Initializing Automake:"
 401
 402 AM_INIT_AUTOMAKE([1.10 foreign tar-v7 filename-length-max=99])
 403 AC_PROG_LN_S
 404
 405 AC_PROG_CC_C99
 406 if test x$ac_cv_prog_cc_c99 = xno ; then
 407         AC_MSG_ERROR([No C99 compiler was found.])
 408 fi
 409
 410 AM_PROG_CC_C_O
 411 AM_PROG_AS
 412 AC_USE_SYSTEM_EXTENSIONS
 413
 414 if test "x$enable_threads" = xyes; then
 415         echo
 416         echo "Threading support:"
 417         ACX_PTHREAD
 418         LIBS="$LIBS $PTHREAD_LIBS"
 419         CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 420         CC="$PTHREAD_CC"
 421 fi
 422
 423 echo
 424 echo "Initializing Libtool:"
 425 CXX=no
 426 F77=no
 427 AC_PROG_LIBTOOL
 428
 429
 430 ###############################################################################
 431 # Checks for libraries.
 432 ###############################################################################
 433
 434 echo
 435 echo "Initializing gettext:"
 436 AM_GNU_GETTEXT_VERSION([0.16.1])
 437 AM_GNU_GETTEXT([external])
 438
 439 ###############################################################################
 440 # Checks for header files.
 441 ###############################################################################
 442
 443 echo
 444 echo "System headers and functions:"
 445
 446 # There is currently no workarounds in this package if some of
 447 # these headers are missing.
 448 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 449         [],
 450         [AC_MSG_ERROR([Required header file(s) are missing.])])
 451
 452 # If any of these headers are missing, things should still work correctly:
 453 AC_CHECK_HEADERS([sys/param.h sys/sysctl.h byteswap.h],
 454         [], [], [
 455 #ifdef HAVE_SYS_PARAM_H
 456 #       include <sys/param.h>
 457 #endif
 458 ])
 459
 460 # Even if we have byteswap.h, we may lack the specific macros/functions.
 461 if test x$ac_cv_header_byteswap_h = xyes ; then
 462         m4_foreach([FUNC], [bswap_16,bswap_32,bswap_64], [
 463                 AC_MSG_CHECKING([if FUNC is available])
 464                 AC_LINK_IFELSE([AC_LANG_SOURCE([
 465 #include <byteswap.h>
 466 int
 467 main(void)
 468 {
 469         FUNC[](42);
 470         return 0;
 471 }
 472                 ])], [
 473                         AC_DEFINE(HAVE_[]m4_toupper(FUNC), [1],
 474                                         [Define to 1 if] FUNC [is available.])
 475                         AC_MSG_RESULT([yes])
 476                 ], [AC_MSG_RESULT([no])])
 477
 478         ])dnl
 479 fi
 480
 481
 482 ###############################################################################
 483 # Checks for typedefs, structures, and compiler characteristics.
 484 ###############################################################################
 485
 486 dnl We don't need these as long as we need a C99 compiler anyway.
 487 dnl AC_C_INLINE
 488 dnl AC_C_RESTRICT
 489
 490 AC_HEADER_STDBOOL
 491
 492 AC_TYPE_UINT8_T
 493 AC_TYPE_UINT16_T
 494 AC_TYPE_INT32_T
 495 AC_TYPE_UINT32_T
 496 AC_TYPE_INT64_T
 497 AC_TYPE_UINT64_T
 498 AC_TYPE_UINTPTR_T
 499
 500 AC_CHECK_SIZEOF([size_t])
 501
 502 # The command line tool can copy high resolution timestamps if such
 503 # information is availabe in struct stat. Otherwise one second accuracy
 504 # is used.
 505 AC_CHECK_MEMBERS([
 506         struct stat.st_atim.tv_nsec,
 507         struct stat.st_atimespec.tv_nsec,
 508         struct stat.st_atimensec,
 509         struct stat.st_uatime,
 510         struct stat.st_atim.st__tim.tv_nsec])
 511
 512 AC_SYS_LARGEFILE
 513 AC_C_BIGENDIAN
 514
 515
 516 ###############################################################################
 517 # Checks for library functions.
 518 ###############################################################################
 519
 520 # Gnulib replacements as needed
 521 gl_GETOPT
 522
 523 # Find the best function to set timestamps.
 524 AC_CHECK_FUNCS([futimens futimes futimesat utimes utime], [break])
 525
 526 # Check how to find out the amount of physical memory in the system. The
 527 # xz command line tool uses this to automatically limit its memory usage.
 528 # - sysconf() gives all the needed info on GNU+Linux and Solaris.
 529 # - BSDs use sysctl().
 530 AC_MSG_CHECKING([how to detect the amount of physical memory])
 531 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 532 #include <unistd.h>
 533 int
 534 main()
 535 {
 536         long i;
 537         i = sysconf(_SC_PAGESIZE);
 538         i = sysconf(_SC_PHYS_PAGES);
 539         return 0;
 540 }
 541 ]])], [
 542         AC_DEFINE([HAVE_PHYSMEM_SYSCONF], [1],
 543                 [Define to 1 if the amount of physical memory can be detected
 544                 with sysconf(_SC_PAGESIZE) and sysconf(_SC_PHYS_PAGES).])
 545         AC_MSG_RESULT([sysconf])
 546 ], [
 547 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 548 #include <sys/types.h>
 549 #ifdef HAVE_SYS_PARAM_H
 550 #       include <sys/param.h>
 551 #endif
 552 #include <sys/sysctl.h>
 553 int
 554 main()
 555 {
 556         int name[2] = { CTL_HW, HW_PHYSMEM };
 557         unsigned long mem;
 558         size_t mem_ptr_size = sizeof(mem);
 559         sysctl(name, 2, &mem, &mem_ptr_size, NULL, NULL);
 560         return 0;
 561 }
 562 ]])], [
 563         AC_DEFINE([HAVE_PHYSMEM_SYSCTL], [1],
 564                 [Define to 1 if the amount of physical memory can be detected
 565                 with sysctl().])
 566         AC_MSG_RESULT([sysctl])
 567 ], [
 568         AC_MSG_RESULT([unknown])
 569 ])])
 570
 571 # Check how to find out the number of available CPU cores in the system.
 572 # sysconf(_SC_NPROCESSORS_ONLN) works on most systems, except that BSDs
 573 # use sysctl().
 574 AC_MSG_CHECKING([how to detect the number of available CPU cores])
 575 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 576 #include <unistd.h>
 577 int
 578 main()
 579 {
 580         long i;
 581         i = sysconf(_SC_NPROCESSORS_ONLN);
 582         return 0;
 583 }
 584 ]])], [
 585         AC_DEFINE([HAVE_NCPU_SYSCONF], [1],
 586                 [Define to 1 if the number of available CPU cores can be
 587                 detected with sysconf(_SC_NPROCESSORS_ONLN).])
 588         AC_MSG_RESULT([sysconf])
 589 ], [
 590 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 591 #include <sys/types.h>
 592 #ifdef HAVE_SYS_PARAM_H
 593 #       include <sys/param.h>
 594 #endif
 595 #include <sys/sysctl.h>
 596 int
 597 main()
 598 {
 599         int name[2] = { CTL_HW, HW_NCPU };
 600         int cpus;
 601         size_t cpus_size = sizeof(cpus);
 602         sysctl(name, 2, &cpus, &cpus_size, NULL, NULL);
 603         return 0;
 604 }
 605 ]])], [
 606         AC_DEFINE([HAVE_NCPU_SYSCTL], [1],
 607                 [Define to 1 if the number of available CPU cores can be
 608                 detected with sysctl().])
 609         AC_MSG_RESULT([sysctl])
 610 ], [
 611         AC_MSG_RESULT([unknown])
 612 ])])
 613
 614
 615 ###############################################################################
 616 # If using GCC, set some additional CFLAGS:
 617 ###############################################################################
 618
 619 Wno_uninitialized=no
 620
 621 if test "x$GCC" = xyes ; then
 622         echo
 623         echo "GCC extensions:"
 624         gl_VISIBILITY
 625         if test -n "$CFLAG_VISIBILITY" ; then
 626                 CFLAGS="$CFLAG_VISIBILITY $CFLAGS"
 627         fi
 628
 629         # -Wno-uninitialized is needed with -Werror with SHA256 code
 630         # to omit a bogus warning.
 631         AC_MSG_CHECKING([if $CC accepts -Wno-uninitialized])
 632         OLD_CFLAGS="$CFLAGS"
 633         CFLAGS="$CFLAGS -Wno-uninitialized"
 634         AC_COMPILE_IFELSE([void foo(void) { }], [Wno_uninitialized=yes])
 635         CFLAGS="$OLD_CFLAGS"
 636         AC_MSG_RESULT([$Wno_uninitialized])
 637
 638         # Enable as much warnings as possible. These commented warnings won't
 639         # work for this package though:
 640         #   * -Wunreachable-code breaks several assert(0) cases, which are
 641         #     backed up with "return LZMA_PROG_ERROR".
 642         #   * -Wcast-qual would break various things where we need a non-const
 643         #     pointer although we don't modify anything through it.
 644         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 645         #     on some architectures (not on x86), where this warning is bogus,
 646         #     because we take care of correct alignment.
 647         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 648         #     don't seem so useful here; at least the last one gives some
 649         #     warnings which are not bugs.
 650         #
 651         # The flags are in reverse order below so they end up in "beautiful"
 652         # order on the actual command line.
 653         for NEW_FLAG in \
 654                         -Wredundant-decls \
 655                         -Wmissing-noreturn \
 656                         -Wmissing-declarations \
 657                         -Wmissing-prototypes \
 658                         -Wold-style-definition \
 659                         -Wstrict-prototypes \
 660                         -Waggregate-return \
 661                         -Wlogical-op \
 662                         -Wwrite-strings \
 663                         -Wbad-function-cast \
 664                         -Wpointer-arith \
 665                         -Wshadow \
 666                         -Wundef \
 667                         -Wfloat-equal \
 668                         -Wstrict-aliasing \
 669                         -Wmissing-include-dirs \
 670                         -Winit-self \
 671                         -Wformat=2 \
 672                         -Wextra \
 673                         -Wall
 674         do
 675                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 676                 OLD_CFLAGS="$CFLAGS"
 677                 CFLAGS="$NEW_FLAG $CFLAGS"
 678                 AC_COMPILE_IFELSE([void foo(void) { }], [
 679                         AC_MSG_RESULT([yes])
 680                 ], [
 681                         CFLAGS="$OLD_CFLAGS"
 682                         AC_MSG_RESULT([no])
 683                 ])
 684         done
 685
 686         AC_ARG_ENABLE([werror],
 687                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 688                         compilation on all compiler warnings.]),
 689                 [], [enable_werror=no])
 690         if test "x$enable_werror" = "xyes"; then
 691                 CFLAGS="-Werror $CFLAGS"
 692         fi
 693 fi
 694
 695 AM_CONDITIONAL([COND_WNO_UNINITIALIZED], test "x$Wno_uninitialized" = "xyes")
 696
 697
 698 ###############################################################################
 699 # Create the makefiles and config.h
 700 ###############################################################################
 701
 702 echo
 703
 704 # Don't build the lib directory at all if we don't need any replacement
 705 # functions.
 706 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 707
 708 AC_CONFIG_FILES([
 709         Doxyfile
 710         Makefile
 711         po/Makefile.in
 712         lib/Makefile
 713         src/Makefile
 714         src/liblzma/liblzma.pc
 715         src/liblzma/Makefile
 716         src/liblzma/api/Makefile
 717         src/liblzma/common/Makefile
 718         src/liblzma/check/Makefile
 719         src/liblzma/rangecoder/Makefile
 720         src/liblzma/lz/Makefile
 721         src/liblzma/lzma/Makefile
 722         src/liblzma/subblock/Makefile
 723         src/liblzma/delta/Makefile
 724         src/liblzma/simple/Makefile
 725         src/xz/Makefile
 726         src/xzdec/Makefile
 727         src/scripts/Makefile
 728         tests/Makefile
 729         debug/Makefile
 730 ])
 731
 732 AC_OUTPUT