data/qcsrc/server/t_teleporters.qc

   1 .entity pusher;
   2 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
   3 {
   4         entity head;
   5         entity oldself;
   6         entity telefragger;
   7
   8         if(teleporter.owner)
   9                 telefragger = teleporter.owner;
  10         else
  11                 telefragger = player;
  12
  13         sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  14         pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  15
  16         makevectors (to_angles);
  17         pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  18
  19         // Relocate the player
  20         // assuming to allows PL_MIN to PL_MAX box and some more
  21         setorigin (player, to);
  22         player.angles = to_angles;
  23         player.fixangle = TRUE;
  24         player.velocity = to_velocity;
  25
  26         if(player.classname == "player")
  27         {
  28                 // Kill anyone else in the teleporter box (NO MORE TDEATH)
  29                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  30                 {
  31                         vector deathmin;
  32                         vector deathmax;
  33                         float deathradius;
  34                         deathmin = player.absmin;
  35                         deathmax = player.absmax;
  36                         if(telefragmin != telefragmax)
  37                         {
  38                                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  39                                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  40                                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  41                                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  42                                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  43                                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  44                         }
  45                         deathradius = max(vlen(deathmin), vlen(deathmax));
  46                         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  47                                 if(head != player)
  48                                         if(head.takedamage)
  49                                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  50                                                 {
  51                                                         if ((player.classname == "player") && (player.health >= 1))
  52                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  53                                                         else if (telefragger.health < 1) // corpses gib
  54                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  55                                                         else // dead bodies and monsters gib themselves instead of telefragging
  56                                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  57                                                 }
  58                 }
  59
  60                 // hide myself a tic
  61                 player.effects = player.effects | EF_NODRAW;
  62                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  63                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  64                 player.teleport_time = time + cvar("sys_ticrate");
  65
  66                 // player no longer is on ground
  67                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  68
  69                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  70                 player.oldvelocity = player.velocity;
  71
  72                 // reset tracking of who pushed you into a hazard (for kill credit)
  73                 if(teleporter.owner)
  74                 {
  75                         player.pusher = teleporter.owner;
  76                         player.pushltime = time + cvar("g_maxpushtime");
  77                 }
  78                 else
  79                 {
  80                         player.pushltime = 0;
  81                 }
  82
  83                 // stop player name display
  84                 {
  85                         oldself = self;
  86                         self = player;
  87                         ClearSelectedPlayer();
  88                         self = oldself;
  89                 }
  90         }
  91 }
  92
  93 void Teleport_Touch (void)
  94 {
  95         entity oldself;
  96
  97         if (other.health < 1)
  98                 return;
  99         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 100                 return;
 101
 102         EXACTTRIGGER_TOUCH;
 103
 104         makevectors(self.enemy.mangle);
 105
 106         if(other.classname == "player")
 107                 RemoveGrapplingHook(other);
 108
 109         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 110
 111         if(self.enemy.target)
 112         {
 113                 oldself = self;
 114                 activator = other;
 115                 self = self.enemy;
 116                 SUB_UseTargets();
 117                 self = oldself;
 118         }
 119 }
 120
 121 void spawnfunc_info_teleport_destination (void)
 122 {
 123         self.mangle = self.angles;
 124         self.angles = '0 0 0';
 125
 126         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 127         setorigin (self, self.origin);
 128
 129         IFTARGETED
 130         {
 131         }
 132         else
 133                 objerror ("Teleport destination without a targetname");
 134 }
 135
 136 void spawnfunc_misc_teleporter_dest (void)
 137 {
 138         spawnfunc_info_teleport_destination();
 139 }
 140
 141 void spawnfunc_target_teleporter (void)
 142 {
 143         spawnfunc_info_teleport_destination();
 144 }
 145
 146 void teleport_findtarget (void)
 147 {
 148         // now enable touch
 149         self.touch = Teleport_Touch;
 150
 151         self.enemy = find (world, targetname, self.target);
 152         if (!self.enemy)
 153         {
 154                 objerror ("Teleporter with nonexistant target");
 155                 return;
 156         }
 157
 158         self.dest = self.enemy.origin;
 159         waypoint_spawnforteleporter(self, self.dest, 0);
 160 }
 161
 162 void spawnfunc_trigger_teleport (void)
 163 {
 164         self.angles = '0 0 0';
 165
 166         EXACTTRIGGER_INIT;
 167
 168         // this must be called to spawn the teleport waypoints for bots
 169         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 170
 171         if (!self.target)
 172         {
 173                 objerror ("Teleporter with no target");
 174                 return;
 175         }
 176 }