data/qcsrc/server/t_teleporters.qc

   1 void trigger_teleport_use()
   2 {
   3         if(teams_matter)
   4                 self.team = activator.team;
   5 }
   6
   7 void tdeath(entity player, entity teleporter, entity telefragger, vector telefragmin, vector telefragmax)
   8 {
   9         entity head;
  10         vector deathmin;
  11         vector deathmax;
  12         float deathradius;
  13         deathmin = player.absmin;
  14         deathmax = player.absmax;
  15         if(telefragmin != telefragmax)
  16         {
  17                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  18                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  19                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  20                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  21                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  22                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  23         }
  24         deathradius = max(vlen(deathmin), vlen(deathmax));
  25         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  26                 if(head != player)
  27                         if(head.takedamage)
  28                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  29                                 {
  30                                         if ((player.classname == "player") && (player.health >= 1))
  31                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  32                                         else if (telefragger.health < 1) // corpses gib
  33                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  34                                         else // dead bodies and monsters gib themselves instead of telefragging
  35                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  36                                 }
  37 }
  38
  39 void spawn_tdeath(vector v0, entity e, vector v)
  40 {
  41         tdeath(e, e, e, '0 0 0', '0 0 0');
  42 }
  43
  44 .entity pusher;
  45 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
  46 {
  47         entity oldself;
  48         entity telefragger;
  49         vector from;
  50
  51         if(teleporter.owner)
  52                 telefragger = teleporter.owner;
  53         else
  54                 telefragger = player;
  55
  56         makevectors (to_angles);
  57
  58         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  59         {
  60                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  61                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  62                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  63                 self.pushltime = time + 0.2;
  64         }
  65
  66         // Relocate the player
  67         // assuming to allows PL_MIN to PL_MAX box and some more
  68         from = player.origin;
  69         setorigin (player, to);
  70         player.oldorigin = to; // don't undo the teleport by unsticking
  71         player.angles = to_angles;
  72         player.fixangle = TRUE;
  73         player.velocity = to_velocity;
  74         BITXOR_ASSIGN(player.effects, EF_TELEPORT_BIT);
  75
  76         UpdateCSQCProjectile(player);
  77
  78         if(player.classname == "player")
  79         {
  80                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  81                         tdeath(player, teleporter, telefragger, telefragmin, telefragmax);
  82
  83                 // player no longer is on ground
  84                 player.flags &~= FL_ONGROUND;
  85
  86                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  87                 player.oldvelocity = player.velocity;
  88
  89                 // reset tracking of who pushed you into a hazard (for kill credit)
  90                 if(teleporter.owner)
  91                 {
  92                         player.pusher = teleporter.owner;
  93                         player.pushltime = time + cvar("g_maxpushtime");
  94                 }
  95                 else
  96                 {
  97                         player.pushltime = 0;
  98                 }
  99
 100                 if(player.isbot)
 101                         player.lastteleporttime = time;
 102
 103                 // stop player name display
 104                 {
 105                         oldself = self;
 106                         self = player;
 107                         ClearSelectedPlayer();
 108                         self = oldself;
 109                 }
 110         }
 111 }
 112
 113 void Teleport_Touch (void)
 114 {
 115         entity oldself, e;
 116
 117         if (other.health < 1)
 118                 return;
 119         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 120                 return;
 121
 122         if(self.team)
 123                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 124                         return;
 125
 126         EXACTTRIGGER_TOUCH;
 127
 128         makevectors(self.enemy.mangle);
 129
 130         if(other.classname == "player")
 131                 RemoveGrapplingHook(other);
 132
 133         if(self.enemy)
 134         {
 135                 e = self.enemy;
 136         }
 137         else
 138         {
 139                 RandomSelection_Init();
 140                 for(e = world; (e = find(e, targetname, self.target)); )
 141                 {
 142                         if(e.cnt)
 143                                 RandomSelection_Add(e, 0, string_null, e.cnt, 0);
 144                         else
 145                                 RandomSelection_Add(e, 0, string_null, 1, 0);
 146                 }
 147                 e = RandomSelection_chosen_ent;
 148         }
 149
 150         if(!e)
 151         {
 152                 sprint(other, "Teleport destination vanished. Sorry... please complain to the mapper.\n");
 153         }
 154
 155         TeleportPlayer(self, other, e.origin + '0 0 1' * (1 - other.mins_z - 24), e.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 156
 157         if(e.target)
 158         {
 159                 oldself = self;
 160                 activator = other;
 161                 self = e;
 162                 SUB_UseTargets();
 163                 self = oldself;
 164         }
 165 }
 166
 167 void spawnfunc_info_teleport_destination (void)
 168 {
 169         self.classname = "info_teleport_destination";
 170
 171         self.mangle = self.angles;
 172         self.angles = '0 0 0';
 173
 174         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 175         setorigin (self, self.origin);
 176
 177         IFTARGETED
 178         {
 179         }
 180         else
 181                 objerror ("^3Teleport destination without a targetname");
 182 }
 183
 184 void spawnfunc_misc_teleporter_dest (void)
 185 {
 186         spawnfunc_info_teleport_destination();
 187 }
 188
 189 void spawnfunc_target_teleporter (void)
 190 {
 191         spawnfunc_info_teleport_destination();
 192 }
 193
 194 void teleport_findtarget (void)
 195 {
 196         entity e;
 197         float n;
 198
 199         n = 0;
 200         for(e = world; (e = find(e, targetname, self.target)); )
 201         {
 202                 ++n;
 203                 if(e.movetype == MOVETYPE_NONE)
 204                         waypoint_spawnforteleporter(self, e.origin, 0);
 205                 if(e.classname != "info_teleport_destination")
 206                         print("^3MAPPER ERROR: teleporter does target an invalid teleport destination entity. Angles will not work.\n");
 207         }
 208
 209         if(n == 0)
 210         {
 211                 // no dest!
 212                 objerror ("Teleporter with nonexistant target");
 213                 return;
 214         }
 215         else if(n == 1)
 216         {
 217                 // exactly one dest - bots love that
 218                 self.enemy = find(e, targetname, self.target);
 219                 self.dest = self.enemy.origin;
 220         }
 221         else
 222         {
 223                 // have to use random selection every single time
 224                 self.enemy = world;
 225         }
 226
 227         // now enable touch
 228         self.touch = Teleport_Touch;
 229 }
 230
 231 void spawnfunc_trigger_teleport (void)
 232 {
 233         self.angles = '0 0 0';
 234
 235         EXACTTRIGGER_INIT;
 236
 237         self.use = trigger_teleport_use;
 238
 239         // this must be called to spawn the teleport waypoints for bots
 240         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 241
 242         if (!self.target)
 243         {
 244                 objerror ("Teleporter with no target");
 245                 return;
 246         }
 247 }