data/qcsrc/server/tturrets/units/unit_hk.qc

   1 //#define TURRET_DEBUG_HK\r
   2 \r
   3 #ifdef TURRET_DEBUG_HK\r
   4 .float atime;\r
   5 #endif\r
   6 \r
   7 void spawnfunc_turret_hk();\r
   8 void turret_hk_dinit();\r
   9 void turret_hk_attack();\r
  10 void turret_hk_missile_explode();\r
  11 void turret_hk_missile_think();\r
  12 void turret_hk_missile_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);\r
  13 float turret_hk_addtarget(entity e_target,entity e_sender);\r
  14 //void turret_hk_missile_touch();\r
  15 \r
  16 float hk_maxspeed;\r
  17 float hk_minspeed;\r
  18 float hk_accel;\r
  19 float hk_accel2;\r
  20 float hk_decel;\r
  21 \r
  22 float turret_hk_addtarget(entity e_target,entity e_sender)\r
  23 {\r
  24     if (e_target)\r
  25     {\r
  26         if (turret_validate_target(self,e_target,self.target_validate_flags) > 0)\r
  27         {\r
  28             self.enemy = e_target;\r
  29             return 1;\r
  30         }\r
  31     }\r
  32 \r
  33     return 0;\r
  34 }\r
  35 \r
  36 float hk_is_valid_target(entity e_target)\r
  37 {\r
  38     if (e_target == world)\r
  39         return 0;\r
  40 \r
  41     // If only this was used more..\r
  42     if (e_target.flags & FL_NOTARGET)\r
  43         return 0;\r
  44 \r
  45     // Cant touch this\r
  46     if ((e_target.takedamage == DAMAGE_NO) || (e_target.health < 0))\r
  47         return 0;\r
  48 \r
  49     // player\r
  50     if (e_target.flags & FL_CLIENT)\r
  51     {\r
  52         if (self.owner.target_select_playerbias < 0)\r
  53             return 0;\r
  54 \r
  55         if (e_target.deadflag != DEAD_NO)\r
  56             return 0;\r
  57     }\r
  58 \r
  59     // Missile\r
  60     if ((e_target.flags & FL_PROJECTILE) && (self.owner.target_select_missilebias < 0))\r
  61         return 0;\r
  62 \r
  63     // Team check\r
  64     if ((e_target.team == self.owner.team) || (self.owner.team == e_target.owner.team))\r
  65         return 0;\r
  66 \r
  67     return 1;\r
  68 }\r
  69 \r
  70 void turret_hk_missile_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)\r
  71 {\r
  72     if (attacker.team == self.team)\r
  73         damage *= 0.5;\r
  74 \r
  75     self.velocity += force;\r
  76 \r
  77     self.health -= damage;\r
  78 \r
  79     if (self.health <= 0)\r
  80         turret_hk_missile_explode();\r
  81 }\r
  82 \r
  83 void turret_hk_attack()\r
  84 {\r
  85     local entity missile;\r
  86     //local entity flash2;\r
  87 \r
  88     sound (self, CHAN_WEAPON, "weapons/rocket_fire.wav", 1, ATTN_NORM);\r
  89 \r
  90     missile                    = spawn ();\r
  91     missile.solid            = SOLID_BBOX;\r
  92     setmodel (missile, "models/turrets/hunter2.md3"); // precision set below\r
  93     setsize (missile, missile.mins,missile.maxs); // give it some size so it can be shot\r
  94     sound    (missile, CHAN_PROJECTILE, "weapons/rocket_fly.wav", 0.4, ATTN_NORM);\r
  95     setorigin(missile, self.tur_shotorg_updated);\r
  96 \r
  97     missile.scale            = 1;\r
  98     missile.classname        = "hk_missile";\r
  99     missile.owner            = self;\r
 100     missile.bot_dodge        = TRUE;\r
 101     missile.bot_dodgerating  = self.shot_dmg;\r
 102     missile.takedamage       = DAMAGE_YES;\r
 103     missile.damageforcescale = 4;\r
 104     missile.health           = 10;\r
 105     missile.think            = turret_hk_missile_think;\r
 106     missile.event_damage     = turret_hk_missile_damage;\r
 107     missile.nextthink        = time + 0.25;\r
 108     missile.movetype         = MOVETYPE_BOUNCEMISSILE;\r
 109     missile.effects          = EF_LOWPRECISION;\r
 110     missile.velocity         = self.tur_shotdir_updated * (self.shot_speed * 0.75);\r
 111     missile.angles           = vectoangles(missile.velocity);\r
 112     missile.touch            = turret_hk_missile_explode; //turret_hk_missile_touch;\r
 113     missile.flags            = FL_PROJECTILE;\r
 114     missile.enemy            = self.enemy;\r
 115     missile.team             = self.team;\r
 116     missile.cnt              = time + 30;\r
 117     missile.ticrate          = max(cvar("sys_ticrate"),0.05);\r
 118 \r
 119     te_explosion (missile.origin);\r
 120 \r
 121     if (self.tur_head.frame == 0)\r
 122         self.tur_head.frame = self.tur_head.frame + 1;\r
 123 \r
 124 }\r
 125 \r
 126 /*\r
 127 void turret_hk_missile_touch()\r
 128 {\r
 129     if(other == self.enemy)\r
 130         turret_hk_missile_explode();\r
 131     else\r
 132     {\r
 133         if(self.cnt < time)\r
 134         {\r
 135             self.cnt = time + 0.25;\r
 136             self.health = self.health - 5;\r
 137             if(self.health <= 0)\r
 138                 turret_hk_missile_explode();\r
 139 \r
 140         }\r
 141     }\r
 142 }\r
 143 */\r
 144 \r
 145 void turret_hk_missile_think()\r
 146 {\r
 147     vector vu, vd, vf, vl, vr, ve;  // Vector (direction)\r
 148     float  fu, fd, ff, fl, fr, fe;  // Fraction to solid\r
 149     vector olddir,wishdir,newdir;   // Final direction\r
 150     float lt_for;   // Length of Trace FORwrad\r
 151     float lt_seek;  // Length of Trace SEEK (left, right, up down)\r
 152     float pt_seek;  // Pitch of Trace SEEK (How mutch to angele left, right up, down trace towards v_forward)\r
 153     vector pre_pos;\r
 154     float myspeed;\r
 155     entity e;\r
 156     float ad,edist;\r
 157 \r
 158     self.nextthink = time + self.ticrate;\r
 159 \r
 160     //if (self.cnt < time)\r
 161     //    turret_hk_missile_explode();\r
 162 \r
 163     if (self.enemy.deadflag != DEAD_NO)\r
 164         self.enemy = world;\r
 165 \r
 166     // Pick the closest valid target.\r
 167     if (!self.enemy)\r
 168     {\r
 169         e = findradius(self.origin, 5000);\r
 170         while (e)\r
 171         {\r
 172             if (hk_is_valid_target(e))\r
 173             {\r
 174                 if (!self.enemy)\r
 175                     self.enemy = e;\r
 176                 else\r
 177                     if (vlen(self.origin - e.origin) < vlen(self.origin - self.enemy.origin))\r
 178                         self.enemy = e;\r
 179             }\r
 180             e = e.chain;\r
 181         }\r
 182     }\r
 183 \r
 184     self.angles = vectoangles(self.velocity);\r
 185     self.angles_x = self.angles_x * -1;\r
 186     makevectors(self.angles);\r
 187     self.angles_x = self.angles_x * -1;\r
 188 \r
 189     if (self.enemy)\r
 190     {\r
 191         edist = vlen(self.origin - self.enemy.origin);\r
 192         // Close enougth to do decent damage?\r
 193         if ( edist <= (self.owner.shot_radius * 0.25) )\r
 194         {\r
 195             turret_hk_missile_explode();\r
 196             return;\r
 197         }\r
 198 \r
 199         // Get data on enemy position\r
 200         pre_pos = self.enemy.origin +\r
 201                   self.enemy.velocity *\r
 202                   min((vlen(self.enemy.origin - self.origin) / vlen(self.velocity)),0.5);\r
 203 \r
 204         traceline(self.origin, pre_pos,TRUE,self.enemy);\r
 205         ve = normalize(pre_pos - self.origin);\r
 206         fe = trace_fraction;\r
 207 \r
 208     }\r
 209     else\r
 210     {\r
 211         fe = 0;\r
 212     }\r
 213 \r
 214     if ((fe != 1) || (self.enemy == world) || (edist > 1000))\r
 215     {\r
 216         myspeed = vlen(self.velocity);\r
 217 \r
 218         lt_for  = myspeed * 3;\r
 219         lt_seek = myspeed * 2.95;\r
 220 \r
 221         // Trace forward\r
 222         traceline(self.origin, self.origin + v_forward * lt_for,FALSE,self);\r
 223         vf = trace_endpos;\r
 224         ff = trace_fraction;\r
 225 \r
 226         // Find angular offset\r
 227         ad = vlen(vectoangles(normalize(self.enemy.origin - self.origin)) - self.angles);\r
 228 \r
 229         // To close to something, Slow down!\r
 230         if ( ((ff < 0.7) || (ad > 4)) && (myspeed > hk_minspeed) )\r
 231             myspeed = max(myspeed * hk_decel,hk_minspeed);\r
 232 \r
 233         // Failry clear, accelerate.\r
 234         if ( (ff > 0.7) && (myspeed < hk_maxspeed) )\r
 235             myspeed = min(myspeed * hk_accel,hk_maxspeed);\r
 236 \r
 237         // Setup trace pitch\r
 238         pt_seek = 1 - ff;\r
 239         pt_seek = bound(0.15,pt_seek,0.8);\r
 240         if (ff < 0.5) pt_seek = 1;\r
 241 \r
 242         // Trace left\r
 243         traceline(self.origin, self.origin + (-1 * (v_right * pt_seek) + (v_forward * ff)) * lt_seek,FALSE,self);\r
 244         vl = trace_endpos;\r
 245         fl = trace_fraction;\r
 246 \r
 247         // Trace right\r
 248         traceline(self.origin,  self.origin + ((v_right * pt_seek) + (v_forward * ff)) * lt_seek ,FALSE,self);\r
 249         vr = trace_endpos;\r
 250         fr = trace_fraction;\r
 251 \r
 252         // Trace up\r
 253         traceline(self.origin,  self.origin + ((v_up * pt_seek) + (v_forward * ff)) * lt_seek ,FALSE,self);\r
 254         vu = trace_endpos;\r
 255         fu = trace_fraction;\r
 256 \r
 257         // Trace down\r
 258         traceline(self.origin,  self.origin + (-1 * (v_up * pt_seek) + (v_forward * ff)) * lt_seek ,FALSE,self);\r
 259         vd = trace_endpos;\r
 260         fd = trace_fraction;\r
 261 \r
 262         vl = normalize(vl - self.origin);\r
 263         vr = normalize(vr - self.origin);\r
 264         vu = normalize(vu - self.origin);\r
 265         vd = normalize(vd - self.origin);\r
 266 \r
 267         // Panic tresh passed, find a single direction and turn as hard as we can\r
 268         if (pt_seek == 1)\r
 269         {\r
 270             wishdir = v_right;\r
 271             if (fl > fr) wishdir = -1 * v_right;\r
 272             if (fu > fl) wishdir = v_up;\r
 273             if (fd > fu) wishdir = -1 * v_up;\r
 274         }\r
 275         else\r
 276         {\r
 277             // Normalize our trace vectors to make a smooth path\r
 278             wishdir = normalize( (vl * fl) + (vr * fr) +  (vu * fu) +  (vd * fd) );\r
 279         }\r
 280 \r
 281         if (self.enemy)\r
 282         {\r
 283             if (fe < 0.1) fe = 0.1; // Make sure we always try to move sligtly towards our target\r
 284             wishdir = (wishdir * (1 - fe)) + (ve * fe);\r
 285         }\r
 286     }\r
 287     else\r
 288     {\r
 289         // Got a clear path to target, speed up fast (if not at full speed) and go straight for it.\r
 290         myspeed = vlen(self.velocity);\r
 291         if (myspeed < hk_maxspeed)\r
 292             myspeed = min(myspeed * hk_accel2,hk_maxspeed);\r
 293 \r
 294         wishdir = ve;\r
 295         //wishdir = normalize(self.enemy.origin - (self.enemy.origin + self.enemy.velocity));\r
 296     }\r
 297 \r
 298     if ((myspeed > hk_minspeed) && (self.cnt > time))\r
 299         myspeed = min(myspeed * hk_accel2,hk_maxspeed);\r
 300 \r
 301     // Ranoutagazfish?\r
 302     if (self.cnt < time)\r
 303     {\r
 304         self.cnt = time + 0.25;\r
 305         self.nextthink = 0;\r
 306         self.movetype         = MOVETYPE_BOUNCE;\r
 307         sound    (self, CHAN_VOICE, "", 0.4, ATTN_NORM);\r
 308         return;\r
 309     }\r
 310 \r
 311     // Calculate new heading\r
 312     olddir = normalize(self.velocity);\r
 313 \r
 314     newdir = normalize(olddir + wishdir * cvar("g_turrets_unit_hk_std_shot_speed_turnrate"));\r
 315 \r
 316     //fu = (1 / hk_maxspeed) * myspeed;\r
 317     //fd = fu - (0.75 - 0.25);\r
 318     //newdir = normalize(olddir + wishdir * fd);\r
 319 \r
 320     // Set heading & speed\r
 321     self.velocity = newdir * myspeed;\r
 322 \r
 323     // Align model with new heading\r
 324     self.angles = vectoangles(self.velocity);\r
 325 \r
 326 \r
 327 #ifdef TURRET_DEBUG_HK\r
 328     //if(self.atime < time) {\r
 329     if ((fe <= 0.99)||(edist > 1000))\r
 330     {\r
 331         te_lightning2(world,self.origin, self.origin + vr * lt_seek);\r
 332         te_lightning2(world,self.origin, self.origin + vl * lt_seek);\r
 333         te_lightning2(world,self.origin, self.origin + vu * lt_seek);\r
 334         te_lightning2(world,self.origin, self.origin + vd * lt_seek);\r
 335         te_lightning2(world,self.origin, vf);\r
 336     }\r
 337     else\r
 338     {\r
 339         te_lightning2(world,self.origin, self.enemy.origin);\r
 340     }\r
 341     bprint("Speed: ", ftos(rint(myspeed)), "\n");\r
 342     bprint("Trace to solid: ", ftos(rint(ff * 100)), "%\n");\r
 343     bprint("Trace to target:", ftos(rint(fe * 100)), "%\n");\r
 344     self.atime = time + 0.2;\r
 345     //}\r
 346 #endif\r
 347 }\r
 348 \r
 349 void turret_hk_missile_explode()\r
 350 {\r
 351     vector org2;\r
 352     float d;\r
 353 \r
 354     if(self.event_damage != SUB_Null)\r
 355     {\r
 356         self.event_damage = SUB_Null;\r
 357         self.think = turret_hk_missile_explode;\r
 358         self.nextthink = time;\r
 359         return;\r
 360     }\r
 361 \r
 362     if ((other == self.owner)||(other == self.owner.tur_head))\r
 363         return;\r
 364 \r
 365     //vector    org2;\r
 366     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", 1, ATTN_NORM);\r
 367     org2 = findbetterlocation (self.origin, 16);\r
 368 \r
 369     // LordHavoc: TE_TEI_BIGEXPLOSION\r
 370     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);\r
 371     WriteByte (MSG_BROADCAST, 78);\r
 372     WriteCoord (MSG_BROADCAST, org2_x);\r
 373     WriteCoord (MSG_BROADCAST, org2_y);\r
 374     WriteCoord (MSG_BROADCAST, org2_z);\r
 375 \r
 376     self.event_damage = SUB_Null;\r
 377     d = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, world, self.owner.shot_force, DEATH_TURRET, world);\r
 378 \r
 379 #ifdef TURRET_DEBUG\r
 380     self.owner.tur_dbg_dmg_t_h = self.owner.tur_dbg_dmg_t_h + d; //self.owner.shot_dmg;\r
 381     self.owner.tur_dbg_dmg_t_f = self.owner.tur_dbg_dmg_t_f + self.owner.shot_dmg;\r
 382 #endif\r
 383 \r
 384     // Target dead, get another is still targeting the same.\r
 385     if ((self.enemy.deadflag != DEAD_NO) && (self.enemy == self.owner.enemy))\r
 386         self.owner.enemy = world;\r
 387 \r
 388     remove (self);\r
 389 }\r
 390 \r
 391 void turret_hk_postthink()\r
 392 {\r
 393     if (cvar("g_turrets_reloadcvars"))\r
 394     {\r
 395         hk_maxspeed = cvar("g_turrets_unit_hk_std_shot_speed_max");\r
 396         hk_minspeed = cvar("g_turrets_unit_hk_std_shot_speed");\r
 397         hk_accel    = cvar("g_turrets_unit_hk_std_shot_speed_accel");\r
 398         hk_accel2   = cvar("g_turrets_unit_hk_std_shot_speed_accel2");\r
 399         hk_decel    = cvar("g_turrets_unit_hk_std_shot_speed_decel");\r
 400     }\r
 401 \r
 402     if (self.tur_head.frame != 0)\r
 403         self.tur_head.frame = self.tur_head.frame + 1;\r
 404 \r
 405     if (self.tur_head.frame > 5)\r
 406         self.tur_head.frame = 0;\r
 407 \r
 408 }\r
 409 \r
 410 void turret_hk_dinit()\r
 411 {\r
 412     if (self.netname == "")      self.netname  = "Hunter-killer turret";\r
 413 \r
 414     hk_maxspeed = cvar("g_turrets_unit_hk_std_shot_speed_max");\r
 415     hk_minspeed = cvar("g_turrets_unit_hk_std_shot_speed");\r
 416     hk_accel    = cvar("g_turrets_unit_hk_std_shot_speed_accel");\r
 417     hk_accel2   = cvar("g_turrets_unit_hk_std_shot_speed_accel2");\r
 418     hk_decel    = cvar("g_turrets_unit_hk_std_shot_speed_decel");\r
 419 \r
 420     self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_MEDPROJ | TFL_TURRCAPS_PLAYERKILL | TFL_TURRCAPS_RECIVETARGETS;\r
 421 \r
 422     self.ammo_flags = TFL_AMMO_ROCKETS | TFL_AMMO_RECHARGE;\r
 423 \r
 424     self.aim_flags = TFL_AIM_SIMPLE;\r
 425 \r
 426     self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_TRIGGERTARGET | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_TEAMCHECK;\r
 427 \r
 428     self.firecheck_flags = TFL_FIRECHECK_WORLD | TFL_FIRECHECK_DEAD | TFL_FIRECHECK_TEAMCECK  | TFL_FIRECHECK_REFIRE | TFL_FIRECHECK_AFF;\r
 429 \r
 430     self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_TRIGGERTARGET | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_TEAMCHECK;\r
 431 \r
 432     self.shoot_flags = TFL_SHOOT_CLEARTARGET;\r
 433 \r
 434     if (turret_stdproc_init("hk_std") == 0)\r
 435     {\r
 436         remove(self);\r
 437         return;\r
 438     }\r
 439 \r
 440     self.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_TEAMCHECK;\r
 441 \r
 442     setmodel(self,"models/turrets/base.md3");\r
 443     setmodel(self.tur_head,"models/turrets/hk.md3");\r
 444 \r
 445     if (!turret_tag_setup(0))\r
 446         dprint("Warning: Turret ",self.classname, " faild to initialize md3 tags\n");\r
 447 \r
 448     // Our fire routine\r
 449     self.turret_firefunc  = turret_hk_attack;\r
 450 \r
 451     // re-color badge & handle recoil effect\r
 452     self.turret_postthink = turret_hk_postthink;\r
 453 \r
 454     // What to do when reciveing foreign target data\r
 455     self.turret_addtarget = turret_hk_addtarget;\r
 456 }\r
 457 \r
 458 /*\r
 459 * Turret that fires Hunter-killer missiles.\r
 460 * Missiles seek their target and try to avoid obstacles. If target dies early, they\r
 461 * pick a new one on their own.\r
 462 */\r
 463 \r
 464 /*QUAKED turret_hk (0 .5 .8) ?\r
 465 hunter-killer missiles.\r
 466 */\r
 467 \r
 468 void spawnfunc_turret_hk()\r
 469 {\r
 470     //precache_model ( "models/turrets/hunter2.md3");\r
 471     //precache_model ("models/turrets/base.md3");\r
 472     //precache_model ("models/turrets/hk.md3");\r
 473 \r
 474     self.think = turret_hk_dinit;\r
 475     self.nextthink = time + 0.5;\r
 476 }\r
 477 \r
 478 \r