data/qcsrc/server/w_porto.qc

   1 .float portal_id;
   2 .vector porto_v_angle; // holds "held" view angles
   3 .float porto_v_angle_held;
   4 .vector right_vector;
   5
   6 void W_Porto_Success (void)
   7 {
   8         self.owner.portal_id = 0;
   9         remove(self);
  10 }
  11
  12 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  13 void W_Porto_Fail (void)
  14 {
  15         centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  16
  17         // no portals here!
  18         Portal_ClearWithID(self.owner, self.portal_id);
  19
  20         self.owner.portal_id = 0;
  21         // TODO maybe instead throw the portal gun there?
  22         // self.owner.weapons = self.owner.weapons | WEPBIT_PORTO;
  23         setsize (self, '-16 -16 0', '16 16 32');
  24         setorigin(self, self.origin + trace_plane_normal);
  25         if(move_out_of_solid(self))
  26         {
  27                 self.flags = FL_ITEM;
  28                 self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  29                 tracetoss(self, self);
  30                 if(vlen(trace_endpos - self.owner.origin) > 128)
  31                         self.velocity = '0 0 0';
  32                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  33         }
  34         else
  35         {
  36                 W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, '0 0 0');
  37         }
  38         remove(self);
  39 }
  40
  41 void W_Porto_Think (void)
  42 {
  43         trace_plane_normal = '0 0 0';
  44         if(self.owner.playerid != self.playerid)
  45                 remove(self);
  46         else
  47                 W_Porto_Fail();
  48 }
  49
  50 void W_Porto_Touch (void)
  51 {
  52         vector norm;
  53         norm = trace_plane_normal;
  54         if(self.owner.playerid != self.playerid)
  55         {
  56                 remove(self);
  57         }
  58         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
  59         {
  60                 // just reflect
  61                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  62         }
  63         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  64         {
  65                 W_Porto_Fail();
  66         }
  67         else if(self.cnt == 0)
  68         {
  69                 self.cnt = 1;
  70                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  71                 {
  72                         trace_plane_normal = norm;
  73                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  74                         self.angles = vectoangles(self.velocity);
  75                 }
  76                 else
  77                 {
  78                         trace_plane_normal = norm;
  79                         W_Porto_Fail();
  80                 }
  81         }
  82         else
  83         {
  84                 if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  85                 {
  86                         W_Porto_Success();
  87                 }
  88                 else
  89                 {
  90                         trace_plane_normal = norm;
  91                         W_Porto_Fail();
  92                 }
  93         }
  94
  95 }
  96
  97 void W_Porto_Attack (void)
  98 {
  99         local entity gren;
 100
 101         if (cvar("g_use_ammunition"))
 102                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 103         W_SetupShot (self, '0 0 0', FALSE, 4, "weapons/grenade_fire.wav");
 104
 105         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 106
 107         gren = spawn ();
 108         gren.owner = self;
 109         gren.classname = "porto";
 110         gren.bot_dodge = TRUE;
 111         gren.bot_dodgerating = 200;
 112         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 113         gren.solid = SOLID_BBOX;
 114         gren.effects = EF_LOWPRECISION;
 115         gren.modelflags = MF_GRENADE;
 116         setmodel(gren, "models/grenademodel.md3"); // precision set above
 117         setsize(gren, '0 0 0', '0 0 0');
 118         setorigin(gren, w_shotorg);
 119
 120         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 121         gren.think = W_Porto_Think;
 122         gren.touch = W_Porto_Touch;
 123         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 124         W_SetupProjectileVelocity(gren);
 125
 126         gren.angles = vectoangles (gren.velocity);
 127         gren.flags = FL_PROJECTILE;
 128
 129         self.portal_id = gren.portal_id = time;
 130         gren.playerid = self.playerid;
 131         fixedmakevectors(vectoangles(gren.velocity));
 132         gren.right_vector = v_right;
 133
 134         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 135 }
 136
 137 void spawnfunc_weapon_porto (void)
 138 {
 139         if(g_race)
 140         {
 141                 startitem_failed = TRUE;
 142                 remove(self);
 143                 return;
 144         }
 145         else
 146                 weapon_defaultspawnfunc(WEP_PORTO);
 147 }
 148
 149 float w_porto(float req)
 150 {
 151         vector v_angle_save;
 152
 153         if (req == WR_AIM)
 154         {
 155                 self.BUTTON_ATCK = FALSE;
 156                 self.BUTTON_ATCK2 = FALSE;
 157                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 158                         self.BUTTON_ATCK = TRUE;
 159         }
 160         else if (req == WR_THINK)
 161         {
 162                 if(self.porto_v_angle_held)
 163                 {
 164                         if(!self.BUTTON_ATCK2)
 165                         {
 166                                 msg_entity = self;
 167                                 WRITESPECTATABLE_MSG_ONE({
 168                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 169                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 170                                         WriteByte(MSG_ONE, WEP_PORTO);
 171                                         WriteByte(MSG_ONE, 0);
 172                                 });
 173                                 self.porto_v_angle_held = 0;
 174                         }
 175                 }
 176                 else
 177                 {
 178                         if(self.BUTTON_ATCK2)
 179                         {
 180                                 self.porto_v_angle = self.v_angle;
 181                                 msg_entity = self;
 182                                 WRITESPECTATABLE_MSG_ONE({
 183                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 184                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 185                                         WriteByte(MSG_ONE, WEP_PORTO);
 186                                         WriteByte(MSG_ONE, 1);
 187                                         WriteCoord(MSG_ONE, self.v_angle_x);
 188                                         WriteCoord(MSG_ONE, self.v_angle_y);
 189                                 });
 190                                 self.porto_v_angle_held = 1;
 191                         }
 192                 }
 193                 v_angle_save = self.v_angle;
 194                 if(self.porto_v_angle_held)
 195                         makevectors(self.porto_v_angle); // override the previously set angles
 196
 197                 if (self.BUTTON_ATCK)
 198                 if (!self.portal_id)
 199                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 200                 {
 201                         W_Porto_Attack();
 202                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 203                 }
 204         }
 205         else if (req == WR_PRECACHE)
 206         {
 207                 precache_model ("models/grenademodel.md3");
 208                 precache_model ("models/weapons/g_porto.md3");
 209                 precache_model ("models/weapons/v_porto.md3");
 210                 precache_model ("models/weapons/w_porto.zym");
 211                 precache_sound ("weapons/grenade_fire.wav");
 212                 precache_model ("models/portal.md3");
 213         }
 214         else if (req == WR_SETUP)
 215                 weapon_setup(WEP_PORTO);
 216         else if (req == WR_SUICIDEMESSAGE)
 217                 w_deathtypestring = "did the impossible";
 218         else if (req == WR_KILLMESSAGE)
 219                 w_deathtypestring = "felt # doing the impossible";
 220         return TRUE;
 221 };