data/qcsrc/server/w_grenadelauncher.qc

   1
   2 void W_Grenade_Explode (void)
   3 {
   4         vector  org2;
   5         org2 = findbetterlocation (self.origin, 12);
   6         te_explosion (org2);
   7         //effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
   8         sound (self, CHAN_BODY, "weapons/grenade_impact.ogg", 1, ATTN_NORM);
   9
  10         self.event_damage = SUB_Null;
  11         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), IT_GRENADE_LAUNCHER);
  12
  13         remove (self);
  14 }
  15
  16 void W_Grenade_Explode2 (void)
  17 {
  18         vector  org2;
  19         org2 = findbetterlocation (self.origin, 12);
  20         te_explosion (org2);
  21         //effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
  22         sound (self, CHAN_BODY, "weapons/grenade_impact.ogg", 1, ATTN_NORM);
  23
  24         self.event_damage = SUB_Null;
  25         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), IT_GRENADE_LAUNCHER);
  26
  27         remove (self);
  28 }
  29
  30 void W_Grenade_Touch1 (void)
  31 {
  32         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  33         {
  34                 remove(self);
  35                 return;
  36         }
  37         W_Grenade_Explode ();
  38 }
  39
  40 void W_Grenade_Touch2 (void)
  41 {
  42         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  43         {
  44                 remove(self);
  45                 return;
  46         }
  47         if (other.takedamage == DAMAGE_AIM)
  48                 self.think ();
  49         else
  50         {
  51                 float r;
  52                 r = random() * 6;
  53                 if(r < 1)
  54                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce1.ogg", 1, ATTN_NORM);
  55                 else if(r < 2)
  56                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce2.ogg", 1, ATTN_NORM);
  57                 else if(r < 3)
  58                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce3.ogg", 1, ATTN_NORM);
  59                 else if(r < 4)
  60                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce4.ogg", 1, ATTN_NORM);
  61                 else if(r < 5)
  62                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce5.ogg", 1, ATTN_NORM);
  63                 else
  64                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce6.ogg", 1, ATTN_NORM);
  65         }
  66 }
  67
  68 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  69 {
  70         self.health = self.health - damage;
  71         if (self.health <= 0)
  72         {
  73                 self.owner = attacker;
  74                 self.think ();
  75         }
  76 }
  77
  78 void W_Grenade_Attack (void)
  79 {
  80         local entity gren;
  81
  82         if (cvar("g_use_ammunition"))
  83                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  84         W_SetupShot (self, '15 8 -8', FALSE, 4, "weapons/grenade_fire.ogg");
  85
  86         gren = spawn ();
  87         gren.owner = self;
  88         gren.classname = "grenade";
  89         gren.bot_dodge = TRUE;
  90         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  91         gren.movetype = MOVETYPE_BOUNCE;
  92         gren.solid = SOLID_BBOX;
  93         gren.effects = EF_NOSHADOW | EF_LOWPRECISION;
  94         setmodel(gren, "models/grenademodel.md3");
  95         setsize(gren, '0 0 0', '0 0 0');
  96         setorigin(gren, w_shotorg);
  97
  98         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
  99         gren.think = W_Grenade_Explode;
 100         gren.touch = W_Grenade_Touch1;
 101         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
 102         gren.avelocity_x = random () * -500 - 500;
 103
 104         gren.angles = vectoangles (gren.velocity);
 105         gren.flags = FL_PROJECTILE;
 106 }
 107
 108 void W_Grenade_Attack2 (void)
 109 {
 110         local entity gren;
 111
 112         if (cvar("g_use_ammunition"))
 113                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 114         W_SetupShot (self, '15 8 -8', FALSE, 4, "weapons/grenade_fire.ogg");
 115
 116         gren = spawn ();
 117         gren.owner = self;
 118         gren.classname = "grenade";
 119         gren.bot_dodge = TRUE;
 120         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 121         gren.movetype = MOVETYPE_BOUNCE;
 122         gren.solid = SOLID_BBOX;
 123         gren.effects = EF_NOSHADOW | EF_LOWPRECISION;
 124         setmodel(gren, "models/grenademodel.md3");
 125         setsize(gren, '0 0 -3', '0 0 -3');
 126         setorigin(gren, w_shotorg);
 127
 128         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 129         gren.think = W_Grenade_Explode2;
 130         gren.touch = W_Grenade_Touch2;
 131         gren.takedamage = DAMAGE_YES;
 132         gren.health = 10;
 133         gren.damageforcescale = 4;
 134         gren.event_damage = W_Grenade_Damage;
 135         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 136         gren.avelocity = '100 150 100';
 137
 138         gren.angles = vectoangles (gren.velocity);
 139         gren.flags = FL_PROJECTILE;
 140 }
 141
 142 .float bot_secondary_grenademooth;
 143 float(float req) w_glauncher =
 144 {
 145         if (req == WR_AIM)
 146         {
 147                 self.button0 = FALSE;
 148                 self.button3 = FALSE;
 149                 if (self.bot_secondary_grenademooth == 0)
 150                 {
 151                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 152                         {
 153                                 self.button0 = TRUE;
 154                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 155                         }
 156                 }
 157                 else
 158                 {
 159                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 160                         {
 161                                 self.button3 = TRUE;
 162                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 163                         }
 164                 }
 165         }
 166         else if (req == WR_THINK)
 167         {
 168                 if (self.button0)
 169                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 170                 {
 171                         W_Grenade_Attack();
 172                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 173                 }
 174                 if (self.button3)
 175                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 176                 {
 177                         W_Grenade_Attack2();
 178                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 179                 }
 180         }
 181         else if (req == WR_SETUP)
 182                 weapon_setup(WEP_GRENADE_LAUNCHER, "gl", IT_ROCKETS);
 183         else if (req == WR_CHECKAMMO1)
 184                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 185         else if (req == WR_CHECKAMMO2)
 186                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 187         return TRUE;
 188 };