data/qcsrc/server/t_teleporters.qc

   1 .entity pusher;
   2 void TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity, vector telefragmin, vector telefragmax)
   3 {
   4         entity head;
   5         entity oldself;
   6         entity telefragger;
   7
   8         if(teleporter.owner)
   9                 telefragger = teleporter.owner;
  10         else
  11                 telefragger = player;
  12
  13         makevectors (to_angles);
  14
  15         if(self.pushltime < time) // only show one teleport effect per teleporter per 0.2 seconds, for better fps
  16         {
  17                 sound (player, CHAN_TRIGGER, "misc/teleport.wav", VOL_BASE, ATTN_NORM);
  18                 pointparticles(particleeffectnum("teleport"), player.origin, '0 0 0', 1);
  19                 pointparticles(particleeffectnum("teleport"), to + v_forward * 32, '0 0 0', 1);
  20                 self.pushltime = time + 0.2;
  21         }
  22
  23         // Relocate the player
  24         // assuming to allows PL_MIN to PL_MAX box and some more
  25         setorigin (player, to);
  26         player.angles = to_angles;
  27         player.fixangle = TRUE;
  28         player.velocity = to_velocity;
  29
  30         if(player.classname == "player")
  31         {
  32                 // Kill anyone else in the teleporter box (NO MORE TDEATH)
  33                 if(player.takedamage && player.deadflag == DEAD_NO && !g_race)
  34                 {
  35                         vector deathmin;
  36                         vector deathmax;
  37                         float deathradius;
  38                         deathmin = player.absmin;
  39                         deathmax = player.absmax;
  40                         if(telefragmin != telefragmax)
  41                         {
  42                                 if(deathmin_x > telefragmin_x) deathmin_x = telefragmin_x;
  43                                 if(deathmin_y > telefragmin_y) deathmin_y = telefragmin_y;
  44                                 if(deathmin_z > telefragmin_z) deathmin_z = telefragmin_z;
  45                                 if(deathmax_x < telefragmax_x) deathmax_x = telefragmax_x;
  46                                 if(deathmax_y < telefragmax_y) deathmax_y = telefragmax_y;
  47                                 if(deathmax_z < telefragmax_z) deathmax_z = telefragmax_z;
  48                         }
  49                         deathradius = max(vlen(deathmin), vlen(deathmax));
  50                         for(head = findradius(player.origin, deathradius); head; head = head.chain)
  51                                 if(head != player)
  52                                         if(head.takedamage)
  53                                                 if(boxesoverlap(deathmin, deathmax, head.absmin, head.absmax))
  54                                                 {
  55                                                         if ((player.classname == "player") && (player.health >= 1))
  56                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  57                                                         else if (telefragger.health < 1) // corpses gib
  58                                                                 Damage (head, teleporter, telefragger, 10000, DEATH_TELEFRAG, head.origin, '0 0 0');
  59                                                         else // dead bodies and monsters gib themselves instead of telefragging
  60                                                                 Damage (telefragger, teleporter, telefragger, 10000, DEATH_TELEFRAG, telefragger.origin, '0 0 0');
  61                                                 }
  62                 }
  63
  64                 // hide myself a tic
  65                 player.effects = player.effects | EF_NODRAW;
  66                 if (player.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  67                         player.weaponentity.flags = player.weaponentity.flags | FL_FLY;
  68                 player.teleport_time = time + cvar("sys_ticrate");
  69
  70                 // player no longer is on ground
  71                 player.flags = player.flags - (player.flags & FL_ONGROUND);
  72
  73                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  74                 player.oldvelocity = player.velocity;
  75
  76                 // reset tracking of who pushed you into a hazard (for kill credit)
  77                 if(teleporter.owner)
  78                 {
  79                         player.pusher = teleporter.owner;
  80                         player.pushltime = time + cvar("g_maxpushtime");
  81                 }
  82                 else
  83                 {
  84                         player.pushltime = 0;
  85                 }
  86
  87                 // stop player name display
  88                 {
  89                         oldself = self;
  90                         self = player;
  91                         ClearSelectedPlayer();
  92                         self = oldself;
  93                 }
  94         }
  95 }
  96
  97 void Teleport_Touch (void)
  98 {
  99         entity oldself;
 100
 101         if (other.health < 1)
 102                 return;
 103         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
 104                 return;
 105
 106         EXACTTRIGGER_TOUCH;
 107
 108         makevectors(self.enemy.mangle);
 109
 110         if(other.classname == "player")
 111                 RemoveGrapplingHook(other);
 112
 113         TeleportPlayer(self, other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24), self.enemy.mangle, v_forward * vlen(other.velocity), '0 0 0', '0 0 0');
 114
 115         if(self.enemy.target)
 116         {
 117                 oldself = self;
 118                 activator = other;
 119                 self = self.enemy;
 120                 SUB_UseTargets();
 121                 self = oldself;
 122         }
 123 }
 124
 125 void spawnfunc_info_teleport_destination (void)
 126 {
 127         self.mangle = self.angles;
 128         self.angles = '0 0 0';
 129
 130         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 131         setorigin (self, self.origin);
 132
 133         IFTARGETED
 134         {
 135         }
 136         else
 137                 objerror ("Teleport destination without a targetname");
 138 }
 139
 140 void spawnfunc_misc_teleporter_dest (void)
 141 {
 142         spawnfunc_info_teleport_destination();
 143 }
 144
 145 void spawnfunc_target_teleporter (void)
 146 {
 147         spawnfunc_info_teleport_destination();
 148 }
 149
 150 void teleport_findtarget (void)
 151 {
 152         // now enable touch
 153         self.touch = Teleport_Touch;
 154
 155         self.enemy = find (world, targetname, self.target);
 156         if (!self.enemy)
 157         {
 158                 objerror ("Teleporter with nonexistant target");
 159                 return;
 160         }
 161
 162         self.dest = self.enemy.origin;
 163         waypoint_spawnforteleporter(self, self.dest, 0);
 164 }
 165
 166 void spawnfunc_trigger_teleport (void)
 167 {
 168         self.angles = '0 0 0';
 169
 170         EXACTTRIGGER_INIT;
 171
 172         // this must be called to spawn the teleport waypoints for bots
 173         InitializeEntity(self, teleport_findtarget, INITPRIO_FINDTARGET);
 174
 175         if (!self.target)
 176         {
 177                 objerror ("Teleporter with no target");
 178                 return;
 179         }
 180 }