data/qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(entity pl)
  76 {
  77         string str;
  78         if(!cvar("sv_eventlog"))
  79                 return;
  80         if(pl.playerid < 1)
  81                 return;
  82         str = strcat(":team:", ftos(pl.playerid), ":");
  83         str = strcat(str, ftos(pl.team));
  84         GameLogEcho(str);
  85 }
  86
  87 void WriteGameCvars()
  88 {
  89         cvar_set("g_dm", ftos(g_dm));
  90         cvar_set("g_tdm", ftos(g_tdm));
  91         cvar_set("g_domination", ftos(g_domination));
  92         cvar_set("g_ctf", ftos(g_ctf));
  93         cvar_set("g_runematch", ftos(g_runematch));
  94         cvar_set("g_lms", ftos(g_lms));
  95         cvar_set("g_arena", ftos(g_arena));
  96         cvar_set("g_keyhunt", ftos(g_keyhunt));
  97         cvar_set("g_assault", ftos(g_assault));
  98         cvar_set("g_onslaught", ftos(g_onslaught));
  99         cvar_set("g_race", ftos(g_race));
 100         cvar_set("g_nexball", ftos(g_nexball));
 101 }
 102
 103 void ReadGameCvars()
 104 {
 105         float found;
 106         float prev;
 107         float i;
 108
 109         found = 0;
 110         prev = cvar("gamecfg");
 111         for(i = 0; i < 2; ++i)
 112         {
 113                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 114                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 115                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 116                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 117                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 118                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 119                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 120                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 121                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 122                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 123                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 124                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 125
 126                 if(found)
 127                         break;
 128
 129                 prev = -1; // second attempt takes place WITHOUT prev set
 130         }
 131
 132         if(!found)
 133                 g_dm = 1;
 134
 135         if(g_dm && cvar("deathmatch_force_teamplay"))
 136         {
 137                 g_dm = 0;
 138                 g_tdm = 1;
 139         }
 140
 141         teams_matter = 0;
 142 }
 143
 144 void default_delayedinit()
 145 {
 146         if(!scores_initialized)
 147                 ScoreRules_generic();
 148 }
 149
 150 void ActivateTeamplay()
 151 {
 152         float teamplay_default;
 153         teamplay_default = cvar("teamplay_default");
 154
 155         if(teamplay_default)
 156                 teamplay = teamplay_default;
 157         else
 158                 teamplay = 3;
 159         cvar_set("teamplay", ftos(teamplay));
 160
 161         teams_matter = 1;
 162 }
 163
 164 void InitGameplayMode()
 165 {
 166         float fraglimit_override, timelimit_override;
 167
 168         VoteReset();
 169
 170         teams_matter = 0;
 171         cvar_set("teamplay", "0");
 172
 173         // make sure only ONE type is selected
 174         ReadGameCvars();
 175         WriteGameCvars();
 176
 177         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 178         get_mi_min_max(1);
 179         world.mins = mi_min;
 180         world.maxs = mi_max;
 181
 182         MapInfo_LoadMapSettings(mapname);
 183
 184         if not(cvar_value_issafe(world.fog))
 185         {
 186                 print("The current map contains a potentially harmful fog setting, ignored\n");
 187                 world.fog = string_null;
 188         }
 189         if(MapInfo_Map_fog != "")
 190                 if(MapInfo_Map_fog == "none")
 191                         world.fog = string_null;
 192                 else
 193                         world.fog = strzone(MapInfo_Map_fog);
 194         clientstuff = strzone(MapInfo_Map_clientstuff);
 195
 196         MapInfo_ClearTemps();
 197
 198         // in case mapinfo switched the type
 199         ReadGameCvars();
 200
 201         // set both here, gamemode can override it later
 202         timelimit_override = cvar("timelimit_override");
 203         fraglimit_override = cvar("fraglimit_override");
 204
 205         if(g_dm)
 206         {
 207                 game = GAME_DEATHMATCH;
 208                 gamemode_name = "Deathmatch";
 209         }
 210
 211         if(g_tdm)
 212         {
 213                 game = GAME_TEAM_DEATHMATCH;
 214                 gamemode_name = "Team Deathmatch";
 215                 ActivateTeamplay();
 216                 tdm_init();
 217         }
 218
 219         if(g_domination)
 220         {
 221                 game = GAME_DOMINATION;
 222                 gamemode_name = "Domination";
 223                 ActivateTeamplay();
 224                 fraglimit_override = cvar("g_domination_point_limit");
 225                 dom_init();
 226         }
 227
 228         if(g_ctf)
 229         {
 230                 game = GAME_CTF;
 231                 gamemode_name = "Capture the Flag";
 232                 ActivateTeamplay();
 233                 if(cvar("g_campaign"))
 234                         g_ctf_win_mode = 2;
 235                 else
 236                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 237                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 238                 if(g_ctf_win_mode == 2)
 239                         fraglimit_override = cvar("g_ctf_capture_limit");
 240                 else
 241                         fraglimit_override = cvar("capturelimit_override");
 242                 ctf_init();
 243         }
 244
 245         if(g_runematch)
 246         {
 247                 game = GAME_RUNEMATCH;
 248                 gamemode_name = "Rune Match";
 249                 if(cvar("deathmatch_force_teamplay"))
 250                         ActivateTeamplay();
 251                 fraglimit_override = cvar("g_runematch_point_limit");
 252                 runematch_init();
 253         }
 254
 255         if(g_lms)
 256         {
 257                 game = GAME_LMS;
 258                 gamemode_name = "Last Man Standing";
 259                 fraglimit_override = cvar("g_lms_lives_override");
 260                 if(fraglimit_override == 0)
 261                         fraglimit_override = -1;
 262                 lms_lowest_lives = 9999;
 263                 lms_next_place = 0;
 264                 ScoreRules_lms();
 265         }
 266
 267         if(g_arena)
 268         {
 269                 game = GAME_ARENA;
 270                 gamemode_name = "Arena";
 271                 fraglimit_override = cvar("g_arena_point_limit");
 272                 maxspawned = cvar("g_arena_maxspawned");
 273                 if(maxspawned < 2)
 274                         maxspawned = 2;
 275                 arena_roundbased = cvar("g_arena_roundbased");
 276         }
 277
 278         if(g_keyhunt)
 279         {
 280                 game = GAME_KEYHUNT;
 281                 gamemode_name = "Key Hunt";
 282                 ActivateTeamplay();
 283                 fraglimit_override = cvar("g_keyhunt_point_limit");
 284                 kh_init();
 285         }
 286
 287         if(g_assault)
 288         {
 289                 game = GAME_ASSAULT;
 290                 gamemode_name = "Assault";
 291                 ActivateTeamplay();
 292                 ScoreRules_assault();
 293         }
 294
 295         if(g_onslaught)
 296         {
 297                 game = GAME_ONSLAUGHT;
 298                 gamemode_name = "Onslaught";
 299                 ActivateTeamplay();
 300         }
 301
 302         if(g_race)
 303         {
 304                 game = GAME_RACE;
 305                 gamemode_name = "Race";
 306                 g_race_qualifying = cvar("g_race_qualifying");
 307
 308                 if(cvar("g_race_teams"))
 309                 {
 310                         g_race_qualifying = 0; // not supported!
 311                         ActivateTeamplay();
 312                         race_teams = bound(2, cvar("g_race_teams"), 4);
 313                 }
 314                 else
 315                         race_teams = 0;
 316
 317                 if(g_race_qualifying == 1)
 318                         fraglimit_override = 0;
 319                 else
 320                         fraglimit_override = cvar("g_race_laps_limit");
 321
 322                 if(g_race_qualifying)
 323                         independent_players = 1;
 324
 325                 ScoreRules_race();
 326         }
 327
 328         if(g_nexball)
 329         {
 330                 game = GAME_NEXBALL;
 331                 gamemode_name = "Nexball";
 332                 fraglimit_override = cvar("g_nexball_goallimit");
 333                 ActivateTeamplay();
 334                 nb_init();
 335         }
 336
 337         if(teams_matter)
 338                 entcs_init();
 339
 340         // save it (for the next startup)
 341         cvar_set("gamecfg", ftos(game));
 342
 343         cache_mutatormsg = strzone("");
 344         cache_lastmutatormsg = strzone("");
 345
 346         // enforce the server's universal frag/time limits
 347         if(!cvar("g_campaign"))
 348         {
 349                 if(fraglimit_override >= 0)
 350                         cvar_set("fraglimit", ftos(fraglimit_override));
 351                 if(timelimit_override >= 0)
 352                         cvar_set("timelimit", ftos(timelimit_override));
 353         }
 354
 355         if(g_race && g_race_qualifying == 2)
 356         {
 357                 race_fraglimit = cvar("fraglimit");
 358                 cvar_set("fraglimit", "0");
 359         }
 360
 361         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 362 }
 363
 364 string GetClientVersionMessage() {
 365         local string versionmsg;
 366         if (self.version_mismatch) {
 367                 if(self.version < cvar("gameversion")) {
 368                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 369                 } else {
 370                         versionmsg = "^3This server is using an outdated Nexuiz version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 371                 }
 372         } else {
 373                 versionmsg = "^2client version and server version are compatible.^8";
 374         }
 375         return versionmsg;
 376 }
 377
 378
 379 void PrintWelcomeMessage(entity pl)
 380 {
 381         string s, modifications, motd;
 382
 383         if(self.cvar_scr_centertime == 0) return;
 384         if((time - self.jointime) > cvar("welcome_message_time")
 385            && !self.BUTTON_INFO)
 386                 return;
 387
 388         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 389                 if(self.welcomemessage_time > time) return;
 390                 self.welcomemessage_time = time + self.cvar_scr_centertime * 0.6;
 391         }
 392
 393         if(cvar("g_campaign"))
 394         {
 395                 centerprint(pl, campaign_message);
 396                 return;
 397         }
 398
 399 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 400         if(!self.BUTTON_INFO)
 401         {
 402                 // TODO get rid of this too
 403                 local string specString;
 404                 specString = NEWLINES;
 405                 //if(time < game_starttime) //also show the countdown when being a spectator
 406                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 407                 //else
 408                 if (timeoutStatus != 0)
 409                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 410                 else
 411                 {
 412                         if(!self.BUTTON_INFO && self.classname == "player")
 413                                 return;
 414                         goto normal;
 415                 }
 416                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 417         }
 418
 419 :normal
 420         modifications = "";
 421         if(g_minstagib)
 422                 modifications = strcat(modifications, ", MinstaGib");
 423         if(g_nixnex)
 424                 modifications = strcat(modifications, ", NixNex");
 425         if(g_weaponarena)
 426                 modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 427         if(cvar("sv_gravity") < 800)
 428                 modifications = strcat(modifications, ", Low gravity");
 429         if(g_cloaked)
 430                 modifications = strcat(modifications, ", Cloaked");
 431         if(g_footsteps)
 432                 modifications = strcat(modifications, ", Steps");
 433         if(g_grappling_hook)
 434                 modifications = strcat(modifications, ", Hook");
 435         if(g_laserguided_missile)
 436                 modifications = strcat(modifications, ", LG missiles");
 437         if(g_midair)
 438                 modifications = strcat(modifications, ", Midair");
 439         if(g_vampire)
 440                 modifications = strcat(modifications, ", Vampire");
 441         if(g_pinata)
 442                 modifications = strcat(modifications, ", Pinata");
 443         if(g_weapon_stay)
 444                 modifications = strcat(modifications, ", Weapons stay");
 445         if(g_bloodloss > 0)
 446                 modifications = strcat(modifications, ", Bloodloss");
 447         if(g_jetpack)
 448                 modifications = strcat(modifications, ", Jet pack");
 449         modifications = substring(modifications, 2, strlen(modifications) - 2);
 450
 451         local string versionmessage;
 452         versionmessage = GetClientVersionMessage();
 453
 454         s = strcat(s, NEWLINES, "This is Nexuiz ", cvar_string("g_nexuizversion"), "\n", versionmessage);
 455         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 456
 457         if(modifications != "")
 458                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 459
 460         if(timeoutStatus != 0)
 461                 s = strcat(s, "\n\n", getTimeoutText(1));
 462
 463         if (g_grappling_hook)
 464                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 465
 466         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 467         {
 468                 if(cache_lastmutatormsg)
 469                         strunzone(cache_lastmutatormsg);
 470                 if(cache_mutatormsg)
 471                         strunzone(cache_mutatormsg);
 472                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 473                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 474         }
 475
 476         if (cache_mutatormsg != "") {
 477                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 478         }
 479
 480         motd = cvar_string("sv_motd");
 481         if (motd != "") {
 482                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 483         }
 484         s = strcat(s, "\n");
 485
 486         centerprint(pl, s);
 487 }
 488
 489
 490 void SetPlayerColors(entity pl, float _color)
 491 {
 492         /*string s;
 493         s = ftos(cl);
 494         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 495         pl.team = cl + 1;
 496         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 497         pl.clientcolors = 16*cl + cl;*/
 498
 499         float pants, shirt;
 500         pants = _color & 0x0F;
 501         shirt = _color & 0xF0;
 502
 503
 504         if(teams_matter) {
 505                 setcolor(pl, 16*pants + pants);
 506         } else {
 507                 setcolor(pl, shirt + pants);
 508         }
 509 }
 510
 511 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 512 {
 513         float _color;
 514
 515         if(t == 4)
 516                 _color = COLOR_TEAM4 - 1;
 517         else if(t == 3)
 518                 _color = COLOR_TEAM3 - 1;
 519         else if(t == 2)
 520                 _color = COLOR_TEAM2 - 1;
 521         else
 522                 _color = COLOR_TEAM1 - 1;
 523
 524         SetPlayerColors(pl,_color);
 525
 526         if(!noprint && t != s)
 527         {
 528                 //bprint(pl.netname, " has changed to ", TeamNoName(t), "\n");
 529                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 530         }
 531
 532         if(t != s)
 533                 LogTeamchange(pl);
 534 }
 535
 536
 537
 538
 539
 540
 541 // set c1...c4 to show what teams are allowed
 542 void CheckAllowedTeams (entity for_whom)
 543 {
 544         string teament_name;
 545         float dm;
 546         entity head;
 547
 548 //      if(!dom && !ctf)
 549 //              dm = 1;
 550
 551         c1 = c2 = c3 = c4 = -1;
 552         cb1 = cb2 = cb3 = cb4 = 0;
 553
 554         // onslaught is special
 555         if(g_onslaught)
 556         {
 557                 head = findchain(classname, "onslaught_generator");
 558                 while (head)
 559                 {
 560                         if (head.team == COLOR_TEAM1) c1 = 0;
 561                         if (head.team == COLOR_TEAM2) c2 = 0;
 562                         if (head.team == COLOR_TEAM3) c3 = 0;
 563                         if (head.team == COLOR_TEAM4) c4 = 0;
 564                         head = head.chain;
 565                 }
 566                 return;
 567         }
 568
 569         if(g_domination)
 570                 teament_name = "dom_team";
 571         else if(g_ctf)
 572                 teament_name = "ctf_team";
 573         else if(g_tdm)
 574                 teament_name = "tdm_team";
 575         else if(g_nexball)
 576                 teament_name = "nexball_team";
 577         else if(g_assault)
 578         {
 579                 c1 = c2 = 0; // Assault always has 2 teams
 580                 return;
 581         }
 582         else
 583         {
 584                 // cover anything else by treating it like tdm with no teams spawned
 585                 if(g_keyhunt)
 586                         dm = kh_teams;
 587                 else if(g_race)
 588                         dm = race_teams;
 589                 else
 590                         dm = cvar("g_tdm_teams");
 591                 if(dm < 2)
 592                         error("g_tdm_teams < 2, not enough teams to play team deathmatch\n");
 593
 594                 if(dm >= 4)
 595                 {
 596                         c1 = c2 = c3 = c4 = 0;
 597                 }
 598                 else if(dm >= 3)
 599                 {
 600                         c1 = c2 = c3 = 0;
 601                 }
 602                 else// if(dm >= 2)
 603                 {
 604                         c1 = c2 = 0;
 605                 }
 606                 return;
 607         }
 608
 609         // first find out what teams are allowed
 610         head = find(world, classname, teament_name);
 611         while(head)
 612         {
 613                 if(!(g_domination && head.netname == ""))
 614                 {
 615                         if(head.team == COLOR_TEAM1)
 616                         {
 617                                 c1 = 0;
 618                         }
 619                         if(head.team == COLOR_TEAM2)
 620                         {
 621                                 c2 = 0;
 622                         }
 623                         if(head.team == COLOR_TEAM3)
 624                         {
 625                                 c3 = 0;
 626                         }
 627                         if(head.team == COLOR_TEAM4)
 628                         {
 629                                 c4 = 0;
 630                         }
 631                 }
 632                 head = find(head, classname, teament_name);
 633         }
 634
 635         if(for_whom)
 636         {
 637                 if(cvar("bot_vs_human") > 0)
 638                 {
 639                         // bots are all blue
 640                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 641                                 c1 = c3 = c4 = -1;
 642                         else
 643                                 c2 = -1;
 644                 }
 645                 else if(cvar("bot_vs_human") < 0)
 646                 {
 647                         // bots are all red
 648                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 649                                 c2 = c3 = c4 = -1;
 650                         else
 651                                 c1 = -1;
 652                 }
 653         }
 654 }
 655
 656 float PlayerValue(entity p)
 657 {
 658         if(IsTeamBalanceForced() == 1)
 659                 return 1;
 660         return 1;
 661 }
 662
 663 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 664 // teams that are allowed will now have their player counts stored in c1...c4
 665 void GetTeamCounts(entity ignore)
 666 {
 667         entity head;
 668         float value, bvalue;
 669         // now count how many players are on each team already
 670
 671         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 672         // also remember the lowest-scoring player
 673
 674         FOR_EACH_PLAYER(head)
 675         {
 676                 if(head != ignore)// && head.netname != "")
 677                 {
 678                         value = PlayerValue(head);
 679                         if(clienttype(head) == CLIENTTYPE_BOT)
 680                                 bvalue = value;
 681                         else
 682                                 bvalue = 0;
 683                         if(head.team == COLOR_TEAM1)
 684                         {
 685                                 if(c1 >= 0)
 686                                 {
 687                                         c1 = c1 + value;
 688                                         cb1 = cb1 + bvalue;
 689                                 }
 690                         }
 691                         if(head.team == COLOR_TEAM2)
 692                         {
 693                                 if(c2 >= 0)
 694                                 {
 695                                         c2 = c2 + value;
 696                                         cb2 = cb2 + bvalue;
 697                                 }
 698                         }
 699                         if(head.team == COLOR_TEAM3)
 700                         {
 701                                 if(c3 >= 0)
 702                                 {
 703                                         c3 = c3 + value;
 704                                         cb3 = cb3 + bvalue;
 705                                 }
 706                         }
 707                         if(head.team == COLOR_TEAM4)
 708                         {
 709                                 if(c4 >= 0)
 710                                 {
 711                                         c4 = c4 + value;
 712                                         cb4 = cb4 + bvalue;
 713                                 }
 714                         }
 715                 }
 716         }
 717 }
 718
 719 // returns # of smallest team (1, 2, 3, 4)
 720 // NOTE: Assumes CheckAllowedTeams has already been called!
 721 float FindSmallestTeam(entity pl, float ignore_pl)
 722 {
 723         float totalteams, smallestteam, smallestteam_count, smallestteam_score, balance_type;
 724         totalteams = 0;
 725
 726         // find out what teams are available
 727         //CheckAllowedTeams();
 728
 729         // make sure there are at least 2 teams to join
 730         if(c1 >= 0)
 731                 totalteams = totalteams + 1;
 732         if(c2 >= 0)
 733                 totalteams = totalteams + 1;
 734         if(c3 >= 0)
 735                 totalteams = totalteams + 1;
 736         if(c4 >= 0)
 737                 totalteams = totalteams + 1;
 738
 739         if(cvar("bot_vs_human"))
 740                 totalteams += 1;
 741
 742         if(totalteams <= 1)
 743         {
 744                 if(g_domination)
 745                         error("Too few teams available for domination\n");
 746                 else if(g_ctf)
 747                         error("Too few teams available for ctf\n");
 748                 else if(g_keyhunt)
 749                         error("Too few teams available for key hunt\n");
 750                 else
 751                         error("Too few teams available for team deathmatch\n");
 752         }
 753
 754         // count how many players are in each team
 755         if(ignore_pl)
 756                 GetTeamCounts(pl);
 757         else
 758                 GetTeamCounts(world);
 759
 760         // c1...c4 now have counts of each team
 761         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 762
 763         smallestteam = 0;
 764         smallestteam_count = 999999999;
 765         smallestteam_score = 999999999;
 766
 767         // 2 gives priority to what team you're already on, 1 goes in order
 768         // 2 doesn't seem to work though...
 769         balance_type = 1;
 770
 771         if(bots_would_leave)
 772         //if(pl.classname != "player")
 773         if(clienttype(pl) != CLIENTTYPE_BOT)
 774         {
 775                 c1 -= cb1 * 255.0/256;
 776                 c2 -= cb2 * 255.0/256;
 777                 c3 -= cb3 * 255.0/256;
 778                 c4 -= cb4 * 255.0/256;
 779         }
 780
 781         if(balance_type == 1)
 782         {
 783                 if(c1 >= 0 && (c1 < smallestteam_count || (c1 <= smallestteam_count && team1_score < smallestteam_score)))
 784                 {
 785                         smallestteam = 1;
 786                         smallestteam_count = c1;
 787                         smallestteam_score = team1_score;
 788                 }
 789                 if(c2 >= 0 && (c2 < smallestteam_count || (c2 <= smallestteam_count && team2_score < smallestteam_score)))
 790                 {
 791                         smallestteam = 2;
 792                         smallestteam_count = c2;
 793                         smallestteam_score = team2_score;
 794                 }
 795                 if(c3 >= 0 && (c3 < smallestteam_count || (c3 <= smallestteam_count && team3_score < smallestteam_score)))
 796                 {
 797                         smallestteam = 3;
 798                         smallestteam_count = c3;
 799                         smallestteam_score = team3_score;
 800                 }
 801                 if(c4 >= 0 && (c4 < smallestteam_count || (c4 <= smallestteam_count && team4_score < smallestteam_score)))
 802                 {
 803                         smallestteam = 4;
 804                         smallestteam_count = c4;
 805                         smallestteam_score = team4_score;
 806                 }
 807         }
 808         else
 809         {
 810                 if(c1 >= 0 && (c1 < smallestteam_count ||
 811                                         (c1 == smallestteam_count && self.team == COLOR_TEAM1) ) )
 812                 {
 813                         smallestteam = 1;
 814                         smallestteam_count = c1;
 815                 }
 816                 if(c2 >= 0 && c2 < (c2 < smallestteam_count ||
 817                                         (c2 == smallestteam_count && self.team == COLOR_TEAM2) ) )
 818                 {
 819                         smallestteam = 2;
 820                         smallestteam_count = c2;
 821                 }
 822                 if(c3 >= 0 && c3 < (c3 < smallestteam_count ||
 823                                         (c3 == smallestteam_count && self.team == COLOR_TEAM3) ) )
 824                 {
 825                         smallestteam = 3;
 826                         smallestteam_count = c3;
 827                 }
 828                 if(c4 >= 0 && c4 < (c4 < smallestteam_count ||
 829                                         (c4 == smallestteam_count && self.team == COLOR_TEAM4) ) )
 830                 {
 831                         smallestteam = 4;
 832                         smallestteam_count = c4;
 833                 }
 834         }
 835
 836         return smallestteam;
 837 }
 838
 839 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 840 {
 841         float smallest, selectedteam;
 842
 843         // don't join a team if we're not playing a team game
 844         if(!teams_matter)
 845                 return 0;
 846
 847         // find out what teams are available
 848         CheckAllowedTeams(pl);
 849
 850         if(g_domination)
 851         {
 852                 // <div0> WHY? TODO
 853                 if(cvar("g_domination_default_teams") < 3)
 854                         c3 = 999999999;
 855                 if(cvar("g_domination_default_teams") < 4)
 856                         c4 = 999999999;
 857         }
 858
 859         // if we don't care what team he ends up on, put him on whatever team he entered as.
 860         // if he's not on a valid team, then let other code put him on the smallest team
 861         if(!forcebestteam)
 862         {
 863                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 864                         selectedteam = pl.team;
 865                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 866                         selectedteam = pl.team;
 867                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 868                         selectedteam = pl.team;
 869                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 870                         selectedteam = pl.team;
 871                 else
 872                         selectedteam = -1;
 873                 if(selectedteam > 0)
 874                 {
 875                         if(!only_return_best)
 876                         {
 877                                 SetPlayerColors(pl, selectedteam - 1);
 878                                 LogTeamchange(pl);
 879                         }
 880                         return selectedteam;
 881                 }
 882                 // otherwise end up on the smallest team (handled below)
 883         }
 884
 885         smallest = FindSmallestTeam(pl, TRUE);
 886
 887
 888         if(!only_return_best)
 889         {
 890                 TeamchangeFrags(self);
 891                 if(smallest == 1)
 892                 {
 893                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 894                 }
 895                 else if(smallest == 2)
 896                 {
 897                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 898                 }
 899                 else if(smallest == 3)
 900                 {
 901                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 902                 }
 903                 else if(smallest == 4)
 904                 {
 905                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 906                 }
 907                 else
 908                 {
 909                         error("smallest team: invalid team\n");
 910                 }
 911                 LogTeamchange(pl);
 912                 if(pl.deadflag == DEAD_NO)
 913                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 914         }
 915
 916         return smallest;
 917 }
 918
 919 //void() ctf_playerchanged;
 920 void SV_ChangeTeam(float _color)
 921 {
 922         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 923
 924         // in normal deathmatch we can just apply the color and we're done
 925         if(!teams_matter) {
 926                 SetPlayerColors(self, _color);
 927                 return;
 928         }
 929
 930         scolor = self.clientcolors & 0x0F;
 931         dcolor = _color & 0x0F;
 932
 933         if(scolor == COLOR_TEAM1 - 1)
 934                 steam = 1;
 935         else if(scolor == COLOR_TEAM2 - 1)
 936                 steam = 2;
 937         else if(scolor == COLOR_TEAM3 - 1)
 938                 steam = 3;
 939         else // if(scolor == COLOR_TEAM4 - 1)
 940                 steam = 4;
 941         if(dcolor == COLOR_TEAM1 - 1)
 942                 dteam = 1;
 943         else if(dcolor == COLOR_TEAM2 - 1)
 944                 dteam = 2;
 945         else if(dcolor == COLOR_TEAM3 - 1)
 946                 dteam = 3;
 947         else // if(dcolor == COLOR_TEAM4 - 1)
 948                 dteam = 4;
 949
 950         CheckAllowedTeams(self);
 951
 952         if(dteam == 1 && c1 < 0) dteam = 4;
 953         if(dteam == 4 && c4 < 0) dteam = 3;
 954         if(dteam == 3 && c3 < 0) dteam = 2;
 955         if(dteam == 2 && c2 < 0) dteam = 1;
 956
 957         // not changing teams
 958         if(scolor == dcolor)
 959         {
 960                 //bprint("same team change\n");
 961                 SetPlayerTeam(self, dteam, steam, TRUE);
 962                 return;
 963         }
 964
 965         if(cvar("g_campaign"))
 966         {
 967                 sprint(self, "Team changes not allowed\n");
 968                 return; // changing teams is not allowed
 969         }
 970
 971         if(cvar("g_changeteam_banned") && self.wasplayer)
 972         {
 973                 sprint(self, "Team changes not allowed\n");
 974                 return;
 975         }
 976
 977         if(cvar("g_balance_teams_prevent_imbalance"))
 978         {
 979                 // only allow changing to a smaller or equal size team
 980
 981                 // find out what teams are available
 982                 //CheckAllowedTeams();
 983                 // count how many players on each team
 984                 GetTeamCounts(world);
 985
 986                 // get desired team
 987                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 988                 {
 989                         dcount = c1;
 990                         dbotcount = cb1;
 991                 }
 992                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 993                 {
 994                         dcount = c2;
 995                         dbotcount = cb2;
 996                 }
 997                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
 998                 {
 999                         dcount = c3;
1000                         dbotcount = cb3;
1001                 }
1002                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1003                 {
1004                         dcount = c4;
1005                         dbotcount = cb4;
1006                 }
1007                 else
1008                 {
1009                         sprint(self, "Cannot change to an invalid team\n");
1010
1011                         return;
1012                 }
1013
1014                 // get starting team
1015                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1016                         scount = c1;
1017                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1018                         scount = c2;
1019                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1020                         scount = c3;
1021                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1022                         scount = c4;
1023
1024                 if(scount) // started at a valid, nonempty team
1025                 {
1026                         // check if we're trying to change to a larger team that doens't have bots to swap with
1027                         if(dcount >= scount && dbotcount <= 0)
1028                         {
1029                                 sprint(self, "Cannot change to a larger team\n");
1030                                 return; // can't change to a larger team
1031                         }
1032                 }
1033         }
1034
1035 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1036
1037         if(self.classname == "player" && steam != dteam)
1038         {
1039                 // reduce frags during a team change
1040                 TeamchangeFrags(self);
1041         }
1042
1043         SetPlayerTeam(self, dteam, steam, FALSE);
1044
1045         if(self.classname == "player" && steam != dteam)
1046         {
1047                 // kill player when changing teams
1048                 if(self.deadflag == DEAD_NO)
1049                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1050         }
1051         //ctf_playerchanged();
1052 }
1053
1054 void ShufflePlayerOutOfTeam (float source_team)
1055 {
1056         float smallestteam, smallestteam_count, steam;
1057         float lowest_bot_score, lowest_player_score;
1058         entity head, lowest_bot, lowest_player, selected;
1059
1060         smallestteam = 0;
1061         smallestteam_count = 999999999;
1062
1063         if(c1 >= 0 && c1 < smallestteam_count)
1064         {
1065                 smallestteam = 1;
1066                 smallestteam_count = c1;
1067         }
1068         if(c2 >= 0 && c2 < smallestteam_count)
1069         {
1070                 smallestteam = 2;
1071                 smallestteam_count = c2;
1072         }
1073         if(c3 >= 0 && c3 < smallestteam_count)
1074         {
1075                 smallestteam = 3;
1076                 smallestteam_count = c3;
1077         }
1078         if(c4 >= 0 && c4 < smallestteam_count)
1079         {
1080                 smallestteam = 4;
1081                 smallestteam_count = c4;
1082         }
1083
1084         if(!smallestteam)
1085         {
1086                 bprint("warning: no smallest team\n");
1087                 return;
1088         }
1089
1090         if(source_team == 1)
1091                 steam = COLOR_TEAM1;
1092         else if(source_team == 2)
1093                 steam = COLOR_TEAM2;
1094         else if(source_team == 3)
1095                 steam = COLOR_TEAM3;
1096         else if(source_team == 4)
1097                 steam = COLOR_TEAM4;
1098
1099         lowest_bot = world;
1100         lowest_bot_score = 999999999;
1101         lowest_player = world;
1102         lowest_player_score = 999999999;
1103
1104         // find the lowest-scoring player & bot of that team
1105         FOR_EACH_PLAYER(head)
1106         {
1107                 if(head.team == steam)
1108                 {
1109                         if(head.isbot)
1110                         {
1111                                 if(head.totalfrags < lowest_bot_score)
1112                                 {
1113                                         lowest_bot = head;
1114                                         lowest_bot_score = head.totalfrags;
1115                                 }
1116                         }
1117                         else
1118                         {
1119                                 if(head.totalfrags < lowest_player_score)
1120                                 {
1121                                         lowest_player = head;
1122                                         lowest_player_score = head.totalfrags;
1123                                 }
1124                         }
1125                 }
1126         }
1127
1128         // prefers to move a bot...
1129         if(lowest_bot != world)
1130                 selected = lowest_bot;
1131         // but it will move a player if it has to
1132         else
1133                 selected = lowest_player;
1134         // don't do anything if it couldn't find anyone
1135         if(!selected)
1136         {
1137                 bprint("warning: couldn't find a player to move from team\n");
1138                 return;
1139         }
1140
1141         // smallest team gains a member
1142         if(smallestteam == 1)
1143         {
1144                 c1 = c1 + 1;
1145         }
1146         else if(smallestteam == 2)
1147         {
1148                 c2 = c2 + 1;
1149         }
1150         else if(smallestteam == 3)
1151         {
1152                 c3 = c3 + 1;
1153         }
1154         else if(smallestteam == 4)
1155         {
1156                 c4 = c4 + 1;
1157         }
1158         else
1159         {
1160                 bprint("warning: destination team invalid\n");
1161                 return;
1162         }
1163         // source team loses a member
1164         if(source_team == 1)
1165         {
1166                 c1 = c1 + 1;
1167         }
1168         else if(source_team == 2)
1169         {
1170                 c2 = c2 + 2;
1171         }
1172         else if(source_team == 3)
1173         {
1174                 c3 = c3 + 3;
1175         }
1176         else if(source_team == 4)
1177         {
1178                 c4 = c4 + 4;
1179         }
1180         else
1181         {
1182                 bprint("warning: source team invalid\n");
1183                 return;
1184         }
1185
1186         // move the player to the new team
1187         TeamchangeFrags(selected);
1188         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1189
1190         if(selected.deadflag == DEAD_NO)
1191                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1192         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1193 }
1194
1195 void CauseRebalance(float source_team, float howmany_toomany)
1196 {
1197         if(IsTeamBalanceForced() == 1)
1198         {
1199                 bprint("Rebalancing Teams\n");
1200                 ShufflePlayerOutOfTeam(source_team);
1201         }
1202 }
1203
1204 // part of g_balance_teams_force
1205 // occasionally perform an audit of the teams to make
1206 // sure they're more or less balanced in player count.
1207 void AuditTeams()
1208 {
1209         float numplayers, numteams, smallest, toomany;
1210         float balance;
1211         balance = IsTeamBalanceForced();
1212         if(balance == 0)
1213                 return;
1214
1215         if(audit_teams_time > time)
1216                 return;
1217
1218         audit_teams_time = time + 4 + random();
1219
1220 //      bprint("Auditing teams\n");
1221
1222         CheckAllowedTeams(world);
1223         GetTeamCounts(world);
1224
1225
1226         numteams = numplayers = smallest = 0;
1227         if(c1 >= 0)
1228         {
1229                 numteams = numteams + 1;
1230                 numplayers = numplayers + c1;
1231                 smallest = c1;
1232         }
1233         if(c2 >= 0)
1234         {
1235                 numteams = numteams + 1;
1236                 numplayers = numplayers + c2;
1237                 if(c2 < smallest)
1238                         smallest = c2;
1239         }
1240         if(c3 >= 0)
1241         {
1242                 numteams = numteams + 1;
1243                 numplayers = numplayers + c3;
1244                 if(c3 < smallest)
1245                         smallest = c3;
1246         }
1247         if(c4 >= 0)
1248         {
1249                 numteams = numteams + 1;
1250                 numplayers = numplayers + c4;
1251                 if(c4 < smallest)
1252                         smallest = c4;
1253         }
1254
1255         if(numplayers <= 0)
1256                 return; // no players to move around
1257         if(numteams < 2)
1258                 return; // don't bother shuffling if for some reason there aren't any teams
1259
1260         toomany = smallest + 1;
1261
1262         if(c1 && c1 > toomany)
1263                 CauseRebalance(1, c1 - toomany);
1264         if(c2 && c2 > toomany)
1265                 CauseRebalance(2, c2 - toomany);
1266         if(c3 && c3 > toomany)
1267                 CauseRebalance(3, c3 - toomany);
1268         if(c4 && c4 > toomany)
1269                 CauseRebalance(4, c4 - toomany);
1270
1271         // if teams are still unbalanced, balance them further in the next audit,
1272         // which will happen sooner (keep doing rapid audits until things are in order)
1273         audit_teams_time = time + 0.7 + random()*0.3;
1274 }
1275
1276 // code from here on is just to support maps that don't have team entities
1277 void tdm_spawnteam (string teamname, float teamcolor)
1278 {
1279         local entity e;
1280         e = spawn();
1281         e.classname = "tdm_team";
1282         e.netname = teamname;
1283         e.cnt = teamcolor;
1284         e.team = e.cnt + 1;
1285 };
1286
1287 // spawn some default teams if the map is not set up for tdm
1288 void tdm_spawnteams()
1289 {
1290         float numteams;
1291
1292         numteams = cvar("g_tdm_teams");
1293
1294         tdm_spawnteam("Red", COLOR_TEAM1-1);
1295         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1296         if(numteams >= 3)
1297                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1298         if(numteams >= 4)
1299                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1300 };
1301
1302 void tdm_delayedinit()
1303 {
1304         // if no teams are found, spawn defaults
1305         if (find(world, classname, "tdm_team") == world)
1306                 tdm_spawnteams();
1307 };
1308
1309 void tdm_init()
1310 {
1311         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1312 };