data/qcsrc/server/w_electro.qc

   1
   2 void W_Plasma_Explode (void)
   3 {
   4         vector org2;
   5         org2 = findbetterlocation (self.origin, 8);
   6         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
   7         WriteByte (MSG_BROADCAST, 79);
   8         WriteCoord (MSG_BROADCAST, org2_x);
   9         WriteCoord (MSG_BROADCAST, org2_y);
  10         WriteCoord (MSG_BROADCAST, org2_z);
  11         WriteCoord (MSG_BROADCAST, 0);          // SeienAbunae: groan... Useless clutter
  12         WriteCoord (MSG_BROADCAST, 0);
  13         WriteCoord (MSG_BROADCAST, 0);
  14         WriteByte (MSG_BROADCAST, 155);
  15
  16         self.event_damage = SUB_Null;
  17         if (self.movetype == MOVETYPE_BOUNCE)
  18                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), IT_ELECTRO);
  19         else
  20                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), IT_ELECTRO);
  21         sound (self, CHAN_BODY, "weapons/electro_impact.wav", 1, ATTN_NORM);
  22
  23         remove (self);
  24 }
  25
  26 void W_Plasma_Explode_Combo (void) {
  27         vector org2;
  28
  29         org2 = findbetterlocation (self.origin, 8);
  30         te_spikequad(self.origin);
  31
  32         sound (self, CHAN_BODY, "weapons/electro_impact_combo.wav", 1, ATTN_NORM);
  33
  34         self.event_damage = SUB_Null;
  35         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), IT_ELECTRO);
  36         te_explosionrgb(org2, '0.5 0.5 1');
  37         remove (self);
  38 }
  39
  40 void W_Plasma_Touch (void)
  41 {
  42         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  43         {
  44                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  45                 remove(self);
  46                 return;
  47         }
  48         if (other.takedamage == DAMAGE_AIM) {
  49                 W_Plasma_Explode ();
  50         } else {
  51                 sound (self, CHAN_IMPACT, "weapons/electro_bounce.wav", 1, ATTN_NORM);
  52         }
  53 }
  54
  55 void W_Plasma_TouchExplode (void)
  56 {
  57         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  58         {
  59                 sound (self, CHAN_BODY, "misc/null.wav", 1, ATTN_NORM);
  60                 remove(self);
  61                 return;
  62         }
  63         W_Plasma_Explode ();
  64 }
  65
  66 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  67 {
  68         self.health = self.health - damage;
  69         if (self.health <= 0)
  70         {
  71                 self.takedamage = DAMAGE_NO;
  72                 self.nextthink = time;
  73                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  74                 {
  75                         // change owner to whoever caused the combo explosion
  76                         self.owner = inflictor.owner;
  77                         self.classname = "plasma_chain";
  78                         self.think = W_Plasma_Explode_Combo;
  79                 }
  80                 else
  81                         self.think = W_Plasma_Explode;
  82         }
  83 }
  84
  85 void() W_Electro_Attack
  86 {
  87         local entity proj;
  88
  89         W_SetupShot (self, '11 8 -8', FALSE, 2, "weapons/electro_fire.wav");
  90
  91         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg + v_forward * 8, v_forward * 1000, 1);
  92
  93         proj = spawn ();
  94         proj.classname = "plasma_prim";
  95         proj.owner = self;
  96         proj.bot_dodge = TRUE;
  97         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
  98         proj.think = W_Plasma_Explode;
  99         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 100         proj.solid = SOLID_BBOX;
 101         setorigin(proj, w_shotorg);
 102
 103         if (cvar("g_use_ammunition"))
 104                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 105         proj.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
 106         proj.movetype = MOVETYPE_FLY;
 107         proj.velocity = w_shotdir * cvar("g_balance_electro_primary_speed");
 108         W_SetupProjectileVelocity(proj);
 109         proj.angles = vectoangles(proj.velocity);
 110         proj.touch = W_Plasma_TouchExplode;
 111         proj.flags = FL_PROJECTILE;
 112         setmodel(proj, "models/elaser.mdl"); // precision set above
 113         setsize(proj, '0 0 0', '0 0 0');
 114
 115         // LordHavoc: disabled because no one likes this sound and it sometimes never stops due to packet loss
 116         //sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 117 }
 118
 119 void() W_Electro_Attack2
 120 {
 121         local entity proj;
 122
 123         W_SetupShot (self, '8 4.5 -13', FALSE, 2, "weapons/electro_fire2.wav");
 124
 125         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg + v_forward * 8, v_forward * 1000, 1);
 126
 127         proj = spawn ();
 128         proj.classname = "plasma";
 129         proj.owner = self;
 130         proj.think = W_Plasma_Explode;
 131         proj.bot_dodge = TRUE;
 132         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 133         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 134         proj.solid = SOLID_BBOX;
 135         setorigin(proj, w_shotorg);
 136
 137         if (cvar("g_use_ammunition"))
 138                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 139         proj.effects = EF_LOWPRECISION;
 140         //proj.glow_size = 50;
 141         //proj.glow_color = 45;
 142         proj.movetype = MOVETYPE_BOUNCE;
 143         proj.velocity = (v_forward + randomvec() * cvar("g_balance_electro_secondary_spread")) * cvar("g_balance_electro_secondary_speed") + v_up * cvar("g_balance_electro_secondary_speed_up");
 144         W_SetupProjectileVelocity(proj);
 145         proj.touch = W_Plasma_Touch;
 146         setmodel(proj, "models/ebomb.mdl"); // precision set above
 147         setsize(proj, '0 0 -3', '0 0 -3');
 148         proj.takedamage = DAMAGE_YES;
 149         proj.damageforcescale = 4;
 150         proj.health = 5;
 151         proj.event_damage = W_Plasma_Damage;
 152         proj.flags = FL_PROJECTILE;
 153
 154         // LordHavoc: disabled because no one likes this sound and it sometimes never stops due to packet loss
 155         //sound (proj, CHAN_BODY, "weapons/electro_fly.wav", 1, ATTN_NORM);
 156 }
 157
 158 .float bot_secondary_electromooth;
 159 float(float req) w_electro =
 160 {
 161         if (req == WR_AIM)
 162         {
 163                 self.button0=FALSE;
 164                 self.button3=FALSE;
 165                 if(vlen(self.origin-self.enemy.origin) > 1000)
 166                         self.bot_secondary_electromooth = 0;
 167                 if(self.bot_secondary_electromooth == 0)
 168                 {
 169                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 170                         {
 171                                 self.button0 = TRUE;
 172                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 173                         }
 174                 }
 175                 else
 176                 {
 177                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 178                         {
 179                                 self.button3 = TRUE;
 180                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 181                         }
 182                 }
 183         }
 184         else if (req == WR_THINK)
 185         {
 186                 if (self.button0)
 187                 if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 188                 {
 189                         W_Electro_Attack();
 190                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 191                 }
 192                 if (self.button3)
 193                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 194                 {
 195                         W_Electro_Attack2();
 196                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_secondary_animtime"), w_ready);
 197                 }
 198         }
 199         else if (req == WR_PRECACHE)
 200         {
 201                 precache_model ("models/ebomb.mdl");
 202                 precache_model ("models/elaser.mdl");
 203                 precache_model ("models/weapons/g_electro.md3");
 204                 precache_model ("models/weapons/v_electro.md3");
 205                 precache_model ("models/weapons/w_electro.zym");
 206                 precache_sound ("weapons/electro_bounce.wav");
 207                 precache_sound ("weapons/electro_fire.wav");
 208                 precache_sound ("weapons/electro_fire2.wav");
 209                 precache_sound ("weapons/electro_fly.wav");
 210                 precache_sound ("weapons/electro_impact.wav");
 211                 precache_sound ("weapons/electro_impact_combo.wav");
 212         }
 213         else if (req == WR_SETUP)
 214                 weapon_setup(WEP_ELECTRO, "electro", IT_CELLS);
 215         else if (req == WR_CHECKAMMO1)
 216                 return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 217         else if (req == WR_CHECKAMMO2)
 218                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 219         else if (req == WR_REGISTER)
 220                 weapon_register(WEP_ELECTRO, min(cvar("g_balance_electro_primary_ammo"), cvar("g_balance_electro_secondary_ammo")));
 221         return TRUE;
 222 };