data/qcsrc/server/w_laser.qc

   1 void(float imp) W_SwitchWeapon;
   2
   3 void W_Laser_Touch (void)
   4 {
   5         vector  dir;
   6         vector org2;
   7
   8         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
   9         {
  10                 remove(self);
  11                 return;
  12         }
  13
  14         if (other == self.owner)
  15                 return;
  16
  17         dir = normalize (self.owner.origin - self.origin);
  18         org2 = findbetterlocation (self.origin, 8);
  19
  20         te_knightspike(org2);
  21
  22
  23         self.event_damage = SUB_Null;
  24         if (self.dmg)
  25                 RadiusDamage (self, self.owner, cvar("g_balance_laser_secondary_damage"), cvar("g_balance_laser_secondary_edgedamage"), cvar("g_balance_laser_secondary_radius"), world, cvar("g_balance_laser_secondary_force"), IT_LASER);
  26         else
  27                 RadiusDamage (self, self.owner, cvar("g_balance_laser_primary_damage"), cvar("g_balance_laser_primary_edgedamage"), cvar("g_balance_laser_primary_radius"), world, cvar("g_balance_laser_primary_force"), IT_LASER);
  28         sound (self, CHAN_BODY, "weapons/laserimpact.ogg", 1, ATTN_NORM);
  29
  30         remove (self);
  31 }
  32
  33 void W_Laser_Attack (float issecondary)
  34 {
  35         local entity missile;
  36
  37         W_SetupShot (self, '15 8 -8', FALSE, 3, "weapons/lasergun_fire.ogg");
  38         //te_customflash(w_shotorg, 160, 0.2, '1 0 0');
  39
  40         missile = spawn ();
  41         missile.owner = self;
  42         missile.classname = "laserbolt";
  43         missile.dmg = issecondary;
  44         missile.bot_dodge = TRUE;
  45         if (issecondary)
  46                 missile.bot_dodgerating = cvar("g_balance_laser_secondary_damage");
  47         else
  48                 missile.bot_dodgerating = cvar("g_balance_laser_primary_damage");
  49
  50         missile.movetype = MOVETYPE_FLY;
  51         missile.solid = SOLID_BBOX;
  52
  53         setmodel (missile, "models/laser.mdl"); // precision set below
  54         setsize (missile, '0 0 0', '0 0 0');
  55         setorigin (missile, w_shotorg);
  56
  57         if (issecondary)
  58                 missile.velocity = w_shotdir * cvar("g_balance_laser_secondary_speed");
  59         else
  60                 missile.velocity = w_shotdir * cvar("g_balance_laser_primary_speed");
  61         W_SetupProjectileVelocity(missile);
  62         missile.angles = vectoangles (missile.velocity);
  63         //missile.glow_color = 250; // 244, 250
  64         //missile.glow_size = 120;
  65         missile.touch = W_Laser_Touch;
  66         missile.think = SUB_Remove;
  67         if (issecondary)
  68                 missile.nextthink = time + cvar("g_balance_laser_secondary_lifetime");
  69         else
  70                 missile.nextthink = time + cvar("g_balance_laser_primary_lifetime");
  71
  72         missile.effects = EF_NOSHADOW | EF_FULLBRIGHT | EF_FULLBRIGHT | EF_LOWPRECISION;
  73         missile.flags = FL_PROJECTILE;
  74 }
  75
  76 float(float req) w_laser =
  77 {
  78         local float r1;
  79         local float r2;
  80         if (req == WR_AIM)
  81         {
  82                 r1 = cvar("g_balance_laser_primary_damage");
  83                 r2 = cvar("g_balance_laser_secondary_damage");
  84                 if (random() * (r2 + r1) > r1)
  85                         self.button3 = bot_aim(cvar("g_balance_laser_secondary_speed"), 0, cvar("g_balance_laser_secondary_lifetime"), FALSE);
  86                 else
  87                         self.button0 = bot_aim(cvar("g_balance_laser_primary_speed"), 0, cvar("g_balance_laser_primary_lifetime"), FALSE);
  88         }
  89         else if (req == WR_THINK)
  90         {
  91                 if (self.button3)
  92                 if (weapon_prepareattack(0, cvar("g_balance_laser_secondary_refire")))
  93                 {
  94                         W_Laser_Attack(TRUE);
  95                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_laser_secondary_animtime"), w_ready);
  96                 }
  97                 if (self.button0)
  98                 if (weapon_prepareattack(0, cvar("g_balance_laser_primary_refire")))
  99                 {
 100                         W_Laser_Attack(FALSE);
 101                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_laser_primary_animtime"), w_ready);
 102                 }
 103                 //if (self.button3)
 104                 //if (client_hasweapon(self, self.cnt, TRUE, FALSE))
 105                 //      W_SwitchWeapon (self.cnt);
 106         }
 107         else if (req == WR_SETUP)
 108                 weapon_setup(WEP_LASER, "laser", 0);
 109         else if (req == WR_CHECKAMMO1)
 110                 return TRUE;
 111         else if (req == WR_CHECKAMMO2)
 112                 return TRUE;
 113         return TRUE;
 114 };