data/qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 /*
  12         trigger_push_calculatevelocity
  13
  14         Arguments:
  15           org - origin of the object which is to be pushed
  16           tgt - target entity (can be either a point or a model entity; if it is
  17                 the latter, its midpoint is used)
  18           ht  - jump height, measured from the higher one of org and tgt's midpoint
  19
  20         Returns: velocity for the jump
  21         the global trigger_push_calculatevelocity_flighttime is set to the total
  22         jump time
  23  */
  24
  25 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  26 {
  27         local float grav, sdist, zdist, vs, vz, jumpheight, trajsign;
  28         local vector sdir, torg;
  29
  30         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  31
  32         grav = cvar("sv_gravity");
  33
  34         zdist = torg_z - org_z;
  35         sdist = vlen(torg - org - zdist * '0 0 1');
  36         sdir = normalize(torg - org - zdist * '0 0 1');
  37
  38         // how high do we need to push the player?
  39         jumpheight = fabs(ht);
  40         if(zdist > 0)
  41                 jumpheight = jumpheight + zdist;
  42
  43         /*
  44                 STOP.
  45
  46                 You will not understand the following equations anyway...
  47                 But here is what I did to get them.
  48
  49                 I used the functions
  50
  51                   s(t) = t * vs
  52                   z(t) = t * vz - 1/2 grav t^2
  53
  54                 and solved for:
  55
  56                   s(ti) = sdist
  57                   z(ti) = zdist
  58                   max(z, ti) = jumpheight
  59
  60                 From these three equations, you will find the three parameters vs, vz
  61                 and ti.
  62          */
  63
  64         // push him so high...
  65         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  66         if(ht < 0)
  67                 if(zdist < 0)
  68                         vz = -vz;
  69
  70         // how far to push him?
  71         if(zdist == 0)
  72         {
  73                 trigger_push_calculatevelocity_flighttime = sqrt(jumpheight * 8 / grav);
  74                 vs = sdist / trigger_push_calculatevelocity_flighttime;
  75                         // trajsign is ignored (the high point MUST be inside the jump!)
  76         }
  77         else
  78         {
  79                 if(ht > 0)
  80                         trajsign = +1;
  81                 else
  82                         trajsign = -1;
  83
  84                 // >0: the lower speed that achieves "it"
  85                 //     (parabola's maximum inside the jump)
  86                 // <0: the higher speed that achieves "it"
  87                 //     (parabola's maximum outside the jump)
  88
  89                 vs = sqrt(jumpheight - zdist);
  90                 vs = sqrt(jumpheight) - trajsign * vs; // fteqcc sucks
  91                 vs = fabs(vs * sqrt(grav/2) / zdist);
  92                 //vs = fabs((sdist / zdist) * sqrt(grav/2) * (sqrt(jumpheight) - trajsign * sqrt(jumpheight - zdist)));
  93                 trigger_push_calculatevelocity_flighttime = 1 / vs;
  94                         // note: vs cannot be zero here. The difference between the sqrts is zero IFF zdist == 0, which we have excluded.
  95                 vs = vs * sdist;
  96
  97                 // cases to test: "jump up", "jump down" with positive and negative height
  98         }
  99
 100         // finally calculate the velocity
 101         return sdir * vs + '0 0 1' * vz;
 102 }
 103
 104 void trigger_push_touch()
 105 {
 106         // FIXME: add a .float for whether an entity should be tossed by jumppads
 107         if (!other.iscreature)
 108         if (other.classname != "corpse")
 109         if (other.classname != "body")
 110         if (other.classname != "gib")
 111         if (other.classname != "casing")
 112         if (other.classname != "droppedweapon")
 113         if (!other.projectiledeathtype || other.classname == "bullet")
 114                 return;
 115
 116         if (other.deadflag && other.iscreature)
 117                 return;
 118
 119         EXACTTRIGGER_TOUCH;
 120
 121         if(self.target)
 122                 self.movedir = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 123
 124         other.flags &~= FL_ONGROUND;
 125         // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 126         other.oldvelocity = other.velocity = self.movedir;
 127
 128         UpdateCSQCProjectile(other);
 129
 130         if (other.classname == "player")
 131         {
 132                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 133                 {
 134                         // flash when activated
 135                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 136                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 137                         self.pushltime = time + 0.2;
 138                 }
 139                 if(clienttype(other) == CLIENTTYPE_REAL)
 140                 {
 141                         local float i;
 142                         local float found;
 143                         found = FALSE;
 144                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 145                                 if(other.(jumppadsused[i]) == self)
 146                                         found = TRUE;
 147                         if(!found)
 148                         {
 149                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 150                                 other.jumppadcount = other.jumppadcount + 1;
 151                         }
 152
 153                         if(self.message)
 154                                 centerprint(other, self.message);
 155                 }
 156                 else
 157                         other.jumppadcount = TRUE;
 158         }
 159
 160         if(self.enemy.target)
 161         {
 162                 entity oldself;
 163                 oldself = self;
 164                 activator = other;
 165                 self = self.enemy;
 166                 SUB_UseTargets();
 167                 self = oldself;
 168         }
 169
 170         // reset tracking of who pushed you into a hazard (for kill credit)
 171         other.pushltime = 0;
 172
 173         if (other.flags & FL_PROJECTILE)
 174                 other.angles = vectoangles (other.velocity);
 175
 176         if (self.spawnflags & PUSH_ONCE)
 177         {
 178                 self.touch = SUB_Null;
 179                 self.think = SUB_Remove;
 180                 self.nextthink = time;
 181         }
 182 };
 183
 184 .vector dest;
 185
 186 void trigger_push_findtarget()
 187 {
 188         local entity e;
 189         local vector org;
 190         local float flighttime;
 191
 192         // first calculate a typical start point for the jump
 193         org = (self.absmin + self.absmax) * 0.5;
 194         org_z = self.absmax_z - PL_MIN_z;
 195
 196         if (self.target)
 197         {
 198                 // find the target
 199                 self.enemy = find(world, targetname, self.target);
 200                 if (!self.enemy)
 201                 {
 202                         objerror("trigger_push: target not found\n");
 203                         remove(self);
 204                         return;
 205                 }
 206
 207                 self.movedir = trigger_push_calculatevelocity(org, self.enemy, self.height);
 208                 flighttime = trigger_push_calculatevelocity_flighttime;
 209         }
 210         else
 211                 flighttime = 0;
 212
 213         // calculate the destination and spawn a teleporter spawnfunc_waypoint
 214         e = spawn();
 215         setorigin(e, org);
 216         setsize(e, PL_MIN, PL_MAX);
 217         e.velocity = self.movedir;
 218         tracetoss(e, e);
 219         self.dest = trace_endpos;
 220         remove(e);
 221
 222         waypoint_spawnforteleporter(self, self.dest, flighttime);
 223 };
 224
 225 /*
 226  * ENTITY PARAMETERS:
 227  *
 228  *   target:  target of jump
 229  *   height:  the absolute value is the height of the highest point of the jump
 230  *            trajectory above the higher one of the player and the target.
 231  *            the sign indicates whether the highest point is INSIDE (positive)
 232  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 233  *            positive values for targets mounted on the floor, and use negative
 234  *            values to target a point on the ceiling.
 235  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 236  */
 237 void spawnfunc_trigger_push()
 238 {
 239         if (self.angles != '0 0 0')
 240                 SetMovedir ();
 241
 242         EXACTTRIGGER_INIT;
 243
 244         self.touch = trigger_push_touch;
 245
 246         // normal push setup
 247         if (!self.speed)
 248                 self.speed = 1000;
 249         self.movedir = self.movedir * self.speed * 10;
 250
 251         if not(self.noise)
 252                 self.noise = "misc/jumppad.wav";
 253         precache_sound (self.noise);
 254
 255         // this must be called to spawn the teleport waypoints for bots
 256         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 257 };
 258
 259 void spawnfunc_target_push() {};
 260 void spawnfunc_info_notnull() {};
 261 void spawnfunc_target_position() {};