data/qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void entcs_init();
  73
  74 void LogTeamchange(entity pl)
  75 {
  76         string str;
  77         if(!cvar("sv_eventlog"))
  78                 return;
  79         if(pl.playerid < 1)
  80                 return;
  81         str = strcat(":team:", ftos(pl.playerid), ":");
  82         str = strcat(str, ftos(pl.team));
  83         GameLogEcho(str);
  84 }
  85
  86 void WriteGameCvars()
  87 {
  88         cvar_set("g_dm", ftos(g_dm));
  89         cvar_set("g_tdm", ftos(g_tdm));
  90         cvar_set("g_domination", ftos(g_domination));
  91         cvar_set("g_ctf", ftos(g_ctf));
  92         cvar_set("g_runematch", ftos(g_runematch));
  93         cvar_set("g_lms", ftos(g_lms));
  94         cvar_set("g_arena", ftos(g_arena));
  95         cvar_set("g_keyhunt", ftos(g_keyhunt));
  96         cvar_set("g_assault", ftos(g_assault));
  97         cvar_set("g_onslaught", ftos(g_onslaught));
  98         cvar_set("g_race", ftos(g_race));
  99 }
 100
 101 void ReadGameCvars()
 102 {
 103         float found;
 104         float prev;
 105         float i;
 106
 107         found = 0;
 108         prev = cvar("gamecfg");
 109         for(i = 0; i < 2; ++i)
 110         {
 111                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 112                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 113                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 114                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 115                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 116                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 117                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 118                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 119                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 120                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 121                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 122
 123                 if(found)
 124                         break;
 125
 126                 prev = -1; // second attempt takes place WITHOUT prev set
 127         }
 128
 129         if(!found)
 130                 g_dm = 1;
 131
 132         if(g_dm && cvar("deathmatch_force_teamplay"))
 133         {
 134                 g_dm = 0;
 135                 g_tdm = 1;
 136         }
 137
 138         teams_matter = 0;
 139 }
 140
 141 void default_delayedinit()
 142 {
 143         if(!scores_initialized)
 144                 ScoreRules_generic();
 145 }
 146
 147 void ActivateTeamplay()
 148 {
 149         float teamplay_default;
 150         teamplay_default = cvar("teamplay_default");
 151
 152         if(teamplay_default)
 153                 teamplay = teamplay_default;
 154         else
 155                 teamplay = 3;
 156         cvar_set("teamplay", ftos(teamplay));
 157
 158         teams_matter = 1;
 159 }
 160
 161 void InitGameplayMode()
 162 {
 163         float fraglimit_override, timelimit_override;
 164
 165         VoteReset();
 166
 167         teams_matter = 0;
 168         cvar_set("teamplay", "0");
 169
 170         // make sure only ONE type is selected
 171         ReadGameCvars();
 172         WriteGameCvars();
 173
 174         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 175         get_mi_min_max(1);
 176         world.mins = mi_min;
 177         world.maxs = mi_max;
 178
 179         MapInfo_LoadMapSettings(mapname);
 180
 181         if not(cvar_value_issafe(world.fog))
 182         {
 183                 print("The current map contains a potentially harmful fog setting, ignored\n");
 184                 world.fog = string_null;
 185         }
 186         if(MapInfo_Map_fog != "")
 187                 if(MapInfo_Map_fog == "none")
 188                         world.fog = string_null;
 189                 else
 190                         world.fog = strzone(MapInfo_Map_fog);
 191         clientstuff = strzone(MapInfo_Map_clientstuff);
 192
 193         MapInfo_ClearTemps();
 194
 195         // in case mapinfo switched the type
 196         ReadGameCvars();
 197
 198         // set both here, gamemode can override it later
 199         timelimit_override = cvar("timelimit_override");
 200         fraglimit_override = cvar("fraglimit_override");
 201
 202         if(g_dm)
 203         {
 204                 game = GAME_DEATHMATCH;
 205                 gamemode_name = "Deathmatch";
 206         }
 207
 208         if(g_tdm)
 209         {
 210                 game = GAME_TEAM_DEATHMATCH;
 211                 gamemode_name = "Team Deathmatch";
 212                 ActivateTeamplay();
 213                 tdm_init();
 214         }
 215
 216         if(g_domination)
 217         {
 218                 game = GAME_DOMINATION;
 219                 gamemode_name = "Domination";
 220                 ActivateTeamplay();
 221                 fraglimit_override = cvar("g_domination_point_limit");
 222                 dom_init();
 223         }
 224
 225         if(g_ctf)
 226         {
 227                 game = GAME_CTF;
 228                 gamemode_name = "Capture the Flag";
 229                 ActivateTeamplay();
 230                 if(cvar("g_campaign"))
 231                         g_ctf_win_mode = 2;
 232                 else
 233                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 234                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 235                 if(g_ctf_win_mode == 2)
 236                         fraglimit_override = cvar("g_ctf_capture_limit");
 237                 else
 238                         fraglimit_override = cvar("capturelimit_override");
 239                 ctf_init();
 240         }
 241
 242         if(g_runematch)
 243         {
 244                 game = GAME_RUNEMATCH;
 245                 gamemode_name = "Rune Match";
 246                 if(cvar("deathmatch_force_teamplay"))
 247                         ActivateTeamplay();
 248                 fraglimit_override = cvar("g_runematch_point_limit");
 249                 runematch_init();
 250         }
 251
 252         if(g_lms)
 253         {
 254                 game = GAME_LMS;
 255                 gamemode_name = "Last Man Standing";
 256                 fraglimit_override = cvar("g_lms_lives_override");
 257                 if(fraglimit_override == 0)
 258                         fraglimit_override = -1;
 259                 lms_lowest_lives = 9999;
 260                 lms_next_place = 0;
 261                 ScoreRules_lms();
 262         }
 263
 264         if(g_arena)
 265         {
 266                 game = GAME_ARENA;
 267                 gamemode_name = "Arena";
 268                 fraglimit_override = cvar("g_arena_point_limit");
 269                 maxspawned = cvar("g_arena_maxspawned");
 270                 if(maxspawned < 2)
 271                         maxspawned = 2;
 272                 arena_roundbased = cvar("g_arena_roundbased");
 273         }
 274
 275         if(g_keyhunt)
 276         {
 277                 game = GAME_KEYHUNT;
 278                 gamemode_name = "Key Hunt";
 279                 ActivateTeamplay();
 280                 fraglimit_override = cvar("g_keyhunt_point_limit");
 281                 kh_init();
 282         }
 283
 284         if(g_assault)
 285         {
 286                 game = GAME_ASSAULT;
 287                 gamemode_name = "Assault";
 288                 ActivateTeamplay();
 289                 ScoreRules_assault();
 290         }
 291
 292         if(g_onslaught)
 293         {
 294                 game = GAME_ONSLAUGHT;
 295                 gamemode_name = "Onslaught";
 296                 ActivateTeamplay();
 297         }
 298
 299         if(g_race)
 300         {
 301                 game = GAME_RACE;
 302                 gamemode_name = "Race";
 303                 g_race_qualifying = cvar("g_race_qualifying");
 304
 305                 if(cvar("g_race_teams"))
 306                 {
 307                         g_race_qualifying = 0; // not supported!
 308                         ActivateTeamplay();
 309                         race_teams = bound(2, cvar("g_race_teams"), 4);
 310                 }
 311                 else
 312                         race_teams = 0;
 313
 314                 if(g_race_qualifying == 1)
 315                         fraglimit_override = 0;
 316                 else
 317                         fraglimit_override = cvar("g_race_laps_limit");
 318
 319                 if(g_race_qualifying)
 320                         independent_players = 1;
 321
 322                 ScoreRules_race();
 323         }
 324
 325         if(teams_matter)
 326                 entcs_init();
 327
 328         // save it (for the next startup)
 329         cvar_set("gamecfg", ftos(game));
 330
 331         cache_mutatormsg = strzone("");
 332         cache_lastmutatormsg = strzone("");
 333
 334         // enforce the server's universal frag/time limits
 335         if(!cvar("g_campaign"))
 336         {
 337                 if(fraglimit_override >= 0)
 338                         cvar_set("fraglimit", ftos(fraglimit_override));
 339                 if(timelimit_override >= 0)
 340                         cvar_set("timelimit", ftos(timelimit_override));
 341         }
 342
 343         if(g_race && g_race_qualifying == 2)
 344         {
 345                 race_fraglimit = cvar("fraglimit");
 346                 cvar_set("fraglimit", "0");
 347         }
 348
 349         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 350 }
 351
 352 string GetClientVersionMessage() {
 353         local string versionmsg;
 354         if (self.version_mismatch) {
 355                 if(self.version < cvar("gameversion")) {
 356                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 357                 } else {
 358                         versionmsg = "^3This server is using an outdated Nexuiz version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 359                 }
 360         } else {
 361                 versionmsg = "^2client version and server version are compatible.^8";
 362         }
 363         return versionmsg;
 364 }
 365
 366
 367 void PrintWelcomeMessage(entity pl)
 368 {
 369         string s, modifications, motd;
 370
 371         if(self.cvar_scr_centertime == 0) return;
 372         if((time - self.jointime) > cvar("welcome_message_time")
 373            && !self.BUTTON_INFO)
 374                 return;
 375
 376         if( !(timeoutStatus >= 1 || (time < game_starttime) ) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 377                 if(self.welcomemessage_time > time) return;
 378                 self.welcomemessage_time = time + self.cvar_scr_centertime * 0.6;
 379         }
 380
 381         if(cvar("g_campaign"))
 382         {
 383                 centerprint(pl, campaign_message);
 384                 return;
 385         }
 386
 387 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 388         if(!self.BUTTON_INFO)
 389         {
 390                 // TODO get rid of this too
 391                 local string specString;
 392                 specString = NEWLINES;
 393                 //if(time < game_starttime) //also show the countdown when being a spectator
 394                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 395                 //else
 396                 if (timeoutStatus != 0)
 397                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 398                 else
 399                 {
 400                         if(!self.BUTTON_INFO && self.classname == "player")
 401                                 return;
 402                         goto normal;
 403                 }
 404                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 405         }
 406
 407 :normal
 408         modifications = "";
 409         if(g_minstagib)
 410                 modifications = strcat(modifications, ", MinstaGib");
 411         if(g_nixnex)
 412                 modifications = strcat(modifications, ", NixNex");
 413         if(g_weaponarena)
 414                 modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 415         if(cvar("sv_gravity") < 800)
 416                 modifications = strcat(modifications, ", Low gravity");
 417         if(g_cloaked)
 418                 modifications = strcat(modifications, ", Cloaked");
 419         if(g_footsteps)
 420                 modifications = strcat(modifications, ", Steps");
 421         if(g_grappling_hook)
 422                 modifications = strcat(modifications, ", Hook");
 423         if(g_laserguided_missile)
 424                 modifications = strcat(modifications, ", LG missiles");
 425         if(g_midair)
 426                 modifications = strcat(modifications, ", Midair");
 427         if(g_vampire)
 428                 modifications = strcat(modifications, ", Vampire");
 429         if(g_pinata)
 430                 modifications = strcat(modifications, ", Pinata");
 431         if(g_weapon_stay)
 432                 modifications = strcat(modifications, ", Weapons stay");
 433         if(g_bloodloss > 0)
 434                 modifications = strcat(modifications, ", Bloodloss");
 435         modifications = substring(modifications, 2, strlen(modifications) - 2);
 436
 437         local string versionmessage;
 438         versionmessage = GetClientVersionMessage();
 439
 440         s = strcat(s, NEWLINES, "This is Nexuiz ", cvar_string("g_nexuizversion"), "\n", versionmessage);
 441         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 442
 443         if(modifications != "")
 444                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 445
 446         if(timeoutStatus != 0)
 447                 s = strcat(s, "\n\n", getTimeoutText(1));
 448
 449         if (g_grappling_hook)
 450                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 451
 452         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 453         {
 454                 if(cache_lastmutatormsg)
 455                         strunzone(cache_lastmutatormsg);
 456                 if(cache_mutatormsg)
 457                         strunzone(cache_mutatormsg);
 458                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 459                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 460         }
 461
 462         if (cache_mutatormsg != "") {
 463                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 464         }
 465
 466         motd = cvar_string("sv_motd");
 467         if (motd != "") {
 468                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 469         }
 470         s = strcat(s, "\n");
 471
 472         centerprint(pl, s);
 473 }
 474
 475
 476 void SetPlayerColors(entity pl, float _color)
 477 {
 478         /*string s;
 479         s = ftos(cl);
 480         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 481         pl.team = cl + 1;
 482         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 483         pl.clientcolors = 16*cl + cl;*/
 484
 485         float pants, shirt;
 486         pants = _color & 0x0F;
 487         shirt = _color & 0xF0;
 488
 489
 490         if(teams_matter) {
 491                 setcolor(pl, 16*pants + pants);
 492         } else {
 493                 setcolor(pl, shirt + pants);
 494         }
 495 }
 496
 497 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 498 {
 499         float _color;
 500
 501         if(t == 4)
 502                 _color = COLOR_TEAM4 - 1;
 503         else if(t == 3)
 504                 _color = COLOR_TEAM3 - 1;
 505         else if(t == 2)
 506                 _color = COLOR_TEAM2 - 1;
 507         else
 508                 _color = COLOR_TEAM1 - 1;
 509
 510         SetPlayerColors(pl,_color);
 511
 512         if(!noprint && t != s)
 513         {
 514                 //bprint(pl.netname, " has changed to ", TeamNoName(t), "\n");
 515                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 516         }
 517
 518         if(t != s)
 519                 LogTeamchange(pl);
 520 }
 521
 522
 523
 524
 525
 526
 527 // set c1...c4 to show what teams are allowed
 528 void CheckAllowedTeams (entity for_whom)
 529 {
 530         string teament_name;
 531         float dm;
 532         entity head;
 533
 534 //      if(!dom && !ctf)
 535 //              dm = 1;
 536
 537         c1 = c2 = c3 = c4 = -1;
 538         cb1 = cb2 = cb3 = cb4 = 0;
 539
 540         // onslaught is special
 541         if(g_onslaught)
 542         {
 543                 head = findchain(classname, "onslaught_generator");
 544                 while (head)
 545                 {
 546                         if (head.team == COLOR_TEAM1) c1 = 0;
 547                         if (head.team == COLOR_TEAM2) c2 = 0;
 548                         if (head.team == COLOR_TEAM3) c3 = 0;
 549                         if (head.team == COLOR_TEAM4) c4 = 0;
 550                         head = head.chain;
 551                 }
 552                 return;
 553         }
 554
 555         if(g_domination)
 556                 teament_name = "dom_team";
 557         else if(g_ctf)
 558                 teament_name = "ctf_team";
 559         else if(g_tdm)
 560                 teament_name = "tdm_team";
 561         else if(g_assault)
 562         {
 563                 c1 = c2 = 0; // Assault always has 2 teams
 564                 return;
 565         }
 566         else
 567         {
 568                 // cover anything else by treating it like tdm with no teams spawned
 569                 if(g_keyhunt)
 570                         dm = kh_teams;
 571                 else if(g_race)
 572                         dm = race_teams;
 573                 else
 574                         dm = cvar("g_tdm_teams");
 575                 if(dm < 2)
 576                         error("g_tdm_teams < 2, not enough teams to play team deathmatch\n");
 577
 578                 if(dm >= 4)
 579                 {
 580                         c1 = c2 = c3 = c4 = 0;
 581                 }
 582                 else if(dm >= 3)
 583                 {
 584                         c1 = c2 = c3 = 0;
 585                 }
 586                 else// if(dm >= 2)
 587                 {
 588                         c1 = c2 = 0;
 589                 }
 590                 return;
 591         }
 592
 593         // first find out what teams are allowed
 594         head = find(world, classname, teament_name);
 595         while(head)
 596         {
 597                 if(!(g_domination && head.netname == ""))
 598                 {
 599                         if(head.team == COLOR_TEAM1)
 600                         {
 601                                 c1 = 0;
 602                         }
 603                         if(head.team == COLOR_TEAM2)
 604                         {
 605                                 c2 = 0;
 606                         }
 607                         if(head.team == COLOR_TEAM3)
 608                         {
 609                                 c3 = 0;
 610                         }
 611                         if(head.team == COLOR_TEAM4)
 612                         {
 613                                 c4 = 0;
 614                         }
 615                 }
 616                 head = find(head, classname, teament_name);
 617         }
 618
 619         if(for_whom)
 620         {
 621                 if(cvar("bot_vs_human") > 0)
 622                 {
 623                         // bots are all blue
 624                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 625                                 c1 = c3 = c4 = -1;
 626                         else
 627                                 c2 = -1;
 628                 }
 629                 else if(cvar("bot_vs_human") < 0)
 630                 {
 631                         // bots are all red
 632                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 633                                 c2 = c3 = c4 = -1;
 634                         else
 635                                 c1 = -1;
 636                 }
 637         }
 638 }
 639
 640 float PlayerValue(entity p)
 641 {
 642         if(IsTeamBalanceForced() == 1)
 643                 return 1;
 644         return 1;
 645 }
 646
 647 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 648 // teams that are allowed will now have their player counts stored in c1...c4
 649 void GetTeamCounts(entity ignore)
 650 {
 651         entity head;
 652         float value, bvalue;
 653         // now count how many players are on each team already
 654
 655         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 656         // also remember the lowest-scoring player
 657
 658         FOR_EACH_PLAYER(head)
 659         {
 660                 if(head != ignore)// && head.netname != "")
 661                 {
 662                         value = PlayerValue(head);
 663                         if(clienttype(head) == CLIENTTYPE_BOT)
 664                                 bvalue = value;
 665                         else
 666                                 bvalue = 0;
 667                         if(head.team == COLOR_TEAM1)
 668                         {
 669                                 if(c1 >= 0)
 670                                 {
 671                                         c1 = c1 + value;
 672                                         cb1 = cb1 + bvalue;
 673                                 }
 674                         }
 675                         if(head.team == COLOR_TEAM2)
 676                         {
 677                                 if(c2 >= 0)
 678                                 {
 679                                         c2 = c2 + value;
 680                                         cb2 = cb2 + bvalue;
 681                                 }
 682                         }
 683                         if(head.team == COLOR_TEAM3)
 684                         {
 685                                 if(c3 >= 0)
 686                                 {
 687                                         c3 = c3 + value;
 688                                         cb3 = cb3 + bvalue;
 689                                 }
 690                         }
 691                         if(head.team == COLOR_TEAM4)
 692                         {
 693                                 if(c4 >= 0)
 694                                 {
 695                                         c4 = c4 + value;
 696                                         cb4 = cb4 + bvalue;
 697                                 }
 698                         }
 699                 }
 700         }
 701 }
 702
 703 // returns # of smallest team (1, 2, 3, 4)
 704 // NOTE: Assumes CheckAllowedTeams has already been called!
 705 float FindSmallestTeam(entity pl, float ignore_pl)
 706 {
 707         float totalteams, smallestteam, smallestteam_count, smallestteam_score, balance_type;
 708         totalteams = 0;
 709
 710         // find out what teams are available
 711         //CheckAllowedTeams();
 712
 713         // make sure there are at least 2 teams to join
 714         if(c1 >= 0)
 715                 totalteams = totalteams + 1;
 716         if(c2 >= 0)
 717                 totalteams = totalteams + 1;
 718         if(c3 >= 0)
 719                 totalteams = totalteams + 1;
 720         if(c4 >= 0)
 721                 totalteams = totalteams + 1;
 722
 723         if(cvar("bot_vs_human"))
 724                 totalteams += 1;
 725
 726         if(totalteams <= 1)
 727         {
 728                 if(g_domination)
 729                         error("Too few teams available for domination\n");
 730                 else if(g_ctf)
 731                         error("Too few teams available for ctf\n");
 732                 else if(g_keyhunt)
 733                         error("Too few teams available for key hunt\n");
 734                 else
 735                         error("Too few teams available for team deathmatch\n");
 736         }
 737
 738         // count how many players are in each team
 739         if(ignore_pl)
 740                 GetTeamCounts(pl);
 741         else
 742                 GetTeamCounts(world);
 743
 744         // c1...c4 now have counts of each team
 745         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 746
 747         smallestteam = 0;
 748         smallestteam_count = 999999999;
 749         smallestteam_score = 999999999;
 750
 751         // 2 gives priority to what team you're already on, 1 goes in order
 752         // 2 doesn't seem to work though...
 753         balance_type = 1;
 754
 755         if(bots_would_leave)
 756         //if(pl.classname != "player")
 757         if(clienttype(pl) != CLIENTTYPE_BOT)
 758         {
 759                 c1 -= cb1 * 255.0/256;
 760                 c2 -= cb2 * 255.0/256;
 761                 c3 -= cb3 * 255.0/256;
 762                 c4 -= cb4 * 255.0/256;
 763         }
 764
 765         if(balance_type == 1)
 766         {
 767                 if(c1 >= 0 && (c1 < smallestteam_count || (c1 <= smallestteam_count && team1_score < smallestteam_score)))
 768                 {
 769                         smallestteam = 1;
 770                         smallestteam_count = c1;
 771                         smallestteam_score = team1_score;
 772                 }
 773                 if(c2 >= 0 && (c2 < smallestteam_count || (c2 <= smallestteam_count && team2_score < smallestteam_score)))
 774                 {
 775                         smallestteam = 2;
 776                         smallestteam_count = c2;
 777                         smallestteam_score = team2_score;
 778                 }
 779                 if(c3 >= 0 && (c3 < smallestteam_count || (c3 <= smallestteam_count && team3_score < smallestteam_score)))
 780                 {
 781                         smallestteam = 3;
 782                         smallestteam_count = c3;
 783                         smallestteam_score = team3_score;
 784                 }
 785                 if(c4 >= 0 && (c4 < smallestteam_count || (c4 <= smallestteam_count && team4_score < smallestteam_score)))
 786                 {
 787                         smallestteam = 4;
 788                         smallestteam_count = c4;
 789                         smallestteam_score = team4_score;
 790                 }
 791         }
 792         else
 793         {
 794                 if(c1 >= 0 && (c1 < smallestteam_count ||
 795                                         (c1 == smallestteam_count && self.team == COLOR_TEAM1) ) )
 796                 {
 797                         smallestteam = 1;
 798                         smallestteam_count = c1;
 799                 }
 800                 if(c2 >= 0 && c2 < (c2 < smallestteam_count ||
 801                                         (c2 == smallestteam_count && self.team == COLOR_TEAM2) ) )
 802                 {
 803                         smallestteam = 2;
 804                         smallestteam_count = c2;
 805                 }
 806                 if(c3 >= 0 && c3 < (c3 < smallestteam_count ||
 807                                         (c3 == smallestteam_count && self.team == COLOR_TEAM3) ) )
 808                 {
 809                         smallestteam = 3;
 810                         smallestteam_count = c3;
 811                 }
 812                 if(c4 >= 0 && c4 < (c4 < smallestteam_count ||
 813                                         (c4 == smallestteam_count && self.team == COLOR_TEAM4) ) )
 814                 {
 815                         smallestteam = 4;
 816                         smallestteam_count = c4;
 817                 }
 818         }
 819
 820         return smallestteam;
 821 }
 822
 823 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 824 {
 825         float smallest, selectedteam;
 826
 827         // don't join a team if we're not playing a team game
 828         if(!teams_matter)
 829                 return 0;
 830
 831         // find out what teams are available
 832         CheckAllowedTeams(pl);
 833
 834         if(g_domination)
 835         {
 836                 // <div0> WHY? TODO
 837                 if(cvar("g_domination_default_teams") < 3)
 838                         c3 = 999999999;
 839                 if(cvar("g_domination_default_teams") < 4)
 840                         c4 = 999999999;
 841         }
 842
 843         // if we don't care what team he ends up on, put him on whatever team he entered as.
 844         // if he's not on a valid team, then let other code put him on the smallest team
 845         if(!forcebestteam)
 846         {
 847                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 848                         selectedteam = pl.team;
 849                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 850                         selectedteam = pl.team;
 851                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 852                         selectedteam = pl.team;
 853                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 854                         selectedteam = pl.team;
 855                 else
 856                         selectedteam = -1;
 857                 if(selectedteam > 0)
 858                 {
 859                         if(!only_return_best)
 860                         {
 861                                 SetPlayerColors(pl, selectedteam - 1);
 862                                 LogTeamchange(pl);
 863                         }
 864                         return selectedteam;
 865                 }
 866                 // otherwise end up on the smallest team (handled below)
 867         }
 868
 869         smallest = FindSmallestTeam(pl, TRUE);
 870
 871
 872         if(!only_return_best)
 873         {
 874                 TeamchangeFrags(self);
 875                 if(smallest == 1)
 876                 {
 877                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 878                 }
 879                 else if(smallest == 2)
 880                 {
 881                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 882                 }
 883                 else if(smallest == 3)
 884                 {
 885                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 886                 }
 887                 else if(smallest == 4)
 888                 {
 889                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 890                 }
 891                 else
 892                 {
 893                         error("smallest team: invalid team\n");
 894                 }
 895                 LogTeamchange(pl);
 896                 if(pl.deadflag == DEAD_NO)
 897                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 898         }
 899
 900         return smallest;
 901 }
 902
 903 //void() ctf_playerchanged;
 904 void SV_ChangeTeam(float _color)
 905 {
 906         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 907
 908         // in normal deathmatch we can just apply the color and we're done
 909         if(!teams_matter) {
 910                 SetPlayerColors(self, _color);
 911                 return;
 912         }
 913
 914         scolor = self.clientcolors & 0x0F;
 915         dcolor = _color & 0x0F;
 916
 917         if(scolor == COLOR_TEAM1 - 1)
 918                 steam = 1;
 919         else if(scolor == COLOR_TEAM2 - 1)
 920                 steam = 2;
 921         else if(scolor == COLOR_TEAM3 - 1)
 922                 steam = 3;
 923         else // if(scolor == COLOR_TEAM4 - 1)
 924                 steam = 4;
 925         if(dcolor == COLOR_TEAM1 - 1)
 926                 dteam = 1;
 927         else if(dcolor == COLOR_TEAM2 - 1)
 928                 dteam = 2;
 929         else if(dcolor == COLOR_TEAM3 - 1)
 930                 dteam = 3;
 931         else // if(dcolor == COLOR_TEAM4 - 1)
 932                 dteam = 4;
 933
 934         CheckAllowedTeams(self);
 935
 936         if(dteam == 1 && c1 < 0) dteam = 4;
 937         if(dteam == 4 && c4 < 0) dteam = 3;
 938         if(dteam == 3 && c3 < 0) dteam = 2;
 939         if(dteam == 2 && c2 < 0) dteam = 1;
 940
 941         // not changing teams
 942         if(scolor == dcolor)
 943         {
 944                 //bprint("same team change\n");
 945                 SetPlayerTeam(self, dteam, steam, TRUE);
 946                 return;
 947         }
 948
 949         if(cvar("g_campaign"))
 950         {
 951                 sprint(self, "Team changes not allowed\n");
 952                 return; // changing teams is not allowed
 953         }
 954
 955         if(cvar("g_changeteam_banned") && self.wasplayer)
 956         {
 957                 sprint(self, "Team changes not allowed\n");
 958                 return;
 959         }
 960
 961         if(cvar("g_balance_teams_prevent_imbalance"))
 962         {
 963                 // only allow changing to a smaller or equal size team
 964
 965                 // find out what teams are available
 966                 //CheckAllowedTeams();
 967                 // count how many players on each team
 968                 GetTeamCounts(world);
 969
 970                 // get desired team
 971                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 972                 {
 973                         dcount = c1;
 974                         dbotcount = cb1;
 975                 }
 976                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 977                 {
 978                         dcount = c2;
 979                         dbotcount = cb2;
 980                 }
 981                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
 982                 {
 983                         dcount = c3;
 984                         dbotcount = cb3;
 985                 }
 986                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
 987                 {
 988                         dcount = c4;
 989                         dbotcount = cb4;
 990                 }
 991                 else
 992                 {
 993                         sprint(self, "Cannot change to an invalid team\n");
 994
 995                         return;
 996                 }
 997
 998                 // get starting team
 999                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1000                         scount = c1;
1001                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1002                         scount = c2;
1003                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1004                         scount = c3;
1005                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1006                         scount = c4;
1007
1008                 if(scount) // started at a valid, nonempty team
1009                 {
1010                         // check if we're trying to change to a larger team that doens't have bots to swap with
1011                         if(dcount >= scount && dbotcount <= 0)
1012                         {
1013                                 sprint(self, "Cannot change to a larger team\n");
1014                                 return; // can't change to a larger team
1015                         }
1016                 }
1017         }
1018
1019 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1020
1021         if(self.classname == "player" && steam != dteam)
1022         {
1023                 // reduce frags during a team change
1024                 TeamchangeFrags(self);
1025         }
1026
1027         SetPlayerTeam(self, dteam, steam, FALSE);
1028
1029         if(self.classname == "player" && steam != dteam)
1030         {
1031                 // kill player when changing teams
1032                 if(self.deadflag == DEAD_NO)
1033                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1034         }
1035         //ctf_playerchanged();
1036 }
1037
1038 void ShufflePlayerOutOfTeam (float source_team)
1039 {
1040         float smallestteam, smallestteam_count, steam;
1041         float lowest_bot_score, lowest_player_score;
1042         entity head, lowest_bot, lowest_player, selected;
1043
1044         smallestteam = 0;
1045         smallestteam_count = 999999999;
1046
1047         if(c1 >= 0 && c1 < smallestteam_count)
1048         {
1049                 smallestteam = 1;
1050                 smallestteam_count = c1;
1051         }
1052         if(c2 >= 0 && c2 < smallestteam_count)
1053         {
1054                 smallestteam = 2;
1055                 smallestteam_count = c2;
1056         }
1057         if(c3 >= 0 && c3 < smallestteam_count)
1058         {
1059                 smallestteam = 3;
1060                 smallestteam_count = c3;
1061         }
1062         if(c4 >= 0 && c4 < smallestteam_count)
1063         {
1064                 smallestteam = 4;
1065                 smallestteam_count = c4;
1066         }
1067
1068         if(!smallestteam)
1069         {
1070                 bprint("warning: no smallest team\n");
1071                 return;
1072         }
1073
1074         if(source_team == 1)
1075                 steam = COLOR_TEAM1;
1076         else if(source_team == 2)
1077                 steam = COLOR_TEAM2;
1078         else if(source_team == 3)
1079                 steam = COLOR_TEAM3;
1080         else if(source_team == 4)
1081                 steam = COLOR_TEAM4;
1082
1083         lowest_bot = world;
1084         lowest_bot_score = 999999999;
1085         lowest_player = world;
1086         lowest_player_score = 999999999;
1087
1088         // find the lowest-scoring player & bot of that team
1089         FOR_EACH_PLAYER(head)
1090         {
1091                 if(head.team == steam)
1092                 {
1093                         if(head.isbot)
1094                         {
1095                                 if(head.totalfrags < lowest_bot_score)
1096                                 {
1097                                         lowest_bot = head;
1098                                         lowest_bot_score = head.totalfrags;
1099                                 }
1100                         }
1101                         else
1102                         {
1103                                 if(head.totalfrags < lowest_player_score)
1104                                 {
1105                                         lowest_player = head;
1106                                         lowest_player_score = head.totalfrags;
1107                                 }
1108                         }
1109                 }
1110         }
1111
1112         // prefers to move a bot...
1113         if(lowest_bot != world)
1114                 selected = lowest_bot;
1115         // but it will move a player if it has to
1116         else
1117                 selected = lowest_player;
1118         // don't do anything if it couldn't find anyone
1119         if(!selected)
1120         {
1121                 bprint("warning: couldn't find a player to move from team\n");
1122                 return;
1123         }
1124
1125         // smallest team gains a member
1126         if(smallestteam == 1)
1127         {
1128                 c1 = c1 + 1;
1129         }
1130         else if(smallestteam == 2)
1131         {
1132                 c2 = c2 + 1;
1133         }
1134         else if(smallestteam == 3)
1135         {
1136                 c3 = c3 + 1;
1137         }
1138         else if(smallestteam == 4)
1139         {
1140                 c4 = c4 + 1;
1141         }
1142         else
1143         {
1144                 bprint("warning: destination team invalid\n");
1145                 return;
1146         }
1147         // source team loses a member
1148         if(source_team == 1)
1149         {
1150                 c1 = c1 + 1;
1151         }
1152         else if(source_team == 2)
1153         {
1154                 c2 = c2 + 2;
1155         }
1156         else if(source_team == 3)
1157         {
1158                 c3 = c3 + 3;
1159         }
1160         else if(source_team == 4)
1161         {
1162                 c4 = c4 + 4;
1163         }
1164         else
1165         {
1166                 bprint("warning: source team invalid\n");
1167                 return;
1168         }
1169
1170         // move the player to the new team
1171         TeamchangeFrags(selected);
1172         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1173
1174         if(selected.deadflag == DEAD_NO)
1175                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1176         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1177 }
1178
1179 void CauseRebalance(float source_team, float howmany_toomany)
1180 {
1181         if(IsTeamBalanceForced() == 1)
1182         {
1183                 bprint("Rebalancing Teams\n");
1184                 ShufflePlayerOutOfTeam(source_team);
1185         }
1186 }
1187
1188 // part of g_balance_teams_force
1189 // occasionally perform an audit of the teams to make
1190 // sure they're more or less balanced in player count.
1191 void AuditTeams()
1192 {
1193         float numplayers, numteams, smallest, toomany;
1194         float balance;
1195         balance = IsTeamBalanceForced();
1196         if(balance == 0)
1197                 return;
1198
1199         if(audit_teams_time > time)
1200                 return;
1201
1202         audit_teams_time = time + 4 + random();
1203
1204 //      bprint("Auditing teams\n");
1205
1206         CheckAllowedTeams(world);
1207         GetTeamCounts(world);
1208
1209
1210         numteams = numplayers = smallest = 0;
1211         if(c1 >= 0)
1212         {
1213                 numteams = numteams + 1;
1214                 numplayers = numplayers + c1;
1215                 smallest = c1;
1216         }
1217         if(c2 >= 0)
1218         {
1219                 numteams = numteams + 1;
1220                 numplayers = numplayers + c2;
1221                 if(c2 < smallest)
1222                         smallest = c2;
1223         }
1224         if(c3 >= 0)
1225         {
1226                 numteams = numteams + 1;
1227                 numplayers = numplayers + c3;
1228                 if(c3 < smallest)
1229                         smallest = c3;
1230         }
1231         if(c4 >= 0)
1232         {
1233                 numteams = numteams + 1;
1234                 numplayers = numplayers + c4;
1235                 if(c4 < smallest)
1236                         smallest = c4;
1237         }
1238
1239         if(numplayers <= 0)
1240                 return; // no players to move around
1241         if(numteams < 2)
1242                 return; // don't bother shuffling if for some reason there aren't any teams
1243
1244         toomany = smallest + 1;
1245
1246         if(c1 && c1 > toomany)
1247                 CauseRebalance(1, c1 - toomany);
1248         if(c2 && c2 > toomany)
1249                 CauseRebalance(2, c2 - toomany);
1250         if(c3 && c3 > toomany)
1251                 CauseRebalance(3, c3 - toomany);
1252         if(c4 && c4 > toomany)
1253                 CauseRebalance(4, c4 - toomany);
1254
1255         // if teams are still unbalanced, balance them further in the next audit,
1256         // which will happen sooner (keep doing rapid audits until things are in order)
1257         audit_teams_time = time + 0.7 + random()*0.3;
1258 }
1259
1260 // code from here on is just to support maps that don't have team entities
1261 void tdm_spawnteam (string teamname, float teamcolor)
1262 {
1263         local entity e;
1264         e = spawn();
1265         e.classname = "tdm_team";
1266         e.netname = teamname;
1267         e.cnt = teamcolor;
1268         e.team = e.cnt + 1;
1269 };
1270
1271 // spawn some default teams if the map is not set up for tdm
1272 void tdm_spawnteams()
1273 {
1274         float numteams;
1275
1276         numteams = cvar("g_tdm_teams");
1277
1278         tdm_spawnteam("Red", COLOR_TEAM1-1);
1279         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1280         if(numteams >= 3)
1281                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1282         if(numteams >= 4)
1283                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1284 };
1285
1286 void tdm_delayedinit()
1287 {
1288         // if no teams are found, spawn defaults
1289         if (find(world, classname, "tdm_team") == world)
1290                 tdm_spawnteams();
1291 };
1292
1293 void tdm_init()
1294 {
1295         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1296 };