data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centermsg_freefor(other, CENTERMSG_MINSTAGIB);
  57                         centermsg_freefor(other, CENTERMSG_MINSTAGIB2);
  58                         if(other.health <= 5)
  59                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  60                         else if(other.health < 50)
  61                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  62                         // sound not available
  63                         // else if(self.items == IT_CELLS)
  64                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  65
  66                         if (self.items & IT_NEX)
  67                                 W_GiveWeapon (other, IT_NEX, "Nex");
  68                         if (self.ammo_cells)
  69                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  70                         other.health = 100;
  71                 }
  72
  73                 // extralife powerup
  74                 if (self.max_health)
  75                 {
  76                         // sound not available
  77                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  78                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  79                         sprint(other, "^3You picked up some extra lives\n");
  80                 }
  81
  82                 // invis powerup
  83                 if (self.strength_finished)
  84                 {
  85                         // sound not available
  86                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  87                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  88                 }
  89
  90                 // speed powerup
  91                 if (self.invincible_finished)
  92                 {
  93                         // sound not available
  94                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  95                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  96                 }
  97         }
  98         else
  99         {
 100                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 101                 {
 102                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 103                                 return;
 104                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
 105                                 return;
 106                 }
 107
 108                 if (self.ammo_shells)
 109                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 110                 if (self.ammo_nails)
 111                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 112                 if (self.ammo_rockets)
 113                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 114                 if (self.ammo_cells)
 115                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 116
 117                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 118                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 119                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 120                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 121                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 122                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 123                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 124                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 125
 126                 if (self.strength_finished)
 127                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 128                 if (self.invincible_finished)
 129                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 130                 //if (self.speed_finished)
 131                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 132                 //if (self.slowmo_finished)
 133                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 134
 135                 if (self.max_health)
 136                 {
 137                         other.health = other.health + self.max_health;
 138                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 139                 }
 140                 if (self.health && other.health < other.max_health)
 141                         other.health = min(other.health + self.health, other.max_health);
 142                 if (self.armorvalue)
 143                 {
 144                         other.armorvalue = other.armorvalue + self.armorvalue;
 145                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 146                 }
 147         }
 148
 149         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 150
 151         oldself = self;
 152         self = other;
 153
 154         if (_switchweapon)
 155                 self.switchweapon = w_getbestweapon(self);
 156         if (self.switchweapon != self.weapon)
 157                 self.cnt = self.weapon;
 158
 159         self = oldself;
 160
 161         if (self.classname == "droppedweapon")
 162                 remove (self);
 163         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 164                 return;
 165         else
 166         {
 167                 self.solid = SOLID_NOT;
 168                 self.model = string_null;
 169                 self.nextthink = time + self.respawntime;
 170                 self.think = Item_Respawn;
 171                 setorigin (self, self.origin);
 172         }
 173 }
 174
 175 // Savage: used for item garbage-collection
 176 // TODO: perhaps nice special effect?
 177 void RemoveItem(void) = {
 178         remove(self);
 179 }
 180
 181 // pickup evaluation functions
 182 // these functions decide how desirable an item is to the bots
 183
 184 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 185
 186 float(entity player, entity item) weapon_pickupevalfunc =
 187 {
 188         // if we already have the weapon, rate it 1/5th normal value
 189         if ((player.items & item.items) == item.items)
 190                 return item.bot_pickupbasevalue * 0.2;
 191         return item.bot_pickupbasevalue;
 192 };
 193
 194 float(entity player, entity item) commodity_pickupevalfunc =
 195 {
 196         float c;
 197         c = 0;
 198         // TODO: figure out if the player even has the weapon this ammo is for?
 199         // may not affect strategy much though...
 200         // find out how much ammo the player has, in terms of this ammo pickup
 201         // (how many of these ammo pickups it would take to total the player's
 202         // current ammo)
 203         if (item.ammo_shells)
 204                 c = c + player.ammo_shells / item.ammo_shells;
 205         if (item.ammo_nails)
 206                 c = c + player.ammo_nails / item.ammo_nails;
 207         if (item.ammo_rockets)
 208                 c = c + player.ammo_rockets / item.ammo_rockets;
 209         if (item.ammo_cells)
 210                 c = c + player.ammo_cells / item.ammo_cells;
 211         if (item.armorvalue)
 212                 c = c + player.armorvalue / item.armorvalue;
 213         if (item.health)
 214                 c = c + player.health / item.health / 10;
 215         // the more ammo the player has, the less desirable this pickup becomes
 216         c = 1 / (1 + c);
 217
 218         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 219         if (item.flags & FL_WEAPON)
 220         if (self.items & item.items)
 221         if (item.classname != "droppedweapon")
 222                 c = 0;
 223
 224         return item.bot_pickupbasevalue * c;
 225 };
 226
 227
 228 .float is_item;
 229 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 230 {
 231         vector org;
 232         org = self.origin;
 233
 234         startitem_failed = FALSE;
 235
 236         if (self.classname != "droppedweapon" && !self.noalign)
 237         {
 238                 vector z_offset;
 239
 240                 z_offset = '0 0 1';
 241
 242                 if (itemid == IT_SHELLS)
 243                         z_offset = '0 0 4';
 244                 else if (itemid == IT_ROCKETS)
 245                         z_offset = '0 0 4';
 246                 else if (itemid == IT_NAILS)
 247                         z_offset = '0 0 0';
 248                 else if (itemid == IT_25HP)
 249                         z_offset = '0 0 5';
 250                 else if (itemid == IT_ARMOR)
 251                         z_offset = '0 0 3';
 252                 else if (itemid == IT_SHOTGUN)
 253                         z_offset = '0 0 10';
 254
 255                 org = find_floor(org) + z_offset;
 256                 setorigin(self, org);
 257         }
 258
 259         if(cvar("spawn_debug") >= 2)
 260         {
 261                 if(self.classname != "droppedweapon")
 262                 {
 263                         entity otheritem;
 264                         for(otheritem = findradius(org, 3); otheritem; otheritem = otheritem.chain)
 265                         {
 266                                 if(otheritem.is_item)
 267                                 {
 268                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 269                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 270                                         error("Mapper sucks.");
 271                                 }
 272                         }
 273                         self.is_item = TRUE;
 274                 }
 275         }
 276
 277         if (self.classname != "droppedweapon")
 278                 waypoint_spawnforitem(self);
 279
 280         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 281                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 282         {
 283                 startitem_failed = TRUE;
 284                 remove (self);
 285                 return;
 286         }
 287
 288         if (cvar("g_minstagib"))
 289         {
 290                 // don't remove dropped items and powerups
 291                 if (self.classname != "droppedweapon" &&
 292                     self.classname != "minstagib")
 293                 {
 294                         startitem_failed = TRUE;
 295                         remove (self);
 296                         return;
 297                 }
 298         }
 299
 300         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 301         {
 302                 startitem_failed = TRUE;
 303                 remove(self);
 304                 return;
 305         }
 306
 307         if(cvar("g_instagib") || cvar("g_rocketarena"))
 308         {
 309                 startitem_failed = TRUE;
 310                 remove(self);
 311                 return;
 312         }
 313
 314         if (self.classname == "droppedweapon")
 315         {
 316                 // don't drop if in a NODROP zone (such as lava)
 317                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 318                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 319                 {
 320                         startitem_failed = TRUE;
 321                         remove(self);
 322                         return;
 323                 }
 324         }
 325
 326         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 327                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 328                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 329         {
 330                 self.target = "###item###"; // for finding the nearest item using find()
 331         }
 332         self.bot_pickup = TRUE;
 333         self.bot_pickupevalfunc = pickupevalfunc;
 334         self.bot_pickupbasevalue = pickupbasevalue;
 335         self.mdl = itemmodel;
 336         //self.noise = pickupsound;
 337         self.item_pickupsound = pickupsound;
 338         // let mappers override respawntime
 339         if (!self.respawntime)
 340                 self.respawntime = defaultrespawntime;
 341         self.netname = itemname;
 342         self.items = itemid;
 343         self.flags = FL_ITEM | itemflags;
 344         setmodel (self, self.mdl);
 345         if (itemflags & FL_WEAPON)
 346         {
 347                 setorigin (self, self.origin + '0 0 23');
 348                 setsize (self, '-12 -12 -12', '12 12 12');
 349
 350                 // neutral team color for pickup weapons
 351                 self.colormap = 160 * 1024 + 160;
 352         }
 353         else
 354         {
 355                 setorigin (self, self.origin + '0 0 25');
 356         //      setsize (self, '-8 -8 -5', '8 8 8');
 357         }
 358         self.movetype = MOVETYPE_TOSS;
 359         self.solid = SOLID_TRIGGER;
 360         self.touch = Item_Touch;
 361
 362         // Savage: remove thrown items after a certain period of time ("garbage collection")
 363         if (self.classname == "droppedweapon")
 364         {
 365                 self.think = RemoveItem;
 366                 self.nextthink = time + 60;
 367         }
 368         else
 369         {
 370                 self.movetype = MOVETYPE_NONE;
 371                 setorigin(self, org);
 372         }
 373
 374         if (cvar("g_fullbrightitems"))
 375                 self.effects = self.effects | EF_FULLBRIGHT;
 376 }
 377
 378 /* replace items in minstagib
 379  * IT_STRENGTH   = invisibility
 380  * IT_NAILS      = extra lives
 381  * IT_INVINCIBLE = speed
 382  */
 383 void minstagib_items (float itemid)
 384 {
 385         // we don't want to replace dropped weapons ;)
 386         if (self.classname == "droppedweapon")
 387         {
 388                 self.ammo_cells = 25;
 389                 StartItem ("models/weapons/g_nex.md3",
 390                         "weapons/weaponpickup.ogg", 15,
 391                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 392                 return;
 393         }
 394
 395         local float rnd;
 396         self.classname = "minstagib";
 397
 398         // replace rocket launchers and nex guns with ammo cells
 399         if (itemid == IT_CELLS)
 400         {
 401                 self.ammo_cells = 1;
 402                 StartItem ("models/items/a_cells.md3",
 403                         "misc/itempickup.ogg", 45,
 404                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 405                 return;
 406         }
 407
 408         // randomize
 409         rnd = random() * 3;
 410         if (rnd <= 1)
 411                 itemid = IT_STRENGTH;
 412         else if (rnd <= 2)
 413                 itemid = IT_NAILS;
 414         else
 415                 itemid = IT_INVINCIBLE;
 416
 417         // replace with invis
 418         if (itemid == IT_STRENGTH)
 419         {
 420                 self.effects = EF_ADDITIVE;
 421                 self.strength_finished = 30;
 422                 StartItem ("models/items/g_strength.md3",
 423                         "misc/powerup.ogg", 120,
 424                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 425         }
 426         // replace with extra lives
 427         if (itemid == IT_NAILS)
 428         {
 429                 self.max_health = 1;
 430                 StartItem ("models/items/g_h100.md3",
 431                         "misc/megahealth.ogg", 120,
 432                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 433
 434         }
 435         // replace with speed
 436         if (itemid == IT_INVINCIBLE)
 437         {
 438                 self.effects = EF_ADDITIVE;
 439                 self.invincible_finished = 30;
 440                 StartItem ("models/items/g_invincible.md3",
 441                         "misc/powerup_shield.ogg", 120,
 442                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 443         }
 444
 445 }
 446
 447 void weapon_uzi (void) {
 448         if(!self.ammo_nails)
 449                 self.ammo_nails = 120;
 450         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 451 }
 452
 453 void weapon_shotgun (void) {
 454         if(!self.ammo_shells)
 455                 self.ammo_shells = 15;
 456         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 457 }
 458
 459 void weapon_grenadelauncher (void) {
 460         if(!self.ammo_rockets)
 461                 self.ammo_rockets = 15;
 462         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 463 }
 464
 465 void weapon_electro (void) {
 466         if(!self.ammo_cells)
 467                 self.ammo_cells = 25;
 468         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 469 }
 470
 471 void weapon_crylink (void) {
 472         if(!self.ammo_cells)
 473                 self.ammo_cells = 25;
 474         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 475 }
 476
 477 void weapon_nex (void) {
 478         if (cvar("g_minstagib")) {
 479                 minstagib_items(IT_CELLS);
 480         } else {
 481                 float nextime;
 482                 if(!self.ammo_cells)
 483                         self.ammo_cells = 25;
 484                 nextime = cvar("g_balance_nex_respawntime_modifier");
 485                 if(nextime)
 486                         nextime = 15 * nextime;
 487                 else
 488                         nextime = 15;
 489                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 490         }
 491 }
 492
 493 void weapon_hagar (void) {
 494         if(!self.ammo_rockets)
 495                 self.ammo_rockets = 15;
 496         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 497 }
 498
 499 void weapon_rocketlauncher (void) {
 500         if (cvar("g_minstagib")) {
 501                 minstagib_items(IT_CELLS);
 502         } else {
 503                 if(!self.ammo_rockets)
 504                         self.ammo_rockets = 15;
 505                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 506         }
 507 }
 508
 509 void item_rockets (void) {
 510         if(!self.ammo_rockets)
 511                 self.ammo_rockets = 15;
 512         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 513 }
 514
 515 void item_bullets (void) {
 516         if(!self.ammo_nails)
 517                 self.ammo_nails = 120;
 518         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 519 }
 520
 521 void item_cells (void) {
 522         if(!self.ammo_cells)
 523                 self.ammo_cells = 25;
 524         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 525 }
 526
 527 void item_shells (void) {
 528         if(!self.ammo_shells)
 529                 self.ammo_shells = 15;
 530         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 531 }
 532
 533 void item_armor1 (void) {
 534         if(!self.armorvalue)
 535                 self.armorvalue = 5;
 536         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 537 }
 538
 539 void item_armor25 (void) {
 540         if(!self.armorvalue)
 541                 self.armorvalue = 100;
 542         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 543 }
 544
 545 void item_health1 (void) {
 546         if(!self.max_health)
 547                 self.max_health = 5;
 548         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 549 }
 550
 551 void item_health25 (void) {
 552         if(!self.max_health)
 553                 self.max_health = 25;
 554         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 555 }
 556
 557 void item_health100 (void) {
 558         if(!cvar("g_powerup_superhealth"))
 559                 return;
 560
 561         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 562                 return;
 563
 564         if(cvar("g_minstagib")) {
 565                 minstagib_items(IT_NAILS);
 566         } else {
 567                 if(!self.max_health)
 568                         self.max_health = 100;
 569                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 570         }
 571 }
 572
 573 void item_strength (void) {
 574         if(!cvar("g_powerup_strength"))
 575                 return;
 576
 577         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 578                 return;
 579
 580         if(cvar("g_minstagib")) {
 581                 minstagib_items(IT_STRENGTH);
 582         } else {
 583                 self.strength_finished = 30;
 584                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 585         }
 586 }
 587
 588 void item_invincible (void) {
 589         if(!cvar("g_powerup_shield"))
 590                 return;
 591
 592         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 593                 return;
 594
 595         if(cvar("g_minstagib")) {
 596                 minstagib_items(IT_INVINCIBLE);
 597         } else {
 598                 self.invincible_finished = 30;
 599                 self.effects = EF_ADDITIVE;
 600                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 601         }
 602 }
 603 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 604 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 605
 606 // compatibility:
 607 void item_quad (void) {self.classname = "item_strength";item_strength();}
 608
 609 void misc_models (void)
 610 {
 611         precache_model (self.model);
 612         setmodel (self, self.model);
 613         setsize (self, self.mins, self.maxs);
 614 }
 615
 616
 617
 618
 619
 620 floatfield Item_CounterField(float it)
 621 {
 622         switch(it)
 623         {
 624                 case IT_SHELLS:      return ammo_shells;
 625                 case IT_NAILS:       return ammo_nails;
 626                 case IT_ROCKETS:     return ammo_rockets;
 627                 case IT_CELLS:       return ammo_cells;
 628                 case IT_5HP:         return health;
 629                 case IT_25HP:        return health;
 630                 case IT_HEALTH:      return health;
 631                 case IT_ARMOR_SHARD: return armorvalue;
 632                 case IT_ARMOR:       return armorvalue;
 633                 // add more things here (health, armor)
 634                 default:             error("requested item has no counter field");
 635         }
 636 }
 637
 638 float Item_WeaponCode(float it)
 639 {
 640         switch(it)
 641         {
 642                 case IT_LASER:            return WEP_LASER;
 643                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 644                 case IT_UZI:              return WEP_UZI;
 645                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 646                 case IT_ELECTRO:          return WEP_ELECTRO;
 647                 case IT_CRYLINK:          return WEP_CRYLINK;
 648                 case IT_NEX:              return WEP_NEX;
 649                 case IT_HAGAR:            return WEP_HAGAR;
 650                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 651                 default:                  return 0;
 652         }
 653 }
 654
 655 spawnfunc Item_SpawnFunc(float it)
 656 {
 657         switch(it)
 658         {
 659                 case IT_SHOTGUN:          return weapon_shotgun;
 660                 case IT_UZI:              return weapon_uzi;
 661                 case IT_GRENADE_LAUNCHER: return weapon_grenadelauncher;
 662                 case IT_ELECTRO:          return weapon_electro;
 663                 case IT_CRYLINK:          return weapon_crylink;
 664                 case IT_NEX:              return weapon_nex;
 665                 case IT_HAGAR:            return weapon_hagar;
 666                 case IT_ROCKET_LAUNCHER:  return weapon_rocketlauncher;
 667                 // add all other item spawn functions here
 668                 default:                  error("requested item can't be spawned");
 669         }
 670 }