data/qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!cvar("teamplay"))
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void entcs_init();
  73
  74 void LogTeamchange(entity pl)
  75 {
  76         string str;
  77         if(!cvar("sv_eventlog"))
  78                 return;
  79         if(pl.playerid < 1)
  80                 return;
  81         str = strcat(":team:", ftos(pl.playerid), ":");
  82         str = strcat(str, ftos(pl.team));
  83         GameLogEcho(str);
  84 }
  85
  86 void WriteGameCvars()
  87 {
  88         cvar_set("g_dm", ftos(g_dm));
  89         cvar_set("g_tdm", ftos(g_tdm));
  90         cvar_set("g_domination", ftos(g_domination));
  91         cvar_set("g_ctf", ftos(g_ctf));
  92         cvar_set("g_runematch", ftos(g_runematch));
  93         cvar_set("g_lms", ftos(g_lms));
  94         cvar_set("g_arena", ftos(g_arena));
  95         cvar_set("g_keyhunt", ftos(g_keyhunt));
  96         cvar_set("g_assault", ftos(g_assault));
  97         cvar_set("g_onslaught", ftos(g_onslaught));
  98         cvar_set("g_race", ftos(g_race));
  99 }
 100
 101 void ReadGameCvars()
 102 {
 103         float found;
 104         float prev;
 105         float i;
 106
 107         found = 0;
 108         prev = cvar("gamecfg");
 109         for(i = 0; i < 2; ++i)
 110         {
 111                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 112                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 113                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 114                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 115                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 116                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 117                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 118                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 119                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 120                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 121                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 122
 123                 if(found)
 124                         break;
 125
 126                 prev = -1; // second attempt takes place WITHOUT prev set
 127         }
 128
 129         if(!found)
 130                 g_dm = 1;
 131
 132         if(g_dm && cvar("deathmatch_force_teamplay"))
 133         {
 134                 g_dm = 0;
 135                 g_tdm = 1;
 136         }
 137
 138         teams_matter = 0;
 139 }
 140
 141 void default_delayedinit()
 142 {
 143         if(!scores_initialized)
 144                 ScoreRules_generic();
 145 }
 146
 147 void ActivateTeamplay()
 148 {
 149         float teamplay_default;
 150         teamplay_default = cvar("teamplay_default");
 151
 152         if(teamplay_default)
 153                 teamplay = teamplay_default;
 154         else
 155                 teamplay = 3;
 156         cvar_set("teamplay", ftos(teamplay));
 157
 158         teams_matter = 1;
 159 }
 160
 161 void InitGameplayMode()
 162 {
 163         float fraglimit_override, timelimit_override;
 164
 165         VoteReset();
 166
 167         teams_matter = 0;
 168         cvar_set("teamplay", "0");
 169
 170         // make sure only ONE type is selected
 171         ReadGameCvars();
 172         WriteGameCvars();
 173
 174         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 175         get_mi_min_max(1);
 176         world.mins = mi_min;
 177         world.maxs = mi_max;
 178
 179         MapInfo_LoadMapSettings(mapname);
 180
 181         if not(cvar_value_issafe(world.fog))
 182         {
 183                 print("The current map contains a potentially harmful fog setting, ignored\n");
 184                 world.fog = string_null;
 185         }
 186         if(MapInfo_Map_fog != "")
 187                 if(MapInfo_Map_fog == "none")
 188                         world.fog = string_null;
 189                 else
 190                         world.fog = strzone(MapInfo_Map_fog);
 191         clientstuff = strzone(MapInfo_Map_clientstuff);
 192         MapInfo_ClearTemps();
 193
 194         // in case mapinfo switched the type
 195         ReadGameCvars();
 196
 197         // set both here, gamemode can override it later
 198         timelimit_override = cvar("timelimit_override");
 199         fraglimit_override = cvar("fraglimit_override");
 200
 201         if(g_dm)
 202         {
 203                 game = GAME_DEATHMATCH;
 204                 gamemode_name = "Deathmatch";
 205         }
 206
 207         if(g_tdm)
 208         {
 209                 game = GAME_TEAM_DEATHMATCH;
 210                 gamemode_name = "Team Deathmatch";
 211                 ActivateTeamplay();
 212                 tdm_init();
 213         }
 214
 215         if(g_domination)
 216         {
 217                 game = GAME_DOMINATION;
 218                 gamemode_name = "Domination";
 219                 ActivateTeamplay();
 220                 fraglimit_override = cvar("g_domination_point_limit");
 221                 dom_init();
 222         }
 223
 224         if(g_ctf)
 225         {
 226                 game = GAME_CTF;
 227                 gamemode_name = "Capture the Flag";
 228                 ActivateTeamplay();
 229                 if(cvar("g_campaign"))
 230                         g_ctf_win_mode = 2;
 231                 else
 232                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 233                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 234                 if(g_ctf_win_mode == 2)
 235                         fraglimit_override = cvar("g_ctf_capture_limit");
 236                 else
 237                         fraglimit_override = cvar("capturelimit_override");
 238                 ctf_init();
 239         }
 240
 241         if(g_runematch)
 242         {
 243                 game = GAME_RUNEMATCH;
 244                 gamemode_name = "Rune Match";
 245                 if(cvar("deathmatch_force_teamplay"))
 246                         ActivateTeamplay();
 247                 fraglimit_override = cvar("g_runematch_point_limit");
 248                 runematch_init();
 249         }
 250
 251         if(g_lms)
 252         {
 253                 game = GAME_LMS;
 254                 gamemode_name = "Last Man Standing";
 255                 fraglimit_override = cvar("g_lms_lives_override");
 256                 if(fraglimit_override == 0)
 257                         fraglimit_override = -1;
 258                 lms_lowest_lives = 9999;
 259                 lms_next_place = 0;
 260                 ScoreRules_lms();
 261         }
 262
 263         if(g_arena)
 264         {
 265                 game = GAME_ARENA;
 266                 gamemode_name = "Arena";
 267                 fraglimit_override = cvar("g_arena_point_limit");
 268                 maxspawned = cvar("g_arena_maxspawned");
 269                 if(maxspawned < 2)
 270                         maxspawned = 2;
 271                 arena_roundbased = cvar("g_arena_roundbased");
 272         }
 273
 274         if(g_keyhunt)
 275         {
 276                 game = GAME_KEYHUNT;
 277                 gamemode_name = "Key Hunt";
 278                 ActivateTeamplay();
 279                 fraglimit_override = cvar("g_keyhunt_point_limit");
 280                 kh_init();
 281         }
 282
 283         if(g_assault)
 284         {
 285                 game = GAME_ASSAULT;
 286                 gamemode_name = "Assault";
 287                 ActivateTeamplay();
 288                 ScoreRules_assault();
 289         }
 290
 291         if(g_onslaught)
 292         {
 293                 game = GAME_ONSLAUGHT;
 294                 gamemode_name = "Onslaught";
 295                 ActivateTeamplay();
 296         }
 297
 298         if(g_race)
 299         {
 300                 game = GAME_RACE;
 301                 gamemode_name = "Race";
 302                 g_race_qualifying = cvar("g_race_qualifying");
 303
 304                 if(cvar("g_race_teams"))
 305                 {
 306                         g_race_qualifying = 0; // not supported!
 307                         ActivateTeamplay();
 308                         race_teams = bound(2, cvar("g_race_teams"), 4);
 309                 }
 310                 else
 311                         race_teams = 0;
 312
 313                 if(g_race_qualifying == 1)
 314                         fraglimit_override = 0;
 315                 else
 316                         fraglimit_override = cvar("g_race_laps_limit");
 317
 318                 if(g_race_qualifying)
 319                         independent_players = 1;
 320
 321                 ScoreRules_race();
 322         }
 323
 324         if(teams_matter)
 325                 entcs_init();
 326
 327         // save it (for the next startup)
 328         cvar_set("gamecfg", ftos(game));
 329
 330         cache_mutatormsg = strzone("");
 331         cache_lastmutatormsg = strzone("");
 332
 333         // enforce the server's universal frag/time limits
 334         if(!cvar("g_campaign"))
 335         {
 336                 if(fraglimit_override >= 0)
 337                         cvar_set("fraglimit", ftos(fraglimit_override));
 338                 if(timelimit_override >= 0)
 339                         cvar_set("timelimit", ftos(timelimit_override));
 340         }
 341
 342         if(g_race && g_race_qualifying == 2)
 343         {
 344                 race_fraglimit = cvar("fraglimit");
 345                 cvar_set("fraglimit", "0");
 346         }
 347
 348         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 349 }
 350
 351 string GetClientVersionMessage() {
 352         local string versionmsg;
 353         if (self.version_mismatch) {
 354                 if(self.version < cvar("gameversion")) {
 355                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 356                 } else {
 357                         versionmsg = "^3This server is using an outdated Nexuiz version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 358                 }
 359         } else {
 360                 versionmsg = "^2client version and server version are compatible.^8";
 361         }
 362         return versionmsg;
 363 }
 364
 365
 366 void PrintWelcomeMessage(entity pl)
 367 {
 368         string s, modifications, motd;
 369
 370         if(self.cvar_scr_centertime == 0) return;
 371         if((time - self.jointime) > cvar("welcome_message_time")
 372            && !self.BUTTON_INFO)
 373                 return;
 374
 375         if( !(timeoutStatus >= 1 || (time < game_starttime) ) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 376                 if(self.welcomemessage_time > time) return;
 377                 self.welcomemessage_time = time + self.cvar_scr_centertime * 0.6;
 378         }
 379
 380         if(cvar("g_campaign"))
 381         {
 382                 centerprint(pl, campaign_message);
 383                 return;
 384         }
 385
 386 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 387         if(!self.BUTTON_INFO)
 388         {
 389                 // TODO get rid of this too
 390                 local string specString;
 391                 specString = NEWLINES;
 392                 //if(time < game_starttime) //also show the countdown when being a spectator
 393                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 394                 //else
 395                 if (timeoutStatus != 0)
 396                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 397                 else
 398                 {
 399                         if(!self.BUTTON_INFO && self.classname == "player")
 400                                 return;
 401                         goto normal;
 402                 }
 403                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 404         }
 405
 406 :normal
 407         modifications = "";
 408         if(g_minstagib)
 409                 modifications = strcat(modifications, ", MinstaGib");
 410         if(g_nixnex)
 411                 modifications = strcat(modifications, ", NixNex");
 412         if(g_weaponarena)
 413                 modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 414         if(cvar("sv_gravity") < 800)
 415                 modifications = strcat(modifications, ", Low gravity");
 416         if(g_cloaked)
 417                 modifications = strcat(modifications, ", Cloaked");
 418         if(g_footsteps)
 419                 modifications = strcat(modifications, ", Steps");
 420         if(g_grappling_hook)
 421                 modifications = strcat(modifications, ", Hook");
 422         if(g_laserguided_missile)
 423                 modifications = strcat(modifications, ", LG missiles");
 424         if(g_midair)
 425                 modifications = strcat(modifications, ", Midair");
 426         if(g_vampire)
 427                 modifications = strcat(modifications, ", Vampire");
 428         if(g_pinata)
 429                 modifications = strcat(modifications, ", Pinata");
 430         if(g_weapon_stay)
 431                 modifications = strcat(modifications, ", Weapons stay");
 432         if(g_bloodloss > 0)
 433                 modifications = strcat(modifications, ", Bloodloss");
 434         modifications = substring(modifications, 2, strlen(modifications) - 2);
 435
 436         local string versionmessage;
 437         versionmessage = GetClientVersionMessage();
 438
 439         s = strcat(s, NEWLINES, "This is Nexuiz ", cvar_string("g_nexuizversion"), "\n", versionmessage);
 440         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 441
 442         if(modifications != "")
 443                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 444
 445         if(timeoutStatus != 0)
 446                 s = strcat(s, "\n\n", getTimeoutText(1));
 447
 448         if (g_grappling_hook)
 449                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 450
 451         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 452         {
 453                 if(cache_lastmutatormsg)
 454                         strunzone(cache_lastmutatormsg);
 455                 if(cache_mutatormsg)
 456                         strunzone(cache_mutatormsg);
 457                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 458                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 459         }
 460
 461         if (cache_mutatormsg != "") {
 462                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 463         }
 464
 465         motd = cvar_string("sv_motd");
 466         if (motd != "") {
 467                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 468         }
 469         s = strcat(s, "\n");
 470
 471         centerprint(pl, s);
 472 }
 473
 474
 475 void SetPlayerColors(entity pl, float _color)
 476 {
 477         /*string s;
 478         s = ftos(cl);
 479         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 480         pl.team = cl + 1;
 481         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 482         pl.clientcolors = 16*cl + cl;*/
 483
 484         float pants, shirt;
 485         pants = _color & 0x0F;
 486         shirt = _color & 0xF0;
 487
 488
 489         if(teamplay) {
 490                 setcolor(pl, 16*pants + pants);
 491         } else {
 492                 setcolor(pl, shirt + pants);
 493         }
 494 }
 495
 496 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 497 {
 498         float _color;
 499
 500         if(t == 4)
 501                 _color = COLOR_TEAM4 - 1;
 502         else if(t == 3)
 503                 _color = COLOR_TEAM3 - 1;
 504         else if(t == 2)
 505                 _color = COLOR_TEAM2 - 1;
 506         else
 507                 _color = COLOR_TEAM1 - 1;
 508
 509         SetPlayerColors(pl,_color);
 510
 511         if(!noprint && t != s)
 512         {
 513                 //bprint(pl.netname, " has changed to ", TeamNoName(t), "\n");
 514                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 515         }
 516
 517         if(t != s)
 518                 LogTeamchange(pl);
 519 }
 520
 521
 522
 523
 524
 525
 526 // set c1...c4 to show what teams are allowed
 527 void CheckAllowedTeams (entity for_whom)
 528 {
 529         string teament_name;
 530         float dm;
 531         entity head;
 532
 533 //      if(!dom && !ctf)
 534 //              dm = 1;
 535
 536         c1 = c2 = c3 = c4 = -1;
 537         cb1 = cb2 = cb3 = cb4 = 0;
 538
 539         // onslaught is special
 540         if(g_onslaught)
 541         {
 542                 head = findchain(classname, "onslaught_generator");
 543                 while (head)
 544                 {
 545                         if (head.team == COLOR_TEAM1) c1 = 0;
 546                         if (head.team == COLOR_TEAM2) c2 = 0;
 547                         if (head.team == COLOR_TEAM3) c3 = 0;
 548                         if (head.team == COLOR_TEAM4) c4 = 0;
 549                         head = head.chain;
 550                 }
 551                 return;
 552         }
 553
 554         if(g_domination)
 555                 teament_name = "dom_team";
 556         else if(g_ctf)
 557                 teament_name = "ctf_team";
 558         else if(g_tdm)
 559                 teament_name = "tdm_team";
 560         else if(g_assault)
 561         {
 562                 c1 = c2 = 0; // Assault always has 2 teams
 563                 return;
 564         }
 565         else
 566         {
 567                 // cover anything else by treating it like tdm with no teams spawned
 568                 if(g_keyhunt)
 569                         dm = kh_teams;
 570                 else if(g_race)
 571                         dm = race_teams;
 572                 else
 573                         dm = cvar("g_tdm_teams");
 574                 if(dm < 2)
 575                         error("g_tdm_teams < 2, not enough teams to play team deathmatch\n");
 576
 577                 if(dm >= 4)
 578                 {
 579                         c1 = c2 = c3 = c4 = 0;
 580                 }
 581                 else if(dm >= 3)
 582                 {
 583                         c1 = c2 = c3 = 0;
 584                 }
 585                 else// if(dm >= 2)
 586                 {
 587                         c1 = c2 = 0;
 588                 }
 589                 return;
 590         }
 591
 592         // first find out what teams are allowed
 593         head = find(world, classname, teament_name);
 594         while(head)
 595         {
 596                 if(!(g_domination && head.netname == ""))
 597                 {
 598                         if(head.team == COLOR_TEAM1)
 599                         {
 600                                 c1 = 0;
 601                         }
 602                         if(head.team == COLOR_TEAM2)
 603                         {
 604                                 c2 = 0;
 605                         }
 606                         if(head.team == COLOR_TEAM3)
 607                         {
 608                                 c3 = 0;
 609                         }
 610                         if(head.team == COLOR_TEAM4)
 611                         {
 612                                 c4 = 0;
 613                         }
 614                 }
 615                 head = find(head, classname, teament_name);
 616         }
 617
 618         if(for_whom)
 619         {
 620                 if(cvar("bot_vs_human") > 0)
 621                 {
 622                         // bots are all blue
 623                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 624                                 c1 = c3 = c4 = -1;
 625                         else
 626                                 c2 = -1;
 627                 }
 628                 else if(cvar("bot_vs_human") < 0)
 629                 {
 630                         // bots are all red
 631                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 632                                 c2 = c3 = c4 = -1;
 633                         else
 634                                 c1 = -1;
 635                 }
 636         }
 637 }
 638
 639 float PlayerValue(entity p)
 640 {
 641         if(IsTeamBalanceForced() == 1)
 642                 return 1;
 643         return 1;
 644 }
 645
 646 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 647 // teams that are allowed will now have their player counts stored in c1...c4
 648 void GetTeamCounts(entity ignore)
 649 {
 650         entity head;
 651         float value, bvalue;
 652         // now count how many players are on each team already
 653
 654         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 655         // also remember the lowest-scoring player
 656
 657         FOR_EACH_PLAYER(head)
 658         {
 659                 if(head != ignore)// && head.netname != "")
 660                 {
 661                         value = PlayerValue(head);
 662                         if(clienttype(head) == CLIENTTYPE_BOT)
 663                                 bvalue = value;
 664                         else
 665                                 bvalue = 0;
 666                         if(head.team == COLOR_TEAM1)
 667                         {
 668                                 if(c1 >= 0)
 669                                 {
 670                                         c1 = c1 + value;
 671                                         cb1 = cb1 + bvalue;
 672                                 }
 673                         }
 674                         if(head.team == COLOR_TEAM2)
 675                         {
 676                                 if(c2 >= 0)
 677                                 {
 678                                         c2 = c2 + value;
 679                                         cb2 = cb2 + bvalue;
 680                                 }
 681                         }
 682                         if(head.team == COLOR_TEAM3)
 683                         {
 684                                 if(c3 >= 0)
 685                                 {
 686                                         c3 = c3 + value;
 687                                         cb3 = cb3 + bvalue;
 688                                 }
 689                         }
 690                         if(head.team == COLOR_TEAM4)
 691                         {
 692                                 if(c4 >= 0)
 693                                 {
 694                                         c4 = c4 + value;
 695                                         cb4 = cb4 + bvalue;
 696                                 }
 697                         }
 698                 }
 699         }
 700 }
 701
 702 // returns # of smallest team (1, 2, 3, 4)
 703 // NOTE: Assumes CheckAllowedTeams has already been called!
 704 float FindSmallestTeam(entity pl, float ignore_pl)
 705 {
 706         float totalteams, smallestteam, smallestteam_count, smallestteam_score, balance_type;
 707         totalteams = 0;
 708
 709         // find out what teams are available
 710         //CheckAllowedTeams();
 711
 712         // make sure there are at least 2 teams to join
 713         if(c1 >= 0)
 714                 totalteams = totalteams + 1;
 715         if(c2 >= 0)
 716                 totalteams = totalteams + 1;
 717         if(c3 >= 0)
 718                 totalteams = totalteams + 1;
 719         if(c4 >= 0)
 720                 totalteams = totalteams + 1;
 721
 722         if(cvar("bot_vs_human"))
 723                 totalteams += 1;
 724
 725         if(totalteams <= 1)
 726         {
 727                 if(g_domination)
 728                         error("Too few teams available for domination\n");
 729                 else if(g_ctf)
 730                         error("Too few teams available for ctf\n");
 731                 else if(g_keyhunt)
 732                         error("Too few teams available for key hunt\n");
 733                 else
 734                         error("Too few teams available for team deathmatch\n");
 735         }
 736
 737         // count how many players are in each team
 738         if(ignore_pl)
 739                 GetTeamCounts(pl);
 740         else
 741                 GetTeamCounts(world);
 742
 743         // c1...c4 now have counts of each team
 744         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 745
 746         smallestteam = 0;
 747         smallestteam_count = 999999999;
 748         smallestteam_score = 999999999;
 749
 750         // 2 gives priority to what team you're already on, 1 goes in order
 751         // 2 doesn't seem to work though...
 752         balance_type = 1;
 753
 754         if(bots_would_leave)
 755         //if(pl.classname != "player")
 756         if(clienttype(pl) != CLIENTTYPE_BOT)
 757         {
 758                 c1 -= cb1 * 255.0/256;
 759                 c2 -= cb2 * 255.0/256;
 760                 c3 -= cb3 * 255.0/256;
 761                 c4 -= cb4 * 255.0/256;
 762         }
 763
 764         if(balance_type == 1)
 765         {
 766                 if(c1 >= 0 && (c1 < smallestteam_count || (c1 <= smallestteam_count && team1_score < smallestteam_score)))
 767                 {
 768                         smallestteam = 1;
 769                         smallestteam_count = c1;
 770                         smallestteam_score = team1_score;
 771                 }
 772                 if(c2 >= 0 && (c2 < smallestteam_count || (c2 <= smallestteam_count && team2_score < smallestteam_score)))
 773                 {
 774                         smallestteam = 2;
 775                         smallestteam_count = c2;
 776                         smallestteam_score = team2_score;
 777                 }
 778                 if(c3 >= 0 && (c3 < smallestteam_count || (c3 <= smallestteam_count && team3_score < smallestteam_score)))
 779                 {
 780                         smallestteam = 3;
 781                         smallestteam_count = c3;
 782                         smallestteam_score = team3_score;
 783                 }
 784                 if(c4 >= 0 && (c4 < smallestteam_count || (c4 <= smallestteam_count && team4_score < smallestteam_score)))
 785                 {
 786                         smallestteam = 4;
 787                         smallestteam_count = c4;
 788                         smallestteam_score = team4_score;
 789                 }
 790         }
 791         else
 792         {
 793                 if(c1 >= 0 && (c1 < smallestteam_count ||
 794                                         (c1 == smallestteam_count && self.team == COLOR_TEAM1) ) )
 795                 {
 796                         smallestteam = 1;
 797                         smallestteam_count = c1;
 798                 }
 799                 if(c2 >= 0 && c2 < (c2 < smallestteam_count ||
 800                                         (c2 == smallestteam_count && self.team == COLOR_TEAM2) ) )
 801                 {
 802                         smallestteam = 2;
 803                         smallestteam_count = c2;
 804                 }
 805                 if(c3 >= 0 && c3 < (c3 < smallestteam_count ||
 806                                         (c3 == smallestteam_count && self.team == COLOR_TEAM3) ) )
 807                 {
 808                         smallestteam = 3;
 809                         smallestteam_count = c3;
 810                 }
 811                 if(c4 >= 0 && c4 < (c4 < smallestteam_count ||
 812                                         (c4 == smallestteam_count && self.team == COLOR_TEAM4) ) )
 813                 {
 814                         smallestteam = 4;
 815                         smallestteam_count = c4;
 816                 }
 817         }
 818
 819         return smallestteam;
 820 }
 821
 822 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 823 {
 824         float smallest, selectedteam;
 825
 826         // don't join a team if we're not playing a team game
 827         if(!cvar("teamplay") && !g_domination && !g_ctf && !g_keyhunt)
 828                 return 0;
 829
 830         // find out what teams are available
 831         CheckAllowedTeams(pl);
 832
 833         if(g_domination)
 834         {
 835                 // <div0> WHY? TODO
 836                 if(cvar("g_domination_default_teams") < 3)
 837                         c3 = 999999999;
 838                 if(cvar("g_domination_default_teams") < 4)
 839                         c4 = 999999999;
 840         }
 841
 842         // if we don't care what team he ends up on, put him on whatever team he entered as.
 843         // if he's not on a valid team, then let other code put him on the smallest team
 844         if(!forcebestteam)
 845         {
 846                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 847                         selectedteam = pl.team;
 848                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 849                         selectedteam = pl.team;
 850                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 851                         selectedteam = pl.team;
 852                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 853                         selectedteam = pl.team;
 854                 else
 855                         selectedteam = -1;
 856                 if(selectedteam > 0)
 857                 {
 858                         if(!only_return_best)
 859                         {
 860                                 SetPlayerColors(pl, selectedteam - 1);
 861                                 LogTeamchange(pl);
 862                         }
 863                         return selectedteam;
 864                 }
 865                 // otherwise end up on the smallest team (handled below)
 866         }
 867
 868         smallest = FindSmallestTeam(pl, TRUE);
 869
 870
 871         if(!only_return_best)
 872         {
 873                 TeamchangeFrags(self);
 874                 if(smallest == 1)
 875                 {
 876                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 877                 }
 878                 else if(smallest == 2)
 879                 {
 880                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 881                 }
 882                 else if(smallest == 3)
 883                 {
 884                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 885                 }
 886                 else if(smallest == 4)
 887                 {
 888                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 889                 }
 890                 else
 891                 {
 892                         error("smallest team: invalid team\n");
 893                 }
 894                 LogTeamchange(pl);
 895                 if(pl.deadflag == DEAD_NO)
 896                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 897         }
 898
 899         return smallest;
 900 }
 901
 902 //void() ctf_playerchanged;
 903 void SV_ChangeTeam(float _color)
 904 {
 905         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 906
 907         // in normal deathmatch we can just apply the color and we're done
 908         if(!cvar("teamplay")) {
 909                 SetPlayerColors(self, _color);
 910                 return;
 911         }
 912
 913         scolor = self.clientcolors & 0x0F;
 914         dcolor = _color & 0x0F;
 915
 916         if(scolor == COLOR_TEAM1 - 1)
 917                 steam = 1;
 918         else if(scolor == COLOR_TEAM2 - 1)
 919                 steam = 2;
 920         else if(scolor == COLOR_TEAM3 - 1)
 921                 steam = 3;
 922         else if(scolor == COLOR_TEAM4 - 1)
 923                 steam = 4;
 924         if(dcolor == COLOR_TEAM1 - 1)
 925                 dteam = 1;
 926         else if(dcolor == COLOR_TEAM2 - 1)
 927                 dteam = 2;
 928         else if(dcolor == COLOR_TEAM3 - 1)
 929                 dteam = 3;
 930         else if(dcolor == COLOR_TEAM4 - 1)
 931                 dteam = 4;
 932
 933         CheckAllowedTeams(self);
 934
 935         if(dteam == 1 && c1 < 0) dteam = 4;
 936         if(dteam == 4 && c4 < 0) dteam = 3;
 937         if(dteam == 3 && c3 < 0) dteam = 2;
 938         if(dteam == 2 && c2 < 0) dteam = 1;
 939
 940         // not changing teams
 941         if(scolor == dcolor)
 942         {
 943                 //bprint("same team change\n");
 944                 SetPlayerTeam(self, dteam, steam, TRUE);
 945                 return;
 946         }
 947
 948         if(cvar("teamplay"))
 949         {
 950                 if(cvar("g_campaign") || cvar("g_changeteam_banned"))
 951                 {
 952                         sprint(self, "Team changes not allowed\n");
 953                         return; // changing teams is not allowed
 954                 }
 955
 956                 if(!cvar("g_campaign") && cvar("g_balance_teams_prevent_imbalance"))
 957                 {
 958                         // only allow changing to a smaller or equal size team
 959
 960                         // find out what teams are available
 961                         //CheckAllowedTeams();
 962                         // count how many players on each team
 963                         GetTeamCounts(world);
 964
 965                         // get desired team
 966                         if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 967                         {
 968                                 dcount = c1;
 969                                 dbotcount = cb1;
 970                         }
 971                         else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 972                         {
 973                                 dcount = c2;
 974                                 dbotcount = cb2;
 975                         }
 976                         else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
 977                         {
 978                                 dcount = c3;
 979                                 dbotcount = cb3;
 980                         }
 981                         else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
 982                         {
 983                                 dcount = c4;
 984                                 dbotcount = cb4;
 985                         }
 986                         else
 987                         {
 988                                 sprint(self, "Cannot change to an invalid team\n");
 989
 990                                 return;
 991                         }
 992
 993                         // get starting team
 994                         if(steam == 1)//scolor == COLOR_TEAM1 - 1)
 995                                 scount = c1;
 996                         else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
 997                                 scount = c2;
 998                         else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
 999                                 scount = c3;
1000                         else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1001                                 scount = c4;
1002
1003                         if(scount) // started at a valid, nonempty team
1004                         {
1005                                 // check if we're trying to change to a larger team that doens't have bots to swap with
1006                                 if(dcount >= scount && dbotcount <= 0)
1007                                 {
1008                                         sprint(self, "Cannot change to a larger team\n");
1009                                         return; // can't change to a larger team
1010                                 }
1011                         }
1012                 }
1013         }
1014
1015 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1016
1017         if(cvar("teamplay") && self.classname == "player" && steam != dteam)
1018         {
1019                 // reduce frags during a team change
1020                 TeamchangeFrags(self);
1021         }
1022
1023         SetPlayerTeam(self, dteam, steam, FALSE);
1024
1025         if(cvar("teamplay") && self.classname == "player" && steam != dteam)
1026         {
1027                 // kill player when changing teams
1028                 if(self.deadflag == DEAD_NO)
1029                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1030         }
1031         //ctf_playerchanged();
1032 }
1033
1034 void ShufflePlayerOutOfTeam (float source_team)
1035 {
1036         float smallestteam, smallestteam_count, steam;
1037         float lowest_bot_score, lowest_player_score;
1038         entity head, lowest_bot, lowest_player, selected;
1039
1040         smallestteam = 0;
1041         smallestteam_count = 999999999;
1042
1043         if(c1 >= 0 && c1 < smallestteam_count)
1044         {
1045                 smallestteam = 1;
1046                 smallestteam_count = c1;
1047         }
1048         if(c2 >= 0 && c2 < smallestteam_count)
1049         {
1050                 smallestteam = 2;
1051                 smallestteam_count = c2;
1052         }
1053         if(c3 >= 0 && c3 < smallestteam_count)
1054         {
1055                 smallestteam = 3;
1056                 smallestteam_count = c3;
1057         }
1058         if(c4 >= 0 && c4 < smallestteam_count)
1059         {
1060                 smallestteam = 4;
1061                 smallestteam_count = c4;
1062         }
1063
1064         if(!smallestteam)
1065         {
1066                 bprint("warning: no smallest team\n");
1067                 return;
1068         }
1069
1070         if(source_team == 1)
1071                 steam = COLOR_TEAM1;
1072         else if(source_team == 2)
1073                 steam = COLOR_TEAM2;
1074         else if(source_team == 3)
1075                 steam = COLOR_TEAM3;
1076         else if(source_team == 4)
1077                 steam = COLOR_TEAM4;
1078
1079         lowest_bot = world;
1080         lowest_bot_score = 999999999;
1081         lowest_player = world;
1082         lowest_player_score = 999999999;
1083
1084         // find the lowest-scoring player & bot of that team
1085         FOR_EACH_PLAYER(head)
1086         {
1087                 if(head.team == steam)
1088                 {
1089                         if(head.isbot)
1090                         {
1091                                 if(head.totalfrags < lowest_bot_score)
1092                                 {
1093                                         lowest_bot = head;
1094                                         lowest_bot_score = head.totalfrags;
1095                                 }
1096                         }
1097                         else
1098                         {
1099                                 if(head.totalfrags < lowest_player_score)
1100                                 {
1101                                         lowest_player = head;
1102                                         lowest_player_score = head.totalfrags;
1103                                 }
1104                         }
1105                 }
1106         }
1107
1108         // prefers to move a bot...
1109         if(lowest_bot != world)
1110                 selected = lowest_bot;
1111         // but it will move a player if it has to
1112         else
1113                 selected = lowest_player;
1114         // don't do anything if it couldn't find anyone
1115         if(!selected)
1116         {
1117                 bprint("warning: couldn't find a player to move from team\n");
1118                 return;
1119         }
1120
1121         // smallest team gains a member
1122         if(smallestteam == 1)
1123         {
1124                 c1 = c1 + 1;
1125         }
1126         else if(smallestteam == 2)
1127         {
1128                 c2 = c2 + 1;
1129         }
1130         else if(smallestteam == 3)
1131         {
1132                 c3 = c3 + 1;
1133         }
1134         else if(smallestteam == 4)
1135         {
1136                 c4 = c4 + 1;
1137         }
1138         else
1139         {
1140                 bprint("warning: destination team invalid\n");
1141                 return;
1142         }
1143         // source team loses a member
1144         if(source_team == 1)
1145         {
1146                 c1 = c1 + 1;
1147         }
1148         else if(source_team == 2)
1149         {
1150                 c2 = c2 + 2;
1151         }
1152         else if(source_team == 3)
1153         {
1154                 c3 = c3 + 3;
1155         }
1156         else if(source_team == 4)
1157         {
1158                 c4 = c4 + 4;
1159         }
1160         else
1161         {
1162                 bprint("warning: source team invalid\n");
1163                 return;
1164         }
1165
1166         // move the player to the new team
1167         TeamchangeFrags(selected);
1168         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1169
1170         if(selected.deadflag == DEAD_NO)
1171                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1172         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1173 }
1174
1175 void CauseRebalance(float source_team, float howmany_toomany)
1176 {
1177         if(IsTeamBalanceForced() == 1)
1178         {
1179                 bprint("Rebalancing Teams\n");
1180                 ShufflePlayerOutOfTeam(source_team);
1181         }
1182 }
1183
1184 // part of g_balance_teams_force
1185 // occasionally perform an audit of the teams to make
1186 // sure they're more or less balanced in player count.
1187 void AuditTeams()
1188 {
1189         float numplayers, numteams, smallest, toomany;
1190         float balance;
1191         balance = IsTeamBalanceForced();
1192         if(balance == 0)
1193                 return;
1194
1195         if(audit_teams_time > time)
1196                 return;
1197
1198         audit_teams_time = time + 4 + random();
1199
1200 //      bprint("Auditing teams\n");
1201
1202         CheckAllowedTeams(world);
1203         GetTeamCounts(world);
1204
1205
1206         numteams = numplayers = smallest = 0;
1207         if(c1 >= 0)
1208         {
1209                 numteams = numteams + 1;
1210                 numplayers = numplayers + c1;
1211                 smallest = c1;
1212         }
1213         if(c2 >= 0)
1214         {
1215                 numteams = numteams + 1;
1216                 numplayers = numplayers + c2;
1217                 if(c2 < smallest)
1218                         smallest = c2;
1219         }
1220         if(c3 >= 0)
1221         {
1222                 numteams = numteams + 1;
1223                 numplayers = numplayers + c3;
1224                 if(c3 < smallest)
1225                         smallest = c3;
1226         }
1227         if(c4 >= 0)
1228         {
1229                 numteams = numteams + 1;
1230                 numplayers = numplayers + c4;
1231                 if(c4 < smallest)
1232                         smallest = c4;
1233         }
1234
1235         if(numplayers <= 0)
1236                 return; // no players to move around
1237         if(numteams < 2)
1238                 return; // don't bother shuffling if for some reason there aren't any teams
1239
1240         toomany = smallest + 1;
1241
1242         if(c1 && c1 > toomany)
1243                 CauseRebalance(1, c1 - toomany);
1244         if(c2 && c2 > toomany)
1245                 CauseRebalance(2, c2 - toomany);
1246         if(c3 && c3 > toomany)
1247                 CauseRebalance(3, c3 - toomany);
1248         if(c4 && c4 > toomany)
1249                 CauseRebalance(4, c4 - toomany);
1250
1251         // if teams are still unbalanced, balance them further in the next audit,
1252         // which will happen sooner (keep doing rapid audits until things are in order)
1253         audit_teams_time = time + 0.7 + random()*0.3;
1254 }
1255
1256 // code from here on is just to support maps that don't have team entities
1257 void tdm_spawnteam (string teamname, float teamcolor)
1258 {
1259         local entity e;
1260         e = spawn();
1261         e.classname = "tdm_team";
1262         e.netname = teamname;
1263         e.cnt = teamcolor;
1264         e.team = e.cnt + 1;
1265 };
1266
1267 // spawn some default teams if the map is not set up for tdm
1268 void tdm_spawnteams()
1269 {
1270         float numteams;
1271
1272         numteams = cvar("g_tdm_teams");
1273
1274         tdm_spawnteam("Red", COLOR_TEAM1-1);
1275         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1276         if(numteams >= 3)
1277                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1278         if(numteams >= 4)
1279                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1280 };
1281
1282 void tdm_delayedinit()
1283 {
1284         // if no teams are found, spawn defaults
1285         if (find(world, classname, "tdm_team") == world)
1286                 tdm_spawnteams();
1287 };
1288
1289 void tdm_init()
1290 {
1291         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1292 };