data/qcsrc/server/w_hook.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_radius;
   4 .float dmg_force;
   5 .float dmg_power;
   6 .float dmg_duration;
   7 .float dmg_last;
   8 .float hook_refire;
   9 .float hook_time_hooked;
  10 .float hook_time_ammodecrease;
  11
  12 void W_Hook_ExplodeThink (void)
  13 {
  14         float dt, dmg_remaining_next, f;
  15
  16         dt = time - self.teleport_time;
  17         dmg_remaining_next = pow(bound(0, 1 - dt / self.dmg_duration, 1), self.dmg_power);
  18
  19         f = self.dmg_last - dmg_remaining_next;
  20         self.dmg_last = dmg_remaining_next;
  21
  22         RadiusDamage (self, self.owner, self.dmg * f, self.dmg_edge * f, self.dmg_radius, self.owner, self.dmg_force * f, self.projectiledeathtype, world);
  23         self.projectiledeathtype |= HITTYPE_BOUNCE;
  24         //RadiusDamage (self, world, self.dmg * f, self.dmg_edge * f, self.dmg_radius, world, self.dmg_force * f, self.projectiledeathtype, world);
  25
  26         if(dt < self.dmg_duration)
  27                 self.nextthink = time + 0.05; // soon
  28         else
  29                 remove(self);
  30 }
  31
  32 void W_Hook_Explode2 (void)
  33 {
  34         self.event_damage = SUB_Null;
  35         self.touch = SUB_Null;
  36
  37         self.think = W_Hook_ExplodeThink;
  38         self.nextthink = time;
  39         self.dmg = cvar("g_balance_hook_secondary_damage");
  40         self.dmg_edge = cvar("g_balance_hook_secondary_edgedamage");
  41         self.dmg_radius = cvar("g_balance_hook_secondary_radius");
  42         self.dmg_force = cvar("g_balance_hook_secondary_force");
  43         self.dmg_power = cvar("g_balance_hook_secondary_power");
  44         self.dmg_duration = cvar("g_balance_hook_secondary_duration");
  45         self.teleport_time = time;
  46         self.dmg_last = 1;
  47         self.movetype = MOVETYPE_NONE;
  48 }
  49
  50 void W_Hook_Touch2 (void)
  51 {
  52         PROJECTILE_TOUCH;
  53         self.use();
  54 }
  55
  56 void W_Hook_Attack2()
  57 {
  58         local entity gren;
  59
  60         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  61                 self.ammo_cells = self.ammo_cells - cvar("g_balance_hook_secondary_ammo");
  62         W_SetupShot (self, '25 6 -8', FALSE, 4, "weapons/hookbomb_fire.wav");
  63
  64         gren = spawn ();
  65         gren.owner = self;
  66         gren.classname = "hookbomb";
  67         gren.bot_dodge = TRUE;
  68         gren.bot_dodgerating = cvar("g_balance_hook_secondary_damage");
  69         gren.movetype = MOVETYPE_TOSS;
  70         gren.solid = SOLID_BBOX;
  71         gren.projectiledeathtype = WEP_HOOK | HITTYPE_SECONDARY;
  72         setorigin(gren, w_shotorg);
  73
  74         gren.nextthink = time + cvar("g_balance_hook_secondary_lifetime");
  75         gren.think = adaptor_think2use;
  76         gren.use = W_Hook_Explode2;
  77         gren.touch = W_Hook_Touch2;
  78
  79         gren.velocity = '0 0 1' * cvar("g_balance_hook_secondary_speed");
  80         if(cvar("g_projectiles_newton_style"))
  81                 gren.velocity = gren.velocity + self.velocity;
  82
  83         gren.gravity = cvar("g_balance_hook_secondary_gravity");
  84         //W_SetupProjectileVelocity(gren); // just falling down!
  85
  86         gren.angles = '0 0 0';
  87         gren.flags = FL_PROJECTILE;
  88
  89         CSQCProjectile(gren, TRUE, PROJECTILE_HOOKBOMB, TRUE);
  90 }
  91
  92 void spawnfunc_weapon_hook (void)
  93 {
  94         if(g_grappling_hook) // offhand hook
  95         {
  96                 startitem_failed = TRUE;
  97                 remove(self);
  98                 return;
  99         }
 100         weapon_defaultspawnfunc(WEP_HOOK);
 101 }
 102
 103 float w_hook(float req)
 104 {
 105         float hooked_time_max, hooked_ammodecrease_delay;
 106
 107         if (req == WR_AIM)
 108         {
 109                 // ... sorry ...
 110         }
 111         else if (req == WR_THINK)
 112         {
 113                 if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 114                 {
 115                         if(!self.hook)
 116                         if not(self.hook_state & HOOK_WAITING_FOR_RELEASE)
 117                         if (time > self.hook_refire)
 118                         if (weapon_prepareattack(0, -1))
 119                         {
 120                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 121                                         self.ammo_cells = self.ammo_cells - cvar("g_balance_hook_primary_ammo");
 122                                 self.hook_state |= HOOK_FIRING;
 123                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hook_primary_animtime"), w_ready);
 124                         }
 125                 }
 126
 127                 if (self.BUTTON_ATCK2)
 128                 {
 129                         if (weapon_prepareattack(1, cvar("g_balance_hook_secondary_refire")))
 130                         {
 131                                 W_Hook_Attack2();
 132                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hook_secondary_animtime"), w_ready);
 133                         }
 134                 }
 135
 136                 if(self.hook)
 137                 {
 138                         // if hooked, no bombs, and increase the timer
 139                         self.hook_refire = max(self.hook_refire, time + cvar("g_balance_hook_primary_refire"));
 140                 }
 141
 142                 if(self.hook && self.hook.state == 1)
 143                 {
 144                         hooked_time_max = cvar("g_balance_hook_primary_hooked_time_max");
 145                         if (hooked_time_max > 0)
 146                         {
 147                                 if ( time > self.hook_time_hooked + hooked_time_max )
 148                                         self.hook_state |= HOOK_REMOVING;
 149                         }
 150
 151                         hooked_ammodecrease_delay = cvar("g_balance_hook_primary_hooked_ammodecrease_delay");
 152                         if (hooked_ammodecrease_delay > 0)
 153                         {
 154                                 if ( time > self.hook_time_ammodecrease )
 155                                 {
 156                                         if ( self.ammo_cells >= 1 )
 157                                         {
 158                                                 self.ammo_cells -= 1;
 159                                                 self.hook_time_ammodecrease = time + hooked_ammodecrease_delay;
 160                                         }
 161                                         else
 162                                         {
 163                                                 self.hook_state |= HOOK_REMOVING;
 164                                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 165                                         }
 166                                 }
 167                         }
 168                 }
 169                 else
 170                 {
 171                         self.hook_time_hooked = time;
 172                         self.hook_time_ammodecrease = time + cvar("g_balance_hook_primary_hooked_time_free");
 173                 }
 174
 175                 if (self.BUTTON_CROUCH)
 176                 {
 177                         self.hook_state &~= HOOK_PULLING;
 178                         if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 179                                 self.hook_state &~= HOOK_RELEASING;
 180                         else
 181                                 self.hook_state |= HOOK_RELEASING;
 182                 }
 183                 else
 184                 {
 185                         self.hook_state |= HOOK_PULLING;
 186                         self.hook_state &~= HOOK_RELEASING;
 187
 188                         if (self.BUTTON_ATCK || self.BUTTON_HOOK)
 189                         {
 190                                 // already fired
 191                                 if(self.hook)
 192                                         self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 193                         }
 194                         else
 195                         {
 196                                 self.hook_state |= HOOK_REMOVING;
 197                                 self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 198                         }
 199                 }
 200         }
 201         else if (req == WR_PRECACHE)
 202         {
 203                 precache_model ("models/weapons/g_hookgun.md3");
 204                 precache_model ("models/weapons/v_hookgun.md3");
 205                 precache_model ("models/weapons/w_hookgun.zym");
 206                 precache_sound ("weapons/hook_impact.wav"); // done by g_hook.qc
 207                 precache_sound ("weapons/hook_fire.wav");
 208                 precache_sound ("weapons/hookbomb_fire.wav");
 209         }
 210         else if (req == WR_SETUP)
 211         {
 212                 weapon_setup(WEP_HOOK);
 213                 self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 214         }
 215         else if (req == WR_CHECKAMMO1)
 216         {
 217                 return self.ammo_cells >= cvar("g_balance_hook_primary_ammo");
 218         }
 219         else if (req == WR_CHECKAMMO2)
 220         {
 221                 return self.ammo_cells >= cvar("g_balance_hook_secondary_ammo");
 222         }
 223         else if (req == WR_SUICIDEMESSAGE)
 224                 w_deathtypestring = "did the impossible";
 225         else if (req == WR_KILLMESSAGE)
 226                 w_deathtypestring = "has run into #'s gravity bomb";
 227         return TRUE;
 228 };