data/qcsrc/server/w_grenadelauncher.qc

   1
   2 void W_Grenade_Explode (void)
   3 {
   4         vector  org2;
   5         org2 = findbetterlocation (self.origin, 12);
   6         te_explosion (org2);
   7         //effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
   8         sound (self, CHAN_BODY, "weapons/grenade_impact.wav", 1, ATTN_NORM);
   9
  10         self.event_damage = SUB_Null;
  11         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), IT_GRENADE_LAUNCHER);
  12
  13         remove (self);
  14 }
  15
  16 void W_Grenade_Explode2 (void)
  17 {
  18         vector  org2;
  19         org2 = findbetterlocation (self.origin, 12);
  20         te_explosion (org2);
  21         //effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
  22         sound (self, CHAN_BODY, "weapons/grenade_impact.wav", 1, ATTN_NORM);
  23
  24         self.event_damage = SUB_Null;
  25         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), IT_GRENADE_LAUNCHER);
  26
  27         remove (self);
  28 }
  29
  30 void W_Grenade_Touch1 (void)
  31 {
  32         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  33         {
  34                 remove(self);
  35                 return;
  36         }
  37         W_Grenade_Explode ();
  38 }
  39
  40 void W_Grenade_Touch2 (void)
  41 {
  42         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  43         {
  44                 remove(self);
  45                 return;
  46         }
  47         if (other.takedamage == DAMAGE_AIM)
  48                 self.think ();
  49         else
  50         {
  51                 float r;
  52                 r = random() * 6;
  53                 if(r < 1)
  54                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce1.wav", 1, ATTN_NORM);
  55                 else if(r < 2)
  56                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce2.wav", 1, ATTN_NORM);
  57                 else if(r < 3)
  58                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce3.wav", 1, ATTN_NORM);
  59                 else if(r < 4)
  60                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce4.wav", 1, ATTN_NORM);
  61                 else if(r < 5)
  62                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce5.wav", 1, ATTN_NORM);
  63                 else
  64                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce6.wav", 1, ATTN_NORM);
  65         }
  66 }
  67
  68 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  69 {
  70         self.health = self.health - damage;
  71         if (self.health <= 0)
  72         {
  73                 self.owner = attacker;
  74                 self.think ();
  75         }
  76 }
  77
  78 void W_Grenade_Attack (void)
  79 {
  80         local entity gren;
  81
  82         if (cvar("g_use_ammunition"))
  83                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
  84         W_SetupShot (self, '11 8 -8', FALSE, 4, "weapons/grenade_fire.wav");
  85
  86         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg + v_forward * 8, v_forward * 1000, 1);
  87
  88         gren = spawn ();
  89         gren.owner = self;
  90         gren.classname = "grenade";
  91         gren.bot_dodge = TRUE;
  92         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
  93         gren.movetype = MOVETYPE_BOUNCE;
  94         gren.solid = SOLID_BBOX;
  95         gren.effects = EF_LOWPRECISION;
  96         gren.modelflags = MF_GRENADE;
  97         setmodel(gren, "models/grenademodel.md3"); // precision set above
  98         setsize(gren, '0 0 0', '0 0 0');
  99         setorigin(gren, w_shotorg);
 100
 101         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
 102         gren.think = W_Grenade_Explode;
 103         gren.touch = W_Grenade_Touch1;
 104         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
 105         W_SetupProjectileVelocity(gren);
 106         gren.avelocity_x = random () * -500 - 500;
 107
 108         gren.angles = vectoangles (gren.velocity);
 109         gren.flags = FL_PROJECTILE;
 110 }
 111
 112 void W_Grenade_Attack2 (void)
 113 {
 114         local entity gren;
 115
 116         if (cvar("g_use_ammunition"))
 117                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 118         W_SetupShot (self, '11 8 -8', FALSE, 4, "weapons/grenade_fire.wav");
 119
 120         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg + v_forward * 8, v_forward * 1000, 1);
 121
 122         gren = spawn ();
 123         gren.owner = self;
 124         gren.classname = "grenade";
 125         gren.bot_dodge = TRUE;
 126         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 127         gren.movetype = MOVETYPE_BOUNCE;
 128         gren.solid = SOLID_BBOX;
 129         gren.effects = EF_LOWPRECISION;
 130         gren.modelflags = MF_GRENADE;
 131         setmodel(gren, "models/grenademodel.md3"); // precision set above
 132         setsize(gren, '0 0 -3', '0 0 -3');
 133         setorigin(gren, w_shotorg);
 134
 135         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 136         gren.think = W_Grenade_Explode2;
 137         gren.touch = W_Grenade_Touch2;
 138         gren.takedamage = DAMAGE_YES;
 139         gren.health = 10;
 140         gren.damageforcescale = 4;
 141         gren.event_damage = W_Grenade_Damage;
 142         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 143         W_SetupProjectileVelocity(gren);
 144         gren.avelocity = '100 150 100';
 145
 146         gren.angles = vectoangles (gren.velocity);
 147         gren.flags = FL_PROJECTILE;
 148 }
 149
 150 .float bot_secondary_grenademooth;
 151 float(float req) w_glauncher =
 152 {
 153         if (req == WR_AIM)
 154         {
 155                 self.button0 = FALSE;
 156                 self.button3 = FALSE;
 157                 if (self.bot_secondary_grenademooth == 0)
 158                 {
 159                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 160                         {
 161                                 self.button0 = TRUE;
 162                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 163                         }
 164                 }
 165                 else
 166                 {
 167                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 168                         {
 169                                 self.button3 = TRUE;
 170                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 171                         }
 172                 }
 173         }
 174         else if (req == WR_THINK)
 175         {
 176                 if (self.button0)
 177                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 178                 {
 179                         W_Grenade_Attack();
 180                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 181                 }
 182                 if (self.button3)
 183                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 184                 {
 185                         W_Grenade_Attack2();
 186                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 187                 }
 188         }
 189         else if (req == WR_PRECACHE)
 190         {
 191                 precache_model ("models/grenademodel.md3");
 192                 precache_model ("models/weapons/g_gl.md3");
 193                 precache_model ("models/weapons/v_gl.md3");
 194                 precache_model ("models/weapons/w_gl.zym");
 195                 precache_sound ("weapons/grenade_bounce1.wav");
 196                 precache_sound ("weapons/grenade_bounce2.wav");
 197                 precache_sound ("weapons/grenade_bounce3.wav");
 198                 precache_sound ("weapons/grenade_bounce4.wav");
 199                 precache_sound ("weapons/grenade_bounce5.wav");
 200                 precache_sound ("weapons/grenade_bounce6.wav");
 201                 precache_sound ("weapons/grenade_fire.wav");
 202                 precache_sound ("weapons/grenade_impact.wav");
 203         }
 204         else if (req == WR_SETUP)
 205                 weapon_setup(WEP_GRENADE_LAUNCHER, "gl", IT_ROCKETS);
 206         else if (req == WR_CHECKAMMO1)
 207                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 208         else if (req == WR_CHECKAMMO2)
 209                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 210         else if (req == WR_REGISTER)
 211                 weapon_register(WEP_GRENADE_LAUNCHER, min(cvar("g_balance_grenadelauncher_primary_ammo"), cvar("g_balance_grenadelauncher_secondary_ammo")));
 212         return TRUE;
 213 };