data/qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(entity pl)
  76 {
  77         string str;
  78         if(!cvar("sv_eventlog"))
  79                 return;
  80         if(pl.playerid < 1)
  81                 return;
  82         str = strcat(":team:", ftos(pl.playerid), ":");
  83         str = strcat(str, ftos(pl.team));
  84         GameLogEcho(str);
  85 }
  86
  87 void WriteGameCvars()
  88 {
  89         cvar_set("g_dm", ftos(g_dm));
  90         cvar_set("g_tdm", ftos(g_tdm));
  91         cvar_set("g_domination", ftos(g_domination));
  92         cvar_set("g_ctf", ftos(g_ctf));
  93         cvar_set("g_runematch", ftos(g_runematch));
  94         cvar_set("g_lms", ftos(g_lms));
  95         cvar_set("g_arena", ftos(g_arena));
  96         cvar_set("g_keyhunt", ftos(g_keyhunt));
  97         cvar_set("g_assault", ftos(g_assault));
  98         cvar_set("g_onslaught", ftos(g_onslaught));
  99         cvar_set("g_race", ftos(g_race));
 100         cvar_set("g_nexball", ftos(g_nexball));
 101         cvar_set("g_cts", ftos(g_cts));
 102 }
 103
 104 void ReadGameCvars()
 105 {
 106         float found;
 107         float prev;
 108         float i;
 109
 110         found = 0;
 111         prev = cvar("gamecfg");
 112         for(i = 0; i < 2; ++i)
 113         {
 114                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 115                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 116                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 117                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 118                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 119                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 120                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 121                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 122                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 123                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 124                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 125                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 126                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 127
 128                 if(found)
 129                         break;
 130
 131                 prev = -1; // second attempt takes place WITHOUT prev set
 132         }
 133
 134         if(!found)
 135                 g_dm = 1;
 136
 137         if(g_dm && cvar("deathmatch_force_teamplay"))
 138         {
 139                 g_dm = 0;
 140                 g_tdm = 1;
 141         }
 142
 143         teams_matter = 0;
 144 }
 145
 146 void default_delayedinit()
 147 {
 148         if(!scores_initialized)
 149                 ScoreRules_generic();
 150 }
 151
 152 void ActivateTeamplay()
 153 {
 154         float teamplay_default;
 155         teamplay_default = cvar("teamplay_default");
 156
 157         if(teamplay_default)
 158                 teamplay = teamplay_default;
 159         else
 160                 teamplay = 3;
 161         cvar_set("teamplay", ftos(teamplay));
 162
 163         teams_matter = 1;
 164 }
 165
 166 void InitGameplayMode()
 167 {
 168         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 169
 170         qualifying_override = -1;
 171
 172         VoteReset();
 173
 174         teams_matter = 0;
 175         cvar_set("teamplay", "0");
 176
 177         // make sure only ONE type is selected
 178         ReadGameCvars();
 179         WriteGameCvars();
 180
 181         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 182         get_mi_min_max(1);
 183         world.mins = mi_min;
 184         world.maxs = mi_max;
 185
 186         MapInfo_LoadMapSettings(mapname);
 187
 188         if not(cvar_value_issafe(world.fog))
 189         {
 190                 print("The current map contains a potentially harmful fog setting, ignored\n");
 191                 world.fog = string_null;
 192         }
 193         if(MapInfo_Map_fog != "")
 194                 if(MapInfo_Map_fog == "none")
 195                         world.fog = string_null;
 196                 else
 197                         world.fog = strzone(MapInfo_Map_fog);
 198         clientstuff = strzone(MapInfo_Map_clientstuff);
 199
 200         MapInfo_ClearTemps();
 201
 202         // in case mapinfo switched the type
 203         ReadGameCvars();
 204
 205         // set both here, gamemode can override it later
 206         timelimit_override = cvar("timelimit_override");
 207         fraglimit_override = cvar("fraglimit_override");
 208         leadlimit_override = cvar("leadlimit_override");
 209
 210         if(g_dm)
 211         {
 212                 game = GAME_DEATHMATCH;
 213                 gamemode_name = "Deathmatch";
 214         }
 215
 216         if(g_tdm)
 217         {
 218                 game = GAME_TEAM_DEATHMATCH;
 219                 gamemode_name = "Team Deathmatch";
 220                 ActivateTeamplay();
 221                 tdm_init();
 222         }
 223
 224         if(g_domination)
 225         {
 226                 game = GAME_DOMINATION;
 227                 gamemode_name = "Domination";
 228                 ActivateTeamplay();
 229                 fraglimit_override = cvar("g_domination_point_limit");
 230                 leadlimit_override = cvar("g_domination_point_leadlimit");
 231                 dom_init();
 232         }
 233
 234         if(g_ctf)
 235         {
 236                 game = GAME_CTF;
 237                 gamemode_name = "Capture the Flag";
 238                 ActivateTeamplay();
 239                 if(cvar("g_campaign"))
 240                         g_ctf_win_mode = 2;
 241                 else
 242                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 243                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 244                 if(g_ctf_win_mode == 2)
 245                 {
 246                         fraglimit_override = cvar("g_ctf_capture_limit");
 247                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 248                 }
 249                 else
 250                 {
 251                         fraglimit_override = cvar("capturelimit_override");
 252                         leadlimit_override = cvar("captureleadlimit_override");
 253                 }
 254                 ctf_init();
 255         }
 256
 257         if(g_runematch)
 258         {
 259                 game = GAME_RUNEMATCH;
 260                 gamemode_name = "Rune Match";
 261                 if(cvar("deathmatch_force_teamplay"))
 262                         ActivateTeamplay();
 263                 fraglimit_override = cvar("g_runematch_point_limit");
 264                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 265                 runematch_init();
 266         }
 267
 268         if(g_lms)
 269         {
 270                 game = GAME_LMS;
 271                 gamemode_name = "Last Man Standing";
 272                 fraglimit_override = cvar("g_lms_lives_override");
 273                 leadlimit_override = 0; // not supported by LMS
 274                 if(fraglimit_override == 0)
 275                         fraglimit_override = -1;
 276                 lms_lowest_lives = 9999;
 277                 lms_next_place = 0;
 278                 ScoreRules_lms();
 279         }
 280
 281         if(g_arena)
 282         {
 283                 game = GAME_ARENA;
 284                 gamemode_name = "Arena";
 285                 fraglimit_override = cvar("g_arena_point_limit");
 286                 leadlimit_override = cvar("g_arena_point_leadlimit");
 287                 maxspawned = cvar("g_arena_maxspawned");
 288                 if(maxspawned < 2)
 289                         maxspawned = 2;
 290                 arena_roundbased = cvar("g_arena_roundbased");
 291         }
 292
 293         if(g_keyhunt)
 294         {
 295                 game = GAME_KEYHUNT;
 296                 gamemode_name = "Key Hunt";
 297                 ActivateTeamplay();
 298                 fraglimit_override = cvar("g_keyhunt_point_limit");
 299                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 300                 kh_init();
 301         }
 302
 303         if(g_assault)
 304         {
 305                 game = GAME_ASSAULT;
 306                 gamemode_name = "Assault";
 307                 ActivateTeamplay();
 308                 ScoreRules_assault();
 309         }
 310
 311         if(g_onslaught)
 312         {
 313                 game = GAME_ONSLAUGHT;
 314                 gamemode_name = "Onslaught";
 315                 ActivateTeamplay();
 316         }
 317
 318         if(g_race)
 319         {
 320                 game = GAME_RACE;
 321                 gamemode_name = "Race";
 322
 323                 if(cvar("g_race_teams"))
 324                 {
 325                         ActivateTeamplay();
 326                         race_teams = bound(2, cvar("g_race_teams"), 4);
 327                 }
 328                 else
 329                         race_teams = 0;
 330
 331                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 332                 fraglimit_override = cvar("g_race_laps_limit");
 333                 leadlimit_override = 0; // currently not supported by race
 334         }
 335
 336         if(g_cts)
 337         {
 338                 game = GAME_CTS;
 339                 gamemode_name = "CTS";
 340                 g_race_qualifying = 1;
 341                 fraglimit_override = 0;
 342                 leadlimit_override = 0;
 343         }
 344
 345         if(g_nexball)
 346         {
 347                 game = GAME_NEXBALL;
 348                 gamemode_name = "Nexball";
 349                 fraglimit_override = cvar("g_nexball_goallimit");
 350                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 351                 ActivateTeamplay();
 352                 nb_init();
 353         }
 354
 355         if(teams_matter)
 356                 entcs_init();
 357
 358         // save it (for the next startup)
 359         cvar_set("gamecfg", ftos(game));
 360
 361         cache_mutatormsg = strzone("");
 362         cache_lastmutatormsg = strzone("");
 363
 364         // enforce the server's universal frag/time limits
 365         if(!cvar("g_campaign"))
 366         {
 367                 if(fraglimit_override >= 0)
 368                         cvar_set("fraglimit", ftos(fraglimit_override));
 369                 if(timelimit_override >= 0)
 370                         cvar_set("timelimit", ftos(timelimit_override));
 371                 if(leadlimit_override >= 0)
 372                         cvar_set("leadlimit", ftos(leadlimit_override));
 373                 if(qualifying_override >= 0)
 374                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 375         }
 376
 377         if(g_race)
 378         {
 379                 // we need to find out the correct value for g_race_qualifying
 380                 if(cvar("g_campaign"))
 381                 {
 382                         g_race_qualifying = 1;
 383                 }
 384                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 385                 {
 386                         g_race_qualifying = 2;
 387                         race_fraglimit = cvar("fraglimit");
 388                         race_leadlimit = cvar("leadlimit");
 389                         race_timelimit = cvar("timelimit");
 390                         cvar_set("fraglimit", "0");
 391                         cvar_set("leadlimit", "0");
 392                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 393                 }
 394                 else
 395                         g_race_qualifying = 0;
 396         }
 397
 398         if(g_race || g_cts)
 399         {
 400                 if(g_race_qualifying)
 401                         independent_players = 1;
 402
 403                 ScoreRules_race();
 404         }
 405
 406         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 407 }
 408
 409 string GetClientVersionMessage() {
 410         local string versionmsg;
 411         if (self.version_mismatch) {
 412                 if(self.version < cvar("gameversion")) {
 413                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 414                 } else {
 415                         versionmsg = "^3This server is using an outdated Nexuiz version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 416                 }
 417         } else {
 418                 versionmsg = "^2client version and server version are compatible.^8";
 419         }
 420         return versionmsg;
 421 }
 422
 423
 424 void PrintWelcomeMessage(entity pl)
 425 {
 426         string s, modifications, motd;
 427
 428         if(self.cvar_scr_centertime == 0) return;
 429
 430         if(cvar("g_campaign"))
 431         {
 432                 if(self.classname == "player")
 433                         return;
 434         }
 435         else
 436         {
 437                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 438                         return;
 439         }
 440
 441         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 442                 if(self.welcomemessage_time > time) return;
 443                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 444         }
 445
 446         if(cvar("g_campaign"))
 447         {
 448                 centerprint(pl, campaign_message);
 449                 return;
 450         }
 451
 452 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 453         if(!self.BUTTON_INFO)
 454         {
 455                 // TODO get rid of this too
 456                 local string specString;
 457                 specString = NEWLINES;
 458                 //if(time < game_starttime) //also show the countdown when being a spectator
 459                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 460                 //else
 461                 if (timeoutStatus != 0)
 462                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 463                 else
 464                 {
 465                         if(!self.BUTTON_INFO && self.classname == "player")
 466                                 return;
 467                         goto normal;
 468                 }
 469                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 470         }
 471
 472 :normal
 473         modifications = "";
 474         if(g_minstagib)
 475                 modifications = strcat(modifications, ", MinstaGib");
 476         if(g_nixnex)
 477                 modifications = strcat(modifications, ", NixNex");
 478         if(g_weaponarena)
 479                 modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 480         if(cvar("g_start_weapon_laser") == 0)
 481                 modifications = strcat(modifications, ", No start weapons");
 482         if(cvar("sv_gravity") < 800)
 483                 modifications = strcat(modifications, ", Low gravity");
 484         if(g_cloaked)
 485                 modifications = strcat(modifications, ", Cloaked");
 486         if(g_footsteps)
 487                 modifications = strcat(modifications, ", Steps");
 488         if(g_grappling_hook)
 489                 modifications = strcat(modifications, ", Hook");
 490         if(g_laserguided_missile)
 491                 modifications = strcat(modifications, ", LG missiles");
 492         if(g_midair)
 493                 modifications = strcat(modifications, ", Midair");
 494         if(g_vampire)
 495                 modifications = strcat(modifications, ", Vampire");
 496         if(g_pinata)
 497                 modifications = strcat(modifications, ", Pinata");
 498         if(g_weapon_stay)
 499                 modifications = strcat(modifications, ", Weapons stay");
 500         if(g_bloodloss > 0)
 501                 modifications = strcat(modifications, ", Bloodloss");
 502         if(g_jetpack)
 503                 modifications = strcat(modifications, ", Jet pack");
 504         modifications = substring(modifications, 2, strlen(modifications) - 2);
 505
 506         local string versionmessage;
 507         versionmessage = GetClientVersionMessage();
 508
 509         s = strcat(s, NEWLINES, "This is Nexuiz ", cvar_string("g_nexuizversion"), "\n", versionmessage);
 510         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 511
 512         if(modifications != "")
 513                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 514
 515         if(timeoutStatus != 0)
 516                 s = strcat(s, "\n\n", getTimeoutText(1));
 517
 518         if (g_grappling_hook)
 519                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 520
 521         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 522         {
 523                 if(cache_lastmutatormsg)
 524                         strunzone(cache_lastmutatormsg);
 525                 if(cache_mutatormsg)
 526                         strunzone(cache_mutatormsg);
 527                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 528                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 529         }
 530
 531         if (cache_mutatormsg != "") {
 532                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 533         }
 534
 535         motd = cvar_string("sv_motd");
 536         if (motd != "") {
 537                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 538         }
 539         s = strcat(s, "\n");
 540
 541         centerprint(pl, s);
 542 }
 543
 544
 545 void SetPlayerColors(entity pl, float _color)
 546 {
 547         /*string s;
 548         s = ftos(cl);
 549         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 550         pl.team = cl + 1;
 551         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 552         pl.clientcolors = 16*cl + cl;*/
 553
 554         float pants, shirt;
 555         pants = _color & 0x0F;
 556         shirt = _color & 0xF0;
 557
 558
 559         if(teams_matter) {
 560                 setcolor(pl, 16*pants + pants);
 561         } else {
 562                 setcolor(pl, shirt + pants);
 563         }
 564 }
 565
 566 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 567 {
 568         float _color;
 569
 570         if(t == 4)
 571                 _color = COLOR_TEAM4 - 1;
 572         else if(t == 3)
 573                 _color = COLOR_TEAM3 - 1;
 574         else if(t == 2)
 575                 _color = COLOR_TEAM2 - 1;
 576         else
 577                 _color = COLOR_TEAM1 - 1;
 578
 579         SetPlayerColors(pl,_color);
 580
 581         if(!noprint && t != s)
 582         {
 583                 //bprint(pl.netname, " has changed to ", TeamNoName(t), "\n");
 584                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 585         }
 586
 587         if(t != s)
 588                 LogTeamchange(pl);
 589 }
 590
 591 // set c1...c4 to show what teams are allowed
 592 void CheckAllowedTeams (entity for_whom)
 593 {
 594         float dm;
 595         entity head;
 596         string teament_name;
 597
 598         c1 = c2 = c3 = c4 = -1;
 599         cb1 = cb2 = cb3 = cb4 = 0;
 600
 601         if(g_onslaught)
 602         {
 603                 // onslaught is special
 604                 head = findchain(classname, "onslaught_generator");
 605                 while (head)
 606                 {
 607                         if (head.team == COLOR_TEAM1) c1 = 0;
 608                         if (head.team == COLOR_TEAM2) c2 = 0;
 609                         if (head.team == COLOR_TEAM3) c3 = 0;
 610                         if (head.team == COLOR_TEAM4) c4 = 0;
 611                         head = head.chain;
 612                 }
 613         }
 614         else if(g_domination)
 615                 teament_name = "dom_team";
 616         else if(g_ctf)
 617                 teament_name = "ctf_team";
 618         else if(g_tdm)
 619                 teament_name = "tdm_team";
 620         else if(g_nexball)
 621                 teament_name = "nexball_team";
 622         else if(g_assault)
 623                 c1 = c2 = 0; // Assault always has 2 teams
 624         else
 625         {
 626                 // cover anything else by treating it like tdm with no teams spawned
 627                 if(g_keyhunt)
 628                         dm = kh_teams;
 629                 else if(g_race)
 630                         dm = race_teams;
 631                 else
 632                         dm = 2;
 633
 634                 if(dm >= 4)
 635                         c1 = c2 = c3 = c4 = 0;
 636                 else if(dm >= 3)
 637                         c1 = c2 = c3 = 0;
 638                 else
 639                         c1 = c2 = 0;
 640         }
 641
 642         // find out what teams are allowed if necessary
 643         if(teament_name)
 644         {
 645                 head = find(world, classname, teament_name);
 646                 while(head)
 647                 {
 648                         if(!(g_domination && head.netname == ""))
 649                         {
 650                                 if(head.team == COLOR_TEAM1)
 651                                         c1 = 0;
 652                                 else if(head.team == COLOR_TEAM2)
 653                                         c2 = 0;
 654                                 else if(head.team == COLOR_TEAM3)
 655                                         c3 = 0;
 656                                 else if(head.team == COLOR_TEAM4)
 657                                         c4 = 0;
 658                         }
 659                         head = find(head, classname, teament_name);
 660                 }
 661         }
 662
 663         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 664         if(c3==-1&&c4==-1)
 665         if(cvar("bot_vs_human") && for_whom)
 666         {
 667                 if(cvar("bot_vs_human") > 0)
 668                 {
 669                         // bots are all blue
 670                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 671                                 c1 = c3 = c4 = -1;
 672                         else
 673                                 c2 = -1;
 674                 }
 675                 else
 676                 {
 677                         // bots are all red
 678                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 679                                 c2 = c3 = c4 = -1;
 680                         else
 681                                 c1 = -1;
 682                 }
 683         }
 684 }
 685
 686 float PlayerValue(entity p)
 687 {
 688         if(IsTeamBalanceForced() == 1)
 689                 return 1;
 690         return 1;
 691 }
 692
 693 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 694 // teams that are allowed will now have their player counts stored in c1...c4
 695 void GetTeamCounts(entity ignore)
 696 {
 697         entity head;
 698         float value, bvalue;
 699         // now count how many players are on each team already
 700
 701         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 702         // also remember the lowest-scoring player
 703
 704         FOR_EACH_PLAYER(head)
 705         {
 706                 if(head != ignore)// && head.netname != "")
 707                 {
 708                         value = PlayerValue(head);
 709                         if(clienttype(head) == CLIENTTYPE_BOT)
 710                                 bvalue = value;
 711                         else
 712                                 bvalue = 0;
 713                         if(head.team == COLOR_TEAM1)
 714                         {
 715                                 if(c1 >= 0)
 716                                 {
 717                                         c1 = c1 + value;
 718                                         cb1 = cb1 + bvalue;
 719                                 }
 720                         }
 721                         if(head.team == COLOR_TEAM2)
 722                         {
 723                                 if(c2 >= 0)
 724                                 {
 725                                         c2 = c2 + value;
 726                                         cb2 = cb2 + bvalue;
 727                                 }
 728                         }
 729                         if(head.team == COLOR_TEAM3)
 730                         {
 731                                 if(c3 >= 0)
 732                                 {
 733                                         c3 = c3 + value;
 734                                         cb3 = cb3 + bvalue;
 735                                 }
 736                         }
 737                         if(head.team == COLOR_TEAM4)
 738                         {
 739                                 if(c4 >= 0)
 740                                 {
 741                                         c4 = c4 + value;
 742                                         cb4 = cb4 + bvalue;
 743                                 }
 744                         }
 745                 }
 746         }
 747 }
 748
 749 // returns # of smallest team (1, 2, 3, 4)
 750 // NOTE: Assumes CheckAllowedTeams has already been called!
 751 float FindSmallestTeam(entity pl, float ignore_pl)
 752 {
 753         float totalteams, smallestteam, smallestteam_count, smallestteam_score, balance_type;
 754         totalteams = 0;
 755
 756         // find out what teams are available
 757         //CheckAllowedTeams();
 758
 759         // make sure there are at least 2 teams to join
 760         if(c1 >= 0)
 761                 totalteams = totalteams + 1;
 762         if(c2 >= 0)
 763                 totalteams = totalteams + 1;
 764         if(c3 >= 0)
 765                 totalteams = totalteams + 1;
 766         if(c4 >= 0)
 767                 totalteams = totalteams + 1;
 768
 769         if(cvar("bot_vs_human"))
 770                 totalteams += 1;
 771
 772         if(totalteams <= 1)
 773         {
 774                 if(g_domination)
 775                         error("Too few teams available for domination\n");
 776                 else if(g_ctf)
 777                         error("Too few teams available for ctf\n");
 778                 else if(g_keyhunt)
 779                         error("Too few teams available for key hunt\n");
 780                 else
 781                         error("Too few teams available for team deathmatch\n");
 782         }
 783
 784         // count how many players are in each team
 785         if(ignore_pl)
 786                 GetTeamCounts(pl);
 787         else
 788                 GetTeamCounts(world);
 789
 790         // c1...c4 now have counts of each team
 791         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 792
 793         smallestteam = 0;
 794         smallestteam_count = 999999999;
 795         smallestteam_score = 999999999;
 796
 797         // 2 gives priority to what team you're already on, 1 goes in order
 798         // 2 doesn't seem to work though...
 799         balance_type = 1;
 800
 801         if(bots_would_leave)
 802         //if(pl.classname != "player")
 803         if(clienttype(pl) != CLIENTTYPE_BOT)
 804         {
 805                 c1 -= cb1 * 255.0/256;
 806                 c2 -= cb2 * 255.0/256;
 807                 c3 -= cb3 * 255.0/256;
 808                 c4 -= cb4 * 255.0/256;
 809         }
 810
 811         if(balance_type == 1)
 812         {
 813                 if(c1 >= 0 && (c1 < smallestteam_count || (c1 <= smallestteam_count && team1_score < smallestteam_score)))
 814                 {
 815                         smallestteam = 1;
 816                         smallestteam_count = c1;
 817                         smallestteam_score = team1_score;
 818                 }
 819                 if(c2 >= 0 && (c2 < smallestteam_count || (c2 <= smallestteam_count && team2_score < smallestteam_score)))
 820                 {
 821                         smallestteam = 2;
 822                         smallestteam_count = c2;
 823                         smallestteam_score = team2_score;
 824                 }
 825                 if(c3 >= 0 && (c3 < smallestteam_count || (c3 <= smallestteam_count && team3_score < smallestteam_score)))
 826                 {
 827                         smallestteam = 3;
 828                         smallestteam_count = c3;
 829                         smallestteam_score = team3_score;
 830                 }
 831                 if(c4 >= 0 && (c4 < smallestteam_count || (c4 <= smallestteam_count && team4_score < smallestteam_score)))
 832                 {
 833                         smallestteam = 4;
 834                         smallestteam_count = c4;
 835                         smallestteam_score = team4_score;
 836                 }
 837         }
 838         else
 839         {
 840                 if(c1 >= 0 && (c1 < smallestteam_count ||
 841                                         (c1 == smallestteam_count && self.team == COLOR_TEAM1) ) )
 842                 {
 843                         smallestteam = 1;
 844                         smallestteam_count = c1;
 845                 }
 846                 if(c2 >= 0 && c2 < (c2 < smallestteam_count ||
 847                                         (c2 == smallestteam_count && self.team == COLOR_TEAM2) ) )
 848                 {
 849                         smallestteam = 2;
 850                         smallestteam_count = c2;
 851                 }
 852                 if(c3 >= 0 && c3 < (c3 < smallestteam_count ||
 853                                         (c3 == smallestteam_count && self.team == COLOR_TEAM3) ) )
 854                 {
 855                         smallestteam = 3;
 856                         smallestteam_count = c3;
 857                 }
 858                 if(c4 >= 0 && c4 < (c4 < smallestteam_count ||
 859                                         (c4 == smallestteam_count && self.team == COLOR_TEAM4) ) )
 860                 {
 861                         smallestteam = 4;
 862                         smallestteam_count = c4;
 863                 }
 864         }
 865
 866         return smallestteam;
 867 }
 868
 869 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 870 {
 871         float smallest, selectedteam;
 872
 873         // don't join a team if we're not playing a team game
 874         if(!teams_matter)
 875                 return 0;
 876
 877         // find out what teams are available
 878         CheckAllowedTeams(pl);
 879
 880         // if we don't care what team he ends up on, put him on whatever team he entered as.
 881         // if he's not on a valid team, then let other code put him on the smallest team
 882         if(!forcebestteam)
 883         {
 884                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 885                         selectedteam = pl.team;
 886                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 887                         selectedteam = pl.team;
 888                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 889                         selectedteam = pl.team;
 890                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 891                         selectedteam = pl.team;
 892                 else
 893                         selectedteam = -1;
 894                 if(selectedteam > 0)
 895                 {
 896                         if(!only_return_best)
 897                         {
 898                                 SetPlayerColors(pl, selectedteam - 1);
 899                                 LogTeamchange(pl);
 900                         }
 901                         return selectedteam;
 902                 }
 903                 // otherwise end up on the smallest team (handled below)
 904         }
 905
 906         smallest = FindSmallestTeam(pl, TRUE);
 907
 908
 909         if(!only_return_best)
 910         {
 911                 TeamchangeFrags(self);
 912                 if(smallest == 1)
 913                 {
 914                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 915                 }
 916                 else if(smallest == 2)
 917                 {
 918                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 919                 }
 920                 else if(smallest == 3)
 921                 {
 922                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 923                 }
 924                 else if(smallest == 4)
 925                 {
 926                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 927                 }
 928                 else
 929                 {
 930                         error("smallest team: invalid team\n");
 931                 }
 932                 LogTeamchange(pl);
 933                 if(pl.deadflag == DEAD_NO)
 934                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 935         }
 936
 937         return smallest;
 938 }
 939
 940 //void() ctf_playerchanged;
 941 void SV_ChangeTeam(float _color)
 942 {
 943         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 944
 945         // in normal deathmatch we can just apply the color and we're done
 946         if(!teams_matter) {
 947                 SetPlayerColors(self, _color);
 948                 return;
 949         }
 950
 951         scolor = self.clientcolors & 0x0F;
 952         dcolor = _color & 0x0F;
 953
 954         if(scolor == COLOR_TEAM1 - 1)
 955                 steam = 1;
 956         else if(scolor == COLOR_TEAM2 - 1)
 957                 steam = 2;
 958         else if(scolor == COLOR_TEAM3 - 1)
 959                 steam = 3;
 960         else // if(scolor == COLOR_TEAM4 - 1)
 961                 steam = 4;
 962         if(dcolor == COLOR_TEAM1 - 1)
 963                 dteam = 1;
 964         else if(dcolor == COLOR_TEAM2 - 1)
 965                 dteam = 2;
 966         else if(dcolor == COLOR_TEAM3 - 1)
 967                 dteam = 3;
 968         else // if(dcolor == COLOR_TEAM4 - 1)
 969                 dteam = 4;
 970
 971         CheckAllowedTeams(self);
 972
 973         if(dteam == 1 && c1 < 0) dteam = 4;
 974         if(dteam == 4 && c4 < 0) dteam = 3;
 975         if(dteam == 3 && c3 < 0) dteam = 2;
 976         if(dteam == 2 && c2 < 0) dteam = 1;
 977
 978         // not changing teams
 979         if(scolor == dcolor)
 980         {
 981                 //bprint("same team change\n");
 982                 SetPlayerTeam(self, dteam, steam, TRUE);
 983                 return;
 984         }
 985
 986         if(cvar("g_campaign"))
 987         {
 988                 sprint(self, "Team changes not allowed\n");
 989                 return; // changing teams is not allowed
 990         }
 991
 992         if(cvar("g_changeteam_banned") && self.wasplayer)
 993         {
 994                 sprint(self, "Team changes not allowed\n");
 995                 return;
 996         }
 997
 998         if(cvar("g_balance_teams_prevent_imbalance"))
 999         {
1000                 // only allow changing to a smaller or equal size team
1001
1002                 // find out what teams are available
1003                 //CheckAllowedTeams();
1004                 // count how many players on each team
1005                 GetTeamCounts(world);
1006
1007                 // get desired team
1008                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
1009                 {
1010                         dcount = c1;
1011                         dbotcount = cb1;
1012                 }
1013                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
1014                 {
1015                         dcount = c2;
1016                         dbotcount = cb2;
1017                 }
1018                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1019                 {
1020                         dcount = c3;
1021                         dbotcount = cb3;
1022                 }
1023                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1024                 {
1025                         dcount = c4;
1026                         dbotcount = cb4;
1027                 }
1028                 else
1029                 {
1030                         sprint(self, "Cannot change to an invalid team\n");
1031
1032                         return;
1033                 }
1034
1035                 // get starting team
1036                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1037                         scount = c1;
1038                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1039                         scount = c2;
1040                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1041                         scount = c3;
1042                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1043                         scount = c4;
1044
1045                 if(scount) // started at a valid, nonempty team
1046                 {
1047                         // check if we're trying to change to a larger team that doens't have bots to swap with
1048                         if(dcount >= scount && dbotcount <= 0)
1049                         {
1050                                 sprint(self, "Cannot change to a larger team\n");
1051                                 return; // can't change to a larger team
1052                         }
1053                 }
1054         }
1055
1056 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1057
1058         if(self.classname == "player" && steam != dteam)
1059         {
1060                 // reduce frags during a team change
1061                 TeamchangeFrags(self);
1062         }
1063
1064         SetPlayerTeam(self, dteam, steam, FALSE);
1065
1066         if(self.classname == "player" && steam != dteam)
1067         {
1068                 // kill player when changing teams
1069                 if(self.deadflag == DEAD_NO)
1070                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1071         }
1072         //ctf_playerchanged();
1073 }
1074
1075 void ShufflePlayerOutOfTeam (float source_team)
1076 {
1077         float smallestteam, smallestteam_count, steam;
1078         float lowest_bot_score, lowest_player_score;
1079         entity head, lowest_bot, lowest_player, selected;
1080
1081         smallestteam = 0;
1082         smallestteam_count = 999999999;
1083
1084         if(c1 >= 0 && c1 < smallestteam_count)
1085         {
1086                 smallestteam = 1;
1087                 smallestteam_count = c1;
1088         }
1089         if(c2 >= 0 && c2 < smallestteam_count)
1090         {
1091                 smallestteam = 2;
1092                 smallestteam_count = c2;
1093         }
1094         if(c3 >= 0 && c3 < smallestteam_count)
1095         {
1096                 smallestteam = 3;
1097                 smallestteam_count = c3;
1098         }
1099         if(c4 >= 0 && c4 < smallestteam_count)
1100         {
1101                 smallestteam = 4;
1102                 smallestteam_count = c4;
1103         }
1104
1105         if(!smallestteam)
1106         {
1107                 bprint("warning: no smallest team\n");
1108                 return;
1109         }
1110
1111         if(source_team == 1)
1112                 steam = COLOR_TEAM1;
1113         else if(source_team == 2)
1114                 steam = COLOR_TEAM2;
1115         else if(source_team == 3)
1116                 steam = COLOR_TEAM3;
1117         else if(source_team == 4)
1118                 steam = COLOR_TEAM4;
1119
1120         lowest_bot = world;
1121         lowest_bot_score = 999999999;
1122         lowest_player = world;
1123         lowest_player_score = 999999999;
1124
1125         // find the lowest-scoring player & bot of that team
1126         FOR_EACH_PLAYER(head)
1127         {
1128                 if(head.team == steam)
1129                 {
1130                         if(head.isbot)
1131                         {
1132                                 if(head.totalfrags < lowest_bot_score)
1133                                 {
1134                                         lowest_bot = head;
1135                                         lowest_bot_score = head.totalfrags;
1136                                 }
1137                         }
1138                         else
1139                         {
1140                                 if(head.totalfrags < lowest_player_score)
1141                                 {
1142                                         lowest_player = head;
1143                                         lowest_player_score = head.totalfrags;
1144                                 }
1145                         }
1146                 }
1147         }
1148
1149         // prefers to move a bot...
1150         if(lowest_bot != world)
1151                 selected = lowest_bot;
1152         // but it will move a player if it has to
1153         else
1154                 selected = lowest_player;
1155         // don't do anything if it couldn't find anyone
1156         if(!selected)
1157         {
1158                 bprint("warning: couldn't find a player to move from team\n");
1159                 return;
1160         }
1161
1162         // smallest team gains a member
1163         if(smallestteam == 1)
1164         {
1165                 c1 = c1 + 1;
1166         }
1167         else if(smallestteam == 2)
1168         {
1169                 c2 = c2 + 1;
1170         }
1171         else if(smallestteam == 3)
1172         {
1173                 c3 = c3 + 1;
1174         }
1175         else if(smallestteam == 4)
1176         {
1177                 c4 = c4 + 1;
1178         }
1179         else
1180         {
1181                 bprint("warning: destination team invalid\n");
1182                 return;
1183         }
1184         // source team loses a member
1185         if(source_team == 1)
1186         {
1187                 c1 = c1 + 1;
1188         }
1189         else if(source_team == 2)
1190         {
1191                 c2 = c2 + 2;
1192         }
1193         else if(source_team == 3)
1194         {
1195                 c3 = c3 + 3;
1196         }
1197         else if(source_team == 4)
1198         {
1199                 c4 = c4 + 4;
1200         }
1201         else
1202         {
1203                 bprint("warning: source team invalid\n");
1204                 return;
1205         }
1206
1207         // move the player to the new team
1208         TeamchangeFrags(selected);
1209         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1210
1211         if(selected.deadflag == DEAD_NO)
1212                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1213         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1214 }
1215
1216 void CauseRebalance(float source_team, float howmany_toomany)
1217 {
1218         if(IsTeamBalanceForced() == 1)
1219         {
1220                 bprint("Rebalancing Teams\n");
1221                 ShufflePlayerOutOfTeam(source_team);
1222         }
1223 }
1224
1225 // part of g_balance_teams_force
1226 // occasionally perform an audit of the teams to make
1227 // sure they're more or less balanced in player count.
1228 void AuditTeams()
1229 {
1230         float numplayers, numteams, smallest, toomany;
1231         float balance;
1232         balance = IsTeamBalanceForced();
1233         if(balance == 0)
1234                 return;
1235
1236         if(audit_teams_time > time)
1237                 return;
1238
1239         audit_teams_time = time + 4 + random();
1240
1241 //      bprint("Auditing teams\n");
1242
1243         CheckAllowedTeams(world);
1244         GetTeamCounts(world);
1245
1246
1247         numteams = numplayers = smallest = 0;
1248         if(c1 >= 0)
1249         {
1250                 numteams = numteams + 1;
1251                 numplayers = numplayers + c1;
1252                 smallest = c1;
1253         }
1254         if(c2 >= 0)
1255         {
1256                 numteams = numteams + 1;
1257                 numplayers = numplayers + c2;
1258                 if(c2 < smallest)
1259                         smallest = c2;
1260         }
1261         if(c3 >= 0)
1262         {
1263                 numteams = numteams + 1;
1264                 numplayers = numplayers + c3;
1265                 if(c3 < smallest)
1266                         smallest = c3;
1267         }
1268         if(c4 >= 0)
1269         {
1270                 numteams = numteams + 1;
1271                 numplayers = numplayers + c4;
1272                 if(c4 < smallest)
1273                         smallest = c4;
1274         }
1275
1276         if(numplayers <= 0)
1277                 return; // no players to move around
1278         if(numteams < 2)
1279                 return; // don't bother shuffling if for some reason there aren't any teams
1280
1281         toomany = smallest + 1;
1282
1283         if(c1 && c1 > toomany)
1284                 CauseRebalance(1, c1 - toomany);
1285         if(c2 && c2 > toomany)
1286                 CauseRebalance(2, c2 - toomany);
1287         if(c3 && c3 > toomany)
1288                 CauseRebalance(3, c3 - toomany);
1289         if(c4 && c4 > toomany)
1290                 CauseRebalance(4, c4 - toomany);
1291
1292         // if teams are still unbalanced, balance them further in the next audit,
1293         // which will happen sooner (keep doing rapid audits until things are in order)
1294         audit_teams_time = time + 0.7 + random()*0.3;
1295 }
1296
1297 // code from here on is just to support maps that don't have team entities
1298 void tdm_spawnteam (string teamname, float teamcolor)
1299 {
1300         local entity e;
1301         e = spawn();
1302         e.classname = "tdm_team";
1303         e.netname = teamname;
1304         e.cnt = teamcolor;
1305         e.team = e.cnt + 1;
1306 };
1307
1308 // spawn some default teams if the map is not set up for tdm
1309 void tdm_spawnteams()
1310 {
1311         float numteams;
1312
1313         numteams = cvar("g_tdm_teams_override");
1314         if(numteams < 2)
1315                 numteams = cvar("g_tdm_teams");
1316         numteams = bound(2, numteams, 4);
1317
1318         tdm_spawnteam("Red", COLOR_TEAM1-1);
1319         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1320         if(numteams >= 3)
1321                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1322         if(numteams >= 4)
1323                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1324 };
1325
1326 void tdm_delayedinit()
1327 {
1328         // if no teams are found, spawn defaults
1329         if (find(world, classname, "tdm_team") == world)
1330                 tdm_spawnteams();
1331 };
1332
1333 void tdm_init()
1334 {
1335         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1336 };