data/qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(entity pl)
  76 {
  77         string str;
  78         if(!cvar("sv_eventlog"))
  79                 return;
  80         if(pl.playerid < 1)
  81                 return;
  82         str = strcat(":team:", ftos(pl.playerid), ":");
  83         str = strcat(str, ftos(pl.team));
  84         GameLogEcho(str);
  85 }
  86
  87 void WriteGameCvars()
  88 {
  89         cvar_set("g_dm", ftos(g_dm));
  90         cvar_set("g_tdm", ftos(g_tdm));
  91         cvar_set("g_domination", ftos(g_domination));
  92         cvar_set("g_ctf", ftos(g_ctf));
  93         cvar_set("g_runematch", ftos(g_runematch));
  94         cvar_set("g_lms", ftos(g_lms));
  95         cvar_set("g_arena", ftos(g_arena));
  96         cvar_set("g_keyhunt", ftos(g_keyhunt));
  97         cvar_set("g_assault", ftos(g_assault));
  98         cvar_set("g_onslaught", ftos(g_onslaught));
  99         cvar_set("g_race", ftos(g_race));
 100         cvar_set("g_nexball", ftos(g_nexball));
 101 }
 102
 103 void ReadGameCvars()
 104 {
 105         float found;
 106         float prev;
 107         float i;
 108
 109         found = 0;
 110         prev = cvar("gamecfg");
 111         for(i = 0; i < 2; ++i)
 112         {
 113                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 114                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 115                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 116                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 117                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 118                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 119                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 120                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 121                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 122                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 123                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 124                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 125
 126                 if(found)
 127                         break;
 128
 129                 prev = -1; // second attempt takes place WITHOUT prev set
 130         }
 131
 132         if(!found)
 133                 g_dm = 1;
 134
 135         if(g_dm && cvar("deathmatch_force_teamplay"))
 136         {
 137                 g_dm = 0;
 138                 g_tdm = 1;
 139         }
 140
 141         teams_matter = 0;
 142 }
 143
 144 void default_delayedinit()
 145 {
 146         if(!scores_initialized)
 147                 ScoreRules_generic();
 148 }
 149
 150 void ActivateTeamplay()
 151 {
 152         float teamplay_default;
 153         teamplay_default = cvar("teamplay_default");
 154
 155         if(teamplay_default)
 156                 teamplay = teamplay_default;
 157         else
 158                 teamplay = 3;
 159         cvar_set("teamplay", ftos(teamplay));
 160
 161         teams_matter = 1;
 162 }
 163
 164 void InitGameplayMode()
 165 {
 166         float fraglimit_override, timelimit_override;
 167
 168         VoteReset();
 169
 170         teams_matter = 0;
 171         cvar_set("teamplay", "0");
 172
 173         // make sure only ONE type is selected
 174         ReadGameCvars();
 175         WriteGameCvars();
 176
 177         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 178         get_mi_min_max(1);
 179         world.mins = mi_min;
 180         world.maxs = mi_max;
 181
 182         MapInfo_LoadMapSettings(mapname);
 183
 184         if not(cvar_value_issafe(world.fog))
 185         {
 186                 print("The current map contains a potentially harmful fog setting, ignored\n");
 187                 world.fog = string_null;
 188         }
 189         if(MapInfo_Map_fog != "")
 190                 if(MapInfo_Map_fog == "none")
 191                         world.fog = string_null;
 192                 else
 193                         world.fog = strzone(MapInfo_Map_fog);
 194         clientstuff = strzone(MapInfo_Map_clientstuff);
 195
 196         MapInfo_ClearTemps();
 197
 198         // in case mapinfo switched the type
 199         ReadGameCvars();
 200
 201         // set both here, gamemode can override it later
 202         timelimit_override = cvar("timelimit_override");
 203         fraglimit_override = cvar("fraglimit_override");
 204
 205         if(g_dm)
 206         {
 207                 game = GAME_DEATHMATCH;
 208                 gamemode_name = "Deathmatch";
 209         }
 210
 211         if(g_tdm)
 212         {
 213                 game = GAME_TEAM_DEATHMATCH;
 214                 gamemode_name = "Team Deathmatch";
 215                 ActivateTeamplay();
 216                 tdm_init();
 217         }
 218
 219         if(g_domination)
 220         {
 221                 game = GAME_DOMINATION;
 222                 gamemode_name = "Domination";
 223                 ActivateTeamplay();
 224                 fraglimit_override = cvar("g_domination_point_limit");
 225                 dom_init();
 226         }
 227
 228         if(g_ctf)
 229         {
 230                 game = GAME_CTF;
 231                 gamemode_name = "Capture the Flag";
 232                 ActivateTeamplay();
 233                 if(cvar("g_campaign"))
 234                         g_ctf_win_mode = 2;
 235                 else
 236                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 237                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 238                 if(g_ctf_win_mode == 2)
 239                         fraglimit_override = cvar("g_ctf_capture_limit");
 240                 else
 241                         fraglimit_override = cvar("capturelimit_override");
 242                 ctf_init();
 243         }
 244
 245         if(g_runematch)
 246         {
 247                 game = GAME_RUNEMATCH;
 248                 gamemode_name = "Rune Match";
 249                 if(cvar("deathmatch_force_teamplay"))
 250                         ActivateTeamplay();
 251                 fraglimit_override = cvar("g_runematch_point_limit");
 252                 runematch_init();
 253         }
 254
 255         if(g_lms)
 256         {
 257                 game = GAME_LMS;
 258                 gamemode_name = "Last Man Standing";
 259                 fraglimit_override = cvar("g_lms_lives_override");
 260                 if(fraglimit_override == 0)
 261                         fraglimit_override = -1;
 262                 lms_lowest_lives = 9999;
 263                 lms_next_place = 0;
 264                 ScoreRules_lms();
 265         }
 266
 267         if(g_arena)
 268         {
 269                 game = GAME_ARENA;
 270                 gamemode_name = "Arena";
 271                 fraglimit_override = cvar("g_arena_point_limit");
 272                 maxspawned = cvar("g_arena_maxspawned");
 273                 if(maxspawned < 2)
 274                         maxspawned = 2;
 275                 arena_roundbased = cvar("g_arena_roundbased");
 276         }
 277
 278         if(g_keyhunt)
 279         {
 280                 game = GAME_KEYHUNT;
 281                 gamemode_name = "Key Hunt";
 282                 ActivateTeamplay();
 283                 fraglimit_override = cvar("g_keyhunt_point_limit");
 284                 kh_init();
 285         }
 286
 287         if(g_assault)
 288         {
 289                 game = GAME_ASSAULT;
 290                 gamemode_name = "Assault";
 291                 ActivateTeamplay();
 292                 ScoreRules_assault();
 293         }
 294
 295         if(g_onslaught)
 296         {
 297                 game = GAME_ONSLAUGHT;
 298                 gamemode_name = "Onslaught";
 299                 ActivateTeamplay();
 300         }
 301
 302         if(g_race)
 303         {
 304                 game = GAME_RACE;
 305                 gamemode_name = "Race";
 306                 g_race_qualifying = cvar("g_race_qualifying");
 307
 308                 if(cvar("g_race_teams"))
 309                 {
 310                         g_race_qualifying = 0; // not supported!
 311                         ActivateTeamplay();
 312                         race_teams = bound(2, cvar("g_race_teams"), 4);
 313                 }
 314                 else
 315                         race_teams = 0;
 316
 317                 if(g_race_qualifying == 1)
 318                         fraglimit_override = 0;
 319                 else
 320                         fraglimit_override = cvar("g_race_laps_limit");
 321
 322                 if(g_race_qualifying)
 323                         independent_players = 1;
 324
 325                 ScoreRules_race();
 326         }
 327
 328         if(g_nexball)
 329         {
 330                 game = GAME_NEXBALL;
 331                 gamemode_name = "Nexball";
 332                 fraglimit_override = cvar("g_nexball_goallimit");
 333                 ActivateTeamplay();
 334                 nb_init();
 335         }
 336
 337         if(teams_matter)
 338                 entcs_init();
 339
 340         // save it (for the next startup)
 341         cvar_set("gamecfg", ftos(game));
 342
 343         cache_mutatormsg = strzone("");
 344         cache_lastmutatormsg = strzone("");
 345
 346         // enforce the server's universal frag/time limits
 347         if(!cvar("g_campaign"))
 348         {
 349                 if(fraglimit_override >= 0)
 350                         cvar_set("fraglimit", ftos(fraglimit_override));
 351                 if(timelimit_override >= 0)
 352                         cvar_set("timelimit", ftos(timelimit_override));
 353         }
 354
 355         if(g_race && g_race_qualifying == 2)
 356         {
 357                 race_fraglimit = cvar("fraglimit");
 358                 cvar_set("fraglimit", "0");
 359         }
 360
 361         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 362 }
 363
 364 string GetClientVersionMessage() {
 365         local string versionmsg;
 366         if (self.version_mismatch) {
 367                 if(self.version < cvar("gameversion")) {
 368                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 369                 } else {
 370                         versionmsg = "^3This server is using an outdated Nexuiz version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 371                 }
 372         } else {
 373                 versionmsg = "^2client version and server version are compatible.^8";
 374         }
 375         return versionmsg;
 376 }
 377
 378
 379 void PrintWelcomeMessage(entity pl)
 380 {
 381         string s, modifications, motd;
 382
 383         if(self.cvar_scr_centertime == 0) return;
 384
 385         if(cvar("g_campaign"))
 386         {
 387                 if(self.classname == "player")
 388                         return;
 389         }
 390         else
 391         {
 392                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 393                         return;
 394         }
 395
 396         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 397                 if(self.welcomemessage_time > time) return;
 398                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 399         }
 400
 401         if(cvar("g_campaign"))
 402         {
 403                 centerprint(pl, campaign_message);
 404                 return;
 405         }
 406
 407 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 408         if(!self.BUTTON_INFO)
 409         {
 410                 // TODO get rid of this too
 411                 local string specString;
 412                 specString = NEWLINES;
 413                 //if(time < game_starttime) //also show the countdown when being a spectator
 414                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 415                 //else
 416                 if (timeoutStatus != 0)
 417                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 418                 else
 419                 {
 420                         if(!self.BUTTON_INFO && self.classname == "player")
 421                                 return;
 422                         goto normal;
 423                 }
 424                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 425         }
 426
 427 :normal
 428         modifications = "";
 429         if(g_minstagib)
 430                 modifications = strcat(modifications, ", MinstaGib");
 431         if(g_nixnex)
 432                 modifications = strcat(modifications, ", NixNex");
 433         if(g_weaponarena)
 434                 modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 435         if(cvar("sv_gravity") < 800)
 436                 modifications = strcat(modifications, ", Low gravity");
 437         if(g_cloaked)
 438                 modifications = strcat(modifications, ", Cloaked");
 439         if(g_footsteps)
 440                 modifications = strcat(modifications, ", Steps");
 441         if(g_grappling_hook)
 442                 modifications = strcat(modifications, ", Hook");
 443         if(g_laserguided_missile)
 444                 modifications = strcat(modifications, ", LG missiles");
 445         if(g_midair)
 446                 modifications = strcat(modifications, ", Midair");
 447         if(g_vampire)
 448                 modifications = strcat(modifications, ", Vampire");
 449         if(g_pinata)
 450                 modifications = strcat(modifications, ", Pinata");
 451         if(g_weapon_stay)
 452                 modifications = strcat(modifications, ", Weapons stay");
 453         if(g_bloodloss > 0)
 454                 modifications = strcat(modifications, ", Bloodloss");
 455         if(g_jetpack)
 456                 modifications = strcat(modifications, ", Jet pack");
 457         modifications = substring(modifications, 2, strlen(modifications) - 2);
 458
 459         local string versionmessage;
 460         versionmessage = GetClientVersionMessage();
 461
 462         s = strcat(s, NEWLINES, "This is Nexuiz ", cvar_string("g_nexuizversion"), "\n", versionmessage);
 463         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 464
 465         if(modifications != "")
 466                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 467
 468         if(timeoutStatus != 0)
 469                 s = strcat(s, "\n\n", getTimeoutText(1));
 470
 471         if (g_grappling_hook)
 472                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 473
 474         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 475         {
 476                 if(cache_lastmutatormsg)
 477                         strunzone(cache_lastmutatormsg);
 478                 if(cache_mutatormsg)
 479                         strunzone(cache_mutatormsg);
 480                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 481                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 482         }
 483
 484         if (cache_mutatormsg != "") {
 485                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 486         }
 487
 488         motd = cvar_string("sv_motd");
 489         if (motd != "") {
 490                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 491         }
 492         s = strcat(s, "\n");
 493
 494         centerprint(pl, s);
 495 }
 496
 497
 498 void SetPlayerColors(entity pl, float _color)
 499 {
 500         /*string s;
 501         s = ftos(cl);
 502         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 503         pl.team = cl + 1;
 504         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 505         pl.clientcolors = 16*cl + cl;*/
 506
 507         float pants, shirt;
 508         pants = _color & 0x0F;
 509         shirt = _color & 0xF0;
 510
 511
 512         if(teams_matter) {
 513                 setcolor(pl, 16*pants + pants);
 514         } else {
 515                 setcolor(pl, shirt + pants);
 516         }
 517 }
 518
 519 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 520 {
 521         float _color;
 522
 523         if(t == 4)
 524                 _color = COLOR_TEAM4 - 1;
 525         else if(t == 3)
 526                 _color = COLOR_TEAM3 - 1;
 527         else if(t == 2)
 528                 _color = COLOR_TEAM2 - 1;
 529         else
 530                 _color = COLOR_TEAM1 - 1;
 531
 532         SetPlayerColors(pl,_color);
 533
 534         if(!noprint && t != s)
 535         {
 536                 //bprint(pl.netname, " has changed to ", TeamNoName(t), "\n");
 537                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 538         }
 539
 540         if(t != s)
 541                 LogTeamchange(pl);
 542 }
 543
 544
 545
 546
 547
 548
 549 // set c1...c4 to show what teams are allowed
 550 void CheckAllowedTeams (entity for_whom)
 551 {
 552         string teament_name;
 553         float dm;
 554         entity head;
 555
 556 //      if(!dom && !ctf)
 557 //              dm = 1;
 558
 559         c1 = c2 = c3 = c4 = -1;
 560         cb1 = cb2 = cb3 = cb4 = 0;
 561
 562         // onslaught is special
 563         if(g_onslaught)
 564         {
 565                 head = findchain(classname, "onslaught_generator");
 566                 while (head)
 567                 {
 568                         if (head.team == COLOR_TEAM1) c1 = 0;
 569                         if (head.team == COLOR_TEAM2) c2 = 0;
 570                         if (head.team == COLOR_TEAM3) c3 = 0;
 571                         if (head.team == COLOR_TEAM4) c4 = 0;
 572                         head = head.chain;
 573                 }
 574                 return;
 575         }
 576
 577         if(g_domination)
 578                 teament_name = "dom_team";
 579         else if(g_ctf)
 580                 teament_name = "ctf_team";
 581         else if(g_tdm)
 582                 teament_name = "tdm_team";
 583         else if(g_nexball)
 584                 teament_name = "nexball_team";
 585         else if(g_assault)
 586         {
 587                 c1 = c2 = 0; // Assault always has 2 teams
 588                 return;
 589         }
 590         else
 591         {
 592                 // cover anything else by treating it like tdm with no teams spawned
 593                 if(g_keyhunt)
 594                         dm = kh_teams;
 595                 else if(g_race)
 596                         dm = race_teams;
 597                 else
 598                         dm = 2;
 599
 600                 if(dm >= 4)
 601                 {
 602                         c1 = c2 = c3 = c4 = 0;
 603                 }
 604                 else if(dm >= 3)
 605                 {
 606                         c1 = c2 = c3 = 0;
 607                 }
 608                 else// if(dm >= 2)
 609                 {
 610                         c1 = c2 = 0;
 611                 }
 612                 return;
 613         }
 614
 615         // first find out what teams are allowed
 616         head = find(world, classname, teament_name);
 617         while(head)
 618         {
 619                 if(!(g_domination && head.netname == ""))
 620                 {
 621                         if(head.team == COLOR_TEAM1)
 622                         {
 623                                 c1 = 0;
 624                         }
 625                         if(head.team == COLOR_TEAM2)
 626                         {
 627                                 c2 = 0;
 628                         }
 629                         if(head.team == COLOR_TEAM3)
 630                         {
 631                                 c3 = 0;
 632                         }
 633                         if(head.team == COLOR_TEAM4)
 634                         {
 635                                 c4 = 0;
 636                         }
 637                 }
 638                 head = find(head, classname, teament_name);
 639         }
 640
 641         if(for_whom)
 642         {
 643                 if(cvar("bot_vs_human") > 0)
 644                 {
 645                         // bots are all blue
 646                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 647                                 c1 = c3 = c4 = -1;
 648                         else
 649                                 c2 = -1;
 650                 }
 651                 else if(cvar("bot_vs_human") < 0)
 652                 {
 653                         // bots are all red
 654                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 655                                 c2 = c3 = c4 = -1;
 656                         else
 657                                 c1 = -1;
 658                 }
 659         }
 660 }
 661
 662 float PlayerValue(entity p)
 663 {
 664         if(IsTeamBalanceForced() == 1)
 665                 return 1;
 666         return 1;
 667 }
 668
 669 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 670 // teams that are allowed will now have their player counts stored in c1...c4
 671 void GetTeamCounts(entity ignore)
 672 {
 673         entity head;
 674         float value, bvalue;
 675         // now count how many players are on each team already
 676
 677         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 678         // also remember the lowest-scoring player
 679
 680         FOR_EACH_PLAYER(head)
 681         {
 682                 if(head != ignore)// && head.netname != "")
 683                 {
 684                         value = PlayerValue(head);
 685                         if(clienttype(head) == CLIENTTYPE_BOT)
 686                                 bvalue = value;
 687                         else
 688                                 bvalue = 0;
 689                         if(head.team == COLOR_TEAM1)
 690                         {
 691                                 if(c1 >= 0)
 692                                 {
 693                                         c1 = c1 + value;
 694                                         cb1 = cb1 + bvalue;
 695                                 }
 696                         }
 697                         if(head.team == COLOR_TEAM2)
 698                         {
 699                                 if(c2 >= 0)
 700                                 {
 701                                         c2 = c2 + value;
 702                                         cb2 = cb2 + bvalue;
 703                                 }
 704                         }
 705                         if(head.team == COLOR_TEAM3)
 706                         {
 707                                 if(c3 >= 0)
 708                                 {
 709                                         c3 = c3 + value;
 710                                         cb3 = cb3 + bvalue;
 711                                 }
 712                         }
 713                         if(head.team == COLOR_TEAM4)
 714                         {
 715                                 if(c4 >= 0)
 716                                 {
 717                                         c4 = c4 + value;
 718                                         cb4 = cb4 + bvalue;
 719                                 }
 720                         }
 721                 }
 722         }
 723 }
 724
 725 // returns # of smallest team (1, 2, 3, 4)
 726 // NOTE: Assumes CheckAllowedTeams has already been called!
 727 float FindSmallestTeam(entity pl, float ignore_pl)
 728 {
 729         float totalteams, smallestteam, smallestteam_count, smallestteam_score, balance_type;
 730         totalteams = 0;
 731
 732         // find out what teams are available
 733         //CheckAllowedTeams();
 734
 735         // make sure there are at least 2 teams to join
 736         if(c1 >= 0)
 737                 totalteams = totalteams + 1;
 738         if(c2 >= 0)
 739                 totalteams = totalteams + 1;
 740         if(c3 >= 0)
 741                 totalteams = totalteams + 1;
 742         if(c4 >= 0)
 743                 totalteams = totalteams + 1;
 744
 745         if(cvar("bot_vs_human"))
 746                 totalteams += 1;
 747
 748         if(totalteams <= 1)
 749         {
 750                 if(g_domination)
 751                         error("Too few teams available for domination\n");
 752                 else if(g_ctf)
 753                         error("Too few teams available for ctf\n");
 754                 else if(g_keyhunt)
 755                         error("Too few teams available for key hunt\n");
 756                 else
 757                         error("Too few teams available for team deathmatch\n");
 758         }
 759
 760         // count how many players are in each team
 761         if(ignore_pl)
 762                 GetTeamCounts(pl);
 763         else
 764                 GetTeamCounts(world);
 765
 766         // c1...c4 now have counts of each team
 767         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 768
 769         smallestteam = 0;
 770         smallestteam_count = 999999999;
 771         smallestteam_score = 999999999;
 772
 773         // 2 gives priority to what team you're already on, 1 goes in order
 774         // 2 doesn't seem to work though...
 775         balance_type = 1;
 776
 777         if(bots_would_leave)
 778         //if(pl.classname != "player")
 779         if(clienttype(pl) != CLIENTTYPE_BOT)
 780         {
 781                 c1 -= cb1 * 255.0/256;
 782                 c2 -= cb2 * 255.0/256;
 783                 c3 -= cb3 * 255.0/256;
 784                 c4 -= cb4 * 255.0/256;
 785         }
 786
 787         if(balance_type == 1)
 788         {
 789                 if(c1 >= 0 && (c1 < smallestteam_count || (c1 <= smallestteam_count && team1_score < smallestteam_score)))
 790                 {
 791                         smallestteam = 1;
 792                         smallestteam_count = c1;
 793                         smallestteam_score = team1_score;
 794                 }
 795                 if(c2 >= 0 && (c2 < smallestteam_count || (c2 <= smallestteam_count && team2_score < smallestteam_score)))
 796                 {
 797                         smallestteam = 2;
 798                         smallestteam_count = c2;
 799                         smallestteam_score = team2_score;
 800                 }
 801                 if(c3 >= 0 && (c3 < smallestteam_count || (c3 <= smallestteam_count && team3_score < smallestteam_score)))
 802                 {
 803                         smallestteam = 3;
 804                         smallestteam_count = c3;
 805                         smallestteam_score = team3_score;
 806                 }
 807                 if(c4 >= 0 && (c4 < smallestteam_count || (c4 <= smallestteam_count && team4_score < smallestteam_score)))
 808                 {
 809                         smallestteam = 4;
 810                         smallestteam_count = c4;
 811                         smallestteam_score = team4_score;
 812                 }
 813         }
 814         else
 815         {
 816                 if(c1 >= 0 && (c1 < smallestteam_count ||
 817                                         (c1 == smallestteam_count && self.team == COLOR_TEAM1) ) )
 818                 {
 819                         smallestteam = 1;
 820                         smallestteam_count = c1;
 821                 }
 822                 if(c2 >= 0 && c2 < (c2 < smallestteam_count ||
 823                                         (c2 == smallestteam_count && self.team == COLOR_TEAM2) ) )
 824                 {
 825                         smallestteam = 2;
 826                         smallestteam_count = c2;
 827                 }
 828                 if(c3 >= 0 && c3 < (c3 < smallestteam_count ||
 829                                         (c3 == smallestteam_count && self.team == COLOR_TEAM3) ) )
 830                 {
 831                         smallestteam = 3;
 832                         smallestteam_count = c3;
 833                 }
 834                 if(c4 >= 0 && c4 < (c4 < smallestteam_count ||
 835                                         (c4 == smallestteam_count && self.team == COLOR_TEAM4) ) )
 836                 {
 837                         smallestteam = 4;
 838                         smallestteam_count = c4;
 839                 }
 840         }
 841
 842         return smallestteam;
 843 }
 844
 845 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 846 {
 847         float smallest, selectedteam;
 848
 849         // don't join a team if we're not playing a team game
 850         if(!teams_matter)
 851                 return 0;
 852
 853         // find out what teams are available
 854         CheckAllowedTeams(pl);
 855
 856         if(g_domination)
 857         {
 858                 // <div0> WHY? TODO
 859                 if(cvar("g_domination_default_teams") < 3)
 860                         c3 = 999999999;
 861                 if(cvar("g_domination_default_teams") < 4)
 862                         c4 = 999999999;
 863         }
 864
 865         // if we don't care what team he ends up on, put him on whatever team he entered as.
 866         // if he's not on a valid team, then let other code put him on the smallest team
 867         if(!forcebestteam)
 868         {
 869                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 870                         selectedteam = pl.team;
 871                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 872                         selectedteam = pl.team;
 873                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 874                         selectedteam = pl.team;
 875                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 876                         selectedteam = pl.team;
 877                 else
 878                         selectedteam = -1;
 879                 if(selectedteam > 0)
 880                 {
 881                         if(!only_return_best)
 882                         {
 883                                 SetPlayerColors(pl, selectedteam - 1);
 884                                 LogTeamchange(pl);
 885                         }
 886                         return selectedteam;
 887                 }
 888                 // otherwise end up on the smallest team (handled below)
 889         }
 890
 891         smallest = FindSmallestTeam(pl, TRUE);
 892
 893
 894         if(!only_return_best)
 895         {
 896                 TeamchangeFrags(self);
 897                 if(smallest == 1)
 898                 {
 899                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 900                 }
 901                 else if(smallest == 2)
 902                 {
 903                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 904                 }
 905                 else if(smallest == 3)
 906                 {
 907                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 908                 }
 909                 else if(smallest == 4)
 910                 {
 911                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 912                 }
 913                 else
 914                 {
 915                         error("smallest team: invalid team\n");
 916                 }
 917                 LogTeamchange(pl);
 918                 if(pl.deadflag == DEAD_NO)
 919                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 920         }
 921
 922         return smallest;
 923 }
 924
 925 //void() ctf_playerchanged;
 926 void SV_ChangeTeam(float _color)
 927 {
 928         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 929
 930         // in normal deathmatch we can just apply the color and we're done
 931         if(!teams_matter) {
 932                 SetPlayerColors(self, _color);
 933                 return;
 934         }
 935
 936         scolor = self.clientcolors & 0x0F;
 937         dcolor = _color & 0x0F;
 938
 939         if(scolor == COLOR_TEAM1 - 1)
 940                 steam = 1;
 941         else if(scolor == COLOR_TEAM2 - 1)
 942                 steam = 2;
 943         else if(scolor == COLOR_TEAM3 - 1)
 944                 steam = 3;
 945         else // if(scolor == COLOR_TEAM4 - 1)
 946                 steam = 4;
 947         if(dcolor == COLOR_TEAM1 - 1)
 948                 dteam = 1;
 949         else if(dcolor == COLOR_TEAM2 - 1)
 950                 dteam = 2;
 951         else if(dcolor == COLOR_TEAM3 - 1)
 952                 dteam = 3;
 953         else // if(dcolor == COLOR_TEAM4 - 1)
 954                 dteam = 4;
 955
 956         CheckAllowedTeams(self);
 957
 958         if(dteam == 1 && c1 < 0) dteam = 4;
 959         if(dteam == 4 && c4 < 0) dteam = 3;
 960         if(dteam == 3 && c3 < 0) dteam = 2;
 961         if(dteam == 2 && c2 < 0) dteam = 1;
 962
 963         // not changing teams
 964         if(scolor == dcolor)
 965         {
 966                 //bprint("same team change\n");
 967                 SetPlayerTeam(self, dteam, steam, TRUE);
 968                 return;
 969         }
 970
 971         if(cvar("g_campaign"))
 972         {
 973                 sprint(self, "Team changes not allowed\n");
 974                 return; // changing teams is not allowed
 975         }
 976
 977         if(cvar("g_changeteam_banned") && self.wasplayer)
 978         {
 979                 sprint(self, "Team changes not allowed\n");
 980                 return;
 981         }
 982
 983         if(cvar("g_balance_teams_prevent_imbalance"))
 984         {
 985                 // only allow changing to a smaller or equal size team
 986
 987                 // find out what teams are available
 988                 //CheckAllowedTeams();
 989                 // count how many players on each team
 990                 GetTeamCounts(world);
 991
 992                 // get desired team
 993                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 994                 {
 995                         dcount = c1;
 996                         dbotcount = cb1;
 997                 }
 998                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 999                 {
1000                         dcount = c2;
1001                         dbotcount = cb2;
1002                 }
1003                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1004                 {
1005                         dcount = c3;
1006                         dbotcount = cb3;
1007                 }
1008                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1009                 {
1010                         dcount = c4;
1011                         dbotcount = cb4;
1012                 }
1013                 else
1014                 {
1015                         sprint(self, "Cannot change to an invalid team\n");
1016
1017                         return;
1018                 }
1019
1020                 // get starting team
1021                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1022                         scount = c1;
1023                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1024                         scount = c2;
1025                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1026                         scount = c3;
1027                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1028                         scount = c4;
1029
1030                 if(scount) // started at a valid, nonempty team
1031                 {
1032                         // check if we're trying to change to a larger team that doens't have bots to swap with
1033                         if(dcount >= scount && dbotcount <= 0)
1034                         {
1035                                 sprint(self, "Cannot change to a larger team\n");
1036                                 return; // can't change to a larger team
1037                         }
1038                 }
1039         }
1040
1041 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1042
1043         if(self.classname == "player" && steam != dteam)
1044         {
1045                 // reduce frags during a team change
1046                 TeamchangeFrags(self);
1047         }
1048
1049         SetPlayerTeam(self, dteam, steam, FALSE);
1050
1051         if(self.classname == "player" && steam != dteam)
1052         {
1053                 // kill player when changing teams
1054                 if(self.deadflag == DEAD_NO)
1055                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1056         }
1057         //ctf_playerchanged();
1058 }
1059
1060 void ShufflePlayerOutOfTeam (float source_team)
1061 {
1062         float smallestteam, smallestteam_count, steam;
1063         float lowest_bot_score, lowest_player_score;
1064         entity head, lowest_bot, lowest_player, selected;
1065
1066         smallestteam = 0;
1067         smallestteam_count = 999999999;
1068
1069         if(c1 >= 0 && c1 < smallestteam_count)
1070         {
1071                 smallestteam = 1;
1072                 smallestteam_count = c1;
1073         }
1074         if(c2 >= 0 && c2 < smallestteam_count)
1075         {
1076                 smallestteam = 2;
1077                 smallestteam_count = c2;
1078         }
1079         if(c3 >= 0 && c3 < smallestteam_count)
1080         {
1081                 smallestteam = 3;
1082                 smallestteam_count = c3;
1083         }
1084         if(c4 >= 0 && c4 < smallestteam_count)
1085         {
1086                 smallestteam = 4;
1087                 smallestteam_count = c4;
1088         }
1089
1090         if(!smallestteam)
1091         {
1092                 bprint("warning: no smallest team\n");
1093                 return;
1094         }
1095
1096         if(source_team == 1)
1097                 steam = COLOR_TEAM1;
1098         else if(source_team == 2)
1099                 steam = COLOR_TEAM2;
1100         else if(source_team == 3)
1101                 steam = COLOR_TEAM3;
1102         else if(source_team == 4)
1103                 steam = COLOR_TEAM4;
1104
1105         lowest_bot = world;
1106         lowest_bot_score = 999999999;
1107         lowest_player = world;
1108         lowest_player_score = 999999999;
1109
1110         // find the lowest-scoring player & bot of that team
1111         FOR_EACH_PLAYER(head)
1112         {
1113                 if(head.team == steam)
1114                 {
1115                         if(head.isbot)
1116                         {
1117                                 if(head.totalfrags < lowest_bot_score)
1118                                 {
1119                                         lowest_bot = head;
1120                                         lowest_bot_score = head.totalfrags;
1121                                 }
1122                         }
1123                         else
1124                         {
1125                                 if(head.totalfrags < lowest_player_score)
1126                                 {
1127                                         lowest_player = head;
1128                                         lowest_player_score = head.totalfrags;
1129                                 }
1130                         }
1131                 }
1132         }
1133
1134         // prefers to move a bot...
1135         if(lowest_bot != world)
1136                 selected = lowest_bot;
1137         // but it will move a player if it has to
1138         else
1139                 selected = lowest_player;
1140         // don't do anything if it couldn't find anyone
1141         if(!selected)
1142         {
1143                 bprint("warning: couldn't find a player to move from team\n");
1144                 return;
1145         }
1146
1147         // smallest team gains a member
1148         if(smallestteam == 1)
1149         {
1150                 c1 = c1 + 1;
1151         }
1152         else if(smallestteam == 2)
1153         {
1154                 c2 = c2 + 1;
1155         }
1156         else if(smallestteam == 3)
1157         {
1158                 c3 = c3 + 1;
1159         }
1160         else if(smallestteam == 4)
1161         {
1162                 c4 = c4 + 1;
1163         }
1164         else
1165         {
1166                 bprint("warning: destination team invalid\n");
1167                 return;
1168         }
1169         // source team loses a member
1170         if(source_team == 1)
1171         {
1172                 c1 = c1 + 1;
1173         }
1174         else if(source_team == 2)
1175         {
1176                 c2 = c2 + 2;
1177         }
1178         else if(source_team == 3)
1179         {
1180                 c3 = c3 + 3;
1181         }
1182         else if(source_team == 4)
1183         {
1184                 c4 = c4 + 4;
1185         }
1186         else
1187         {
1188                 bprint("warning: source team invalid\n");
1189                 return;
1190         }
1191
1192         // move the player to the new team
1193         TeamchangeFrags(selected);
1194         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1195
1196         if(selected.deadflag == DEAD_NO)
1197                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1198         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1199 }
1200
1201 void CauseRebalance(float source_team, float howmany_toomany)
1202 {
1203         if(IsTeamBalanceForced() == 1)
1204         {
1205                 bprint("Rebalancing Teams\n");
1206                 ShufflePlayerOutOfTeam(source_team);
1207         }
1208 }
1209
1210 // part of g_balance_teams_force
1211 // occasionally perform an audit of the teams to make
1212 // sure they're more or less balanced in player count.
1213 void AuditTeams()
1214 {
1215         float numplayers, numteams, smallest, toomany;
1216         float balance;
1217         balance = IsTeamBalanceForced();
1218         if(balance == 0)
1219                 return;
1220
1221         if(audit_teams_time > time)
1222                 return;
1223
1224         audit_teams_time = time + 4 + random();
1225
1226 //      bprint("Auditing teams\n");
1227
1228         CheckAllowedTeams(world);
1229         GetTeamCounts(world);
1230
1231
1232         numteams = numplayers = smallest = 0;
1233         if(c1 >= 0)
1234         {
1235                 numteams = numteams + 1;
1236                 numplayers = numplayers + c1;
1237                 smallest = c1;
1238         }
1239         if(c2 >= 0)
1240         {
1241                 numteams = numteams + 1;
1242                 numplayers = numplayers + c2;
1243                 if(c2 < smallest)
1244                         smallest = c2;
1245         }
1246         if(c3 >= 0)
1247         {
1248                 numteams = numteams + 1;
1249                 numplayers = numplayers + c3;
1250                 if(c3 < smallest)
1251                         smallest = c3;
1252         }
1253         if(c4 >= 0)
1254         {
1255                 numteams = numteams + 1;
1256                 numplayers = numplayers + c4;
1257                 if(c4 < smallest)
1258                         smallest = c4;
1259         }
1260
1261         if(numplayers <= 0)
1262                 return; // no players to move around
1263         if(numteams < 2)
1264                 return; // don't bother shuffling if for some reason there aren't any teams
1265
1266         toomany = smallest + 1;
1267
1268         if(c1 && c1 > toomany)
1269                 CauseRebalance(1, c1 - toomany);
1270         if(c2 && c2 > toomany)
1271                 CauseRebalance(2, c2 - toomany);
1272         if(c3 && c3 > toomany)
1273                 CauseRebalance(3, c3 - toomany);
1274         if(c4 && c4 > toomany)
1275                 CauseRebalance(4, c4 - toomany);
1276
1277         // if teams are still unbalanced, balance them further in the next audit,
1278         // which will happen sooner (keep doing rapid audits until things are in order)
1279         audit_teams_time = time + 0.7 + random()*0.3;
1280 }
1281
1282 // code from here on is just to support maps that don't have team entities
1283 void tdm_spawnteam (string teamname, float teamcolor)
1284 {
1285         local entity e;
1286         e = spawn();
1287         e.classname = "tdm_team";
1288         e.netname = teamname;
1289         e.cnt = teamcolor;
1290         e.team = e.cnt + 1;
1291 };
1292
1293 // spawn some default teams if the map is not set up for tdm
1294 void tdm_spawnteams()
1295 {
1296         float numteams;
1297
1298         numteams = cvar("g_tdm_teams_override");
1299         if(numteams < 2)
1300                 numteams = cvar("g_tdm_teams");
1301         numteams = bound(2, numteams, 4);
1302
1303         tdm_spawnteam("Red", COLOR_TEAM1-1);
1304         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1305         if(numteams >= 3)
1306                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1307         if(numteams >= 4)
1308                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1309 };
1310
1311 void tdm_delayedinit()
1312 {
1313         // if no teams are found, spawn defaults
1314         if (find(world, classname, "tdm_team") == world)
1315                 tdm_spawnteams();
1316 };
1317
1318 void tdm_init()
1319 {
1320         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1321 };