Scaled the weapon models down about 30% to match 2.5.2 sizes. Except the tuba, I...
[divverent/nexuiz.git] / data / qcsrc / server / waypointsprites.qc
1 ..entity owned_by_field;
2 .float rule;
3 .string model1;
4 .string model2;
5 .string model3;
6
7 .float(entity) waypointsprite_visible_for_player;
8
9 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
10 {
11         if(m1 != e.model1)
12         {
13                 e.model1 = m1;
14                 e.SendFlags |= 2;
15         }
16         if(m2 != e.model2)
17         {
18                 e.model2 = m2;
19                 e.SendFlags |= 4;
20         }
21         if(m3 != e.model3)
22         {
23                 e.model3 = m3;
24                 e.SendFlags |= 8;
25         }
26 }
27
28 void WaypointSprite_UpdateHealth(entity e, float f)
29 {
30         f = bound(0, f, e.max_health);
31         if(f != e.health || e.pain_finished)
32         {
33                 e.health = f;
34                 e.pain_finished = 0;
35                 e.SendFlags |= 0x80;
36         }
37 }
38
39 void WaypointSprite_UpdateMaxHealth(entity e, float f)
40 {
41         if(f != e.max_health || e.pain_finished)
42         {
43                 e.max_health = f;
44                 e.pain_finished = 0;
45                 e.SendFlags |= 0x80;
46         }
47 }
48
49 void WaypointSprite_UpdateBuildFinished(entity e, float f)
50 {
51         if(f != e.pain_finished || e.max_health)
52         {
53                 e.max_health = 0;
54                 e.pain_finished = f;
55                 e.SendFlags |= 0x80;
56         }
57 }
58
59 void WaypointSprite_UpdateOrigin(entity e, vector o)
60 {
61         if(o != e.origin)
62         {
63                 setorigin(e, o);
64                 e.SendFlags |= 64;
65         }
66 }
67
68 void WaypointSprite_UpdateRule(entity e, float t, float r)
69 {
70         // no check, as this is never called without doing an actual change (usually only once)
71         e.rule = r;
72         e.team = t;
73         e.SendFlags |= 1;
74 }
75
76 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
77 {
78         // no check, as this is never called without doing an actual change (usually only once)
79         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
80         e.colormod = col;
81         e.SendFlags |= 32;
82 }
83
84 void WaypointSprite_Ping(entity e)
85 {
86         // ALWAYS sends (this causes a radar circle), thus no check
87         e.cnt |= 0x80;
88         e.SendFlags |= 32;
89 }
90
91 void WaypointSprite_FadeOutIn(entity e, float t)
92 {
93         if(!e.fade_time)
94         {
95                 e.fade_time = t;
96                 e.teleport_time = time + t;
97         }
98         else if(t < (e.teleport_time - time))
99         {
100                 // accelerate the waypoint's dying
101                 // ensure:
102                 //   (e.teleport_time - time) / wp.fade_time stays
103                 //   e.teleport_time = time + fadetime
104                 float current_fadetime;
105                 current_fadetime = e.teleport_time - time;
106                 e.teleport_time = time + t;
107                 e.fade_time = e.fade_time * t / current_fadetime;
108         }
109
110         e.SendFlags |= 16;
111 }
112
113 float waypointsprite_limitedrange, waypointsprite_deployed_lifetime, waypointsprite_deadlifetime;
114 void WaypointSprite_Init()
115 {
116         waypointsprite_limitedrange = cvar("g_waypointsprite_limitedrange");
117         waypointsprite_deployed_lifetime = cvar("g_waypointsprite_deployed_lifetime");
118         waypointsprite_deadlifetime = cvar("g_waypointsprite_deadlifetime");
119 }
120 void WaypointSprite_InitClient(entity e)
121 {
122 }
123
124 void WaypointSprite_Kill(entity wp)
125 {
126         if(!wp)
127                 return;
128         if(wp.owner)
129                 wp.owner.(wp.owned_by_field) = world;
130         remove(wp);
131 }
132
133 void WaypointSprite_Disown(entity wp, float fadetime)
134 {
135         if(!wp)
136                 return;
137         if(wp.classname != "sprite_waypoint")
138         {
139                 backtrace("Trying to disown a non-waypointsprite");
140                 return;
141         }
142         if(wp.owner)
143         {
144                 if(wp.exteriormodeltoclient == wp.owner)
145                         wp.exteriormodeltoclient = world;
146                 wp.owner.(wp.owned_by_field) = world;
147                 wp.owner = world;
148
149                 WaypointSprite_FadeOutIn(wp, fadetime);
150         }
151 }
152
153 void WaypointSprite_Think()
154 {
155         float doremove;
156
157         doremove = FALSE;
158
159         if(self.fade_time)
160         {
161                 if(time >= self.teleport_time)
162                         doremove = TRUE;
163         }
164
165         if(self.exteriormodeltoclient)
166                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
167
168         if(doremove)
169                 WaypointSprite_Kill(self);
170         else
171                 self.nextthink = time; // WHY?!?
172 }
173
174 float WaypointSprite_visible_for_player(entity e)
175 {
176         // personal waypoints
177         if(self.enemy)
178                 if(self.enemy != other)
179                         return FALSE;
180
181         // team waypoints
182         if(self.team && self.rule == SPRITERULE_DEFAULT)
183         {
184                 if(self.team != other.team)
185                         return FALSE;
186                 if(other.classname != "player")
187                         return FALSE;
188         }
189
190         return TRUE;
191 }
192
193 float WaypointSprite_Customize()
194 {
195         // this is not in SendEntity because it shall run every frame, not just every update
196
197         // make spectators see what the player would see
198         entity e;
199         e = other;
200         if(e.classname == "spectator")
201                 e = e.enemy;
202
203         return self.waypointsprite_visible_for_player(e);
204 }
205
206 float WaypointSprite_SendEntity(entity to, float sendflags)
207 {
208         float dt;
209
210         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
211
212         sendflags = sendflags & 0x7F;
213         
214         if(g_nexball)
215                 sendflags &~= 0x80;
216         else if(self.max_health || (self.pain_finished && (time < self.pain_finished + 0.25)))
217                 sendflags |= 0x80;
218
219         WriteByte(MSG_ENTITY, sendflags);
220
221         if(sendflags & 0x80)
222         {
223                 if(self.max_health)
224                 {
225                         WriteByte(MSG_ENTITY, (self.health / self.max_health) * 191.0);
226                 }
227                 else
228                 {
229                         dt = self.pain_finished - time;
230                         dt = bound(0, dt * 32, 16383);
231                         WriteByte(MSG_ENTITY, (dt & 0xFF00) / 256 + 192);
232                         WriteByte(MSG_ENTITY, (dt & 0x00FF));
233                 }
234         }
235
236         if(sendflags & 64)
237         {
238                 WriteCoord(MSG_ENTITY, self.origin_x);
239                 WriteCoord(MSG_ENTITY, self.origin_y);
240                 WriteCoord(MSG_ENTITY, self.origin_z);
241         }
242
243         if(sendflags & 1)
244         {
245                 WriteByte(MSG_ENTITY, self.team);
246                 WriteByte(MSG_ENTITY, self.rule);
247         }
248
249         if(sendflags & 2)
250                 WriteString(MSG_ENTITY, self.model1);
251
252         if(sendflags & 4)
253                 WriteString(MSG_ENTITY, self.model2);
254
255         if(sendflags & 8)
256                 WriteString(MSG_ENTITY, self.model3);
257
258         if(sendflags & 16)
259         {
260                 WriteCoord(MSG_ENTITY, self.fade_time);
261                 WriteCoord(MSG_ENTITY, self.teleport_time);
262                 WriteShort(MSG_ENTITY, self.fade_rate); // maxdist
263                 float f;
264                 f = 0;
265                 if(self.currentammo)
266                         f |= 1; // hideable
267                 if(self.exteriormodeltoclient == to)
268                         f |= 2; // my own
269                 WriteByte(MSG_ENTITY, f);
270         }
271
272         if(sendflags & 32)
273         {
274                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
275                 WriteByte(MSG_ENTITY, self.colormod_x * 255.0);
276                 WriteByte(MSG_ENTITY, self.colormod_y * 255.0);
277                 WriteByte(MSG_ENTITY, self.colormod_z * 255.0);
278         }
279
280         return TRUE;
281 }
282
283 void WaypointSprite_Reset()
284 {
285         // if a WP wants to time out, let it time out immediately; other WPs ought to be reset/killed by their owners
286
287         if(self.fade_time) // there was there before: || g_keyhunt, do we really need this?
288                 WaypointSprite_Kill(self);
289 }
290
291 entity WaypointSprite_Spawn(
292         string spr, // sprite
293         float lifetime, float maxdistance, // lifetime, max distance
294         entity ref, vector ofs, // position
295         entity showto, float t, // show to whom? Use a flag to indicate a team
296         entity own, .entity ownfield, // remove when own gets killed
297         float hideable // true when it should be controlled by cl_hidewaypoints
298 )
299 {
300         entity wp;
301         wp = spawn();
302         wp.classname = "sprite_waypoint";
303         wp.teleport_time = time + lifetime;
304         wp.fade_time = lifetime;
305         wp.exteriormodeltoclient = ref;
306         if(ref)
307         {
308                 wp.view_ofs = ofs;
309                 setorigin(wp, ref.origin + ofs);
310         }
311         else
312                 setorigin(wp, ofs);
313         wp.enemy = showto;
314         wp.team = t;
315         wp.owner = own;
316         wp.currentammo = hideable;
317         if(own)
318         {
319                 if(own.ownfield)
320                         remove(own.ownfield);
321                 own.ownfield = wp;
322                 wp.owned_by_field = ownfield;
323         }
324         wp.fade_rate = maxdistance;
325         wp.think = WaypointSprite_Think;
326         wp.nextthink = time;
327         wp.model1 = spr;
328         wp.customizeentityforclient = WaypointSprite_Customize;
329         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
330         wp.reset2 = WaypointSprite_Reset;
331         Net_LinkEntity(wp, FALSE, 0, WaypointSprite_SendEntity);
332         return wp;
333 }
334
335 entity WaypointSprite_SpawnFixed(
336         string spr,
337         vector ofs,
338         entity own,
339         .entity ownfield
340 )
341 {
342         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, TRUE);
343 }
344
345 .entity waypointsprite_deployed_fixed;
346 entity WaypointSprite_DeployFixed(
347         string spr,
348         float limited_range,
349         vector ofs
350 )
351 {
352         float t, maxdistance;
353         if(teams_matter)
354                 t = self.team;
355         else
356                 t = 0;
357         if(limited_range)
358                 maxdistance = waypointsprite_limitedrange;
359         else
360                 maxdistance = 0;
361         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, FALSE);
362 }
363
364 .entity waypointsprite_deployed_personal;
365 entity WaypointSprite_DeployPersonal(
366         string spr,
367         vector ofs
368 )
369 {
370         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, self, waypointsprite_deployed_personal, FALSE);
371 }
372
373 .entity waypointsprite_attached;
374 .entity waypointsprite_attachedforcarrier;
375 entity WaypointSprite_Attach(
376         string spr,
377         float limited_range
378 )
379 {
380         float t, maxdistance;
381         if(self.waypointsprite_attachedforcarrier)
382                 return world; // can't attach to FC
383         if(teams_matter)
384                 t = self.team;
385         else
386                 t = 0;
387         if(limited_range)
388                 maxdistance = waypointsprite_limitedrange;
389         else
390                 maxdistance = 0;
391         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, FALSE);
392 }
393
394 entity WaypointSprite_AttachCarrier(
395         string spr,
396         entity carrier
397 )
398 {
399         entity e;
400         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
401         e = WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, FALSE);
402         if(e)
403         {
404                 WaypointSprite_UpdateMaxHealth(e, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, cvar("g_balance_armor_blockpercent")) * 2);
405                 WaypointSprite_UpdateHealth(e, '1 0 0' * healtharmor_maxdamage(carrier.health, carrier.armorvalue, cvar("g_balance_armor_blockpercent")));
406         }
407         return e;
408 }
409
410 void WaypointSprite_DetachCarrier(entity carrier)
411 {
412         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
413 }
414
415 void WaypointSprite_ClearPersonal()
416 {
417         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
418 }
419
420 void WaypointSprite_ClearOwned()
421 {
422         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
423         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
424         WaypointSprite_Kill(self.waypointsprite_attached);
425 }
426
427 void WaypointSprite_PlayerDead()
428 {
429         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
430         WaypointSprite_DetachCarrier(self);
431 }
432
433 void WaypointSprite_PlayerGone()
434 {
435         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
436         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
437         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
438         WaypointSprite_DetachCarrier(self);
439 }