data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Unregister()
   5 {
   6         if(self.owner && self.owner.lastrocket == self)
   7         {
   8                 self.owner.lastrocket = world;
   9                 // self.owner.rl_release = 1;
  10         }
  11 }
  12
  13 void W_Rocket_Explode (void)
  14 {
  15         W_Rocket_Unregister();
  16
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  19
  20         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  21         {
  22                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  23                 {
  24                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  25                         ATTACK_FINISHED(self.owner) = time;
  26                         self.owner.switchweapon = w_getbestweapon(self.owner);
  27                 }
  28                 if(g_laserguided_missile)
  29                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire");
  30         }
  31         remove (self);
  32 }
  33
  34 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  35 {
  36         entity head, selected;
  37         vector dir;
  38         float dist, maxdist,// bestdist,
  39                 dot,// bestdot,
  40                 points, bestpoints;
  41         //bestdist = 9999;
  42         //bestdot = -2;
  43         bestpoints = 0;
  44         maxdist = 800;
  45         selected = world;
  46
  47         makevectors(e.angles);
  48
  49         head = find(world, classname, "laser_target");
  50         while(head)
  51         {
  52                 points = 0;
  53                 dir = normalize(head.origin - self.origin);
  54                 dot = dir * v_forward;
  55                 dist = vlen(head.origin - self.origin);
  56                 if(dist > maxdist)
  57                         dist = maxdist;
  58
  59                 // gain points for being in front
  60                 points = points + ((dot+1)*0.5) * 500
  61                         * (1 + crandom()*dot_variance);
  62                 // gain points for being close away
  63                 points = points + (1 - dist/maxdist) * 1000
  64                         * (1 + crandom()*dot_variance);
  65
  66                 traceline(e.origin, head.origin, TRUE, self);
  67                 if(trace_fraction < 1)
  68                 {
  69                         points = 0;
  70                 }
  71
  72                 if(points > bestpoints)//random() > 0.5)//
  73                 {
  74                         bestpoints = points;
  75                         selected = head;
  76                 }
  77
  78                 head = find(head, classname, "laser_target");
  79         }
  80
  81         //bprint(selected.owner.netname);
  82         //bprint("\n");
  83         return selected;
  84 }
  85
  86 void W_Rocket_RemoteExplode()
  87 {
  88         if(self.owner.deadflag == DEAD_NO)
  89         if(self.owner.lastrocket)
  90         {
  91                 if((self.spawnshieldtime >= 0)
  92                         ? (time >= self.spawnshieldtime) // timer
  93                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  94                 )
  95                 {
  96                         other = world;
  97                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  98                         W_Rocket_Explode ();
  99                 }
 100                 else
 101                 {
 102                 }
 103         }
 104 }
 105
 106 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 107 {
 108         if(thisdir * goaldir > maxturn_cos)
 109                 return goaldir;
 110         float f, m2;
 111         vector v;
 112         // solve:
 113         //   g = normalize(thisdir + goaldir * X)
 114         //   thisdir * g = maxturn
 115         //
 116         //   gg = thisdir + goaldir * X
 117         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 118         //
 119         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 120         f = thisdir * goaldir;
 121         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 122         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 123         m2 = maxturn_cos * maxturn_cos;
 124         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 125         return normalize(thisdir + goaldir * v_y); // the larger solution!
 126 }
 127
 128 void W_Rocket_Think (void)
 129 {
 130         entity e;
 131         vector desireddir, olddir, newdir, desiredorigin, goal;
 132         float turnrate, velspeed;
 133         self.nextthink = time;
 134         if (time > self.cnt)
 135         {
 136                 other = world;
 137                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 138                 W_Rocket_Explode ();
 139                 return;
 140         }
 141
 142         if(g_laserguided_missile)
 143         {
 144                 // accelerate
 145                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 146                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") - (self.velocity * v_forward);
 147                 if (velspeed > 0)
 148                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 149         }
 150         else
 151         {
 152                 // accelerate
 153                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 154                 velspeed = cvar("g_balance_rocketlauncher_speed") - (self.velocity * v_forward);
 155                 if (velspeed > 0)
 156                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * frametime, velspeed);
 157         }
 158
 159         // laser guided, or remote detonation
 160         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 161         {
 162                 if(g_laserguided_missile)
 163                 {
 164                         if(self.rl_detonate_later)
 165                                 W_Rocket_RemoteExplode();
 166
 167                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 168                         {
 169                                 if(self.owner.laser_on)
 170                                 {
 171                                         if(self.attack_finished_single < time)
 172                                         {
 173                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 174                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 175                                         }
 176
 177                                         if(!self.enemy)
 178                                                 self.enemy = self.owner.weaponentity.lasertarget;
 179                                 }
 180                                 else self.enemy = world;
 181                         }
 182                         else // don't allow stealing: always target my owner's laser (if it exists)
 183                                 self.enemy = self.owner.weaponentity.lasertarget;
 184
 185                         if(self.enemy != world)
 186                         {
 187                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 188                                 velspeed = vlen(self.velocity);
 189                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 190                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 191                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 192                                 olddir = normalize(self.velocity);                                      // get my current direction
 193                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 194                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 195                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 196
 197                                 ATTACK_FINISHED(self.owner) = time + 0.2;
 198                         }
 199                 }
 200                 else
 201                 {
 202                         if(self == self.owner.lastrocket)
 203                         if(!self.owner.rl_release)
 204                         if(cvar("g_balance_rocketlauncher_guiderate"))
 205                         if(time > self.pushltime)
 206                         if(self.owner.deadflag == DEAD_NO)
 207                         {
 208                                 velspeed = vlen(self.velocity);
 209
 210                                 makevectors(self.owner.v_angle);
 211                                 desireddir = v_forward;
 212                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 213                                 olddir = normalize(self.velocity);
 214
 215                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 216                                 // but we are limiting the rate at which we can turn!
 217                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 218                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * frametime * PI / 180));
 219
 220                                 self.velocity = newdir * velspeed;
 221                         }
 222
 223                         if(self.rl_detonate_later)
 224                                 W_Rocket_RemoteExplode();
 225                 }
 226         }
 227
 228         if(self.csqcprojectile_clientanimate == 0)
 229                 UpdateCSQCProjectile(self);
 230 }
 231
 232 void W_Rocket_Touch (void)
 233 {
 234         W_Rocket_Unregister();
 235
 236         PROJECTILE_TOUCH;
 237         W_Rocket_Explode ();
 238 }
 239
 240 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 241 {
 242         self.health = self.health - damage;
 243         self.angles = vectoangles(self.velocity);
 244         if (self.health <= 0)
 245                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 246 }
 247
 248 void W_Rocket_Attack (void)
 249 {
 250         local entity missile;
 251         local entity flash;
 252
 253         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 254                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 255
 256         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav");
 257         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 258
 259         missile = spawn ();
 260         missile.owner = self;
 261         self.lastrocket = missile;
 262         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 263                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 264         else
 265                 missile.spawnshieldtime = -1;
 266         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 267         missile.classname = "rocket";
 268         missile.bot_dodge = TRUE;
 269         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 270
 271         missile.takedamage = DAMAGE_YES;
 272         missile.damageforcescale = 4;
 273         missile.health = cvar("g_balance_rocketlauncher_health");
 274         missile.event_damage = W_Rocket_Damage;
 275
 276         missile.movetype = MOVETYPE_FLY;
 277         missile.solid = SOLID_BBOX;
 278         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 279         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 280
 281         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 282         if(g_laserguided_missile && self.laser_on)
 283                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart");
 284         else
 285                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart");
 286         W_SetupProjectileVelocity(missile);
 287         missile.angles = vectoangles (missile.velocity);
 288
 289         missile.touch = W_Rocket_Touch;
 290         missile.think = W_Rocket_Think;
 291         missile.nextthink = time;
 292         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 293         missile.flags = FL_PROJECTILE;
 294
 295         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 296
 297         // muzzle flash for 1st person view
 298         flash = spawn ();
 299         setmodel (flash, "models/flash.md3"); // precision set below
 300         SUB_SetFade (flash, time, 0.1);
 301         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 302         W_AttachToShotorg(flash, '5 0 0');
 303
 304         // common properties
 305 }
 306
 307 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 308
 309 float w_rlauncher(float req)
 310 {
 311         entity rock;
 312         float rockfound;
 313         if (req == WR_AIM)
 314         {
 315                 // aim and decide to fire if appropriate
 316                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 317                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 318                 {
 319                         // decide whether to detonate rockets
 320                         local entity missile, targetlist, targ;
 321                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 322                         local float selfdamage, teamdamage, enemydamage;
 323                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 324                         coredamage = cvar("g_balance_rocketlauncher_damage");
 325                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 326                         recipricoledgeradius = 1 / edgeradius;
 327                         selfdamage = 0;
 328                         teamdamage = 0;
 329                         enemydamage = 0;
 330                         targetlist = findchainfloat(bot_attack, TRUE);
 331                         missile = find(world, classname, "rocket");
 332                         while (missile)
 333                         {
 334                                 if (missile.owner != self)
 335                                 {
 336                                         missile = find(missile, classname, "rocket");
 337                                         continue;
 338                                 }
 339                                 targ = targetlist;
 340                                 while (targ)
 341                                 {
 342                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 343                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 344                                         // count potential damage according to type of target
 345                                         if (targ == self)
 346                                                 selfdamage = selfdamage + d;
 347                                         else if (targ.team == self.team && teams_matter)
 348                                                 teamdamage = teamdamage + d;
 349                                         else if (bot_shouldattack(targ))
 350                                                 enemydamage = enemydamage + d;
 351                                         targ = targ.chain;
 352                                 }
 353                                 missile = find(missile, classname, "rocket");
 354                         }
 355                         local float desirabledamage;
 356                         desirabledamage = enemydamage;
 357                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 358                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 359                         if (self.team && teamplay != 1)
 360                                 desirabledamage = desirabledamage - teamdamage;
 361
 362                         missile = find(world, classname, "rocket");
 363                         while (missile)
 364                         {
 365                                 if (missile.owner != self)
 366                                 {
 367                                         missile = find(missile, classname, "rocket");
 368                                         continue;
 369                                 }
 370                                 makevectors(missile.v_angle);
 371                                 targ = targetlist;
 372                                 if (skill > 9) // normal players only do this for the target they are tracking
 373                                 {
 374                                         targ = targetlist;
 375                                         while (targ)
 376                                         {
 377                                                 if (
 378                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 379                                                         && desirabledamage > 0.1*coredamage
 380                                                 )self.BUTTON_ATCK2 = TRUE;
 381                                                 targ = targ.chain;
 382                                         }
 383                                 }else{
 384                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 385                                         //As the distance gets larger, a correct detonation gets near imposible
 386                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 387                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 388                                                 if(self.enemy.classname == "player")
 389                                                         if(desirabledamage >= 0.1*coredamage)
 390                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 391                                                                         self.BUTTON_ATCK2 = TRUE;
 392                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 393                                 }
 394
 395                                 missile = find(missile, classname, "rocket");
 396                         }
 397                         // if we would be doing at X percent of the core damage, detonate it
 398                         // but don't fire a new shot at the same time!
 399                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 400                                 self.BUTTON_ATCK2 = TRUE;
 401                         if ((skill > 6.5) && (selfdamage > self.health))
 402                                 self.BUTTON_ATCK2 = FALSE;
 403                         //if(self.BUTTON_ATCK2 == TRUE)
 404                         //      dprint(ftos(desirabledamage),"\n");
 405                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 406                 }
 407         }
 408         else if (req == WR_THINK)
 409         {
 410                 if(g_laserguided_missile)
 411                 {
 412                         if (self.BUTTON_ATCK && self.rl_release)
 413                         {
 414                                 rockfound = 0;
 415                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 416                                 {
 417                                         if(!rock.rl_detonate_later)
 418                                         {
 419                                                 rock.rl_detonate_later = TRUE;
 420                                                 rockfound = 1;
 421                                         }
 422                                 }
 423                                 if(rockfound)
 424                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 425                                 else
 426                                 {
 427                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 428                                         {
 429                                                 W_Rocket_Attack();
 430                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 431                                         }
 432                                 }
 433                                 self.rl_release = 0;
 434                         }
 435                         if (!self.BUTTON_ATCK)
 436                                 self.rl_release = 1;
 437                         if (self.BUTTON_ATCK2)
 438                         if(self.exteriorweaponentity.attack_finished_single < time)
 439                         {
 440                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 441                                 self.laser_on = !self.laser_on;
 442                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 443                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 444                         }
 445                 }
 446                 else
 447                 {
 448                         if (self.BUTTON_ATCK)
 449                         {
 450                                 if(self.rl_release)
 451                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 452                                 {
 453                                         W_Rocket_Attack();
 454                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 455                                         self.rl_release = 0;
 456                                 }
 457                         }
 458                         else
 459                                 self.rl_release = 1;
 460
 461                         if (self.BUTTON_ATCK2)
 462                         {
 463                                 rockfound = 0;
 464                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 465                                 {
 466                                         if(!rock.rl_detonate_later)
 467                                         {
 468                                                 rock.rl_detonate_later = TRUE;
 469                                                 rockfound = 1;
 470                                         }
 471                                 }
 472                                 if(rockfound)
 473                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 474                         }
 475                 }
 476         }
 477         else if (req == WR_PRECACHE)
 478         {
 479                 precache_model ("models/flash.md3");
 480                 precache_model ("models/weapons/g_rl.md3");
 481                 precache_model ("models/weapons/v_rl.md3");
 482                 precache_model ("models/weapons/h_rl.dpm");
 483                 precache_sound ("weapons/rocket_det.wav");
 484                 precache_sound ("weapons/rocket_fire.wav");
 485                 if (g_laserguided_missile)
 486                 {
 487                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 488                         precache_sound ("weapons/rocket_mode.wav");
 489                 }
 490         }
 491         else if (req == WR_SETUP)
 492         {
 493                 weapon_setup(WEP_ROCKET_LAUNCHER);
 494                 self.rl_release = 1;
 495         }
 496         else if (req == WR_CHECKAMMO1)
 497         {
 498                 // don't switch while guiding a missile
 499                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 500                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 501                         return FALSE;
 502         }
 503         else if (req == WR_CHECKAMMO2)
 504                 return FALSE;
 505         else if (req == WR_SUICIDEMESSAGE)
 506                 w_deathtypestring = "exploded";
 507         else if (req == WR_KILLMESSAGE)
 508         {
 509                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 510                         w_deathtypestring = "got too close to #'s rocket";
 511                 else if(w_deathtype & HITTYPE_SPLASH)
 512                         w_deathtypestring = "almost dodged #'s rocket";
 513                 else
 514                         w_deathtypestring = "ate #'s rocket";
 515         }
 516         return TRUE;
 517 };