data/qcsrc/server/w_uzi.qc

   1 .float uzi_bulletcounter;
   2 void W_Uzi_Attack (void)
   3 {
   4         local entity flash, flash2;
   5
   6         if (cvar("g_use_ammunition"))
   7         {
   8                 if (self.uzi_bulletcounter == 1)
   9                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
  10                 else
  11                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
  12         }
  13         W_SetupShot (self, '11 5.5 -8', TRUE, 0, "weapons/uzi_fire.wav");
  14         if (!cvar("g_norecoil"))
  15         {
  16                 self.punchangle_x = random () - 0.5;
  17                 self.punchangle_y = random () - 0.5;
  18         }
  19
  20         // this attack_finished just enforces a cooldown at the end of a burst
  21         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire");
  22
  23         if (self.uzi_bulletcounter == 1)
  24                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_first_damage"), cvar("g_balance_uzi_first_force"), IT_UZI, TRUE);
  25         else
  26                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_sustained_damage"), cvar("g_balance_uzi_sustained_force"), IT_UZI, (self.uzi_bulletcounter & 3) == 0);
  27
  28         // muzzle flash for 1st person view
  29         flash = spawn();
  30         setorigin(flash, '53 5 0');
  31         setmodel(flash, "models/uziflash.md3"); // precision set below
  32         setattachment(flash, self.weaponentity, "bone01");
  33         flash.owner = self;
  34         flash.viewmodelforclient = self;
  35         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
  36         flash.scale = 1.2;
  37         SUB_SetFade(flash, time, 0.2);
  38
  39         // muzzle flash for 3rd person view
  40         flash2 = spawn();
  41         setorigin(flash2, '43 1 8');
  42         setmodel(flash2, "models/uziflash.md3"); // precision set below
  43         setattachment(flash2, self.exteriorweaponentity, "");
  44         SUB_SetFade(flash2, time, 0.2);
  45
  46         // common properties
  47         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
  48         flash.alpha = flash2.alpha = 0.5;
  49         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  50
  51         // casing code
  52         if (cvar("g_casings") >= 2)
  53                 SpawnCasing (w_shotorg + v_forward * 10, ((random () * 50 + 50) * v_right) - ((random () * 25 + 25) * v_forward) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
  54 }
  55
  56 // weapon frames
  57 void()  uzi_fire1_02 =
  58 {
  59         if(self.weapon != self.switchweapon) // abort immediately if switching
  60         {
  61                 w_ready();
  62                 return;
  63         }
  64         if (self.button0)
  65         {
  66                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  67                 {
  68                         self.switchweapon = w_getbestweapon(self);
  69                         if (self.switchweapon != self.weapon)
  70                                 self.cnt = self.weapon;
  71                         w_ready();
  72                         return;
  73                 }
  74                 ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_refire");
  75                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
  76                 W_Uzi_Attack();
  77                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
  78         }
  79         else
  80                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
  81 };
  82
  83 float(float req) w_uzi =
  84 {
  85         if (req == WR_AIM)
  86                 if(vlen(self.origin-self.enemy.origin)<750)
  87                         self.button0 = bot_aim(1000000, 0, 0.001, FALSE);
  88                 else
  89                 {
  90                         self.button3 = bot_aim(1000000, 0, 0.001, FALSE);
  91                 }
  92         else if (req == WR_THINK)
  93         {
  94                 if (self.button0)
  95                 if (weapon_prepareattack(0, cvar("g_balance_uzi_refire")))
  96                 {
  97                         self.uzi_bulletcounter = 1;
  98                         W_Uzi_Attack();
  99                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
 100                 }
 101                 if (self.button3)
 102                 if (weapon_prepareattack(1, cvar("g_balance_uzi_refire")))
 103                 {
 104                         self.uzi_bulletcounter = 1;
 105                         W_Uzi_Attack();
 106                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
 107                 }
 108         }
 109         else if (req == WR_PRECACHE)
 110         {
 111                 precache_model ("models/tracer.mdl");
 112                 precache_model ("models/uziflash.md3");
 113                 precache_model ("models/weapons/g_uzi.md3");
 114                 precache_model ("models/weapons/v_uzi.md3");
 115                 precache_model ("models/weapons/w_uzi.zym");
 116                 precache_sound ("weapons/ric1.wav");
 117                 precache_sound ("weapons/ric2.wav");
 118                 precache_sound ("weapons/ric3.wav");
 119                 precache_sound ("weapons/tink1.wav");
 120                 precache_sound ("weapons/uzi_fire.wav");
 121                 if (cvar("g_casings") >= 2)
 122                         precache_model ("models/casing_bronze.mdl");
 123         }
 124         else if (req == WR_SETUP)
 125                 weapon_setup(WEP_UZI, "uzi", IT_NAILS);
 126         else if (req == WR_CHECKAMMO1)
 127                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
 128         else if (req == WR_CHECKAMMO2)
 129                 return self.ammo_nails >= cvar("g_balance_uzi_sustained_ammo");
 130         return TRUE;
 131 };