leileilol's effect updates
[divverent/nexuiz.git] / data / qcsrc / server / w_uzi.qc
1 // leilei's fancy muzzleflash stuff
2 void() W_Uzi_Flash_Go;
3 void() W_Uzi_Flash_Go {
4         if (self.frame > 10){
5                 SUB_Remove();
6                 return;
7         }
8         self.frame = self.frame + 2;
9         self.alpha = self.alpha - 0.2;
10         self.think = W_Uzi_Flash_Go;
11         self.nextthink = time + 0.02;
12 };
13
14 .float uzi_bulletcounter;
15 void W_Uzi_Attack (void)
16 {
17         local entity flash, flash2;
18
19         if (cvar("g_use_ammunition"))
20         {
21                 if (self.uzi_bulletcounter == 1)
22                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_first_ammo");
23                 else
24                         self.ammo_nails = self.ammo_nails - cvar("g_balance_uzi_sustained_ammo");
25         }
26         W_SetupShot (self, '11 5.5 -8', TRUE, 0, "weapons/uzi_fire.wav");
27         if (!g_norecoil)
28         {
29                 self.punchangle_x = random () - 0.5;
30                 self.punchangle_y = random () - 0.5;
31         }
32
33         // this attack_finished just enforces a cooldown at the end of a burst
34         ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_first_refire");
35
36         if (self.uzi_bulletcounter == 1)
37                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_first_spread"), cvar("g_balance_uzi_first_damage"), cvar("g_balance_uzi_first_force"), IT_UZI, TRUE);
38         else
39                 fireBullet (w_shotorg, w_shotdir, cvar("g_balance_uzi_sustained_spread"), cvar("g_balance_uzi_sustained_damage"), cvar("g_balance_uzi_sustained_force"), IT_UZI, (self.uzi_bulletcounter & 3) == 0);
40
41         // muzzle flash for 1st person view
42         flash = spawn();
43         setorigin(flash, '53 5 0');
44         setmodel(flash, "models/uziflash.md3"); // precision set below
45         setattachment(flash, self.weaponentity, "bone01");
46         flash.owner = self;
47         flash.viewmodelforclient = self;
48         flash.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
49         flash.scale = 1.2;
50         //SUB_SetFade(flash, time + 0.06, 0);
51         flash.think = W_Uzi_Flash_Go;
52         flash.nextthink = time + 0.02;
53         flash.frame = 2;
54
55         // muzzle flash for 3rd person view
56         flash2 = spawn();
57         setorigin(flash2, '43 1 8');
58         setmodel(flash2, "models/uziflash.md3"); // precision set below
59         setattachment(flash2, self.exteriorweaponentity, "");
60         //SUB_SetFade(flash2, time + 0.06, 0);
61         flash2.think = W_Uzi_Flash_Go;
62         flash2.nextthink = time + 0.02;
63         flash2.frame = 2;
64         // common properties
65         flash.angles_z = flash2.angles_z = flash.v_angle_z + random() * 180;
66         flash.alpha = flash2.alpha = 1;
67         flash.effects = flash2.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
68
69         // casing code
70         if (cvar("g_casings") >= 2)
71                 SpawnCasing (w_shotorg + v_forward * 10, ((random () * 50 + 50) * v_right) - ((random () * 25 + 25) * v_forward) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3);
72 }
73
74 // weapon frames
75 void()  uzi_fire1_02 =
76 {
77         if(self.weapon != self.switchweapon) // abort immediately if switching
78         {
79                 w_ready();
80                 return;
81         }
82         if (self.button0)
83         {
84                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
85                 {
86                         self.switchweapon = w_getbestweapon(self);
87                         if (self.switchweapon != self.weapon)
88                                 self.cnt = self.weapon;
89                         w_ready();
90                         return;
91                 }
92                 ATTACK_FINISHED(self) = time + cvar("g_balance_uzi_refire");
93                 self.uzi_bulletcounter = self.uzi_bulletcounter + 1;
94                 W_Uzi_Attack();
95                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
96         }
97         else
98                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
99 };
100
101 float(float req) w_uzi =
102 {
103         if (req == WR_AIM)
104                 if(vlen(self.origin-self.enemy.origin)<750)
105                         self.button0 = bot_aim(1000000, 0, 0.001, FALSE);
106                 else
107                 {
108                         self.button3 = bot_aim(1000000, 0, 0.001, FALSE);
109                 }
110         else if (req == WR_THINK)
111         {
112                 if (self.button0)
113                 if (weapon_prepareattack(0, cvar("g_balance_uzi_refire")))
114                 {
115                         self.uzi_bulletcounter = 1;
116                         W_Uzi_Attack();
117                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), uzi_fire1_02);
118                 }
119                 if (self.button3)
120                 if (weapon_prepareattack(1, cvar("g_balance_uzi_refire")))
121                 {
122                         self.uzi_bulletcounter = 1;
123                         W_Uzi_Attack();
124                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_uzi_sustained_refire"), w_ready);
125                 }
126         }
127         else if (req == WR_PRECACHE)
128         {
129                 precache_model ("models/tracer.mdl");
130                 precache_model ("models/uziflash.md3");
131                 precache_model ("models/weapons/g_uzi.md3");
132                 precache_model ("models/weapons/v_uzi.md3");
133                 precache_model ("models/weapons/w_uzi.zym");
134                 precache_sound ("weapons/ric1.wav");
135                 precache_sound ("weapons/ric2.wav");
136                 precache_sound ("weapons/ric3.wav");
137                 precache_sound ("weapons/tink1.wav");
138                 precache_sound ("weapons/uzi_fire.wav");
139                 if (cvar("g_casings") >= 2)
140                         precache_model ("models/casing_bronze.mdl");
141         }
142         else if (req == WR_SETUP)
143                 weapon_setup(WEP_UZI, "uzi", IT_NAILS);
144         else if (req == WR_CHECKAMMO1)
145                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
146         else if (req == WR_CHECKAMMO2)
147                 return self.ammo_nails >= cvar("g_balance_uzi_first_ammo");
148         else if (req == WR_REGISTER)
149                 weapon_register(WEP_UZI, cvar("g_balance_uzi_first_ammo"));
150         return TRUE;
151 };