data/qcsrc/server/w_uzi.qc

   1 // leilei's fancy muzzleflash stuff
   2 void W_Uzi_Flash_Go() {
   3         if (self.frame > 10){
   4                 SUB_Remove();
   5                 return;
   6         }
   7         self.frame = self.frame + 2;
   8         self.alpha = self.alpha - 0.2;
   9         self.think = W_Uzi_Flash_Go;
  10         self.nextthink = time + 0.02;
  11 };
  12
  13 .float uzi_bulletcounter;
  14 void W_Uzi_Attack (float deathtype)
  15 {
  16         local entity flash;
  17
  18         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  19         {
  20                 if (self.uzi_bulletcounter == 1)
  21                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  22                 else
  23                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  24         }
  25         W_SetupShot (self, cvar("g_antilag_bullets") && cvar("g_balance_uzi_speed") >= cvar("g_antilag_bullets"), 0, "weapons/uzi_fire.wav", cvar("g_balance_uzi_first_damage"));
  26         if (!g_norecoil)
  27         {
  28                 self.punchangle_x = random () - 0.5;
  29                 self.punchangle_y = random () - 0.5;
  30         }
  31
  32         // this attack_finished just enforces a cooldown at the end of a burst
  33         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire") * W_WeaponSpeedFactor();
  34
  35         if (self.uzi_bulletcounter == 1)
  36                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_first_damage"), 0, cvar("g_balance_uzi_first_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  37         else
  38                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_sustained_damage"), 0, cvar("g_balance_uzi_sustained_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  39
  40         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  41
  42         // muzzle flash for 1st person view
  43         flash = spawn();
  44         setmodel(flash, "models/uziflash.md3"); // precision set below
  45         //SUB_SetFade(flash, time + 0.06, 0);
  46         flash.think = W_Uzi_Flash_Go;
  47         flash.nextthink = time + 0.02;
  48         flash.frame = 2;
  49         flash.alpha = 1;
  50         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  51         W_AttachToShotorg(flash, '5 0 0');
  52
  53         // casing code
  54         if (cvar("g_casings") >= 2)
  55                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  56 }
  57
  58 // weapon frames
  59 void uzi_fire1_02()
  60 {
  61         if(self.weapon != self.switchweapon) // abort immediately if switching
  62         {
  63                 w_ready();
  64                 return;
  65         }
  66         if (self.BUTTON_ATCK)
  67         {
  68                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  69                 {
  70                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  71                         w_ready();
  72                         return;
  73                 }
  74                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
  75                 W_Uzi_Attack(WEP_UZI);
  76                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  77         }
  78         else
  79                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
  80 };
  81
  82 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
  83
  84 float w_uzi(float req)
  85 {
  86         if (req == WR_AIM)
  87                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
  88                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
  89                 else
  90                 {
  91                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
  92                 }
  93         else if (req == WR_THINK)
  94         {
  95                 if (self.BUTTON_ATCK)
  96                 if (weapon_prepareattack(0, 0))
  97                 {
  98                         self.uzi_bulletcounter = 1;
  99                         W_Uzi_Attack(WEP_UZI); // sets attack_finished
 100                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 101                 }
 102                 if (self.BUTTON_ATCK2)
 103                 if (weapon_prepareattack(1, 0))
 104                 {
 105                         self.uzi_bulletcounter = 1;
 106                         W_Uzi_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 107                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_uzi_first_refire"), w_ready);
 108                 }
 109         }
 110         else if (req == WR_PRECACHE)
 111         {
 112                 precache_model ("models/uziflash.md3");
 113                 precache_model ("models/weapons/g_uzi.md3");
 114                 precache_model ("models/weapons/v_uzi.md3");
 115                 precache_model ("models/weapons/h_uzi.dpm");
 116                 precache_sound ("weapons/uzi_fire.wav");
 117         }
 118         else if (req == WR_SETUP)
 119                 weapon_setup(WEP_UZI);
 120         else if (req == WR_CHECKAMMO1)
 121                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 122         else if (req == WR_CHECKAMMO2)
 123                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 124         else if (req == WR_SUICIDEMESSAGE)
 125                 w_deathtypestring = "did the impossible";
 126         else if (req == WR_KILLMESSAGE)
 127         {
 128                 if(w_deathtype & HITTYPE_SECONDARY)
 129                         w_deathtypestring = "was sniped by";
 130                 else
 131                         w_deathtypestring = "was riddled full of holes by";
 132         }
 133         return TRUE;
 134 };