data/qcsrc/server/w_common.qc

   1 .float bullets_hit[WEP_COUNT];          //for hitscan bullets hit
   2 .float bullets_fired[WEP_COUNT];        //for hitscan bullets fired
   3
   4 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(bullets_hit);
   5 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(bullets_fired);
   6
   7 void W_GiveWeapon (entity e, float wep, string name)
   8 {
   9         entity oldself;
  10
  11         if (!wep)
  12                 return;
  13
  14         e.weapons = e.weapons | W_WeaponBit(wep);
  15
  16         oldself = self;
  17         self = e;
  18
  19         if not(g_minstagib)
  20         if (other.classname == "player")
  21         {
  22                 sprint (other, "You got the ^2");
  23                 sprint (other, name);
  24                 sprint (other, "\n");
  25         }
  26
  27
  28         self = oldself;
  29 }
  30
  31 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float deathtype)
  32 {
  33         local vector hitloc, force, endpoint, dir;
  34         local entity ent, endent;
  35         local float endq3surfaceflags;
  36         //local entity explosion;
  37         float did_hit;
  38         float length;
  39         vector beampos;
  40         string snd;
  41         entity pseudoprojectile;
  42         float f;
  43
  44         did_hit = 0;
  45
  46         railgun_start = start;
  47         railgun_end = end;
  48
  49         dir = normalize(end - start);
  50         length = vlen(end - start);
  51         force = dir * bforce;
  52
  53         // go a little bit into the wall because we need to hit this wall later
  54         end = end + dir;
  55
  56         // trace multiple times until we hit a wall, each obstacle will be made
  57         // non-solid so we can hit the next, while doing this we spawn effects and
  58         // note down which entities were hit so we can damage them later
  59         while (1)
  60         {
  61                 if(self.antilag_debug)
  62                         traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
  63                 else
  64                         traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
  65
  66                 // if it is world we can't hurt it so stop now
  67                 if (trace_ent == world || trace_fraction == 1)
  68                         break;
  69
  70                 // make the entity non-solid so we can hit the next one
  71                 trace_ent.railgunhit = TRUE;
  72                 trace_ent.railgunhitloc = end;
  73                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
  74
  75                 // stop if this is a wall
  76                 if (trace_ent.solid == SOLID_BSP)
  77                         break;
  78
  79                 // make the entity non-solid
  80                 trace_ent.solid = SOLID_NOT;
  81         }
  82
  83         endpoint = trace_endpos;
  84         endent = trace_ent;
  85         endq3surfaceflags = trace_dphitq3surfaceflags;
  86
  87         // find all the entities the railgun hit and restore their solid state
  88         ent = findfloat(world, railgunhit, TRUE);
  89         while (ent)
  90         {
  91                 // restore their solid type
  92                 ent.solid = ent.railgunhitsolidbackup;
  93                 ent = findfloat(ent, railgunhit, TRUE);
  94         }
  95
  96         // spawn a temporary explosion entity for RadiusDamage calls
  97         //explosion = spawn();
  98
  99         // Find all non-hit players the beam passed close by
 100         if(deathtype == WEP_MINSTANEX || deathtype == WEP_NEX)
 101         {
 102                 FOR_EACH_REALCLIENT(msg_entity) if(msg_entity != self) if(!msg_entity.railgunhit) if not(msg_entity.classname == "spectator" && msg_entity.enemy == self) // we use realclient, so spectators can hear the whoosh too
 103                 {
 104                         // nearest point on the beam
 105                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 106
 107                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 108                         if(f <= 0)
 109                                 continue;
 110
 111                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 112
 113                         if(!pseudoprojectile)
 114                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 115                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CHAN_PROJECTILE, snd, VOL_BASE * f, ATTN_NONE);
 116                 }
 117
 118                 if(pseudoprojectile)
 119                         remove(pseudoprojectile);
 120         }
 121
 122         // find all the entities the railgun hit and hurt them
 123         ent = findfloat(world, railgunhit, TRUE);
 124         while (ent)
 125         {
 126                 // get the details we need to call the damage function
 127                 hitloc = ent.railgunhitloc;
 128                 ent.railgunhitloc = '0 0 0';
 129                 ent.railgunhitsolidbackup = SOLID_NOT;
 130                 ent.railgunhit = FALSE;
 131
 132                 //for stats so that team hit will count as a miss
 133                 if(ent.flags & FL_CLIENT)
 134                 if(ent.deadflag == DEAD_NO)
 135                         did_hit = 1;
 136
 137                 if(teams_matter)
 138                 if(ent.team == self.team)
 139                         did_hit = 0;
 140
 141                 // apply the damage
 142                 if (ent.takedamage || ent.classname == "case")
 143                         Damage (ent, self, self, bdamage, deathtype, hitloc, force);
 144
 145                 // create a small explosion to throw gibs around (if applicable)
 146                 //setorigin (explosion, hitloc);
 147                 //RadiusDamage (explosion, self, 10, 0, 50, world, 300, deathtype);
 148
 149                 // advance to the next entity
 150                 ent = findfloat(ent, railgunhit, TRUE);
 151         }
 152
 153         //calculate hits and fired shots for hitscan
 154         if not(inWarmupStage)
 155         if not(self.isbot)
 156         {
 157                 self.bullets_fired[self.weapon] += 1;
 158
 159                 if(did_hit)
 160                         self.bullets_hit[self.weapon] += 1;
 161
 162                 // update the client and store in addstat() in g_world
 163                 self.damage_hits = self.weapon + 64 * rint(self.bullets_hit[self.weapon]);
 164                 self.maxdamage_fired = self.weapon + 64 * rint(self.bullets_fired[self.weapon]);
 165         }
 166
 167         // we're done with the explosion entity, remove it
 168         //remove(explosion);
 169
 170         trace_endpos = endpoint;
 171         trace_ent = endent;
 172         trace_dphitq3surfaceflags = endq3surfaceflags;
 173 }
 174
 175 .float dmg_edge;
 176 .float dmg_force;
 177 .float dmg_radius;
 178 void W_BallisticBullet_Hit (void)
 179 {
 180         float f;
 181
 182         float hit;
 183         hit = 0;
 184
 185         f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 186
 187         if(other.solid == SOLID_BSP)
 188                 Damage_DamageInfo(self.origin, self.dmg * f, 0, 0, self.dmg_force * normalize(self.velocity) * f, self.projectiledeathtype, self);
 189
 190         if(other && other != self.enemy)
 191         {
 192                 endzcurveparticles();
 193
 194                 headshot = 0;
 195                 yoda = 0;
 196                 damage_headshotbonus = self.dmg_edge;
 197                 railgun_start = self.origin - 2 * frametime * self.velocity;
 198                 railgun_end = self.origin + 2 * frametime * self.velocity;
 199
 200                 if(other.flags & FL_CLIENT)
 201                 if(other.deadflag == DEAD_NO)
 202                         hit = 1;
 203
 204                 if(teamplay)
 205                 if(other.team == self.owner.team)
 206                         hit = 0;
 207
 208                 Damage(other, self, self.owner, self.dmg * f, self.projectiledeathtype, self.origin, self.dmg_force * normalize(self.velocity) * f);
 209                 damage_headshotbonus = 0;
 210
 211                 if(self.dmg_edge != 0)
 212                 {
 213                         if(headshot)
 214                                 announce(self.owner, "announcer/male/headshot.wav");
 215                         if(yoda)
 216                                 announce(self.owner, "announcer/male/awesome.wav");
 217                 }
 218
 219                 //calculate hits for ballistic weapons
 220                 if not(inWarmupStage)
 221                 if not(self.owner.isbot)
 222                 {
 223                         if(hit)
 224                                 self.owner.bullets_hit[self.owner.weapon] += 1;
 225                         // update the client
 226                         self.owner.damage_hits = self.owner.weapon + 64 * rint(self.owner.bullets_hit[self.owner.weapon]);
 227                 }
 228
 229                 //sound (self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 230         }
 231
 232         self.enemy = other; // don't hit the same player twice with the same bullet
 233 }
 234
 235 .void(void) W_BallisticBullet_LeaveSolid_think_save;
 236 .float W_BallisticBullet_LeaveSolid_nextthink_save;
 237 .vector W_BallisticBullet_LeaveSolid_origin;
 238 .vector W_BallisticBullet_LeaveSolid_velocity;
 239
 240 void W_BallisticBullet_LeaveSolid_think()
 241 {
 242         setorigin(self, self.W_BallisticBullet_LeaveSolid_origin);
 243         self.velocity = self.W_BallisticBullet_LeaveSolid_velocity;
 244
 245         self.think = self.W_BallisticBullet_LeaveSolid_think_save;
 246         self.nextthink = max(time, self.W_BallisticBullet_LeaveSolid_nextthink_save);
 247         self.W_BallisticBullet_LeaveSolid_think_save = SUB_Null;
 248
 249         self.flags &~= FL_ONGROUND;
 250
 251         if(self.enemy.solid == SOLID_BSP)
 252         {
 253                 float f;
 254                 f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 255                 Damage_DamageInfo(self.origin, 0, 0, 0, self.dmg_force * normalize(self.velocity) * -f, self.projectiledeathtype, self);
 256         }
 257
 258         UpdateCSQCProjectile(self);
 259 }
 260
 261 // a fake logarithm function
 262 float log(float x)
 263 {
 264         if(x < 0.0001)
 265                 return 0;
 266         if(x > 0.9 && x < 1.1)
 267                 return x - 1;
 268         return 2 * log(sqrt(x));
 269 }
 270
 271 float W_BallisticBullet_LeaveSolid(entity e, vector vel, float constant)
 272 {
 273         // move the entity along its velocity until it's out of solid, then let it resume
 274
 275         float dt, dst, velfactor, v0, vs;
 276         float maxdist;
 277         float E0_m, Es_m;
 278
 279         // outside the world? forget it
 280         if(self.origin_x > world.maxs_x || self.origin_y > world.maxs_y || self.origin_z > world.maxs_z || self.origin_x < world.mins_x || self.origin_y < world.mins_y || self.origin_z < world.mins_z)
 281                 return 0;
 282
 283         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 284         v0 = vlen(vel);
 285
 286         E0_m = 0.5 * v0 * v0;
 287         maxdist = E0_m / constant;
 288         // maxdist = 0.5 * v0 * v0 / constant
 289         // dprint("max dist = ", ftos(maxdist), "\n");
 290
 291         if(maxdist <= cvar("g_ballistics_mindistance"))
 292                 return 0;
 293
 294         traceline_inverted (self.origin, self.origin + normalize(vel) * maxdist, MOVE_NORMAL, self);
 295
 296         if(trace_fraction == 1) // 1: we never got out of solid
 297                 return 0;
 298
 299         self.W_BallisticBullet_LeaveSolid_origin = trace_endpos;
 300
 301         dst = vlen(trace_endpos - self.origin);
 302         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 303         Es_m = E0_m - constant * dst;
 304         if(Es_m <= 0)
 305         {
 306                 // roundoff errors got us
 307                 return 0;
 308         }
 309         vs = sqrt(2 * Es_m);
 310         velfactor = vs / v0;
 311
 312         dt = dst / (0.5 * (v0 + vs));
 313         // this is not correct, but the differential equations have no analytic
 314         // solution - and these times are very small anyway
 315         //print("dt = ", ftos(dt), "\n");
 316
 317         self.W_BallisticBullet_LeaveSolid_think_save = self.think;
 318         self.W_BallisticBullet_LeaveSolid_nextthink_save = self.nextthink;
 319         self.think = W_BallisticBullet_LeaveSolid_think;
 320         self.nextthink = time + dt;
 321
 322         vel = vel * velfactor;
 323
 324         self.velocity = '0 0 0';
 325         self.flags |= FL_ONGROUND; // prevent moving
 326         self.W_BallisticBullet_LeaveSolid_velocity = vel;
 327
 328         return 1;
 329 }
 330
 331 void W_BallisticBullet_Touch (void)
 332 {
 333         if(self.think == W_BallisticBullet_LeaveSolid_think) // skip this!
 334                 return;
 335
 336         PROJECTILE_TOUCH;
 337         W_BallisticBullet_Hit ();
 338
 339         // go through solid!
 340         if(!W_BallisticBullet_LeaveSolid(self, self.velocity, self.dmg_radius))
 341         {
 342                 remove(self);
 343                 return;
 344         }
 345
 346         self.projectiledeathtype |= HITTYPE_BOUNCE;
 347 }
 348
 349 void endFireBallisticBullet()
 350 {
 351         endzcurveparticles();
 352 }
 353 void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float headshotbonus, float force, float dtype, float tracereffects, float gravityfactor, float bulletconstant)
 354 {
 355         float lag, dt, savetime;
 356         entity pl, oldself;
 357
 358         entity proj;
 359         proj = spawn();
 360         proj.classname = "bullet";
 361         proj.owner = self;
 362         PROJECTILE_MAKETRIGGER(proj);
 363         if(gravityfactor > 0)
 364         {
 365                 proj.movetype = MOVETYPE_TOSS;
 366                 proj.gravity = gravityfactor;
 367         }
 368         else
 369                 proj.movetype = MOVETYPE_FLY;
 370         proj.think = SUB_Remove;
 371         proj.nextthink = time + lifetime; // min(pLifetime, vlen(world.maxs - world.mins) / pSpeed);
 372         proj.velocity = (dir + randomvec() * spread) * pSpeed;
 373         W_SetupProjectileVelocity(proj);
 374         proj.angles = vectoangles(proj.velocity);
 375         proj.dmg_radius = cvar("g_ballistics_materialconstant") / bulletconstant;
 376         // so: bulletconstant = bullet mass / area of bullet circle
 377         setorigin(proj, start);
 378         proj.flags = FL_PROJECTILE;
 379
 380         proj.touch = W_BallisticBullet_Touch;
 381         proj.dmg = damage;
 382         proj.dmg_edge = headshotbonus;
 383         proj.dmg_force = force;
 384         proj.projectiledeathtype = dtype;
 385
 386         proj.oldvelocity = proj.velocity;
 387
 388         //calculate fired bullets for ballistics
 389         if not(inWarmupStage)
 390         if not(self.isbot)
 391         {
 392                 self.bullets_fired[self.weapon] += 1;
 393                 self.maxdamage_fired = self.weapon + 64 * rint(self.bullets_fired[self.weapon]);
 394         }
 395
 396         if(cvar("g_antilag_bullets"))
 397         if(pSpeed >= cvar("g_antilag_bullets"))
 398         {
 399                 float eff;
 400
 401                 if(tracereffects & EF_RED)
 402                         eff = particleeffectnum("tr_rifle");
 403                 else
 404                         eff = particleeffectnum("tr_bullet");
 405
 406                 // NOTE: this may severely throw off weapon balance
 407                 lag = ANTILAG_LATENCY(self);
 408                 if(lag < 0.001)
 409                         lag = 0;
 410                 if(clienttype(self) != CLIENTTYPE_REAL)
 411                         lag = 0;
 412                 if(cvar("g_antilag") == 0)
 413                         lag = 0; // only do hitscan, but no antilag
 414
 415                 if(lag)
 416                         FOR_EACH_PLAYER(pl)
 417                                 antilag_takeback(pl, time - lag);
 418
 419                 oldself = self;
 420                 self = proj;
 421
 422                 savetime = frametime;
 423                 frametime = 0.05;
 424
 425                 for(;;)
 426                 {
 427                         // DP tracetoss is stupid and always traces in 0.05s
 428                         // ticks. This makes it trace in 0.05*0.125s ticks
 429                         // instead.
 430                         vector v0;
 431                         float g0;
 432                         v0 = self.velocity;
 433                         g0 = self.gravity;
 434                         self.velocity = self.velocity * 0.125;
 435                         self.gravity *= 0.125 * 0.125;
 436                         trace_fraction = 0;
 437                         tracetoss(self, oldself);
 438                         self.velocity = v0;
 439                         self.gravity = g0;
 440
 441                         if not(inWarmupStage)
 442                         if not(self.isbot)
 443                         {
 444                                 self.bullets_fired[self.weapon] += 1;
 445                                 self.maxdamage_fired = self.weapon + 64 * rint(self.bullets_fired[self.weapon]);
 446                         }
 447
 448                         if(vlen(trace_endpos - self.origin) > 16)
 449                                 zcurveparticles_from_tracetoss(eff, self.origin, trace_endpos, self.velocity);
 450                         if(trace_fraction == 1)
 451                                 break;
 452                                 // won't hit anything anytime soon (DP's
 453                                 // tracetoss does 200 tics of, here,
 454                                 // 0.05*0.125s, that is, 1.25 seconds
 455
 456                         other = trace_ent;
 457                         dt = vlen(trace_endpos - self.origin) / vlen(self.velocity); // this is only approximate!
 458                         setorigin(self, trace_endpos);
 459                         self.velocity_z -= sv_gravity * dt;
 460
 461                         if(!SUB_OwnerCheck())
 462                         {
 463                                 if(SUB_NoImpactCheck())
 464                                         break;
 465
 466                                 // hit the player
 467                                 W_BallisticBullet_Hit ();
 468                         }
 469
 470                         // go through solid!
 471                         if(!W_BallisticBullet_LeaveSolid(self, self.velocity, self.dmg_radius))
 472                                 break;
 473
 474                         W_BallisticBullet_LeaveSolid_think();
 475                 }
 476                 frametime = savetime;
 477                 self = oldself;
 478
 479                 if(lag)
 480                         FOR_EACH_PLAYER(pl)
 481                                 antilag_restore(pl);
 482
 483                 remove(proj);
 484
 485                 return;
 486         }
 487
 488         if(tracereffects & EF_RED)
 489                 CSQCProjectile(proj, TRUE, PROJECTILE_BULLET_GLOWING, TRUE);
 490         else
 491                 CSQCProjectile(proj, TRUE, PROJECTILE_BULLET, TRUE);
 492 }
 493
 494
 495 void fireBullet (vector start, vector dir, float spread, float damage, float force, float dtype, float tracer)
 496 {
 497         vector  end;
 498         //local entity e;
 499
 500         dir = normalize(dir + randomvec() * spread);
 501         end = start + dir * MAX_SHOT_DISTANCE;
 502         if(self.antilag_debug)
 503                 traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
 504         else
 505                 traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
 506
 507     end = trace_endpos;
 508
 509         if ((trace_fraction != 1.0) && (pointcontents (trace_endpos) != CONTENT_SKY))
 510         {
 511                 pointparticles(particleeffectnum("TE_KNIGHTSPIKE"),end,trace_plane_normal * 2500,1);
 512                 if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 513                         Damage_DamageInfo(trace_endpos, damage, 0, 0, dir * force, dtype, self);
 514                 Damage (trace_ent, self, self, damage, dtype, trace_endpos, dir * force);
 515                 //void(float effectnum, vector org, vector vel, float howmany) pointparticles = #337; // same as in CSQC
 516         }
 517         trace_endpos = end;
 518 }
 519
 520
 521 void W_PrepareExplosionByDamage(entity attacker, void() explode)
 522 {
 523         self.takedamage = DAMAGE_NO;
 524         self.event_damage = SUB_Null;
 525         self.owner = attacker;
 526
 527         // do not explode NOW but in the NEXT FRAME!
 528         // because recursive calls to RadiusDamage are not allowed
 529         self.nextthink = time;
 530         self.think = explode;
 531 }