data/qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 /*
  12         trigger_push_calculatevelocity
  13
  14         Arguments:
  15           org - origin of the object which is to be pushed
  16           tgt - target entity (can be either a point or a model entity; if it is
  17                 the latter, its midpoint is used)
  18           ht  - jump height, measured from the higher one of org and tgt's midpoint
  19
  20         Returns: velocity for the jump
  21         the global trigger_push_calculatevelocity_flighttime is set to the total
  22         jump time
  23  */
  24
  25 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  26 {
  27         local float grav, sdist, zdist, vs, vz, jumpheight, trajsign;
  28         local vector sdir, torg;
  29
  30         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  31
  32         grav = cvar("sv_gravity");
  33
  34         zdist = torg_z - org_z;
  35         sdist = vlen(torg - org - zdist * '0 0 1');
  36         sdir = normalize(torg - org - zdist * '0 0 1');
  37
  38         // how high do we need to push the player?
  39         jumpheight = fabs(ht);
  40         if(zdist > 0)
  41                 jumpheight = jumpheight + zdist;
  42
  43         /*
  44                 STOP.
  45
  46                 You will not understand the following equations anyway...
  47                 But here is what I did to get them.
  48
  49                 I used the functions
  50
  51                   s(t) = t * vs
  52                   z(t) = t * vz - 1/2 grav t^2
  53
  54                 and solved for:
  55
  56                   s(ti) = sdist
  57                   z(ti) = zdist
  58                   max(z, ti) = jumpheight
  59
  60                 From these three equations, you will find the three parameters vs, vz
  61                 and ti.
  62          */
  63
  64         // push him so high...
  65         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  66         if(ht < 0)
  67                 if(zdist < 0)
  68                         vz = -vz;
  69
  70         // how far to push him?
  71         if(zdist == 0)
  72         {
  73                 trigger_push_calculatevelocity_flighttime = sqrt(jumpheight * 8 / grav);
  74                 vs = sdist / trigger_push_calculatevelocity_flighttime;
  75                         // trajsign is ignored (the high point MUST be inside the jump!)
  76         }
  77         else
  78         {
  79                 if(ht > 0)
  80                         trajsign = +1;
  81                 else
  82                         trajsign = -1;
  83
  84                 // >0: the lower speed that achieves "it"
  85                 //     (parabola's maximum inside the jump)
  86                 // <0: the higher speed that achieves "it"
  87                 //     (parabola's maximum outside the jump)
  88
  89                 vs = sqrt(jumpheight - zdist);
  90                 vs = sqrt(jumpheight) - trajsign * vs; // fteqcc sucks
  91                 vs = fabs(vs * sqrt(grav/2) / zdist);
  92                 //vs = fabs((sdist / zdist) * sqrt(grav/2) * (sqrt(jumpheight) - trajsign * sqrt(jumpheight - zdist)));
  93                 trigger_push_calculatevelocity_flighttime = 1 / vs;
  94                         // note: vs cannot be zero here. The difference between the sqrts is zero IFF zdist == 0, which we have excluded.
  95                 vs = vs * sdist;
  96
  97                 // cases to test: "jump up", "jump down" with positive and negative height
  98         }
  99
 100         // finally calculate the velocity
 101         return sdir * vs + '0 0 1' * vz;
 102 }
 103
 104 void trigger_push_touch()
 105 {
 106         // FIXME: add a .float for whether an entity should be tossed by jumppads
 107         if (other.classname != "player")
 108         if (other.classname != "corpse")
 109         if (other.classname != "body")
 110         if (other.classname != "gib")
 111         if (other.classname != "missile")
 112         if (other.classname != "casing")
 113         if (other.classname != "grenade")
 114         if (other.classname != "plasma")
 115         if (other.classname != "plasma_prim")
 116         if (other.classname != "plasma_chain")
 117         if (other.classname != "droppedweapon")
 118                 return;
 119
 120         if (other.deadflag && other.classname == "player")
 121                 return;
 122
 123         EXACTTRIGGER_TOUCH;
 124
 125         if(self.target)
 126                 self.movedir = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 127
 128         other.flags = other.flags - (other.flags & FL_ONGROUND);
 129         // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 130         other.oldvelocity = other.velocity = self.movedir;
 131
 132         if (other.classname == "player")
 133         {
 134                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 135                 {
 136                         // flash when activated
 137                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 138                         sound (other, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 139                         self.pushltime = time + 0.2;
 140                 }
 141                 if(clienttype(other) == CLIENTTYPE_REAL)
 142                 {
 143                         local float i;
 144                         local float found;
 145                         found = FALSE;
 146                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 147                                 if(other.(jumppadsused[i]) == self)
 148                                         found = TRUE;
 149                         if(!found)
 150                         {
 151                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 152                                 other.jumppadcount = other.jumppadcount + 1;
 153                         }
 154                 }
 155                 else
 156                         other.jumppadcount = TRUE;
 157
 158                 if(self.message)
 159                         centerprint(other, self.message);
 160         }
 161
 162         if(self.enemy.target)
 163         {
 164                 entity oldself;
 165                 oldself = self;
 166                 activator = other;
 167                 self = self.enemy;
 168                 SUB_UseTargets();
 169                 self = oldself;
 170         }
 171
 172         // reset tracking of who pushed you into a hazard (for kill credit)
 173         other.pushltime = 0;
 174
 175         if (other.flags & FL_PROJECTILE)
 176                 other.angles = vectoangles (other.velocity);
 177
 178         if (self.spawnflags & PUSH_ONCE)
 179         {
 180                 self.touch = SUB_Null;
 181                 self.think = SUB_Remove;
 182                 self.nextthink = time;
 183         }
 184 };
 185
 186 .vector dest;
 187
 188 void trigger_push_findtarget()
 189 {
 190         local entity e;
 191         local vector org;
 192         local float flighttime;
 193
 194         // first calculate a typical start point for the jump
 195         org = (self.absmin + self.absmax) * 0.5;
 196         org_z = self.absmax_z - PL_MIN_z;
 197
 198         if (self.target)
 199         {
 200                 // find the target
 201                 self.enemy = find(world, targetname, self.target);
 202                 if (!self.enemy)
 203                 {
 204                         objerror("trigger_push: target not found\n");
 205                         remove(self);
 206                         return;
 207                 }
 208
 209                 self.movedir = trigger_push_calculatevelocity(org, self.enemy, self.height);
 210                 flighttime = trigger_push_calculatevelocity_flighttime;
 211         }
 212         else
 213                 flighttime = 0;
 214
 215         // calculate the destination and spawn a teleporter spawnfunc_waypoint
 216         e = spawn();
 217         setorigin(e, org);
 218         setsize(e, PL_MIN, PL_MAX);
 219         e.velocity = self.movedir;
 220         tracetoss(e, e);
 221         self.dest = trace_endpos;
 222         remove(e);
 223
 224         waypoint_spawnforteleporter(self, self.dest, flighttime);
 225 };
 226
 227 /*
 228  * ENTITY PARAMETERS:
 229  *
 230  *   target:  target of jump
 231  *   height:  the absolute value is the height of the highest point of the jump
 232  *            trajectory above the higher one of the player and the target.
 233  *            the sign indicates whether the highest point is INSIDE (positive)
 234  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 235  *            positive values for targets mounted on the floor, and use negative
 236  *            values to target a point on the ceiling.
 237  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 238  */
 239 void spawnfunc_trigger_push()
 240 {
 241         if (self.angles != '0 0 0')
 242                 SetMovedir ();
 243
 244         EXACTTRIGGER_INIT;
 245
 246         self.touch = trigger_push_touch;
 247
 248         // normal push setup
 249         if (!self.speed)
 250                 self.speed = 1000;
 251         self.movedir = self.movedir * self.speed * 10;
 252
 253         if not(self.noise)
 254                 self.noise = "misc/jumppad.wav";
 255         precache_sound (self.noise);
 256
 257         // this must be called to spawn the teleport waypoints for bots
 258         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 259 };
 260
 261 void spawnfunc_target_push() {};
 262 void spawnfunc_info_notnull() {};
 263 void spawnfunc_target_position() {};