data/qcsrc/server/w_grenadelauncher.qc

   1 void W_Grenade_Explode (void)
   2 {
   3         if(other.takedamage == DAMAGE_AIM)
   4                 if(other.classname == "player")
   5                         if(IsDifferentTeam(self.owner, other))
   6                                 if(other.deadflag == DEAD_NO)
   7                                         if(IsFlying(other))
   8                                                 announce(self.owner, "announcer/male/airshot.wav");
   9
  10         self.event_damage = SUB_Null;
  11         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), self.projectiledeathtype, other);
  12
  13         remove (self);
  14 }
  15
  16 void W_Grenade_Explode2 (void)
  17 {
  18         if(other.takedamage == DAMAGE_AIM)
  19                 if(other.classname == "player")
  20                         if(IsDifferentTeam(self.owner, other))
  21                                 if(IsFlying(other))
  22                                         announce(self.owner, "announcer/male/airshot.wav");
  23
  24         self.event_damage = SUB_Null;
  25         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), self.projectiledeathtype, other);
  26
  27         remove (self);
  28 }
  29
  30 void W_Grenade_Touch1 (void)
  31 {
  32         PROJECTILE_TOUCH;
  33         W_Grenade_Explode ();
  34 }
  35
  36 void W_Grenade_Touch2 (void)
  37 {
  38         PROJECTILE_TOUCH;
  39         if (other.takedamage == DAMAGE_AIM)
  40         {
  41                 self.use ();
  42         }
  43         else
  44         {
  45                 float r;
  46                 r = random() * 6;
  47                 if(r < 1)
  48                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  49                 else if(r < 2)
  50                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  51                 else if(r < 3)
  52                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  53                 else if(r < 4)
  54                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  55                 else if(r < 5)
  56                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  57                 else
  58                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  59                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  60         }
  61 }
  62
  63 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  64 {
  65         if (self.health <= 0)
  66                 return;
  67         self.health = self.health - damage;
  68         if (self.health <= 0)
  69         {
  70                 W_PrepareExplosionByDamage(attacker, self.think);
  71         }
  72 }
  73
  74 void W_Grenade_Attack (void)
  75 {
  76         local entity gren;
  77
  78         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  79                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  80         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav", cvar("g_balance_grenadelauncher_primary_damage"));
  81         w_shotdir = v_forward; // no TrueAim for grenades please
  82
  83         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  84
  85         gren = spawn ();
  86         gren.owner = self;
  87         gren.classname = "grenade";
  88         gren.bot_dodge = TRUE;
  89         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  90         gren.movetype = MOVETYPE_BOUNCE;
  91         gren.solid = SOLID_BBOX;
  92         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
  93         setorigin(gren, w_shotorg);
  94         setsize(gren, '0 0 -3', '0 0 -3');
  95
  96         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
  97         gren.think = adaptor_think2use;
  98         gren.use = W_Grenade_Explode;
  99         gren.touch = W_Grenade_Touch1;
 100         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
 101         W_SetupProjectileVelocity(gren);
 102
 103         gren.angles = vectoangles (gren.velocity);
 104         gren.flags = FL_PROJECTILE;
 105
 106         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 107 }
 108
 109 void W_Grenade_Attack2 (void)
 110 {
 111         local entity gren;
 112
 113         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 114                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 115         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav", cvar("g_balance_grenadelauncher_secondary_damage"));
 116         w_shotdir = v_forward; // no TrueAim for grenades please
 117
 118         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 119
 120         gren = spawn ();
 121         gren.owner = self;
 122         gren.classname = "grenade";
 123         gren.bot_dodge = TRUE;
 124         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 125         gren.movetype = MOVETYPE_BOUNCE;
 126         gren.solid = SOLID_BBOX;
 127         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 128         setsize(gren, '0 0 -3', '0 0 -3');
 129         setorigin(gren, w_shotorg);
 130
 131         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 132         gren.think = adaptor_think2use;
 133         gren.use = W_Grenade_Explode2;
 134         gren.touch = W_Grenade_Touch2;
 135         gren.takedamage = DAMAGE_YES;
 136         gren.health = cvar("g_balance_grenadelauncher_secondary_health");
 137         gren.damageforcescale = cvar("g_balance_grenadelauncher_secondary_damageforcescale");
 138         gren.event_damage = W_Grenade_Damage;
 139         gren.velocity = w_shotdir * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 140         W_SetupProjectileVelocity(gren);
 141
 142         gren.angles = vectoangles (gren.velocity);
 143         gren.flags = FL_PROJECTILE;
 144
 145         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 146 }
 147
 148 void spawnfunc_weapon_grenadelauncher (void)
 149 {
 150         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 151 }
 152
 153 .float bot_secondary_grenademooth;
 154 float w_glauncher(float req)
 155 {
 156         if (req == WR_AIM)
 157         {
 158                 self.BUTTON_ATCK = FALSE;
 159                 self.BUTTON_ATCK2 = FALSE;
 160                 if (self.bot_secondary_grenademooth == 0)
 161                 {
 162                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 163                         {
 164                                 self.BUTTON_ATCK = TRUE;
 165                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 166                         }
 167                 }
 168                 else
 169                 {
 170                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 171                         {
 172                                 self.BUTTON_ATCK2 = TRUE;
 173                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 174                         }
 175                 }
 176         }
 177         else if (req == WR_THINK)
 178         {
 179                 if (self.BUTTON_ATCK)
 180                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 181                 {
 182                         W_Grenade_Attack();
 183                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 184                 }
 185                 if (self.BUTTON_ATCK2)
 186                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 187                 {
 188                         W_Grenade_Attack2();
 189                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 190                 }
 191         }
 192         else if (req == WR_PRECACHE)
 193         {
 194                 precache_model ("models/weapons/g_gl.md3");
 195                 precache_model ("models/weapons/v_gl.md3");
 196                 precache_model ("models/weapons/h_gl.dpm");
 197                 precache_sound ("weapons/grenade_bounce1.wav");
 198                 precache_sound ("weapons/grenade_bounce2.wav");
 199                 precache_sound ("weapons/grenade_bounce3.wav");
 200                 precache_sound ("weapons/grenade_bounce4.wav");
 201                 precache_sound ("weapons/grenade_bounce5.wav");
 202                 precache_sound ("weapons/grenade_bounce6.wav");
 203                 precache_sound ("weapons/grenade_fire.wav");
 204         }
 205         else if (req == WR_SETUP)
 206                 weapon_setup(WEP_GRENADE_LAUNCHER);
 207         else if (req == WR_CHECKAMMO1)
 208                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 209         else if (req == WR_CHECKAMMO2)
 210                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 211         else if (req == WR_SUICIDEMESSAGE)
 212         {
 213                 if(w_deathtype & HITTYPE_SECONDARY)
 214                         w_deathtypestring = "tried out his own grenade";
 215                 else
 216                         w_deathtypestring = "detonated";
 217         }
 218         else if (req == WR_KILLMESSAGE)
 219         {
 220                 if(w_deathtype & HITTYPE_SPLASH)
 221                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 222                                 w_deathtypestring = "didn't see #'s grenade";
 223                         else // unchecked: SECONDARY
 224                                 w_deathtypestring = "almost dodged #'s grenade";
 225                 else // unchecked: SECONDARY, BOUNCE
 226                         w_deathtypestring = "ate #'s grenade";
 227         }
 228         return TRUE;
 229 };