configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ###############################################################################
   5 #
   6 #   Copyright (C) 2007 Lasse Collin
   7 #
   8 #   This library is free software; you can redistribute it and/or
   9 #   modify it under the terms of the GNU Lesser General Public
  10 #   License as published by the Free Software Foundation; either
  11 #   version 2.1 of the License, or (at your option) any later version.
  12 #
  13 #   This library is distributed in the hope that it will be useful,
  14 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 #   Lesser General Public License for more details.
  17 #
  18 ###############################################################################
  19
  20 # NOTE: Don't add useless checks. autoscan detects this and that, but don't
  21 # let it confuse you. For example, we don't care about checking for behavior
  22 # of malloc(), stat(), or lstat(), since we don't use those functions in
  23 # a way that would cause the problems the autoconf macros check.
  24
  25 AC_PREREQ([2.61])
  26
  27 AC_INIT([XZ Utils], [4.999.8beta], [lasse.collin@tukaani.org], [xz])
  28 AC_CONFIG_SRCDIR([src/liblzma/common/common.h])
  29 AC_CONFIG_HEADER([config.h])
  30
  31 echo
  32 echo "$PACKAGE_STRING"
  33
  34 echo
  35 echo "System type:"
  36 # This is needed to know if assembler optimizations can be used.
  37 AC_CANONICAL_HOST
  38
  39
  40 echo
  41 echo "Configure options:"
  42
  43
  44 #############
  45 # Debugging #
  46 #############
  47
  48 AC_MSG_CHECKING([if debugging code should be compiled])
  49 AC_ARG_ENABLE([debug], AC_HELP_STRING([--enable-debug], [Enable debugging code.]),
  50         [], enable_debug=no)
  51 if test "x$enable_debug" = xyes; then
  52         AC_MSG_RESULT([yes])
  53 else
  54         AC_DEFINE([NDEBUG], [1], [Define to 1 to disable debugging code.])
  55         AC_MSG_RESULT([no])
  56 fi
  57
  58
  59 ###########
  60 # Encoder #
  61 ###########
  62
  63 AC_MSG_CHECKING([if encoder components should be built])
  64 AC_ARG_ENABLE([encoder], AC_HELP_STRING([--disable-encoder],
  65                 [Do not build the encoder components.]),
  66         [], enable_encoder=yes)
  67 if test "x$enable_encoder" = xyes; then
  68         AC_DEFINE([HAVE_ENCODER], [1],
  69                 [Define to 1 if encoder components are enabled.])
  70         AC_MSG_RESULT([yes])
  71 else
  72         AC_MSG_RESULT([no])
  73 fi
  74 AM_CONDITIONAL(COND_MAIN_ENCODER, test "x$enable_encoder" = xyes)
  75
  76
  77 ###########
  78 # Decoder #
  79 ###########
  80
  81 AC_MSG_CHECKING([if decoder components should be built])
  82 AC_ARG_ENABLE([decoder], AC_HELP_STRING([--disable-decoder],
  83                 [Do not build the decoder components.]),
  84         [], enable_decoder=yes)
  85 if test "x$enable_decoder" = xyes; then
  86         AC_DEFINE([HAVE_DECODER], [1],
  87                 [Define to 1 if decoder components are enabled.])
  88         AC_MSG_RESULT([yes])
  89 else
  90         AC_MSG_RESULT([no])
  91         if test "x$enable_encoder" = xno; then
  92                 AC_MSG_ERROR([Do not disable both encoder and decoder.])
  93         fi
  94 fi
  95 AM_CONDITIONAL(COND_MAIN_DECODER, test "x$enable_decoder" = xyes)
  96
  97
  98 ###########
  99 # Filters #
 100 ###########
 101
 102 m4_define([SUPPORTED_FILTERS], [lzma1,lzma2,subblock,delta,x86,powerpc,ia64,arm,armthumb,sparc])dnl
 103 m4_define([SIMPLE_FILTERS], [x86,powerpc,ia64,arm,armthumb,sparc])
 104 m4_define([LZ_FILTERS], [lzma1,lzma2])
 105
 106 m4_foreach([NAME], [SUPPORTED_FILTERS],
 107 [enable_filter_[]NAME=no
 108 enable_encoder_[]NAME=no
 109 enable_decoder_[]NAME=no
 110 ])dnl
 111
 112 AC_MSG_CHECKING([which encoders to build])
 113 AC_ARG_ENABLE([encoders], AC_HELP_STRING([--enable-encoders=LIST],
 114                 [Comma-separated list of encoders to build. Default=all.
 115                 Available encoders:]
 116                         m4_translit(m4_defn([SUPPORTED_FILTERS]), [,], [ ])),
 117         [], [enable_encoders=SUPPORTED_FILTERS])
 118 enable_encoders=`echo "$enable_encoders" | sed 's/,subblock//; s/,/ /g'`
 119 if test "x$enable_encoders" = xno || test "x$enable_encoders" = x; then
 120         AC_MSG_RESULT([(none)])
 121 else
 122         for arg in $enable_encoders
 123         do
 124                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 125                         NAME)
 126                                 enable_filter_[]NAME=yes
 127                                 enable_encoder_[]NAME=yes
 128                                 AC_DEFINE(HAVE_ENCODER_[]m4_toupper(NAME), [1],
 129                                 [Define to 1 if] NAME [encoder is enabled.])
 130                                 ;;])
 131                         *)
 132                                 AC_MSG_RESULT([])
 133                                 AC_MSG_ERROR([unknown filter: $arg])
 134                                 ;;
 135                 esac
 136         done
 137         AC_MSG_RESULT([$enable_encoders])
 138 fi
 139
 140 AC_MSG_CHECKING([which decoders to build])
 141 AC_ARG_ENABLE([decoders], AC_HELP_STRING([--enable-decoders=LIST],
 142                 [Comma-separated list of decoders to build. Default=all.
 143                 Available decoders are the same as available encoders.]),
 144         [], [enable_decoders=SUPPORTED_FILTERS])
 145 enable_decoders=`echo "$enable_decoders" | sed 's/,subblock//; s/,/ /g'`
 146 if test "x$enable_decoders" = xno || test "x$enable_decoders" = x; then
 147         AC_MSG_RESULT([(none)])
 148 else
 149         for arg in $enable_decoders
 150         do
 151                 case $arg in m4_foreach([NAME], [SUPPORTED_FILTERS], [
 152                         NAME)
 153                                 enable_filter_[]NAME=yes
 154                                 enable_decoder_[]NAME=yes
 155                                 AC_DEFINE(HAVE_DECODER_[]m4_toupper(NAME), [1],
 156                                 [Define to 1 if] NAME [decoder is enabled.])
 157                                 ;;])
 158                         *)
 159                                 AC_MSG_RESULT([])
 160                                 AC_MSG_ERROR([unknown filter: $arg])
 161                                 ;;
 162                 esac
 163         done
 164
 165         # LZMA2 requires that LZMA1 is enabled.
 166         test "x$enable_encoder_lzma2" = xyes && enable_encoder_lzma1=yes
 167         test "x$enable_decoder_lzma2" = xyes && enable_decoder_lzma1=yes
 168
 169         AC_MSG_RESULT([$enable_decoders])
 170 fi
 171
 172 if test "x$enable_encoder_lzma2$enable_encoder_lzma1" = xyesno \
 173                 || test "x$enable_decoder_lzma2$enable_decoder_lzma1" = xyesno; then
 174         AC_MSG_ERROR([LZMA2 requires that LZMA1 is also enabled.])
 175 fi
 176
 177 m4_foreach([NAME], [SUPPORTED_FILTERS],
 178 [AM_CONDITIONAL(COND_FILTER_[]m4_toupper(NAME), test "x$enable_filter_[]NAME" = xyes)
 179 AM_CONDITIONAL(COND_ENCODER_[]m4_toupper(NAME), test "x$enable_encoder_[]NAME" = xyes)
 180 AM_CONDITIONAL(COND_DECODER_[]m4_toupper(NAME), test "x$enable_decoder_[]NAME" = xyes)
 181 ])dnl
 182
 183 # The so called "simple filters" share common code.
 184 enable_filter_simple=no
 185 enable_encoder_simple=no
 186 enable_decoder_simple=no
 187 m4_foreach([NAME], [SIMPLE_FILTERS],
 188 [test "x$enable_filter_[]NAME" = xyes && enable_filter_simple=yes
 189 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_simple=yes
 190 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_simple=yes
 191 ])dnl
 192 AM_CONDITIONAL(COND_FILTER_SIMPLE, test "x$enable_filter_simple" = xyes)
 193 AM_CONDITIONAL(COND_ENCODER_SIMPLE, test "x$enable_encoder_simple" = xyes)
 194 AM_CONDITIONAL(COND_DECODER_SIMPLE, test "x$enable_decoder_simple" = xyes)
 195
 196 # LZ-based filters share common code.
 197 enable_filter_lz=no
 198 enable_encoder_lz=no
 199 enable_decoder_lz=no
 200 m4_foreach([NAME], [LZ_FILTERS],
 201 [test "x$enable_filter_[]NAME" = xyes && enable_filter_lz=yes
 202 test "x$enable_encoder_[]NAME" = xyes && enable_encoder_lz=yes
 203 test "x$enable_decoder_[]NAME" = xyes && enable_decoder_lz=yes
 204 ])dnl
 205 AM_CONDITIONAL(COND_FILTER_LZ, test "x$enable_filter_lz" = xyes)
 206 AM_CONDITIONAL(COND_ENCODER_LZ, test "x$enable_encoder_lz" = xyes)
 207 AM_CONDITIONAL(COND_DECODER_LZ, test "x$enable_decoder_lz" = xyes)
 208
 209
 210 #################
 211 # Match finders #
 212 #################
 213
 214 m4_define([SUPPORTED_MATCH_FINDERS], [hc3,hc4,bt2,bt3,bt4])
 215
 216 m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS],
 217 [enable_match_finder_[]NAME=no
 218 ])
 219
 220 AC_MSG_CHECKING([which match finders to build])
 221 AC_ARG_ENABLE([match-finders], AC_HELP_STRING([--enable-match-finders=LIST],
 222                 [Comma-separated list of match finders to build. Default=all.
 223                 At least one match finder is required for encoding with
 224                 the LZMA1 and LZMA2 filters. Available match finders:]
 225                 m4_translit(m4_defn([SUPPORTED_MATCH_FINDERS]), [,], [ ])), [],
 226         [enable_match_finders=SUPPORTED_MATCH_FINDERS])
 227 enable_match_finders=`echo "$enable_match_finders" | sed 's/,/ /g'`
 228 if test "x$enable_encoder" = xyes && test "x$enable_encoder_lz" = xyes ; then
 229         for arg in $enable_match_finders
 230                 do
 231                 case $arg in m4_foreach([NAME], [SUPPORTED_MATCH_FINDERS], [
 232                         NAME)
 233                                 enable_match_finder_[]NAME=yes
 234                                 AC_DEFINE(HAVE_MF_[]m4_toupper(NAME), [1],
 235                                 [Define to 1 to enable] NAME [match finder.])
 236                                 ;;])
 237                         *)
 238                                 AC_MSG_RESULT([])
 239                                 AC_MSG_ERROR([unknown match finder: $arg])
 240                                 ;;
 241                 esac
 242         done
 243         AC_MSG_RESULT([$enable_match_finders])
 244 else
 245         AC_MSG_RESULT([(none because not building any LZ-based encoder)])
 246 fi
 247
 248
 249 ####################
 250 # Integrity checks #
 251 ####################
 252
 253 m4_define([SUPPORTED_CHECKS], [crc32,crc64,sha256])
 254
 255 m4_foreach([NAME], [SUPPORTED_FILTERS],
 256 [enable_check_[]NAME=no
 257 ])dnl
 258
 259 AC_MSG_CHECKING([which integrity checks to build])
 260 AC_ARG_ENABLE([checks], AC_HELP_STRING([--enable-checks=LIST],
 261                 [Comma-separated list of integrity checks to build.
 262                 Default=all. Available integrity checks:]
 263                 m4_translit(m4_defn([SUPPORTED_CHECKS]), [,], [ ])),
 264         [], [enable_checks=SUPPORTED_CHECKS])
 265 enable_checks=`echo "$enable_checks" | sed 's/,/ /g'`
 266 if test "x$enable_checks" = xno || test "x$enable_checks" = x; then
 267         AC_MSG_RESULT([(none)])
 268 else
 269         for arg in $enable_checks
 270         do
 271                 case $arg in m4_foreach([NAME], [SUPPORTED_CHECKS], [
 272                         NAME)
 273                                 enable_check_[]NAME=yes
 274                                 AC_DEFINE(HAVE_CHECK_[]m4_toupper(NAME), [1],
 275                                 [Define to 1 if] NAME
 276                                 [integrity check is enabled.])
 277                                 ;;])
 278                         *)
 279                                 AC_MSG_RESULT([])
 280                                 AC_MSG_ERROR([unknown integrity check: $arg])
 281                                 ;;
 282                 esac
 283         done
 284         AC_MSG_RESULT([$enable_checks])
 285 fi
 286 if test "x$enable_checks_crc32" = xno ; then
 287         AC_MSG_ERROR([For now, the CRC32 check must always be enabled.])
 288 fi
 289
 290 m4_foreach([NAME], [SUPPORTED_CHECKS],
 291 [AM_CONDITIONAL(COND_CHECK_[]m4_toupper(NAME), test "x$enable_check_[]NAME" = xyes)
 292 ])dnl
 293
 294
 295 ###########################
 296 # Assembler optimizations #
 297 ###########################
 298
 299 AC_MSG_CHECKING([if assembler optimizations should be used])
 300 AC_ARG_ENABLE([assembler], AC_HELP_STRING([--disable-assembler],
 301                 [Do not use assembler optimizations even if such exist
 302                 for the architecture.]),
 303         [], [enable_assembler=yes])
 304 if test "x$enable_assembler" = xyes; then
 305         case $host_cpu in
 306                 i?86)   enable_assembler=x86 ;;
 307                 x86_64) enable_assembler=x86_64 ;;
 308                 *)      enable_assembler=no ;;
 309         esac
 310         # Darwin has different ABI than GNU+Linux and Solaris,
 311         # and the assembler code doesn't assemble.
 312         case $host_os in
 313                 darwin*) enable_assembler=no ;;
 314                 *)       ;;
 315         esac
 316 fi
 317 case $enable_assembler in
 318         x86)
 319                 AC_DEFINE([HAVE_ASM_X86], [1],
 320                         [Define to 1 if using x86 assembler optimizations.])
 321                 ;;
 322         x86_64)
 323                 AC_DEFINE([HAVE_ASM_X86_64], [1],
 324                         [Define to 1 if using x86_64 assembler optimizations.])
 325                 ;;
 326         no)
 327                 ;;
 328         *)
 329                 AC_MSG_RESULT([])
 330                 AC_MSG_ERROR([--enable-assembler accepts only \`yes', \`no', \`x86', or \`x86_64'.])
 331                 ;;
 332 esac
 333 AC_MSG_RESULT([$enable_assembler])
 334 AM_CONDITIONAL(COND_ASM_X86, test "x$enable_assembler" = xx86)
 335 AM_CONDITIONAL(COND_ASM_X86_64, test "x$enable_assembler" = xx86_64)
 336
 337
 338 ################################
 339 # Fast unaligned memory access #
 340 ################################
 341
 342 AC_MSG_CHECKING([if unaligned memory access should be used])
 343 AC_ARG_ENABLE([unaligned-access], AC_HELP_STRING([--enable-unaligned-access],
 344                 [Enable if the system supports *fast* unaligned memory access
 345                 with 16-bit and 32-bit integers. By default, this is enabled
 346                 only on x86, x86_64, and big endian PowerPC.]),
 347         [], [enable_unaligned_access=auto])
 348 if test "x$enable_unaligned_access" = xauto ; then
 349         case $host_cpu in
 350                 i?86|x86_64|powerpc|powerpc64)
 351                         enable_unaligned_access=yes
 352                         ;;
 353                 *)
 354                         enable_unaligned_access=no
 355                         ;;
 356         esac
 357 fi
 358 if test "x$enable_unaligned_access" = xyes ; then
 359         AC_DEFINE([HAVE_FAST_UNALIGNED_ACCESS], [1], [Define to 1 if
 360                 the system supports fast unaligned memory access.])
 361         AC_MSG_RESULT([yes])
 362 else
 363         AC_MSG_RESULT([no])
 364 fi
 365
 366
 367 #####################
 368 # Size optimization #
 369 #####################
 370
 371 AC_MSG_CHECKING([if small size is preferred over speed])
 372 AC_ARG_ENABLE([small], AC_HELP_STRING([--enable-small],
 373                 [Make liblzma smaller and a little slower.
 374                 This is disabled by default to optimize for speed.]),
 375         [], [enable_small=no])
 376 if test "x$enable_small" = xyes; then
 377         AC_DEFINE([HAVE_SMALL], [1], [Define to 1 if optimizing for size.])
 378 elif test "x$enable_small" != xno; then
 379         AC_MSG_RESULT([])
 380         AC_MSG_ERROR([--enable-small accepts only \`yes' or \`no'])
 381 fi
 382 AC_MSG_RESULT([$enable_small])
 383 AM_CONDITIONAL(COND_SMALL, test "x$enable_small" = xyes)
 384
 385
 386 #############
 387 # Threading #
 388 #############
 389
 390 AC_MSG_CHECKING([if threading support is wanted])
 391 AC_ARG_ENABLE([threads], AC_HELP_STRING([--disable-threads],
 392                 [Disable threading support.
 393                 This makes some things thread-unsafe.]),
 394         [], [enable_threads=yes])
 395 if test "x$enable_threads" != xyes && test "x$enable_threads" != xno; then
 396         AC_MSG_ERROR([--enable-threads accepts only \`yes' or \`no'])
 397 fi
 398 # We use the actual result a little later.
 399
 400
 401 ###############################################################################
 402 # Checks for programs.
 403 ###############################################################################
 404
 405 echo
 406 echo "Initializing Automake:"
 407
 408 AM_INIT_AUTOMAKE([1.10 foreign tar-v7 filename-length-max=99])
 409 AC_PROG_LN_S
 410
 411 AC_PROG_CC_C99
 412 if test x$ac_cv_prog_cc_c99 = xno ; then
 413         AC_MSG_ERROR([No C99 compiler was found.])
 414 fi
 415
 416 AM_PROG_CC_C_O
 417 AM_PROG_AS
 418 AC_USE_SYSTEM_EXTENSIONS
 419
 420 if test "x$enable_threads" = xyes; then
 421         echo
 422         echo "Threading support:"
 423         ACX_PTHREAD
 424         LIBS="$LIBS $PTHREAD_LIBS"
 425         CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 426         CC="$PTHREAD_CC"
 427 fi
 428
 429 echo
 430 echo "Initializing Libtool:"
 431 CXX=no
 432 F77=no
 433 AC_PROG_LIBTOOL
 434
 435
 436 ###############################################################################
 437 # Checks for libraries.
 438 ###############################################################################
 439
 440 echo
 441 echo "Initializing gettext:"
 442 AM_GNU_GETTEXT_VERSION([0.16.1])
 443 AM_GNU_GETTEXT([external])
 444
 445 ###############################################################################
 446 # Checks for header files.
 447 ###############################################################################
 448
 449 echo
 450 echo "System headers and functions:"
 451
 452 # There is currently no workarounds in this package if some of
 453 # these headers are missing.
 454 AC_CHECK_HEADERS([fcntl.h limits.h sys/time.h],
 455         [],
 456         [AC_MSG_ERROR([Required header file(s) are missing.])])
 457
 458 # If any of these headers are missing, things should still work correctly:
 459 AC_CHECK_HEADERS([sys/param.h sys/sysctl.h byteswap.h],
 460         [], [], [
 461 #ifdef HAVE_SYS_PARAM_H
 462 #       include <sys/param.h>
 463 #endif
 464 ])
 465
 466 # Even if we have byteswap.h, we may lack the specific macros/functions.
 467 if test x$ac_cv_header_byteswap_h = xyes ; then
 468         m4_foreach([FUNC], [bswap_16,bswap_32,bswap_64], [
 469                 AC_MSG_CHECKING([if FUNC is available])
 470                 AC_LINK_IFELSE([AC_LANG_SOURCE([
 471 #include <byteswap.h>
 472 int
 473 main(void)
 474 {
 475         FUNC[](42);
 476         return 0;
 477 }
 478                 ])], [
 479                         AC_DEFINE(HAVE_[]m4_toupper(FUNC), [1],
 480                                         [Define to 1 if] FUNC [is available.])
 481                         AC_MSG_RESULT([yes])
 482                 ], [AC_MSG_RESULT([no])])
 483
 484         ])dnl
 485 fi
 486
 487
 488 ###############################################################################
 489 # Checks for typedefs, structures, and compiler characteristics.
 490 ###############################################################################
 491
 492 dnl We don't need these as long as we need a C99 compiler anyway.
 493 dnl AC_C_INLINE
 494 dnl AC_C_RESTRICT
 495
 496 AC_HEADER_STDBOOL
 497
 498 AC_TYPE_UINT8_T
 499 AC_TYPE_UINT16_T
 500 AC_TYPE_INT32_T
 501 AC_TYPE_UINT32_T
 502 AC_TYPE_INT64_T
 503 AC_TYPE_UINT64_T
 504 AC_TYPE_UINTPTR_T
 505
 506 AC_CHECK_SIZEOF([size_t])
 507
 508 # The command line tool can copy high resolution timestamps if such
 509 # information is availabe in struct stat. Otherwise one second accuracy
 510 # is used.
 511 AC_CHECK_MEMBERS([
 512         struct stat.st_atim.tv_nsec,
 513         struct stat.st_atimespec.tv_nsec,
 514         struct stat.st_atimensec,
 515         struct stat.st_uatime,
 516         struct stat.st_atim.st__tim.tv_nsec])
 517
 518 AC_SYS_LARGEFILE
 519 AC_C_BIGENDIAN
 520
 521
 522 ###############################################################################
 523 # Checks for library functions.
 524 ###############################################################################
 525
 526 # Gnulib replacements as needed
 527 gl_GETOPT
 528
 529 # Find the best function to set timestamps.
 530 AC_CHECK_FUNCS([futimens futimes futimesat utimes utime], [break])
 531
 532 # Check how to find out the amount of physical memory in the system. The
 533 # xz command line tool uses this to automatically limit its memory usage.
 534 # - sysconf() gives all the needed info on GNU+Linux and Solaris.
 535 # - BSDs use sysctl().
 536 AC_MSG_CHECKING([how to detect the amount of physical memory])
 537 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 538 #include <unistd.h>
 539 int
 540 main()
 541 {
 542         long i;
 543         i = sysconf(_SC_PAGESIZE);
 544         i = sysconf(_SC_PHYS_PAGES);
 545         return 0;
 546 }
 547 ]])], [
 548         AC_DEFINE([HAVE_PHYSMEM_SYSCONF], [1],
 549                 [Define to 1 if the amount of physical memory can be detected
 550                 with sysconf(_SC_PAGESIZE) and sysconf(_SC_PHYS_PAGES).])
 551         AC_MSG_RESULT([sysconf])
 552 ], [
 553 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 554 #include <sys/types.h>
 555 #ifdef HAVE_SYS_PARAM_H
 556 #       include <sys/param.h>
 557 #endif
 558 #include <sys/sysctl.h>
 559 int
 560 main()
 561 {
 562         int name[2] = { CTL_HW, HW_PHYSMEM };
 563         unsigned long mem;
 564         size_t mem_ptr_size = sizeof(mem);
 565         sysctl(name, 2, &mem, &mem_ptr_size, NULL, NULL);
 566         return 0;
 567 }
 568 ]])], [
 569         AC_DEFINE([HAVE_PHYSMEM_SYSCTL], [1],
 570                 [Define to 1 if the amount of physical memory can be detected
 571                 with sysctl().])
 572         AC_MSG_RESULT([sysctl])
 573 ], [
 574         AC_MSG_RESULT([unknown])
 575 ])])
 576
 577 # Check how to find out the number of available CPU cores in the system.
 578 # sysconf(_SC_NPROCESSORS_ONLN) works on most systems, except that BSDs
 579 # use sysctl().
 580 AC_MSG_CHECKING([how to detect the number of available CPU cores])
 581 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 582 #include <unistd.h>
 583 int
 584 main()
 585 {
 586         long i;
 587         i = sysconf(_SC_NPROCESSORS_ONLN);
 588         return 0;
 589 }
 590 ]])], [
 591         AC_DEFINE([HAVE_NCPU_SYSCONF], [1],
 592                 [Define to 1 if the number of available CPU cores can be
 593                 detected with sysconf(_SC_NPROCESSORS_ONLN).])
 594         AC_MSG_RESULT([sysconf])
 595 ], [
 596 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 597 #include <sys/types.h>
 598 #ifdef HAVE_SYS_PARAM_H
 599 #       include <sys/param.h>
 600 #endif
 601 #include <sys/sysctl.h>
 602 int
 603 main()
 604 {
 605         int name[2] = { CTL_HW, HW_NCPU };
 606         int cpus;
 607         size_t cpus_size = sizeof(cpus);
 608         sysctl(name, 2, &cpus, &cpus_size, NULL, NULL);
 609         return 0;
 610 }
 611 ]])], [
 612         AC_DEFINE([HAVE_NCPU_SYSCTL], [1],
 613                 [Define to 1 if the number of available CPU cores can be
 614                 detected with sysctl().])
 615         AC_MSG_RESULT([sysctl])
 616 ], [
 617         AC_MSG_RESULT([unknown])
 618 ])])
 619
 620
 621 ###############################################################################
 622 # If using GCC, set some additional CFLAGS:
 623 ###############################################################################
 624
 625 Wno_uninitialized=no
 626
 627 if test "x$GCC" = xyes ; then
 628         echo
 629         echo "GCC extensions:"
 630         gl_VISIBILITY
 631         if test -n "$CFLAG_VISIBILITY" ; then
 632                 CFLAGS="$CFLAG_VISIBILITY $CFLAGS"
 633         fi
 634
 635         # -Wno-uninitialized is needed with -Werror with SHA256 code
 636         # to omit a bogus warning.
 637         AC_MSG_CHECKING([if $CC accepts -Wno-uninitialized])
 638         OLD_CFLAGS="$CFLAGS"
 639         CFLAGS="$CFLAGS -Wno-uninitialized"
 640         AC_COMPILE_IFELSE([void foo(void) { }], [Wno_uninitialized=yes])
 641         CFLAGS="$OLD_CFLAGS"
 642         AC_MSG_RESULT([$Wno_uninitialized])
 643
 644         # Enable as much warnings as possible. These commented warnings won't
 645         # work for this package though:
 646         #   * -Wunreachable-code breaks several assert(0) cases, which are
 647         #     backed up with "return LZMA_PROG_ERROR".
 648         #   * -Wcast-qual would break various things where we need a non-const
 649         #     pointer although we don't modify anything through it.
 650         #   * -Wcast-align breaks optimized CRC32 and CRC64 implementation
 651         #     on some architectures (not on x86), where this warning is bogus,
 652         #     because we take care of correct alignment.
 653         #   * -Winline, -Wdisabled-optimization, -Wunsafe-loop-optimizations
 654         #     don't seem so useful here; at least the last one gives some
 655         #     warnings which are not bugs.
 656         #
 657         # The flags are in reverse order below so they end up in "beautiful"
 658         # order on the actual command line.
 659         for NEW_FLAG in \
 660                         -Wredundant-decls \
 661                         -Wmissing-noreturn \
 662                         -Wmissing-declarations \
 663                         -Wmissing-prototypes \
 664                         -Wold-style-definition \
 665                         -Wstrict-prototypes \
 666                         -Waggregate-return \
 667                         -Wlogical-op \
 668                         -Wwrite-strings \
 669                         -Wbad-function-cast \
 670                         -Wpointer-arith \
 671                         -Wshadow \
 672                         -Wundef \
 673                         -Wfloat-equal \
 674                         -Wstrict-aliasing \
 675                         -Wmissing-include-dirs \
 676                         -Winit-self \
 677                         -Wformat=2 \
 678                         -Wextra \
 679                         -Wall
 680         do
 681                 AC_MSG_CHECKING([if $CC accepts $NEW_FLAG])
 682                 OLD_CFLAGS="$CFLAGS"
 683                 CFLAGS="$NEW_FLAG $CFLAGS"
 684                 AC_COMPILE_IFELSE([void foo(void) { }], [
 685                         AC_MSG_RESULT([yes])
 686                 ], [
 687                         CFLAGS="$OLD_CFLAGS"
 688                         AC_MSG_RESULT([no])
 689                 ])
 690         done
 691
 692         AC_ARG_ENABLE([werror],
 693                 AC_HELP_STRING([--enable-werror], [Enable -Werror to abort
 694                         compilation on all compiler warnings.]),
 695                 [], [enable_werror=no])
 696         if test "x$enable_werror" = "xyes"; then
 697                 CFLAGS="-Werror $CFLAGS"
 698         fi
 699 fi
 700
 701 AM_CONDITIONAL([COND_WNO_UNINITIALIZED], test "x$Wno_uninitialized" = "xyes")
 702
 703
 704 ###############################################################################
 705 # Create the makefiles and config.h
 706 ###############################################################################
 707
 708 echo
 709
 710 # Don't build the lib directory at all if we don't need any replacement
 711 # functions.
 712 AM_CONDITIONAL([COND_GNULIB], test -n "$LIBOBJS")
 713
 714 AC_CONFIG_FILES([
 715         Doxyfile
 716         Makefile
 717         po/Makefile.in
 718         lib/Makefile
 719         src/Makefile
 720         src/liblzma/liblzma.pc
 721         src/liblzma/Makefile
 722         src/liblzma/api/Makefile
 723         src/liblzma/common/Makefile
 724         src/liblzma/check/Makefile
 725         src/liblzma/rangecoder/Makefile
 726         src/liblzma/lz/Makefile
 727         src/liblzma/lzma/Makefile
 728         src/liblzma/subblock/Makefile
 729         src/liblzma/delta/Makefile
 730         src/liblzma/simple/Makefile
 731         src/xz/Makefile
 732         src/xzdec/Makefile
 733         src/scripts/Makefile
 734         tests/Makefile
 735         debug/Makefile
 736 ])
 737
 738 AC_OUTPUT