data/qcsrc/server/waypointsprites.qc

   1 ..entity owned_by_field;
   2 .float rule;
   3 .string model1;
   4 .string model2;
   5 .string model3;
   6
   7 .float(entity) waypointsprite_visible_for_player;
   8
   9 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
  10 {
  11         if(m1 != e.model1)
  12         {
  13                 e.model1 = m1;
  14                 e.SendFlags |= 2;
  15         }
  16         if(m2 != e.model2)
  17         {
  18                 e.model2 = m2;
  19                 e.SendFlags |= 4;
  20         }
  21         if(m3 != e.model3)
  22         {
  23                 e.model3 = m3;
  24                 e.SendFlags |= 8;
  25         }
  26 }
  27
  28 void WaypointSprite_UpdateOrigin(entity e, vector o)
  29 {
  30         if(o != e.origin)
  31         {
  32                 e.origin = o;
  33                 e.SendFlags |= 128;
  34         }
  35 }
  36
  37 void WaypointSprite_UpdateRule(entity e, float t, float r)
  38 {
  39         // no check, as this is never called without doing an actual change (usually only once)
  40         e.rule = r;
  41         e.team = t;
  42         e.SendFlags |= 1;
  43 }
  44
  45 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
  46 {
  47         // no check, as this is never called without doing an actual change (usually only once)
  48         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
  49         e.colormod = col;
  50         e.SendFlags |= 32;
  51 }
  52
  53 void WaypointSprite_Ping(entity e)
  54 {
  55         // ALWAYS sends (this causes a radar circle), thus no check
  56         e.cnt |= 0x80;
  57         e.SendFlags |= 32;
  58 }
  59
  60 void WaypointSprite_FadeOutIn(entity e, float t)
  61 {
  62         if(!e.health)
  63         {
  64                 e.health = t;
  65                 e.teleport_time = time + t;
  66         }
  67         else if(t < (e.teleport_time - time))
  68         {
  69                 // accelerate the waypoint's dying
  70                 // ensure:
  71                 //   (e.teleport_time - time) / wp.health stays
  72                 //   e.teleport_time = time + fadetime
  73                 float current_fadetime;
  74                 current_fadetime = e.teleport_time - time;
  75                 e.teleport_time = time + t;
  76                 e.health = e.health * t / current_fadetime;
  77         }
  78
  79         e.SendFlags |= 16;
  80 }
  81
  82 float waypointsprite_limitedrange, waypointsprite_deployed_lifetime, waypointsprite_deadlifetime;
  83 void WaypointSprite_Init()
  84 {
  85         waypointsprite_limitedrange = cvar("g_waypointsprite_limitedrange");
  86         waypointsprite_deployed_lifetime = cvar("g_waypointsprite_deployed_lifetime");
  87         waypointsprite_deadlifetime = cvar("g_waypointsprite_deadlifetime");
  88 }
  89 void WaypointSprite_InitClient(entity e)
  90 {
  91 }
  92
  93 void WaypointSprite_Kill(entity wp)
  94 {
  95         if(!wp)
  96                 return;
  97         if(wp.owner)
  98                 wp.owner.(wp.owned_by_field) = world;
  99         remove(wp);
 100 }
 101
 102 void WaypointSprite_Disown(entity wp, float fadetime)
 103 {
 104         if(!wp)
 105                 return;
 106         if(wp.owner)
 107         {
 108                 if(wp.exteriormodeltoclient == wp.owner)
 109                         wp.exteriormodeltoclient = world;
 110                 wp.owner.(wp.owned_by_field) = world;
 111                 wp.owner = world;
 112
 113                 WaypointSprite_FadeOutIn(wp, fadetime);
 114         }
 115 }
 116
 117 void WaypointSprite_Think()
 118 {
 119         float doremove;
 120
 121         doremove = FALSE;
 122
 123         if(self.health)
 124         {
 125                 if(time >= self.teleport_time)
 126                         doremove = TRUE;
 127         }
 128
 129         if(self.exteriormodeltoclient)
 130                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
 131
 132         if(doremove)
 133                 WaypointSprite_Kill(self);
 134         else
 135                 self.nextthink = time; // WHY?!?
 136 }
 137
 138 float WaypointSprite_visible_for_player(entity e)
 139 {
 140         // personal waypoints
 141         if(self.enemy)
 142                 if(self.enemy != other)
 143                         return FALSE;
 144
 145         // team waypoints
 146         if(self.team && self.rule == SPRITERULE_DEFAULT)
 147         {
 148                 if(self.team != other.team)
 149                         return FALSE;
 150                 if(other.classname != "player")
 151                         return FALSE;
 152         }
 153
 154         return TRUE;
 155 }
 156
 157 float WaypointSprite_Customize()
 158 {
 159         // this is not in SendEntity because it shall run every frame, not just every update
 160
 161         return self.waypointsprite_visible_for_player(other);
 162 }
 163
 164 float WaypointSprite_SendEntity(entity to, float sendflags)
 165 {
 166         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
 167         WriteByte(MSG_ENTITY, sendflags);
 168         WriteCoord(MSG_ENTITY, self.origin_x);
 169         WriteCoord(MSG_ENTITY, self.origin_y);
 170         WriteCoord(MSG_ENTITY, self.origin_z);
 171
 172         if(sendflags & 1)
 173         {
 174                 WriteByte(MSG_ENTITY, self.team);
 175                 WriteByte(MSG_ENTITY, self.rule);
 176         }
 177
 178         if(sendflags & 2)
 179                 WriteString(MSG_ENTITY, self.model1);
 180
 181         if(sendflags & 4)
 182                 WriteString(MSG_ENTITY, self.model2);
 183
 184         if(sendflags & 8)
 185                 WriteString(MSG_ENTITY, self.model3);
 186
 187         if(sendflags & 16)
 188         {
 189                 WriteCoord(MSG_ENTITY, self.health);
 190                 WriteCoord(MSG_ENTITY, self.teleport_time);
 191                 WriteShort(MSG_ENTITY, self.max_health); // maxdist
 192                 float f;
 193                 f = 0;
 194                 if(self.currentammo)
 195                         f |= 1; // hideable
 196                 if(self.exteriormodeltoclient == to)
 197                         f |= 2; // my own
 198                 WriteByte(MSG_ENTITY, f);
 199         }
 200
 201         if(sendflags & 32)
 202         {
 203                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
 204                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
 205                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
 206                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
 207         }
 208
 209         return TRUE;
 210 }
 211
 212 entity WaypointSprite_Spawn(
 213         string spr, // sprite
 214         float lifetime, float maxdistance, // lifetime, max distance
 215         entity ref, vector ofs, // position
 216         entity showto, float t, // show to whom? Use a flag to indicate a team
 217         entity own, .entity ownfield, // remove when own gets killed
 218         float hideable // true when it should be controlled by cl_hidewaypoints
 219 )
 220 {
 221         entity wp;
 222         wp = spawn();
 223         wp.classname = "sprite_waypoint";
 224         wp.teleport_time = time + lifetime;
 225         wp.health = lifetime;
 226         wp.exteriormodeltoclient = ref;
 227         if(ref)
 228                 wp.view_ofs = ofs;
 229         else
 230                 setorigin(wp, ofs);
 231         wp.enemy = showto;
 232         wp.team = t;
 233         wp.owner = own;
 234         wp.currentammo = hideable;
 235         if(own)
 236         {
 237                 if(own.ownfield)
 238                         remove(own.ownfield);
 239                 own.ownfield = wp;
 240                 wp.owned_by_field = ownfield;
 241         }
 242         wp.max_health = maxdistance;
 243         wp.think = WaypointSprite_Think;
 244         wp.nextthink = time;
 245         wp.effects = EF_NODEPTHTEST | EF_LOWPRECISION;
 246         wp.model1 = spr;
 247         wp.model = "net_entity";
 248         wp.modelindex = 1;
 249         wp.SendEntity = WaypointSprite_SendEntity;
 250         wp.customizeentityforclient = WaypointSprite_Customize;
 251         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
 252         return wp;
 253 }
 254
 255 entity WaypointSprite_SpawnFixed(
 256         string spr,
 257         vector ofs,
 258         entity own,
 259         .entity ownfield
 260 )
 261 {
 262         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, TRUE);
 263 }
 264
 265 .entity waypointsprite_deployed_fixed;
 266 entity WaypointSprite_DeployFixed(
 267         string spr,
 268         float limited_range,
 269         vector ofs
 270 )
 271 {
 272         float t, maxdistance;
 273         if(teams_matter)
 274                 t = self.team;
 275         else
 276                 t = 0;
 277         if(limited_range)
 278                 maxdistance = waypointsprite_limitedrange;
 279         else
 280                 maxdistance = 0;
 281         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, FALSE);
 282 }
 283
 284 .entity waypointsprite_deployed_personal;
 285 entity WaypointSprite_DeployPersonal(
 286         string spr,
 287         vector ofs
 288 )
 289 {
 290         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, self, 0, self, waypointsprite_deployed_personal, FALSE);
 291 }
 292
 293 .entity waypointsprite_attached;
 294 .entity waypointsprite_attachedforcarrier;
 295 entity WaypointSprite_Attach(
 296         string spr,
 297         float limited_range
 298 )
 299 {
 300         float t, maxdistance;
 301         if(self.waypointsprite_attachedforcarrier)
 302                 return world; // can't attach to FC
 303         if(teams_matter)
 304                 t = self.team;
 305         else
 306                 t = 0;
 307         if(limited_range)
 308                 maxdistance = waypointsprite_limitedrange;
 309         else
 310                 maxdistance = 0;
 311         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, FALSE);
 312 }
 313
 314 entity WaypointSprite_AttachCarrier(
 315         string spr,
 316         entity carrier
 317 )
 318 {
 319         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
 320         return WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, FALSE);
 321 }
 322
 323 void WaypointSprite_DetachCarrier(entity carrier)
 324 {
 325         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
 326 }
 327
 328 void WaypointSprite_ClearPersonal()
 329 {
 330         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 331 }
 332
 333 void WaypointSprite_ClearOwned()
 334 {
 335         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
 336         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 337         WaypointSprite_Kill(self.waypointsprite_attached);
 338 }
 339
 340 void WaypointSprite_PlayerDead()
 341 {
 342         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 343         WaypointSprite_DetachCarrier(self);
 344 }
 345
 346 void WaypointSprite_PlayerGone()
 347 {
 348         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
 349         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 350         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 351         WaypointSprite_DetachCarrier(self);
 352 }