data/qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teams_matter)
  16                 return 0;
  17         if(cvar("g_campaign"))
  18                 return 0;
  19         if(!cvar("g_balance_teams_force"))
  20                 return -1;
  21         return 1;
  22 }
  23
  24 void TeamchangeFrags(entity e)
  25 {
  26         PlayerScore_Clear(e);
  27 }
  28
  29 vector TeamColor(float teem)
  30 {
  31         switch(teem)
  32         {
  33                 case COLOR_TEAM1:
  34                         return '1 0.0625 0.0625';
  35                 case COLOR_TEAM2:
  36                         return '0.0625 0.0625 1';
  37                 case COLOR_TEAM3:
  38                         return '1 1 0.0625';
  39                 case COLOR_TEAM4:
  40                         return '1 0.0625 1';
  41                 default:
  42                         return '1 1 1';
  43         }
  44 }
  45
  46 string TeamName(float t)
  47 {
  48         return strcat(Team_ColorName(t), " Team");
  49 }
  50 string ColoredTeamName(float t)
  51 {
  52         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  53 }
  54 string TeamNoName(float t)
  55 {
  56         // fixme: Search for team entities and get their .netname's!
  57         if(t == 1)
  58                 return "Red Team";
  59         if(t == 2)
  60                 return "Blue Team";
  61         if(t == 3)
  62                 return "Yellow Team";
  63         if(t == 4)
  64                 return "Pink Team";
  65         return "Neutral Team";
  66 }
  67
  68 void dom_init();
  69 void ctf_init();
  70 void runematch_init();
  71 void tdm_init();
  72 void nb_init();
  73 void entcs_init();
  74
  75 void LogTeamchange(entity pl)
  76 {
  77         string str;
  78         if(!cvar("sv_eventlog"))
  79                 return;
  80         if(pl.playerid < 1)
  81                 return;
  82         str = strcat(":team:", ftos(pl.playerid), ":");
  83         str = strcat(str, ftos(pl.team));
  84         GameLogEcho(str);
  85 }
  86
  87 void WriteGameCvars()
  88 {
  89         cvar_set("g_dm", ftos(g_dm));
  90         cvar_set("g_tdm", ftos(g_tdm));
  91         cvar_set("g_domination", ftos(g_domination));
  92         cvar_set("g_ctf", ftos(g_ctf));
  93         cvar_set("g_runematch", ftos(g_runematch));
  94         cvar_set("g_lms", ftos(g_lms));
  95         cvar_set("g_arena", ftos(g_arena));
  96         cvar_set("g_ca", ftos(g_ca));
  97         cvar_set("g_keyhunt", ftos(g_keyhunt));
  98         cvar_set("g_assault", ftos(g_assault));
  99         cvar_set("g_onslaught", ftos(g_onslaught));
 100         cvar_set("g_race", ftos(g_race));
 101         cvar_set("g_nexball", ftos(g_nexball));
 102         cvar_set("g_cts", ftos(g_cts));
 103 }
 104
 105 void ReadGameCvars()
 106 {
 107         float found;
 108         float prev;
 109         float i;
 110
 111         found = 0;
 112         prev = cvar("gamecfg");
 113         for(i = 0; i < 2; ++i)
 114         {
 115                 found += (g_dm = (!found && (prev != GAME_DEATHMATCH) && cvar("g_dm")));
 116                 found += (g_tdm = (!found && (prev != GAME_TEAM_DEATHMATCH) && cvar("g_tdm")));
 117                 found += (g_domination = (!found && (prev != GAME_DOMINATION) && cvar("g_domination")));
 118                 found += (g_ctf = (!found && (prev != GAME_CTF) && cvar("g_ctf")));
 119                 found += (g_runematch = (!found && (prev != GAME_RUNEMATCH) && cvar("g_runematch")));
 120                 found += (g_lms = (!found && (prev != GAME_LMS) && cvar("g_lms")));
 121                 found += (g_arena = (!found && (prev != GAME_ARENA) && cvar("g_arena")));
 122                 found += (g_ca = (!found && (prev != GAME_CA) && cvar("g_ca")));
 123                 found += (g_keyhunt = (!found && (prev != GAME_KEYHUNT) && cvar("g_keyhunt")));
 124                 found += (g_assault = (!found && (prev != GAME_ASSAULT) && cvar("g_assault")));
 125                 found += (g_onslaught = (!found && (prev != GAME_ONSLAUGHT) && cvar("g_onslaught")));
 126                 found += (g_race = (!found && (prev != GAME_RACE) && cvar("g_race")));
 127                 found += (g_nexball = (!found && (prev != GAME_NEXBALL) && cvar("g_nexball")));
 128                 found += (g_cts = (!found && (prev != GAME_CTS) && cvar("g_cts")));
 129
 130                 if(found)
 131                         break;
 132
 133                 prev = -1; // second attempt takes place WITHOUT prev set
 134         }
 135
 136         if(!found)
 137                 g_dm = 1;
 138
 139         if(g_dm && cvar("deathmatch_force_teamplay"))
 140         {
 141                 g_dm = 0;
 142                 g_tdm = 1;
 143         }
 144
 145         teams_matter = 0;
 146 }
 147
 148 void default_delayedinit()
 149 {
 150         if(!scores_initialized)
 151                 ScoreRules_generic();
 152 }
 153
 154 void ActivateTeamplay()
 155 {
 156         float teamplay_default;
 157         teamplay_default = cvar("teamplay_default");
 158
 159         if(teamplay_default)
 160                 teamplay = teamplay_default;
 161         else
 162                 teamplay = 3;
 163         cvar_set("teamplay", ftos(teamplay));
 164
 165         teams_matter = 1;
 166 }
 167
 168 void InitGameplayMode()
 169 {
 170         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 171
 172         qualifying_override = -1;
 173
 174         VoteReset();
 175
 176         teams_matter = 0;
 177         cvar_set("teamplay", "0");
 178
 179         // make sure only ONE type is selected
 180         ReadGameCvars();
 181         WriteGameCvars();
 182
 183         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 184         get_mi_min_max(1);
 185         world.mins = mi_min;
 186         world.maxs = mi_max;
 187
 188         MapInfo_LoadMapSettings(mapname);
 189
 190         if not(cvar_value_issafe(world.fog))
 191         {
 192                 print("The current map contains a potentially harmful fog setting, ignored\n");
 193                 world.fog = string_null;
 194         }
 195         if(MapInfo_Map_fog != "")
 196                 if(MapInfo_Map_fog == "none")
 197                         world.fog = string_null;
 198                 else
 199                         world.fog = strzone(MapInfo_Map_fog);
 200         clientstuff = strzone(MapInfo_Map_clientstuff);
 201
 202         MapInfo_ClearTemps();
 203
 204         // in case mapinfo switched the type
 205         ReadGameCvars();
 206
 207         // set both here, gamemode can override it later
 208         timelimit_override = cvar("timelimit_override");
 209         fraglimit_override = cvar("fraglimit_override");
 210         leadlimit_override = cvar("leadlimit_override");
 211
 212         if(g_dm)
 213         {
 214                 game = GAME_DEATHMATCH;
 215                 gamemode_name = "Deathmatch";
 216         }
 217
 218         if(g_tdm)
 219         {
 220                 game = GAME_TEAM_DEATHMATCH;
 221                 gamemode_name = "Team Deathmatch";
 222                 ActivateTeamplay();
 223                 tdm_init();
 224                 if(cvar("g_tdm_team_spawns"))
 225                         have_team_spawns = -1; // request team spawns
 226         }
 227
 228         if(g_domination)
 229         {
 230                 game = GAME_DOMINATION;
 231                 gamemode_name = "Domination";
 232                 ActivateTeamplay();
 233                 fraglimit_override = cvar("g_domination_point_limit");
 234                 leadlimit_override = cvar("g_domination_point_leadlimit");
 235                 dom_init();
 236                 have_team_spawns = -1; // request team spawns
 237         }
 238
 239         if(g_ctf)
 240         {
 241                 game = GAME_CTF;
 242                 gamemode_name = "Capture the Flag";
 243                 ActivateTeamplay();
 244                 if(cvar("g_campaign"))
 245                         g_ctf_win_mode = 2;
 246                 else
 247                         g_ctf_win_mode = cvar("g_ctf_win_mode");
 248                 g_ctf_ignore_frags = cvar("g_ctf_ignore_frags");
 249                 if(g_ctf_win_mode == 2)
 250                 {
 251                         fraglimit_override = cvar("g_ctf_capture_limit");
 252                         leadlimit_override = cvar("g_ctf_capture_leadlimit");
 253                 }
 254                 else
 255                 {
 256                         fraglimit_override = cvar("capturelimit_override");
 257                         leadlimit_override = cvar("captureleadlimit_override");
 258                 }
 259                 ctf_init();
 260                 have_team_spawns = -1; // request team spawns
 261         }
 262
 263         if(g_runematch)
 264         {
 265                 game = GAME_RUNEMATCH;
 266                 gamemode_name = "Rune Match";
 267                 if(cvar("deathmatch_force_teamplay"))
 268                         ActivateTeamplay();
 269                 fraglimit_override = cvar("g_runematch_point_limit");
 270                 leadlimit_override = cvar("g_runematch_point_leadlimit");
 271                 runematch_init();
 272         }
 273
 274         if(g_lms)
 275         {
 276                 game = GAME_LMS;
 277                 gamemode_name = "Last Man Standing";
 278                 fraglimit_override = cvar("g_lms_lives_override");
 279                 leadlimit_override = 0; // not supported by LMS
 280                 if(fraglimit_override == 0)
 281                         fraglimit_override = -1;
 282                 lms_lowest_lives = 9999;
 283                 lms_next_place = 0;
 284                 ScoreRules_lms();
 285         }
 286
 287         if(g_arena || g_ca)
 288         {
 289                 game = GAME_ARENA;
 290                 gamemode_name = "Arena";
 291                 if(g_ca)
 292                         ActivateTeamplay();
 293                 fraglimit_override = cvar("g_arena_point_limit");
 294                 leadlimit_override = cvar("g_arena_point_leadlimit");
 295                 maxspawned = cvar("g_arena_maxspawned");
 296                 if(maxspawned < 2)
 297                         maxspawned = 2;
 298                 arena_roundbased = cvar("g_arena_roundbased");
 299         }
 300
 301         if(g_keyhunt)
 302         {
 303                 game = GAME_KEYHUNT;
 304                 gamemode_name = "Key Hunt";
 305                 ActivateTeamplay();
 306                 fraglimit_override = cvar("g_keyhunt_point_limit");
 307                 leadlimit_override = cvar("g_keyhunt_point_leadlimit");
 308                 kh_init();
 309         }
 310
 311         if(g_assault)
 312         {
 313                 game = GAME_ASSAULT;
 314                 gamemode_name = "Assault";
 315                 ActivateTeamplay();
 316                 ScoreRules_assault();
 317                 have_team_spawns = -1; // request team spawns
 318         }
 319
 320         if(g_onslaught)
 321         {
 322                 game = GAME_ONSLAUGHT;
 323                 gamemode_name = "Onslaught";
 324                 ActivateTeamplay();
 325                 have_team_spawns = -1; // request team spawns
 326         }
 327
 328         if(g_race)
 329         {
 330                 game = GAME_RACE;
 331                 gamemode_name = "Race";
 332
 333                 if(cvar("g_race_teams"))
 334                 {
 335                         ActivateTeamplay();
 336                         race_teams = bound(2, cvar("g_race_teams"), 4);
 337                         have_team_spawns = -1; // request team spawns
 338                 }
 339                 else
 340                         race_teams = 0;
 341
 342                 qualifying_override = cvar("g_race_qualifying_timelimit_override");
 343                 fraglimit_override = cvar("g_race_laps_limit");
 344                 leadlimit_override = 0; // currently not supported by race
 345         }
 346
 347         if(g_cts)
 348         {
 349                 game = GAME_CTS;
 350                 gamemode_name = "CTS";
 351                 g_race_qualifying = 1;
 352                 fraglimit_override = 0;
 353                 leadlimit_override = 0;
 354         }
 355
 356         if(g_nexball)
 357         {
 358                 game = GAME_NEXBALL;
 359                 gamemode_name = "Nexball";
 360                 fraglimit_override = cvar("g_nexball_goallimit");
 361                 leadlimit_override = cvar("g_nexball_goalleadlimit");
 362                 ActivateTeamplay();
 363                 nb_init();
 364                 have_team_spawns = -1; // request team spawns
 365         }
 366
 367         if(teams_matter)
 368                 entcs_init();
 369
 370         // save it (for the next startup)
 371         cvar_set("gamecfg", ftos(game));
 372
 373         cache_mutatormsg = strzone("");
 374         cache_lastmutatormsg = strzone("");
 375
 376         // enforce the server's universal frag/time limits
 377         if(!cvar("g_campaign"))
 378         {
 379                 if(fraglimit_override >= 0)
 380                         cvar_set("fraglimit", ftos(fraglimit_override));
 381                 if(timelimit_override >= 0)
 382                         cvar_set("timelimit", ftos(timelimit_override));
 383                 if(leadlimit_override >= 0)
 384                         cvar_set("leadlimit", ftos(leadlimit_override));
 385                 if(qualifying_override >= 0)
 386                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 387         }
 388
 389         if(g_race)
 390         {
 391                 // we need to find out the correct value for g_race_qualifying
 392                 if(cvar("g_campaign"))
 393                 {
 394                         g_race_qualifying = 1;
 395                 }
 396                 else if(!cvar("g_campaign") && cvar("g_race_qualifying_timelimit") > 0)
 397                 {
 398                         g_race_qualifying = 2;
 399                         race_fraglimit = cvar("fraglimit");
 400                         race_leadlimit = cvar("leadlimit");
 401                         race_timelimit = cvar("timelimit");
 402                         cvar_set("fraglimit", "0");
 403                         cvar_set("leadlimit", "0");
 404                         cvar_set("timelimit", cvar_string("g_race_qualifying_timelimit"));
 405                 }
 406                 else
 407                         g_race_qualifying = 0;
 408         }
 409
 410         if(g_race || g_cts)
 411         {
 412                 if(g_race_qualifying)
 413                         independent_players = 1;
 414
 415                 ScoreRules_race();
 416         }
 417
 418         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 419 }
 420
 421 string GetClientVersionMessage() {
 422         local string versionmsg;
 423         if (self.version_mismatch) {
 424                 if(self.version < cvar("gameversion")) {
 425                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 426                 } else {
 427                         versionmsg = "^3This server is using an outdated Nexuiz version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 428                 }
 429         } else {
 430                 versionmsg = "^2client version and server version are compatible.^8";
 431         }
 432         return versionmsg;
 433 }
 434
 435
 436 void PrintWelcomeMessage(entity pl)
 437 {
 438         string s, modifications, motd;
 439
 440         if(self.cvar_scr_centertime == 0) return;
 441
 442         if(cvar("g_campaign"))
 443         {
 444                 if(self.classname == "player" && !self.BUTTON_INFO)
 445                         return;
 446         }
 447         else
 448         {
 449                 if((time - self.jointime) > cvar("welcome_message_time") && !self.BUTTON_INFO)
 450                         return;
 451         }
 452
 453         if( !(timeoutStatus >= 1) ) { //really print the WelcomeMessage to the player every frame when timeout-seconds are shown or the game is restarted, to make sure that the shown number is accurate
 454                 if(self.welcomemessage_time > time) return;
 455                 self.welcomemessage_time = time + max(0.5, self.cvar_scr_centertime * 0.6);
 456         }
 457
 458         if(cvar("g_campaign"))
 459         {
 460                 centerprint(pl, campaign_message);
 461                 return;
 462         }
 463
 464 //TODO GreEn`mArine: make the timeout-messages clientside as well (just like the ready restart countdown)!
 465         if(!self.BUTTON_INFO)
 466         {
 467                 // TODO get rid of this too
 468                 local string specString;
 469                 specString = NEWLINES;
 470                 //if(time < game_starttime) //also show the countdown when being a spectator
 471                 //      specString = strcat(specString, "\n\n^1Game starts in ", ftos(ceil(game_starttime - time)), " seconds^7");
 472                 //else
 473                 if (timeoutStatus != 0)
 474                         specString = strcat(specString, "\n\n", getTimeoutText(1));
 475                 else
 476                 {
 477                         if(self.classname == "player")
 478                                 return;
 479                         goto normal;
 480                 }
 481                 return centerprint_atprio(self, CENTERPRIO_SPAM, specString);
 482         }
 483
 484 :normal
 485         modifications = "";
 486         if(g_minstagib)
 487                 modifications = strcat(modifications, ", MinstaGib");
 488         if(g_nixnex)
 489                 modifications = strcat(modifications, ", NixNex");
 490         if(g_weaponarena)
 491         {
 492                 if(g_weaponarena_random)
 493                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 494                 else
 495                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 496         }
 497         if(cvar("g_start_weapon_laser") == 0)
 498                 modifications = strcat(modifications, ", No start weapons");
 499         if(cvar("sv_gravity") < 800)
 500                 modifications = strcat(modifications, ", Low gravity");
 501         if(g_cloaked)
 502                 modifications = strcat(modifications, ", Cloaked");
 503         if(g_footsteps)
 504                 modifications = strcat(modifications, ", Steps");
 505         if(g_grappling_hook)
 506                 modifications = strcat(modifications, ", Hook");
 507         if(g_laserguided_missile)
 508                 modifications = strcat(modifications, ", LG missiles");
 509         if(g_midair)
 510                 modifications = strcat(modifications, ", Midair");
 511         if(g_vampire)
 512                 modifications = strcat(modifications, ", Vampire");
 513         if(g_pinata)
 514                 modifications = strcat(modifications, ", Pinata");
 515         if(g_weapon_stay)
 516                 modifications = strcat(modifications, ", Weapons stay");
 517         if(g_bloodloss > 0)
 518                 modifications = strcat(modifications, ", Bloodloss");
 519         if(g_jetpack)
 520                 modifications = strcat(modifications, ", Jet pack");
 521         modifications = substring(modifications, 2, strlen(modifications) - 2);
 522
 523         local string versionmessage;
 524         versionmessage = GetClientVersionMessage();
 525
 526         s = strcat(s, NEWLINES, "This is Nexuiz ", cvar_string("g_nexuizversion"), "\n", versionmessage);
 527         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 528
 529         if(modifications != "")
 530                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 531
 532         if(timeoutStatus != 0)
 533                 s = strcat(s, "\n\n", getTimeoutText(1));
 534
 535         if (g_grappling_hook)
 536                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 537
 538         if(cache_lastmutatormsg != cvar_string("g_mutatormsg"))
 539         {
 540                 if(cache_lastmutatormsg)
 541                         strunzone(cache_lastmutatormsg);
 542                 if(cache_mutatormsg)
 543                         strunzone(cache_mutatormsg);
 544                 cache_lastmutatormsg = strzone(cvar_string("g_mutatormsg"));
 545                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 546         }
 547
 548         if (cache_mutatormsg != "") {
 549                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 550         }
 551
 552         motd = cvar_string("sv_motd");
 553         if (motd != "") {
 554                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 555         }
 556         s = strcat(s, "\n");
 557
 558         centerprint(pl, s);
 559 }
 560
 561
 562 void SetPlayerColors(entity pl, float _color)
 563 {
 564         /*string s;
 565         s = ftos(cl);
 566         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 567         pl.team = cl + 1;
 568         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 569         pl.clientcolors = 16*cl + cl;*/
 570
 571         float pants, shirt;
 572         pants = _color & 0x0F;
 573         shirt = _color & 0xF0;
 574
 575
 576         if(teams_matter) {
 577                 setcolor(pl, 16*pants + pants);
 578         } else {
 579                 setcolor(pl, shirt + pants);
 580         }
 581 }
 582
 583 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 584 {
 585         float _color;
 586
 587         if(t == 4)
 588                 _color = COLOR_TEAM4 - 1;
 589         else if(t == 3)
 590                 _color = COLOR_TEAM3 - 1;
 591         else if(t == 2)
 592                 _color = COLOR_TEAM2 - 1;
 593         else
 594                 _color = COLOR_TEAM1 - 1;
 595
 596         SetPlayerColors(pl,_color);
 597
 598         if(!noprint && t != s)
 599         {
 600                 //bprint(pl.netname, " has changed to ", TeamNoName(t), "\n");
 601                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 602         }
 603
 604         if(t != s)
 605                 LogTeamchange(pl);
 606 }
 607
 608 // set c1...c4 to show what teams are allowed
 609 void CheckAllowedTeams (entity for_whom)
 610 {
 611         float dm;
 612         entity head;
 613         string teament_name;
 614
 615         c1 = c2 = c3 = c4 = -1;
 616         cb1 = cb2 = cb3 = cb4 = 0;
 617
 618         if(g_onslaught)
 619         {
 620                 // onslaught is special
 621                 head = findchain(classname, "onslaught_generator");
 622                 while (head)
 623                 {
 624                         if (head.team == COLOR_TEAM1) c1 = 0;
 625                         if (head.team == COLOR_TEAM2) c2 = 0;
 626                         if (head.team == COLOR_TEAM3) c3 = 0;
 627                         if (head.team == COLOR_TEAM4) c4 = 0;
 628                         head = head.chain;
 629                 }
 630         }
 631         else if(g_domination)
 632                 teament_name = "dom_team";
 633         else if(g_ctf)
 634                 teament_name = "ctf_team";
 635         else if(g_tdm)
 636                 teament_name = "tdm_team";
 637         else if(g_nexball)
 638                 teament_name = "nexball_team";
 639         else if(g_assault)
 640                 c1 = c2 = 0; // Assault always has 2 teams
 641         else
 642         {
 643                 // cover anything else by treating it like tdm with no teams spawned
 644                 if(g_keyhunt)
 645                         dm = kh_teams;
 646                 else if(g_race)
 647                         dm = race_teams;
 648                 else
 649                         dm = 2;
 650
 651                 if(dm >= 4)
 652                         c1 = c2 = c3 = c4 = 0;
 653                 else if(dm >= 3)
 654                         c1 = c2 = c3 = 0;
 655                 else
 656                         c1 = c2 = 0;
 657         }
 658
 659         // find out what teams are allowed if necessary
 660         if(teament_name)
 661         {
 662                 head = find(world, classname, teament_name);
 663                 while(head)
 664                 {
 665                         if(!(g_domination && head.netname == ""))
 666                         {
 667                                 if(head.team == COLOR_TEAM1)
 668                                         c1 = 0;
 669                                 else if(head.team == COLOR_TEAM2)
 670                                         c2 = 0;
 671                                 else if(head.team == COLOR_TEAM3)
 672                                         c3 = 0;
 673                                 else if(head.team == COLOR_TEAM4)
 674                                         c4 = 0;
 675                         }
 676                         head = find(head, classname, teament_name);
 677                 }
 678         }
 679
 680         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 681         if(c3==-1&&c4==-1)
 682         if(cvar("bot_vs_human") && for_whom)
 683         {
 684                 if(cvar("bot_vs_human") > 0)
 685                 {
 686                         // bots are all blue
 687                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 688                                 c1 = c3 = c4 = -1;
 689                         else
 690                                 c2 = -1;
 691                 }
 692                 else
 693                 {
 694                         // bots are all red
 695                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 696                                 c2 = c3 = c4 = -1;
 697                         else
 698                                 c1 = -1;
 699                 }
 700         }
 701 }
 702
 703 float PlayerValue(entity p)
 704 {
 705         if(IsTeamBalanceForced() == 1)
 706                 return 1;
 707         return 1;
 708 }
 709
 710 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 711 // teams that are allowed will now have their player counts stored in c1...c4
 712 void GetTeamCounts(entity ignore)
 713 {
 714         entity head;
 715         float value, bvalue;
 716         // now count how many players are on each team already
 717
 718         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 719         // also remember the lowest-scoring player
 720
 721         FOR_EACH_PLAYER(head)
 722         {
 723                 if(head != ignore)// && head.netname != "")
 724                 {
 725                         value = PlayerValue(head);
 726                         if(clienttype(head) == CLIENTTYPE_BOT)
 727                                 bvalue = value;
 728                         else
 729                                 bvalue = 0;
 730                         if(head.team == COLOR_TEAM1)
 731                         {
 732                                 if(c1 >= 0)
 733                                 {
 734                                         c1 = c1 + value;
 735                                         cb1 = cb1 + bvalue;
 736                                 }
 737                         }
 738                         if(head.team == COLOR_TEAM2)
 739                         {
 740                                 if(c2 >= 0)
 741                                 {
 742                                         c2 = c2 + value;
 743                                         cb2 = cb2 + bvalue;
 744                                 }
 745                         }
 746                         if(head.team == COLOR_TEAM3)
 747                         {
 748                                 if(c3 >= 0)
 749                                 {
 750                                         c3 = c3 + value;
 751                                         cb3 = cb3 + bvalue;
 752                                 }
 753                         }
 754                         if(head.team == COLOR_TEAM4)
 755                         {
 756                                 if(c4 >= 0)
 757                                 {
 758                                         c4 = c4 + value;
 759                                         cb4 = cb4 + bvalue;
 760                                 }
 761                         }
 762                 }
 763         }
 764 }
 765
 766 // returns # of smallest team (1, 2, 3, 4)
 767 // NOTE: Assumes CheckAllowedTeams has already been called!
 768 float FindSmallestTeam(entity pl, float ignore_pl)
 769 {
 770         float totalteams, balance_type, maxc;
 771         totalteams = 0;
 772
 773         // find out what teams are available
 774         //CheckAllowedTeams();
 775
 776         // make sure there are at least 2 teams to join
 777         if(c1 >= 0)
 778                 totalteams = totalteams + 1;
 779         if(c2 >= 0)
 780                 totalteams = totalteams + 1;
 781         if(c3 >= 0)
 782                 totalteams = totalteams + 1;
 783         if(c4 >= 0)
 784                 totalteams = totalteams + 1;
 785
 786         if(cvar("bot_vs_human"))
 787                 totalteams += 1;
 788
 789         if(totalteams <= 1)
 790         {
 791                 if(g_domination)
 792                         error("Too few teams available for domination\n");
 793                 else if(g_ctf)
 794                         error("Too few teams available for ctf\n");
 795                 else if(g_keyhunt)
 796                         error("Too few teams available for key hunt\n");
 797                 else
 798                         error("Too few teams available for team deathmatch\n");
 799         }
 800
 801         // count how many players are in each team
 802         if(ignore_pl)
 803                 GetTeamCounts(pl);
 804         else
 805                 GetTeamCounts(world);
 806
 807         // c1...c4 now have counts of each team
 808         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 809
 810         // 2 gives priority to what team you're already on, 1 goes in order
 811         // 2 doesn't seem to work though...
 812         balance_type = 1;
 813
 814         if(bots_would_leave)
 815         //if(pl.classname != "player")
 816         if(clienttype(pl) != CLIENTTYPE_BOT)
 817         {
 818                 c1 -= cb1 * 255.0/256.0;
 819                 c2 -= cb2 * 255.0/256.0;
 820                 c3 -= cb3 * 255.0/256.0;
 821                 c4 -= cb4 * 255.0/256.0;
 822         }
 823         maxc = max4(c1, c2, c3, c4);
 824
 825         RandomSelection_Init();
 826         if(balance_type == 1)
 827         {
 828                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 829                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 830                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 831                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 832                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 833         }
 834         else if(balance_type == 2)
 835         {
 836                 // 1: use team count, if equal prefer own team
 837                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 838                 if(c2 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 839                 if(c3 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 840                 if(c4 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 841         }
 842         else if(balance_type == 3)
 843         {
 844                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 845                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 846                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 847                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 848                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 849         }
 850         return RandomSelection_chosen_float;
 851 }
 852
 853 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 854 {
 855         float smallest, selectedteam;
 856
 857         // don't join a team if we're not playing a team game
 858         if(!teams_matter)
 859                 return 0;
 860
 861         // find out what teams are available
 862         CheckAllowedTeams(pl);
 863
 864         // if we don't care what team he ends up on, put him on whatever team he entered as.
 865         // if he's not on a valid team, then let other code put him on the smallest team
 866         if(!forcebestteam)
 867         {
 868                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 869                         selectedteam = pl.team;
 870                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 871                         selectedteam = pl.team;
 872                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 873                         selectedteam = pl.team;
 874                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 875                         selectedteam = pl.team;
 876                 else
 877                         selectedteam = -1;
 878                 if(selectedteam > 0)
 879                 {
 880                         if(!only_return_best)
 881                         {
 882                                 SetPlayerColors(pl, selectedteam - 1);
 883                                 LogTeamchange(pl);
 884                         }
 885                         return selectedteam;
 886                 }
 887                 // otherwise end up on the smallest team (handled below)
 888         }
 889
 890         smallest = FindSmallestTeam(pl, TRUE);
 891
 892
 893         if(!only_return_best)
 894         {
 895                 TeamchangeFrags(self);
 896                 if(smallest == 1)
 897                 {
 898                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 899                 }
 900                 else if(smallest == 2)
 901                 {
 902                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 903                 }
 904                 else if(smallest == 3)
 905                 {
 906                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 907                 }
 908                 else if(smallest == 4)
 909                 {
 910                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 911                 }
 912                 else
 913                 {
 914                         error("smallest team: invalid team\n");
 915                 }
 916                 LogTeamchange(pl);
 917                 if(pl.deadflag == DEAD_NO)
 918                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 919         }
 920
 921         return smallest;
 922 }
 923
 924 //void() ctf_playerchanged;
 925 void SV_ChangeTeam(float _color)
 926 {
 927         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 928
 929         // in normal deathmatch we can just apply the color and we're done
 930         if(!teams_matter) {
 931                 SetPlayerColors(self, _color);
 932                 return;
 933         }
 934
 935         scolor = self.clientcolors & 0x0F;
 936         dcolor = _color & 0x0F;
 937
 938         if(scolor == COLOR_TEAM1 - 1)
 939                 steam = 1;
 940         else if(scolor == COLOR_TEAM2 - 1)
 941                 steam = 2;
 942         else if(scolor == COLOR_TEAM3 - 1)
 943                 steam = 3;
 944         else // if(scolor == COLOR_TEAM4 - 1)
 945                 steam = 4;
 946         if(dcolor == COLOR_TEAM1 - 1)
 947                 dteam = 1;
 948         else if(dcolor == COLOR_TEAM2 - 1)
 949                 dteam = 2;
 950         else if(dcolor == COLOR_TEAM3 - 1)
 951                 dteam = 3;
 952         else // if(dcolor == COLOR_TEAM4 - 1)
 953                 dteam = 4;
 954
 955         CheckAllowedTeams(self);
 956
 957         if(dteam == 1 && c1 < 0) dteam = 4;
 958         if(dteam == 4 && c4 < 0) dteam = 3;
 959         if(dteam == 3 && c3 < 0) dteam = 2;
 960         if(dteam == 2 && c2 < 0) dteam = 1;
 961
 962         // not changing teams
 963         if(scolor == dcolor)
 964         {
 965                 //bprint("same team change\n");
 966                 SetPlayerTeam(self, dteam, steam, TRUE);
 967                 return;
 968         }
 969
 970         if(cvar("g_campaign"))
 971         {
 972                 sprint(self, "Team changes not allowed\n");
 973                 return; // changing teams is not allowed
 974         }
 975
 976         if(cvar("g_changeteam_banned") && self.wasplayer)
 977         {
 978                 sprint(self, "Team changes not allowed\n");
 979                 return;
 980         }
 981
 982         if(cvar("g_balance_teams_prevent_imbalance"))
 983         {
 984                 // only allow changing to a smaller or equal size team
 985
 986                 // find out what teams are available
 987                 //CheckAllowedTeams();
 988                 // count how many players on each team
 989                 GetTeamCounts(world);
 990
 991                 // get desired team
 992                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 993                 {
 994                         dcount = c1;
 995                         dbotcount = cb1;
 996                 }
 997                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 998                 {
 999                         dcount = c2;
1000                         dbotcount = cb2;
1001                 }
1002                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
1003                 {
1004                         dcount = c3;
1005                         dbotcount = cb3;
1006                 }
1007                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
1008                 {
1009                         dcount = c4;
1010                         dbotcount = cb4;
1011                 }
1012                 else
1013                 {
1014                         sprint(self, "Cannot change to an invalid team\n");
1015
1016                         return;
1017                 }
1018
1019                 // get starting team
1020                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
1021                         scount = c1;
1022                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
1023                         scount = c2;
1024                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
1025                         scount = c3;
1026                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
1027                         scount = c4;
1028
1029                 if(scount) // started at a valid, nonempty team
1030                 {
1031                         // check if we're trying to change to a larger team that doens't have bots to swap with
1032                         if(dcount >= scount && dbotcount <= 0)
1033                         {
1034                                 sprint(self, "Cannot change to a larger team\n");
1035                                 return; // can't change to a larger team
1036                         }
1037                 }
1038         }
1039
1040 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
1041
1042         if(self.classname == "player" && steam != dteam)
1043         {
1044                 // reduce frags during a team change
1045                 TeamchangeFrags(self);
1046         }
1047
1048         SetPlayerTeam(self, dteam, steam, FALSE);
1049
1050         if(self.classname == "player" && steam != dteam)
1051         {
1052                 // kill player when changing teams
1053                 if(self.deadflag == DEAD_NO)
1054                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
1055         }
1056         //ctf_playerchanged();
1057 }
1058
1059 void ShufflePlayerOutOfTeam (float source_team)
1060 {
1061         float smallestteam, smallestteam_count, steam;
1062         float lowest_bot_score, lowest_player_score;
1063         entity head, lowest_bot, lowest_player, selected;
1064
1065         smallestteam = 0;
1066         smallestteam_count = 999999999;
1067
1068         if(c1 >= 0 && c1 < smallestteam_count)
1069         {
1070                 smallestteam = 1;
1071                 smallestteam_count = c1;
1072         }
1073         if(c2 >= 0 && c2 < smallestteam_count)
1074         {
1075                 smallestteam = 2;
1076                 smallestteam_count = c2;
1077         }
1078         if(c3 >= 0 && c3 < smallestteam_count)
1079         {
1080                 smallestteam = 3;
1081                 smallestteam_count = c3;
1082         }
1083         if(c4 >= 0 && c4 < smallestteam_count)
1084         {
1085                 smallestteam = 4;
1086                 smallestteam_count = c4;
1087         }
1088
1089         if(!smallestteam)
1090         {
1091                 bprint("warning: no smallest team\n");
1092                 return;
1093         }
1094
1095         if(source_team == 1)
1096                 steam = COLOR_TEAM1;
1097         else if(source_team == 2)
1098                 steam = COLOR_TEAM2;
1099         else if(source_team == 3)
1100                 steam = COLOR_TEAM3;
1101         else if(source_team == 4)
1102                 steam = COLOR_TEAM4;
1103
1104         lowest_bot = world;
1105         lowest_bot_score = 999999999;
1106         lowest_player = world;
1107         lowest_player_score = 999999999;
1108
1109         // find the lowest-scoring player & bot of that team
1110         FOR_EACH_PLAYER(head)
1111         {
1112                 if(head.team == steam)
1113                 {
1114                         if(head.isbot)
1115                         {
1116                                 if(head.totalfrags < lowest_bot_score)
1117                                 {
1118                                         lowest_bot = head;
1119                                         lowest_bot_score = head.totalfrags;
1120                                 }
1121                         }
1122                         else
1123                         {
1124                                 if(head.totalfrags < lowest_player_score)
1125                                 {
1126                                         lowest_player = head;
1127                                         lowest_player_score = head.totalfrags;
1128                                 }
1129                         }
1130                 }
1131         }
1132
1133         // prefers to move a bot...
1134         if(lowest_bot != world)
1135                 selected = lowest_bot;
1136         // but it will move a player if it has to
1137         else
1138                 selected = lowest_player;
1139         // don't do anything if it couldn't find anyone
1140         if(!selected)
1141         {
1142                 bprint("warning: couldn't find a player to move from team\n");
1143                 return;
1144         }
1145
1146         // smallest team gains a member
1147         if(smallestteam == 1)
1148         {
1149                 c1 = c1 + 1;
1150         }
1151         else if(smallestteam == 2)
1152         {
1153                 c2 = c2 + 1;
1154         }
1155         else if(smallestteam == 3)
1156         {
1157                 c3 = c3 + 1;
1158         }
1159         else if(smallestteam == 4)
1160         {
1161                 c4 = c4 + 1;
1162         }
1163         else
1164         {
1165                 bprint("warning: destination team invalid\n");
1166                 return;
1167         }
1168         // source team loses a member
1169         if(source_team == 1)
1170         {
1171                 c1 = c1 + 1;
1172         }
1173         else if(source_team == 2)
1174         {
1175                 c2 = c2 + 2;
1176         }
1177         else if(source_team == 3)
1178         {
1179                 c3 = c3 + 3;
1180         }
1181         else if(source_team == 4)
1182         {
1183                 c4 = c4 + 4;
1184         }
1185         else
1186         {
1187                 bprint("warning: source team invalid\n");
1188                 return;
1189         }
1190
1191         // move the player to the new team
1192         TeamchangeFrags(selected);
1193         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1194
1195         if(selected.deadflag == DEAD_NO)
1196                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1197         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1198 }
1199
1200 void CauseRebalance(float source_team, float howmany_toomany)
1201 {
1202         if(IsTeamBalanceForced() == 1)
1203         {
1204                 bprint("Rebalancing Teams\n");
1205                 ShufflePlayerOutOfTeam(source_team);
1206         }
1207 }
1208
1209 // part of g_balance_teams_force
1210 // occasionally perform an audit of the teams to make
1211 // sure they're more or less balanced in player count.
1212 void AuditTeams()
1213 {
1214         float numplayers, numteams, smallest, toomany;
1215         float balance;
1216         balance = IsTeamBalanceForced();
1217         if(balance == 0)
1218                 return;
1219
1220         if(audit_teams_time > time)
1221                 return;
1222
1223         audit_teams_time = time + 4 + random();
1224
1225 //      bprint("Auditing teams\n");
1226
1227         CheckAllowedTeams(world);
1228         GetTeamCounts(world);
1229
1230
1231         numteams = numplayers = smallest = 0;
1232         if(c1 >= 0)
1233         {
1234                 numteams = numteams + 1;
1235                 numplayers = numplayers + c1;
1236                 smallest = c1;
1237         }
1238         if(c2 >= 0)
1239         {
1240                 numteams = numteams + 1;
1241                 numplayers = numplayers + c2;
1242                 if(c2 < smallest)
1243                         smallest = c2;
1244         }
1245         if(c3 >= 0)
1246         {
1247                 numteams = numteams + 1;
1248                 numplayers = numplayers + c3;
1249                 if(c3 < smallest)
1250                         smallest = c3;
1251         }
1252         if(c4 >= 0)
1253         {
1254                 numteams = numteams + 1;
1255                 numplayers = numplayers + c4;
1256                 if(c4 < smallest)
1257                         smallest = c4;
1258         }
1259
1260         if(numplayers <= 0)
1261                 return; // no players to move around
1262         if(numteams < 2)
1263                 return; // don't bother shuffling if for some reason there aren't any teams
1264
1265         toomany = smallest + 1;
1266
1267         if(c1 && c1 > toomany)
1268                 CauseRebalance(1, c1 - toomany);
1269         if(c2 && c2 > toomany)
1270                 CauseRebalance(2, c2 - toomany);
1271         if(c3 && c3 > toomany)
1272                 CauseRebalance(3, c3 - toomany);
1273         if(c4 && c4 > toomany)
1274                 CauseRebalance(4, c4 - toomany);
1275
1276         // if teams are still unbalanced, balance them further in the next audit,
1277         // which will happen sooner (keep doing rapid audits until things are in order)
1278         audit_teams_time = time + 0.7 + random()*0.3;
1279 }
1280
1281 // code from here on is just to support maps that don't have team entities
1282 void tdm_spawnteam (string teamname, float teamcolor)
1283 {
1284         local entity e;
1285         e = spawn();
1286         e.classname = "tdm_team";
1287         e.netname = teamname;
1288         e.cnt = teamcolor;
1289         e.team = e.cnt + 1;
1290 };
1291
1292 // spawn some default teams if the map is not set up for tdm
1293 void tdm_spawnteams()
1294 {
1295         float numteams;
1296
1297         numteams = cvar("g_tdm_teams_override");
1298         if(numteams < 2)
1299                 numteams = cvar("g_tdm_teams");
1300         numteams = bound(2, numteams, 4);
1301
1302         tdm_spawnteam("Red", COLOR_TEAM1-1);
1303         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1304         if(numteams >= 3)
1305                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1306         if(numteams >= 4)
1307                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1308 };
1309
1310 void tdm_delayedinit()
1311 {
1312         // if no teams are found, spawn defaults
1313         if (find(world, classname, "tdm_team") == world)
1314                 tdm_spawnteams();
1315 };
1316
1317 void tdm_init()
1318 {
1319         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1320 };