data/qcsrc/server/t_teleporters.qc

   1 void Damage (entity targ, entity inflictor, entity attacker, float
   2 damage, float deathtype, vector hitloc, vector force);
   3
   4 void() tdeath_touch =
   5 {
   6         if (other == self.owner)
   7                 return;
   8         // so teleporting shots etc can't telefrag
   9         if (!self.owner.takedamage)
  10                 return;
  11         if (!other.takedamage)
  12                 return;
  13
  14         if ((self.owner.classname == "player") && (self.owner.health >= 1))
  15                 Damage (other, self, self.owner, 10000, DEATH_TELEFRAG, other.origin, '0 0 0');
  16         else if (other.health < 1) // corpses gib
  17                 Damage (other, self, self.owner, 10000, DEATH_TELEFRAG, other.origin, '0 0 0');
  18         else // dead bodies and monsters gib themselves instead of telefragging
  19                 Damage (self.owner, self, self.owner, 10000, DEATH_TELEFRAG, self.owner.origin, '0 0 0');
  20 };
  21
  22 void tdeath_remove()
  23 {
  24         if (self.owner)
  25         {
  26                 self.owner.effects = self.owner.effects - (self.owner.effects & EF_NODRAW);
  27                 if (self.owner.weaponentity)
  28                         self.owner.weaponentity.flags = self.owner.weaponentity.flags - (self.owner.weaponentity.flags & FL_FLY);
  29         }
  30         remove(self);
  31 }
  32
  33 // org2 is where they will return to if the teleport fails
  34 void(vector org, entity death_owner, vector org2) spawn_tdeath =
  35 {
  36         local entity death;
  37
  38         death = spawn();
  39 //      death.classname = "teledeath";
  40         death.movetype = MOVETYPE_NONE;
  41         death.solid = SOLID_TRIGGER;
  42         death.angles = '0 0 0';
  43         death.dest2 = org2;
  44         setsize (death, death_owner.mins - '1 1 1', death_owner.maxs + '1 1 1');
  45         setorigin (death, org);
  46         death.touch = tdeath_touch;
  47         death.nextthink = time + 0.2;
  48         death.think = tdeath_remove;
  49         death.owner = death_owner;
  50
  51         // hide entity to avoid "ghosts" between teleporter and destination caused by clientside interpolation
  52         death.owner.effects = death.owner.effects | EF_NODRAW;
  53         if (death.owner.weaponentity) // misuse FL_FLY to avoid EF_NODRAW on viewmodel
  54                 death.owner.weaponentity.flags = death.owner.weaponentity.flags | FL_FLY;
  55
  56         force_retouch = 2;              // make sure even still objects get hit
  57 };
  58
  59 void Teleport_Touch (void)
  60 {
  61         if (other.health < 1)
  62                 return;
  63         if (!other.flags & FL_CLIENT)   // FIXME: Make missiles firable through the teleport too
  64                 return;
  65
  66         // Make teleport effect where the player left
  67         sound (other, CHAN_ITEM, "misc/teleport.ogg", 1, ATTN_NORM);
  68         te_teleport (other.origin);
  69
  70         // Make teleport effect where the player arrived
  71         sound (other, CHAN_ITEM, "misc/teleport.ogg", 1, ATTN_NORM);
  72         makevectors (self.enemy.mangle);
  73         te_teleport (self.enemy.origin + v_forward * 32);
  74
  75         spawn_tdeath(self.enemy.origin, other, other.origin);
  76
  77         // Relocate the player
  78         //setorigin (other, self.enemy.origin);
  79         setorigin (other, self.enemy.origin + '0 0 1' * (1 - other.mins_z - 24));
  80         other.angles = self.enemy.mangle;
  81         other.fixangle = TRUE;
  82
  83         // keep velocity but change movement direction
  84         other.velocity = v_forward * vlen(other.velocity);
  85
  86         other.flags = other.flags - (other.flags & FL_ONGROUND);
  87         // reset tracking of oldvelocity for impact damage (sudden velocity changes)
  88         other.oldvelocity = other.velocity;
  89         // reset tracking of who pushed you into a hazard (for kill credit)
  90         other.pushltime = 0;
  91
  92         // stop player name display
  93         {
  94                 entity oldself;
  95                 oldself = self;
  96                 self = other;
  97                 ClearSelectedPlayer();
  98                 self = oldself;
  99         }
 100 }
 101
 102 void info_teleport_destination (void)
 103 {
 104         self.mangle = self.angles;
 105         self.angles = '0 0 0';
 106
 107         //setorigin (self, self.origin + '0 0 27');     // To fix a mappers' habit as old as Quake
 108         setorigin (self, self.origin);
 109
 110         if (!self.targetname)
 111                 objerror ("Teleport destination without a targetname");
 112 }
 113
 114 void misc_teleporter_dest (void)
 115 {
 116         info_teleport_destination();
 117 }
 118
 119 void teleport_findtarget (void)
 120 {
 121         // now enable touch
 122         self.touch = Teleport_Touch;
 123
 124         self.enemy = find (world, targetname, self.target);
 125         if (!self.enemy)
 126         {
 127                 objerror ("Teleporter with nonexistant target");
 128                 remove(self);
 129                 return;
 130         }
 131
 132         self.dest = self.enemy.origin;
 133         waypoint_spawnforteleporter(self, self.dest, 0);
 134 }
 135
 136 void trigger_teleport (void)
 137 {
 138         self.angles = '0 0 0';
 139
 140         self.solid = SOLID_TRIGGER;
 141         self.movetype = MOVETYPE_NONE;
 142
 143         setmodel (self, self.model);
 144
 145         self.model = "";
 146         self.modelindex = 0;
 147
 148         self.think = teleport_findtarget;
 149         self.nextthink = time + 0.2;
 150
 151         if (!self.target)
 152                 objerror ("Teleporter with no target");
 153 }