data/qcsrc/server/w_rocketlauncher.qc

   1 .float rl_release;
   2 .float rl_detonate_later;
   3
   4 void W_Rocket_Unregister()
   5 {
   6         if(self.owner && self.owner.lastrocket == self)
   7         {
   8                 self.owner.lastrocket = world;
   9                 // self.owner.rl_release = 1;
  10         }
  11 }
  12
  13 void W_Rocket_Explode (void)
  14 {
  15         W_Rocket_Unregister();
  16
  17         self.event_damage = SUB_Null;
  18         self.takedamage = DAMAGE_NO;
  19         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  20
  21         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  22         {
  23                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  24                 {
  25                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  26                         ATTACK_FINISHED(self.owner) = time;
  27                         self.owner.switchweapon = w_getbestweapon(self.owner);
  28                 }
  29                 if(g_laserguided_missile)
  30                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  31         }
  32         remove (self);
  33 }
  34
  35 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  36 {
  37         entity head, selected;
  38         vector dir;
  39         float dist, maxdist,// bestdist,
  40                 dot,// bestdot,
  41                 points, bestpoints;
  42         //bestdist = 9999;
  43         //bestdot = -2;
  44         bestpoints = 0;
  45         maxdist = 800;
  46         selected = world;
  47
  48         makevectors(e.angles);
  49
  50         head = find(world, classname, "laser_target");
  51         while(head)
  52         {
  53                 points = 0;
  54                 dir = normalize(head.origin - self.origin);
  55                 dot = dir * v_forward;
  56                 dist = vlen(head.origin - self.origin);
  57                 if(dist > maxdist)
  58                         dist = maxdist;
  59
  60                 // gain points for being in front
  61                 points = points + ((dot+1)*0.5) * 500
  62                         * (1 + crandom()*dot_variance);
  63                 // gain points for being close away
  64                 points = points + (1 - dist/maxdist) * 1000
  65                         * (1 + crandom()*dot_variance);
  66
  67                 traceline(e.origin, head.origin, TRUE, self);
  68                 if(trace_fraction < 1)
  69                 {
  70                         points = 0;
  71                 }
  72
  73                 if(points > bestpoints)//random() > 0.5)//
  74                 {
  75                         bestpoints = points;
  76                         selected = head;
  77                 }
  78
  79                 head = find(head, classname, "laser_target");
  80         }
  81
  82         //bprint(selected.owner.netname);
  83         //bprint("\n");
  84         return selected;
  85 }
  86
  87 void W_Rocket_RemoteExplode()
  88 {
  89         if(self.owner.deadflag == DEAD_NO)
  90         if(self.owner.lastrocket)
  91         {
  92                 if((self.spawnshieldtime >= 0)
  93                         ? (time >= self.spawnshieldtime) // timer
  94                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
  95                 )
  96                 {
  97                         other = world;
  98                         self.projectiledeathtype |= HITTYPE_BOUNCE;
  99                         W_Rocket_Explode ();
 100                 }
 101                 else
 102                 {
 103                 }
 104         }
 105 }
 106
 107 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 108 {
 109         if(thisdir * goaldir > maxturn_cos)
 110                 return goaldir;
 111         float f, m2;
 112         vector v;
 113         // solve:
 114         //   g = normalize(thisdir + goaldir * X)
 115         //   thisdir * g = maxturn
 116         //
 117         //   gg = thisdir + goaldir * X
 118         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 119         //
 120         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 121         f = thisdir * goaldir;
 122         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 123         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 124         m2 = maxturn_cos * maxturn_cos;
 125         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 126         return normalize(thisdir + goaldir * v_y); // the larger solution!
 127 }
 128
 129 void W_Rocket_Think (void)
 130 {
 131         entity e;
 132         vector desireddir, olddir, newdir, desiredorigin, goal;
 133         float turnrate, velspeed, f;
 134         self.nextthink = time;
 135         if (time > self.cnt)
 136         {
 137                 other = world;
 138                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 139                 W_Rocket_Explode ();
 140                 return;
 141         }
 142
 143         if(g_laserguided_missile)
 144         {
 145                 // accelerate
 146                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 147                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 148                 if (velspeed > 0)
 149                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 150         }
 151         else
 152         {
 153                 // accelerate
 154                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 155                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 156                 if (velspeed > 0)
 157                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 158         }
 159
 160         // laser guided, or remote detonation
 161         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 162         {
 163                 if(g_laserguided_missile)
 164                 {
 165                         if(self.rl_detonate_later)
 166                                 W_Rocket_RemoteExplode();
 167
 168                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 169                         {
 170                                 if(self.owner.laser_on)
 171                                 {
 172                                         if(self.attack_finished_single < time)
 173                                         {
 174                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 175                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 176                                         }
 177
 178                                         if(!self.enemy)
 179                                                 self.enemy = self.owner.weaponentity.lasertarget;
 180                                 }
 181                                 else self.enemy = world;
 182                         }
 183                         else // don't allow stealing: always target my owner's laser (if it exists)
 184                                 self.enemy = self.owner.weaponentity.lasertarget;
 185
 186                         if(self.enemy != world)
 187                         {
 188                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 189                                 velspeed = vlen(self.velocity);
 190                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 191                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 192                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 193                                 olddir = normalize(self.velocity);                                      // get my current direction
 194                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 195                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 196                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 197
 198                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 199                         }
 200                 }
 201                 else
 202                 {
 203                         if(self == self.owner.lastrocket)
 204                         if(!self.owner.rl_release)
 205                         if(cvar("g_balance_rocketlauncher_guiderate"))
 206                         if(time > self.pushltime)
 207                         if(self.owner.deadflag == DEAD_NO)
 208                         {
 209                                 f = min(1, (time - self.pushltime) / cvar("g_balance_rocketlauncher_guideratedelay"));
 210                                 velspeed = vlen(self.velocity);
 211
 212                                 makevectors(self.owner.v_angle);
 213                                 desireddir = v_forward;
 214                                 desiredorigin = self.owner.origin + self.owner.view_ofs;
 215                                 olddir = normalize(self.velocity);
 216
 217                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 218                                 // but we are limiting the rate at which we can turn!
 219                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 220                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * PI / 180));
 221
 222                                 self.velocity = newdir * velspeed;
 223                         }
 224
 225                         if(self.rl_detonate_later)
 226                                 W_Rocket_RemoteExplode();
 227                 }
 228         }
 229
 230         if(self.csqcprojectile_clientanimate == 0)
 231                 UpdateCSQCProjectile(self);
 232 }
 233
 234 void W_Rocket_Touch (void)
 235 {
 236         W_Rocket_Unregister();
 237
 238         PROJECTILE_TOUCH;
 239         W_Rocket_Explode ();
 240 }
 241
 242 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 243 {
 244         if (self.health <= 0)
 245                 return;
 246         self.health = self.health - damage;
 247         self.angles = vectoangles(self.velocity);
 248         if (self.health <= 0)
 249                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 250 }
 251
 252 void W_Rocket_Attack (void)
 253 {
 254         local entity missile;
 255         local entity flash;
 256
 257         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 258                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 259
 260         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 261         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 262
 263         missile = spawn ();
 264         missile.owner = self;
 265         self.lastrocket = missile;
 266         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 267                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 268         else
 269                 missile.spawnshieldtime = -1;
 270         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 271         missile.classname = "rocket";
 272         missile.bot_dodge = TRUE;
 273         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_primary_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 274
 275         missile.takedamage = DAMAGE_YES;
 276         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 277         missile.health = cvar("g_balance_rocketlauncher_health");
 278         missile.event_damage = W_Rocket_Damage;
 279
 280         missile.movetype = MOVETYPE_FLY;
 281         PROJECTILE_MAKETRIGGER(missile);
 282         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 283         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 284
 285         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 286         if(g_laserguided_missile && self.laser_on)
 287                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_laserguided_speedstart") * g_weaponspeedfactor;
 288         else
 289                 missile.velocity = w_shotdir * cvar("g_balance_rocketlauncher_speedstart") * g_weaponspeedfactor;
 290         W_SetupProjectileVelocity(missile);
 291         missile.angles = vectoangles (missile.velocity);
 292
 293         missile.touch = W_Rocket_Touch;
 294         missile.think = W_Rocket_Think;
 295         missile.nextthink = time;
 296         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 297         missile.flags = FL_PROJECTILE;
 298
 299         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 300
 301         // muzzle flash for 1st person view
 302         flash = spawn ();
 303         setmodel (flash, "models/flash.md3"); // precision set below
 304         SUB_SetFade (flash, time, 0.1);
 305         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 306         W_AttachToShotorg(flash, '5 0 0');
 307
 308         // common properties
 309 }
 310
 311 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 312
 313 float w_rlauncher(float req)
 314 {
 315         entity rock;
 316         float rockfound;
 317         if (req == WR_AIM)
 318         {
 319                 // aim and decide to fire if appropriate
 320                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 321                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 322                 {
 323                         // decide whether to detonate rockets
 324                         local entity missile, targetlist, targ;
 325                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 326                         local float selfdamage, teamdamage, enemydamage;
 327                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 328                         coredamage = cvar("g_balance_rocketlauncher_damage");
 329                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 330                         recipricoledgeradius = 1 / edgeradius;
 331                         selfdamage = 0;
 332                         teamdamage = 0;
 333                         enemydamage = 0;
 334                         targetlist = findchainfloat(bot_attack, TRUE);
 335                         missile = find(world, classname, "rocket");
 336                         while (missile)
 337                         {
 338                                 if (missile.owner != self)
 339                                 {
 340                                         missile = find(missile, classname, "rocket");
 341                                         continue;
 342                                 }
 343                                 targ = targetlist;
 344                                 while (targ)
 345                                 {
 346                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 347                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 348                                         // count potential damage according to type of target
 349                                         if (targ == self)
 350                                                 selfdamage = selfdamage + d;
 351                                         else if (targ.team == self.team && teams_matter)
 352                                                 teamdamage = teamdamage + d;
 353                                         else if (bot_shouldattack(targ))
 354                                                 enemydamage = enemydamage + d;
 355                                         targ = targ.chain;
 356                                 }
 357                                 missile = find(missile, classname, "rocket");
 358                         }
 359                         local float desirabledamage;
 360                         desirabledamage = enemydamage;
 361                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 362                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 363                         if (self.team && teamplay != 1)
 364                                 desirabledamage = desirabledamage - teamdamage;
 365
 366                         missile = find(world, classname, "rocket");
 367                         while (missile)
 368                         {
 369                                 if (missile.owner != self)
 370                                 {
 371                                         missile = find(missile, classname, "rocket");
 372                                         continue;
 373                                 }
 374                                 makevectors(missile.v_angle);
 375                                 targ = targetlist;
 376                                 if (skill > 9) // normal players only do this for the target they are tracking
 377                                 {
 378                                         targ = targetlist;
 379                                         while (targ)
 380                                         {
 381                                                 if (
 382                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 383                                                         && desirabledamage > 0.1*coredamage
 384                                                 )self.BUTTON_ATCK2 = TRUE;
 385                                                 targ = targ.chain;
 386                                         }
 387                                 }else{
 388                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 389                                         //As the distance gets larger, a correct detonation gets near imposible
 390                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 391                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 392                                                 if(self.enemy.classname == "player")
 393                                                         if(desirabledamage >= 0.1*coredamage)
 394                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 395                                                                         self.BUTTON_ATCK2 = TRUE;
 396                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 397                                 }
 398
 399                                 missile = find(missile, classname, "rocket");
 400                         }
 401                         // if we would be doing at X percent of the core damage, detonate it
 402                         // but don't fire a new shot at the same time!
 403                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 404                                 self.BUTTON_ATCK2 = TRUE;
 405                         if ((skill > 6.5) && (selfdamage > self.health))
 406                                 self.BUTTON_ATCK2 = FALSE;
 407                         //if(self.BUTTON_ATCK2 == TRUE)
 408                         //      dprint(ftos(desirabledamage),"\n");
 409                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 410                 }
 411         }
 412         else if (req == WR_THINK)
 413         {
 414                 if(g_laserguided_missile)
 415                 {
 416                         if (self.BUTTON_ATCK && self.rl_release)
 417                         {
 418                                 rockfound = 0;
 419                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 420                                 {
 421                                         if(!rock.rl_detonate_later)
 422                                         {
 423                                                 rock.rl_detonate_later = TRUE;
 424                                                 rockfound = 1;
 425                                         }
 426                                 }
 427                                 if(rockfound)
 428                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 429                                 else
 430                                 {
 431                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 432                                         {
 433                                                 W_Rocket_Attack();
 434                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 435                                         }
 436                                 }
 437                                 self.rl_release = 0;
 438                         }
 439                         if (!self.BUTTON_ATCK)
 440                                 self.rl_release = 1;
 441                         if (self.BUTTON_ATCK2)
 442                         if(self.exteriorweaponentity.attack_finished_single < time)
 443                         {
 444                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 445                                 self.laser_on = !self.laser_on;
 446                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 447                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 448                         }
 449                 }
 450                 else
 451                 {
 452                         if (self.BUTTON_ATCK)
 453                         {
 454                                 if(self.rl_release)
 455                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 456                                 {
 457                                         W_Rocket_Attack();
 458                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 459                                         self.rl_release = 0;
 460                                 }
 461                         }
 462                         else
 463                                 self.rl_release = 1;
 464
 465                         if (self.BUTTON_ATCK2)
 466                         {
 467                                 rockfound = 0;
 468                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 469                                 {
 470                                         if(!rock.rl_detonate_later)
 471                                         {
 472                                                 rock.rl_detonate_later = TRUE;
 473                                                 rockfound = 1;
 474                                         }
 475                                 }
 476                                 if(rockfound)
 477                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 478                         }
 479                 }
 480         }
 481         else if (req == WR_PRECACHE)
 482         {
 483                 precache_model ("models/flash.md3");
 484                 precache_model ("models/weapons/g_rl.md3");
 485                 precache_model ("models/weapons/v_rl.md3");
 486                 precache_model ("models/weapons/h_rl.dpm");
 487                 precache_sound ("weapons/rocket_det.wav");
 488                 precache_sound ("weapons/rocket_fire.wav");
 489                 if (g_laserguided_missile)
 490                 {
 491                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 492                         precache_sound ("weapons/rocket_mode.wav");
 493                 }
 494         }
 495         else if (req == WR_SETUP)
 496         {
 497                 weapon_setup(WEP_ROCKET_LAUNCHER);
 498                 self.rl_release = 1;
 499         }
 500         else if (req == WR_CHECKAMMO1)
 501         {
 502                 // don't switch while guiding a missile
 503                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 504                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 505                         return FALSE;
 506         }
 507         else if (req == WR_CHECKAMMO2)
 508                 return FALSE;
 509         else if (req == WR_SUICIDEMESSAGE)
 510                 w_deathtypestring = "exploded";
 511         else if (req == WR_KILLMESSAGE)
 512         {
 513                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 514                         w_deathtypestring = "got too close to #'s rocket";
 515                 else if(w_deathtype & HITTYPE_SPLASH)
 516                         w_deathtypestring = "almost dodged #'s rocket";
 517                 else
 518                         w_deathtypestring = "ate #'s rocket";
 519         }
 520         return TRUE;
 521 };