data/qcsrc/server/w_porto.qc

   1 .float portal_id;
   2 .entity porto_current;
   3 .vector porto_v_angle; // holds "held" view angles
   4 .float porto_v_angle_held;
   5 .vector right_vector;
   6
   7 void W_Porto_Success (void)
   8 {
   9         self.owner.porto_current = world;
  10         remove(self);
  11 }
  12
  13 float W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo);
  14 void W_Porto_Fail (float failhard)
  15 {
  16         // no portals here!
  17         Portal_ClearWithID(self.owner, self.portal_id);
  18         self.owner.porto_current = world;
  19
  20         if(!failhard)
  21         {
  22                 centerprint(self.owner, "^1Portal deployment failed.\n\n^2Catch it to try again!");
  23                 setsize (self, '-16 -16 0', '16 16 32');
  24                 setorigin(self, self.origin + trace_plane_normal);
  25                 if(move_out_of_solid(self))
  26                 {
  27                         self.flags = FL_ITEM;
  28                         self.velocity = trigger_push_calculatevelocity(self.origin, self.owner, 128);
  29                         tracetoss(self, self);
  30                         if(vlen(trace_endpos - self.owner.origin) > 128)
  31                                 self.velocity = '0 0 0';
  32                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, self.velocity);
  33                 }
  34                 else
  35                 {
  36                         W_ThrowNewWeapon(self.owner, WEP_PORTO, 0, self.origin, '0 0 0');
  37                 }
  38         }
  39         remove(self);
  40 }
  41
  42 void W_Porto_Think (void)
  43 {
  44         trace_plane_normal = '0 0 0';
  45         if(self.owner.playerid != self.playerid)
  46                 remove(self);
  47         else
  48                 W_Porto_Fail(0);
  49 }
  50
  51 void W_Porto_Touch (void)
  52 {
  53         vector norm;
  54         norm = trace_plane_normal;
  55         if(self.owner.playerid != self.playerid)
  56         {
  57                 remove(self);
  58         }
  59         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK)
  60         {
  61                 // just reflect
  62                 self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  63                 self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  64         }
  65         else if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  66         {
  67                 W_Porto_Fail(0);
  68         }
  69         else if(self.effects & EF_RED)
  70         {
  71                 self.effects += EF_BLUE - EF_RED;
  72                 if(Portal_SpawnInPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  73                 {
  74                         trace_plane_normal = norm;
  75                         self.right_vector = self.right_vector - 2 * trace_plane_normal * (self.right_vector * trace_plane_normal);
  76                         self.angles = vectoangles(self.velocity - 2 * trace_plane_normal * (self.velocity * trace_plane_normal));
  77                 }
  78                 else
  79                 {
  80                         trace_plane_normal = norm;
  81                         W_Porto_Fail(0);
  82                 }
  83         }
  84         else
  85         {
  86                 if(Portal_SpawnOutPortalAtTrace(self.owner, self.right_vector, self.portal_id))
  87                 {
  88                         W_Porto_Success();
  89                 }
  90                 else
  91                 {
  92                         trace_plane_normal = norm;
  93                         W_Porto_Fail(0);
  94                 }
  95         }
  96
  97 }
  98
  99 void W_Porto_Attack (void)
 100 {
 101         local entity gren;
 102
 103         if not(self.items & IT_UNLIMITED_AMMO)
 104                 self.weapons = self.weapons - (self.weapons & WEPBIT_PORTO);
 105         W_SetupShot (self, '0 0 0', FALSE, 4, "weapons/grenade_fire.wav");
 106
 107         //pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 108
 109         gren = spawn ();
 110         gren.owner = self;
 111         gren.classname = "porto";
 112         gren.bot_dodge = TRUE;
 113         gren.bot_dodgerating = 200;
 114         gren.movetype = MOVETYPE_BOUNCEMISSILE;
 115         gren.solid = SOLID_BBOX;
 116         gren.effects = EF_LOWPRECISION | EF_RED;
 117         gren.scale = 4;
 118         gren.modelflags = MF_GRENADE;
 119         setmodel(gren, "models/grenademodel.md3"); // precision set above
 120         setsize(gren, '0 0 0', '0 0 0');
 121         setorigin(gren, w_shotorg);
 122
 123         gren.nextthink = time + cvar("g_balance_porto_primary_lifetime");
 124         gren.think = W_Porto_Think;
 125         gren.touch = W_Porto_Touch;
 126         gren.velocity = w_shotdir * cvar("g_balance_porto_primary_speed");
 127         W_SetupProjectileVelocity(gren);
 128
 129         gren.angles = vectoangles (gren.velocity);
 130         gren.flags = FL_PROJECTILE;
 131
 132         gren.portal_id = time;
 133         self.porto_current = gren;
 134         gren.playerid = self.playerid;
 135         fixedmakevectors(vectoangles(gren.velocity));
 136         gren.right_vector = v_right;
 137
 138         gren.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 139 }
 140
 141 void spawnfunc_weapon_porto (void)
 142 {
 143         if(g_race)
 144         {
 145                 startitem_failed = TRUE;
 146                 remove(self);
 147                 return;
 148         }
 149         else
 150                 weapon_defaultspawnfunc(WEP_PORTO);
 151 }
 152
 153 float w_porto(float req)
 154 {
 155         vector v_angle_save;
 156
 157         if (req == WR_AIM)
 158         {
 159                 self.BUTTON_ATCK = FALSE;
 160                 self.BUTTON_ATCK2 = FALSE;
 161                 if(bot_aim(cvar("g_balance_porto_primary_speed"), 0, cvar("g_balance_grenadelauncher_primary_lifetime"), FALSE))
 162                         self.BUTTON_ATCK = TRUE;
 163         }
 164         else if (req == WR_THINK)
 165         {
 166                 if(self.porto_v_angle_held)
 167                 {
 168                         if(!self.BUTTON_ATCK2)
 169                         {
 170                                 msg_entity = self;
 171                                 WRITESPECTATABLE_MSG_ONE({
 172                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 173                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 174                                         WriteByte(MSG_ONE, WEP_PORTO);
 175                                         WriteByte(MSG_ONE, 0);
 176                                 });
 177                                 self.porto_v_angle_held = 0;
 178                         }
 179                 }
 180                 else
 181                 {
 182                         if(self.BUTTON_ATCK2)
 183                         {
 184                                 self.porto_v_angle = self.v_angle;
 185                                 msg_entity = self;
 186                                 WRITESPECTATABLE_MSG_ONE({
 187                                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 188                                         WriteByte(MSG_ONE, TE_CSQC_HOLDANGLES);
 189                                         WriteByte(MSG_ONE, WEP_PORTO);
 190                                         WriteByte(MSG_ONE, 1);
 191                                         WriteCoord(MSG_ONE, self.v_angle_x);
 192                                         WriteCoord(MSG_ONE, self.v_angle_y);
 193                                 });
 194                                 self.porto_v_angle_held = 1;
 195                         }
 196                 }
 197                 v_angle_save = self.v_angle;
 198                 if(self.porto_v_angle_held)
 199                         makevectors(self.porto_v_angle); // override the previously set angles
 200
 201                 if (self.BUTTON_ATCK)
 202                 if (!self.porto_current)
 203                 if (weapon_prepareattack(0, cvar("g_balance_porto_primary_refire")))
 204                 {
 205                         W_Porto_Attack();
 206                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_porto_primary_animtime"), w_ready);
 207                 }
 208         }
 209         else if (req == WR_PRECACHE)
 210         {
 211                 precache_model ("models/grenademodel.md3");
 212                 precache_model ("models/weapons/g_porto.md3");
 213                 precache_model ("models/weapons/v_porto.md3");
 214                 precache_model ("models/weapons/w_porto.zym");
 215                 precache_sound ("weapons/grenade_fire.wav");
 216                 precache_model ("models/portal.md3");
 217         }
 218         else if (req == WR_SETUP)
 219                 weapon_setup(WEP_PORTO);
 220         else if (req == WR_SUICIDEMESSAGE)
 221                 w_deathtypestring = "did the impossible";
 222         else if (req == WR_KILLMESSAGE)
 223                 w_deathtypestring = "felt # doing the impossible";
 224         return TRUE;
 225 };