data/qcsrc/server/t_teleporters.qc

   1 .entity pusher;
   2 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
   3 {
   4         entity head;
   5         entity oldself;
   6         entity telefragger;
   7
   8         if(teleporter.owner)
   9                 telefragger = teleporter.owner;
  10         else
  11                 telefragger = player;
  12
  13         sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  14         pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  15
  16         makevectors (to_angles);
  17         pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  18
  19         // Relocate the player
  20         // assuming to allows PL_MIN to PL_MAX box and some more
  21         setorigin (player, to);
  22         player.angles = to_angles;
  23         player.fixangle = TRUE;
  24         player.velocity = to_velocity;
  25
  26         if(player.classname == "player")
  27         {
  28                 RemoveGrapplingHook(player);
  29
  30                 // Kill anyone else in the teleporter box (NO MORE TDEATH)
  31                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  32                 {
  33                         vector deathmin;
  34                         vector deathmax;
  35                         float deathradius;
  36                         deathmin = player.absmin;
  37                         deathmax = player.absmax;
  38                         if(telefragmin != telefragmax)
  39                         {
  40                                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  41                                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  42                                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  43                                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  44                                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  45                                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  46                         }
  47                         deathradius = max(vlen(deathmin), vlen(deathmax));
  48                         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  49                                 if(head != player)
  50                                         if(head.takedamage)
  51                                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  52                                                 {
  53                                                         if ((player.classname == "player") && (player.health >= 1))
  54                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  55                                                         else if (telefragger.health < 1) // corpses gib
  56                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  57                                                         else // dead bodies and monsters gib themselves instead of telefragging
  58                                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  59                                                 }
  60                 }
  61
  62                 // hide myself a tic
  63                 player.effects = player.effects | EF_NODRAW;
  64                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  65                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  66                 player.teleport_time = time + cvar("sys_ticrate");
  67
  68                 // player no longer is on ground
  69                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  70
  71                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  72                 player.oldvelocity = player.velocity;
  73
  74                 // reset tracking of who pushed you into a hazard (for kill credit)
  75                 if(teleporter.owner)
  76                 {
  77                         player.pusher = teleporter.owner;
  78                         player.pushltime = time + cvar("g_maxpushtime");
  79                 }
  80                 else
  81                 {
  82                         player.pushltime = 0;
  83                 }
  84
  85                 // stop player name display
  86                 {
  87                         oldself = self;
  88                         self = player;
  89                         ClearSelectedPlayer();
  90                         self = oldself;
  91                 }
  92         }
  93 }
  94
  95 void Teleport_Touch (void)
  96 {
  97         entity oldself;
  98
  99         if (other.health < 1)
 100                 return;
 101         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 102                 return;
 103
 104         EXACTTRIGGER_TOUCH;
 105
 106         makevectors(self.enemy.mangle);
 107         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 108
 109         if(self.enemy.target)
 110         {
 111                 oldself = self;
 112                 activator = other;
 113                 self = self.enemy;
 114                 SUB_UseTargets();
 115                 self = oldself;
 116         }
 117 }
 118
 119 void spawnfunc_info_teleport_destination (void)
 120 {
 121         self.mangle = self.angles;
 122         self.angles = '0 0 0';
 123
 124         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 125         setorigin (self, self.origin);
 126
 127         IFTARGETED
 128         {
 129         }
 130         else
 131                 objerror ("Teleport destination without a targetname");
 132 }
 133
 134 void spawnfunc_misc_teleporter_dest (void)
 135 {
 136         spawnfunc_info_teleport_destination();
 137 }
 138
 139 void spawnfunc_target_teleporter (void)
 140 {
 141         spawnfunc_info_teleport_destination();
 142 }
 143
 144 void teleport_findtarget (void)
 145 {
 146         // now enable touch
 147         self.touch = Teleport_Touch;
 148
 149         self.enemy = find (world, targetname, self.target);
 150         if (!self.enemy)
 151         {
 152                 objerror ("Teleporter with nonexistant target");
 153                 return;
 154         }
 155
 156         self.dest = self.enemy.origin;
 157         waypoint_spawnforteleporter(self, self.dest, 0);
 158 }
 159
 160 void spawnfunc_trigger_teleport (void)
 161 {
 162         self.angles = '0 0 0';
 163
 164         EXACTTRIGGER_INIT;
 165
 166         // this must be called to spawn the teleport waypoints for bots
 167         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 168
 169         if (!self.target)
 170         {
 171                 objerror ("Teleporter with no target");
 172                 return;
 173         }
 174 }