data/qcsrc/server/w_uzi.qc

   1 // leilei's fancy muzzleflash stuff
   2 void W_Uzi_Flash_Go() {
   3         if (self.frame > 10){
   4                 SUB_Remove();
   5                 return;
   6         }
   7         self.frame = self.frame + 2;
   8         self.alpha = self.alpha - 0.2;
   9         self.think = W_Uzi_Flash_Go;
  10         self.nextthink = time + 0.02;
  11 };
  12
  13 .float uzi_bulletcounter;
  14 void W_Uzi_Attack (float deathtype)
  15 {
  16         local entity flash, flash2;
  17
  18         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  19         {
  20                 if (self.uzi_bulletcounter == 1)
  21                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  22                 else
  23                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  24         }
  25         W_SetupShot (self, '23 8 -9.5', TRUE, 0, "weapons/uzi_fire.wav");
  26         if (!g_norecoil)
  27         {
  28                 self.punchangle_x = random () - 0.5;
  29                 self.punchangle_y = random () - 0.5;
  30         }
  31
  32         // this attack_finished just enforces a cooldown at the end of a burst
  33         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire");
  34
  35         if (self.uzi_bulletcounter == 1)
  36                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_first_damage"), 0, cvar("g_balance_uzi_first_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  37         else
  38                 fireBallisticBullet(w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_speed"), 5, cvar("g_balance_uzi_sustained_damage"), 0, cvar("g_balance_uzi_sustained_force"), deathtype, 0, 1, cvar("g_balance_uzi_bulletconstant"));
  39
  40         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  41
  42         // muzzle flash for 1st person view
  43         flash = spawn();
  44         setorigin(flash, '5 0 0');
  45         setmodel(flash, "models/uziflash.md3"); // precision set below
  46         setattachment(flash, self.weaponentity, "bone02");
  47         flash.owner = self;
  48         flash.viewmodelforclient = self;
  49         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
  50         //SUB_SetFade(flash, time + 0.06, 0);
  51         flash.think = W_Uzi_Flash_Go;
  52         flash.nextthink = time + 0.02;
  53         flash.frame = 2;
  54
  55         // muzzle flash for 3rd person view
  56         flash2 = spawn();
  57         setorigin(flash2, '43 1 8');
  58         setmodel(flash2, "models/uziflash.md3"); // precision set below
  59         setattachment(flash2, self.exteriorweaponentity, "");
  60         //SUB_SetFade(flash2, time + 0.06, 0);
  61         flash2.think = W_Uzi_Flash_Go;
  62         flash2.nextthink = time + 0.02;
  63         flash2.frame = 2;
  64         // common properties
  65         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
  66         flash.alpha = flash2.alpha = 1;
  67         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  68
  69         // casing code
  70         if (cvar("g_casings") >= 2)
  71                 SpawnCasing (w_shotorg - v_forward * 10, ((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
  72 }
  73
  74 // weapon frames
  75 void uzi_fire1_02()
  76 {
  77         if(self.weapon != self.switchweapon) // abort immediately if switching
  78         {
  79                 w_ready();
  80                 return;
  81         }
  82         if (self.BUTTON_ATCK)
  83         {
  84                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  85                 {
  86                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  87                         w_ready();
  88                         return;
  89                 }
  90                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
  91                 W_Uzi_Attack(WEP_UZI);
  92                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  93         }
  94         else
  95                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
  96 };
  97
  98 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
  99
 100 float w_uzi(float req)
 101 {
 102         if (req == WR_AIM)
 103                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 104                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 105                 else
 106                 {
 107                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 108                 }
 109         else if (req == WR_THINK)
 110         {
 111                 if (self.BUTTON_ATCK)
 112                 if (weapon_prepareattack(0, 0))
 113                 {
 114                         self.uzi_bulletcounter = 1;
 115                         W_Uzi_Attack(WEP_UZI); // sets attack_finished
 116                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 117                 }
 118                 if (self.BUTTON_ATCK2)
 119                 if (weapon_prepareattack(1, 0))
 120                 {
 121                         self.uzi_bulletcounter = 1;
 122                         W_Uzi_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 123                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_uzi_first_refire"), w_ready);
 124                 }
 125         }
 126         else if (req == WR_PRECACHE)
 127         {
 128                 precache_model ("models/uziflash.md3");
 129                 precache_model ("models/weapons/g_uzi.md3");
 130                 precache_model ("models/weapons/v_uzi.md3");
 131                 precache_model ("models/weapons/w_uzi.zym");
 132                 precache_sound ("weapons/uzi_fire.wav");
 133         }
 134         else if (req == WR_SETUP)
 135                 weapon_setup(WEP_UZI);
 136         else if (req == WR_CHECKAMMO1)
 137                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 138         else if (req == WR_CHECKAMMO2)
 139                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 140         else if (req == WR_SUICIDEMESSAGE)
 141                 w_deathtypestring = "did the impossible";
 142         else if (req == WR_KILLMESSAGE)
 143         {
 144                 if(w_deathtype & HITTYPE_SECONDARY)
 145                         w_deathtypestring = "was sniped by";
 146                 else
 147                         w_deathtypestring = "was riddled full of holes by";
 148         }
 149         return TRUE;
 150 };