data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 float Item_Customize()
  45 {
  46         if(self.spawnshieldtime)
  47                 return TRUE;
  48         if(self.weapons != (self.weapons & other.weapons))
  49         {
  50                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  51                 return TRUE;
  52         }
  53         else
  54         {
  55                 if(g_ghost_items)
  56                 {
  57                         self.alpha = g_ghost_items;
  58                         return TRUE;
  59                 }
  60                 else
  61                         return FALSE;
  62         }
  63 }
  64
  65 void Item_Show (entity e, float mode)
  66 {
  67         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  68         if (mode > 0)
  69         {
  70                 // make the item look normal, and be touchable
  71                 e.model = e.mdl;
  72                 e.solid = SOLID_TRIGGER;
  73                 //e.colormod = '0 0 0';
  74                 e.alpha = 0;
  75                 e.customizeentityforclient = func_null;
  76
  77                 e.spawnshieldtime = 1;
  78         }
  79         else if (mode < 0)
  80         {
  81                 // hide the item completely
  82                 e.model = string_null;
  83                 e.solid = SOLID_NOT;
  84                 //e.colormod = '0 0 0';
  85                 e.alpha = 0;
  86                 e.customizeentityforclient = func_null;
  87
  88                 e.spawnshieldtime = 1;
  89         }
  90         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  91         {
  92                 // make the item translucent green and not touchable
  93                 e.model = e.mdl;
  94                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
  95                 e.effects |= EF_STARDUST;
  96                 //e.colormod = '0.2 1 0.2';
  97                 //e.alpha = 0.5; // will be overridden by CEFC though...
  98                 e.customizeentityforclient = Item_Customize;
  99
 100                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 101         }
 102         else if(g_ghost_items)
 103         {
 104                 // make the item translucent green and not touchable
 105                 e.model = e.mdl;
 106                 e.solid = SOLID_NOT;
 107                 //e.colormod = '0.2 1 0.2';
 108                 e.alpha = g_ghost_items;
 109                 e.customizeentityforclient = func_null;
 110
 111                 e.spawnshieldtime = 1;
 112         }
 113         else
 114         {
 115                 // hide the item completely
 116                 e.model = string_null;
 117                 e.solid = SOLID_NOT;
 118                 //e.colormod = '0 0 0';
 119                 e.alpha = 0;
 120                 e.customizeentityforclient = func_null;
 121
 122                 e.spawnshieldtime = 1;
 123         }
 124
 125         if (e.strength_finished || e.invincible_finished)
 126                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 127         if (cvar("g_nodepthtestitems"))
 128                 e.effects |= EF_NODEPTHTEST;
 129         if (cvar("g_fullbrightitems"))
 130                 e.effects |= EF_FULLBRIGHT;
 131
 132         // relink entity (because solid may have changed)
 133         setorigin(e, e.origin);
 134 }
 135
 136 void Item_Respawn (void)
 137 {
 138         Item_Show(self, 1);
 139         if(!g_minstagib && self.items == IT_STRENGTH)
 140                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 141         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 142                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 143         else
 144                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 145         setorigin (self, self.origin);
 146
 147         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 148         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 149 }
 150
 151 void Item_RespawnCountdown (void)
 152 {
 153         if(self.count >= ITEM_RESPAWN_TICKS)
 154         {
 155                 if(self.waypointsprite_attached)
 156                         WaypointSprite_Kill(self.waypointsprite_attached);
 157                 Item_Respawn();
 158         }
 159         else
 160         {
 161                 self.nextthink = time + 1;
 162                 self.count += 1;
 163                 if(self.count == 1)
 164                 {
 165                         string name;
 166                         vector rgb;
 167                         name = string_null;
 168                         if(g_minstagib)
 169                         {
 170                                 switch(self.items)
 171                                 {
 172                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 173                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 174                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 175                                 }
 176                         }
 177                         else
 178                         {
 179                                 switch(self.items)
 180                                 {
 181                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 182                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 183                                 }
 184                         }
 185                         switch(self.items)
 186                         {
 187                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 188                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 189                         }
 190                         if(name)
 191                         {
 192                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 193                                 if(self.waypointsprite_attached)
 194                                 {
 195                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 196                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 197                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 198                                 }
 199                         }
 200                 }
 201                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 202                 if(self.waypointsprite_attached)
 203                 {
 204                         WaypointSprite_Ping(self.waypointsprite_attached);
 205                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 206                 }
 207         }
 208 }
 209
 210 void Item_ScheduleRespawnIn(entity e, float t)
 211 {
 212         if(e.flags & FL_POWERUP)
 213         {
 214                 e.think = Item_RespawnCountdown;
 215                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 216                 e.count = 0;
 217         }
 218         else
 219         {
 220                 e.think = Item_Respawn;
 221                 e.nextthink = time + t;
 222         }
 223 }
 224
 225 void Item_ScheduleRespawn(entity e)
 226 {
 227         Item_Show(e, 0);
 228         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 229 }
 230
 231 void Item_ScheduleInitialRespawn(entity e)
 232 {
 233         Item_Show(e, 0);
 234         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 235 }
 236
 237 float Item_GiveTo(entity item, entity player)
 238 {
 239         float _switchweapon;
 240         float pickedup;
 241         float it;
 242         float i;
 243         entity e;
 244
 245         // if nothing happens to player, just return without taking the item
 246         pickedup = FALSE;
 247         _switchweapon = FALSE;
 248
 249         if (g_minstagib)
 250         {
 251                 if(item.spawnshieldtime)
 252                 {
 253                         if (item.ammo_fuel)
 254                         if (player.ammo_fuel < g_pickup_fuel_max)
 255                         {
 256                                 pickedup = TRUE;
 257                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 258                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 259                         }
 260                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 261                         {
 262                                 pickedup = TRUE;
 263                                 player.items |= it;
 264                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 265                         }
 266
 267                         _switchweapon = TRUE;
 268                         if (item.ammo_cells)
 269                         {
 270                                 pickedup = TRUE;
 271                                 // play some cool sounds ;)
 272                                 centerprint(player, "\n");
 273                                 if (clienttype(player) == CLIENTTYPE_REAL)
 274                                 {
 275                                         if(player.health <= 5)
 276                                                 play2(player, "announcer/robotic/lastsecond.wav");
 277                                         else if(player.health < 50)
 278                                                 play2(player, "announcer/robotic/narrowly.wav");
 279                                 }
 280                                 // sound not available
 281                                 // else if(item.items == IT_CELLS)
 282                                 //      play2(player, "announce/robotic/ammo.wav");
 283
 284                                 if (item.weapons & WEPBIT_MINSTANEX)
 285                                         W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 286                                 if (item.ammo_cells)
 287                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 288                                 player.health = 100;
 289                         }
 290
 291                         // extralife powerup
 292                         if (item.max_health)
 293                         {
 294                                 pickedup = TRUE;
 295                                 // sound not available
 296                                 // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 297                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 298                                 sprint(player, "^3You picked up some extra lives\n");
 299                         }
 300
 301                         // invis powerup
 302                         if (item.strength_finished)
 303                         {
 304                                 pickedup = TRUE;
 305                                 // sound not available
 306                                 // play2(player, "announce/robotic/invisible.wav");
 307                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 308                         }
 309
 310                         // speed powerup
 311                         if (item.invincible_finished)
 312                         {
 313                                 pickedup = TRUE;
 314                                 // sound not available
 315                                 // play2(player, "announce/robotic/speed.wav");
 316                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 317                         }
 318
 319                         if (item.ammo_fuel)
 320                         if (player.ammo_fuel < g_pickup_fuel_max)
 321                         {
 322                                 pickedup = TRUE;
 323                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 324                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 325                         }
 326                 }
 327         }
 328         else
 329         {
 330                 if (g_weapon_stay == 1)
 331                 if not(item.flags & FL_NO_WEAPON_STAY)
 332                 if (item.flags & FL_WEAPON)
 333                 {
 334                         if(item.classname == "droppedweapon")
 335                         {
 336                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 337                                         goto skip;
 338                         }
 339                         else
 340                         {
 341                                 if (player.weapons & item.weapons)
 342                                         goto skip;
 343                         }
 344                 }
 345
 346                 // in case the player has autoswitch enabled do the following:
 347                 // if the player is using their best weapon before items are given, they
 348                 // probably want to switch to an even better weapon after items are given
 349                 if (player.autoswitch)
 350                 if (player.switchweapon == w_getbestweapon(player))
 351                         _switchweapon = TRUE;
 352
 353                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 354                         _switchweapon = TRUE;
 355
 356                 if(item.spawnshieldtime)
 357                 {
 358                         if (item.ammo_shells)
 359                         if (player.ammo_shells < g_pickup_shells_max)
 360                         {
 361                                 pickedup = TRUE;
 362                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 363                         }
 364                         if (item.ammo_nails)
 365                         if (player.ammo_nails < g_pickup_nails_max)
 366                         {
 367                                 pickedup = TRUE;
 368                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 369                         }
 370                         if (item.ammo_rockets)
 371                         if (player.ammo_rockets < g_pickup_rockets_max)
 372                         {
 373                                 pickedup = TRUE;
 374                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 375                         }
 376                         if (item.ammo_cells)
 377                         if (player.ammo_cells < g_pickup_cells_max)
 378                         {
 379                                 pickedup = TRUE;
 380                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 381                         }
 382                         if (item.ammo_fuel)
 383                         if (player.ammo_fuel < g_pickup_fuel_max)
 384                         {
 385                                 pickedup = TRUE;
 386                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 387                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 388                         }
 389                 }
 390
 391                 if (item.flags & FL_WEAPON)
 392                 if ((it = item.weapons - (item.weapons & player.weapons)))
 393                 {
 394                         pickedup = TRUE;
 395                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 396                         {
 397                                 e = get_weaponinfo(i);
 398                                 if(it & e.weapons)
 399                                         W_GiveWeapon (player, e.weapon, item.netname);
 400                         }
 401                 }
 402
 403                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 404                 {
 405                         pickedup = TRUE;
 406                         player.items |= it;
 407                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 408                 }
 409
 410                 if(item.spawnshieldtime)
 411                 {
 412                         if (item.strength_finished)
 413                         {
 414                                 pickedup = TRUE;
 415                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 416                         }
 417                         if (item.invincible_finished)
 418                         {
 419                                 pickedup = TRUE;
 420                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 421                         }
 422                         //if (item.speed_finished)
 423                         //{
 424                         //      pickedup = TRUE;
 425                         //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 426                         //}
 427                         //if (item.slowmo_finished)
 428                         //{
 429                         //      pickedup = TRUE;
 430                         //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 431                         //}
 432
 433                         if (item.health)
 434                         if (player.health < item.max_health)
 435                         {
 436                                 pickedup = TRUE;
 437                                 player.health = min(player.health + item.health, item.max_health);
 438                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 439                         }
 440                         if (item.armorvalue)
 441                         if (player.armorvalue < item.max_armorvalue)
 442                         {
 443                                 pickedup = TRUE;
 444                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 445                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 446                         }
 447                 }
 448         }
 449
 450 :skip
 451         // always eat teamed entities
 452         if(item.team)
 453                 pickedup = TRUE;
 454
 455         if (!pickedup)
 456                 return 0;
 457
 458         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 459         if (_switchweapon)
 460                 if (player.switchweapon != w_getbestweapon(player))
 461                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 462
 463         return 1;
 464 }
 465
 466 void Item_Touch (void)
 467 {
 468         entity e, head;
 469
 470         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 471         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 472         {
 473                 remove(self);
 474                 return;
 475         }
 476         if (other.classname != "player")
 477                 return;
 478         if (other.deadflag)
 479                 return;
 480         if (self.solid != SOLID_TRIGGER)
 481                 return;
 482         if (self.owner == other)
 483                 return;
 484
 485         if(!Item_GiveTo(self, other))
 486                 return;
 487
 488         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 489
 490         if (self.classname == "droppedweapon")
 491                 remove (self);
 492         else if not(self.spawnshieldtime)
 493                 return;
 494         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 495                 return;
 496         else
 497         {
 498                 if(self.team)
 499                 {
 500                         RandomSelection_Init();
 501                         for(head = world; (head = findfloat(head, team, self.team)); )
 502                         {
 503                                 if(head.flags & FL_ITEM)
 504                                 {
 505                                         Item_Show(head, -1);
 506                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 507                                 }
 508                         }
 509                         e = RandomSelection_chosen_ent;
 510                 }
 511                 else
 512                         e = self;
 513                 Item_ScheduleRespawn(e);
 514         }
 515 }
 516
 517 void Item_FindTeam()
 518 {
 519         entity head, e;
 520
 521         if(self.effects & EF_NODRAW)
 522         {
 523                 // marker for item team search
 524                 dprint("Initializing item team ", ftos(self.team), "\n");
 525                 RandomSelection_Init();
 526                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 527                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 528                 e = RandomSelection_chosen_ent;
 529                 e.state = 0;
 530                 Item_Show(e, 1);
 531
 532                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 533                 {
 534                         if(head != e)
 535                         {
 536                                 // make it a non-spawned item
 537                                 Item_Show(head, -1);
 538                                 head.state = 1; // state 1 = initially hidden item
 539                         }
 540                         head.effects &~= EF_NODRAW;
 541                 }
 542
 543                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 544                         Item_ScheduleInitialRespawn(e);
 545         }
 546 }
 547
 548 void Item_Reset()
 549 {
 550         Item_Show(self, !self.state);
 551         setorigin (self, self.origin);
 552         self.think = SUB_Null;
 553         self.nextthink = 0;
 554
 555         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 556                 Item_ScheduleInitialRespawn(self);
 557 }
 558
 559 // Savage: used for item garbage-collection
 560 // TODO: perhaps nice special effect?
 561 void RemoveItem(void)
 562 {
 563         remove(self);
 564 }
 565
 566 // pickup evaluation functions
 567 // these functions decide how desirable an item is to the bots
 568
 569 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 570
 571 float weapon_pickupevalfunc(entity player, entity item)
 572 {
 573         float c, i, j, position;
 574
 575         // See if I have it already
 576         if(player.weapons & item.weapons == item.weapons)
 577         {
 578                 // If I can pick it up
 579                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 580                         c = 0;
 581                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 582                 {
 583                         // Skilled bots will grab more
 584                         c = bound(0, skill / 10, 1) * 0.5;
 585                 }
 586                 else
 587                         c = 0;
 588         }
 589         else
 590                 c = 1;
 591
 592         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 593         if( bot_custom_weapon && c )
 594         {
 595                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 596                 {
 597                         // Find weapon
 598                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 599                                 continue;
 600
 601                         // Find the highest position on any range
 602                         position = -1;
 603                         for(j = 0; j < WEP_LAST ; ++j){
 604                                 if(
 605                                                 bot_weapons_far[j] == i ||
 606                                                 bot_weapons_mid[j] == i ||
 607                                                 bot_weapons_close[j] == i
 608                                   )
 609                                 {
 610                                         position = j;
 611                                         break;
 612                                 }
 613                         }
 614
 615                         // Rate it
 616                         if (position >= 0 )
 617                         {
 618                                 position = WEP_LAST - position;
 619                                 // item.bot_pickupbasevalue is overwritten here
 620                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 621                         }
 622                 }
 623         }
 624
 625         return item.bot_pickupbasevalue * c;
 626 };
 627
 628 float commodity_pickupevalfunc(entity player, entity item)
 629 {
 630         float c, i, need_shells, need_nails, need_rockets, need_cells;
 631         entity wi;
 632         c = 0;
 633
 634         // Detect needed ammo
 635         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 636         {
 637                 wi = get_weaponinfo(i);
 638
 639                 if not(wi.weapons & player.weapons)
 640                         continue;
 641
 642                 if(wi.items & IT_SHELLS)
 643                         need_shells = TRUE;
 644                 else if(wi.items & IT_NAILS)
 645                         need_nails = TRUE;
 646                 else if(wi.items & IT_ROCKETS)
 647                         need_rockets = TRUE;
 648                 else if(wi.items & IT_CELLS)
 649                         need_cells = TRUE;
 650         }
 651
 652         // TODO: figure out if the player even has the weapon this ammo is for?
 653         // may not affect strategy much though...
 654         // find out how much more ammo/armor/health the player can hold
 655         if (need_shells)
 656         if (item.ammo_shells)
 657         if (player.ammo_shells < g_pickup_shells_max)
 658                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 659         if (need_nails)
 660         if (item.ammo_nails)
 661         if (player.ammo_nails < g_pickup_nails_max)
 662                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 663         if (need_rockets)
 664         if (item.ammo_rockets)
 665         if (player.ammo_rockets < g_pickup_rockets_max)
 666                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 667         if (need_cells)
 668         if (item.ammo_cells)
 669         if (player.ammo_cells < g_pickup_cells_max)
 670                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 671         if (item.armorvalue)
 672         if (player.armorvalue < item.max_armorvalue)
 673                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 674         if (item.health)
 675         if (player.health < item.max_health)
 676                 c = c + max(0, 1 - player.health / item.max_health);
 677
 678         return item.bot_pickupbasevalue * c;
 679 };
 680
 681
 682 .float is_item;
 683 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 684 {
 685         startitem_failed = FALSE;
 686
 687         // is it a dropped weapon?
 688         if (self.classname == "droppedweapon")
 689         {
 690                 self.reset = SUB_Remove;
 691                 // it's a dropped weapon
 692                 self.movetype = MOVETYPE_TOSS;
 693                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 694                 self.think = RemoveItem;
 695                 self.nextthink = time + 60;
 696                 // don't drop if in a NODROP zone (such as lava)
 697                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 698                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 699                 {
 700                         startitem_failed = TRUE;
 701                         remove(self);
 702                         return;
 703                 }
 704         }
 705         else
 706         {
 707                 self.reset = Item_Reset;
 708                 // it's a level item
 709                 if(self.spawnflags & 1)
 710                         self.noalign = 1;
 711                 if (self.noalign)
 712                         self.movetype = MOVETYPE_NONE;
 713                 else
 714                         self.movetype = MOVETYPE_TOSS;
 715                 // do item filtering according to game mode and other things
 716                 if (!self.noalign)
 717                 {
 718                         // first nudge it off the floor a little bit to avoid math errors
 719                         setorigin(self, self.origin + '0 0 1');
 720                         // set item size before we spawn a spawnfunc_waypoint
 721                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 722                                 setsize (self, '-16 -16 0', '16 16 48');
 723                         else
 724                                 setsize (self, '-16 -16 0', '16 16 32');
 725                         // note droptofloor returns FALSE if stuck/or would fall too far
 726                         droptofloor();
 727                         waypoint_spawnforitem(self);
 728                 }
 729
 730                 if(teams_matter)
 731                 {
 732                         if(self.notteam)
 733                         {
 734                                 print("removed non-teamplay ", self.classname, "\n");
 735                                 startitem_failed = TRUE;
 736                                 remove (self);
 737                                 return;
 738                         }
 739                 }
 740                 else
 741                 {
 742                         if(self.notfree)
 743                         {
 744                                 print("removed non-FFA ", self.classname, "\n");
 745                                 startitem_failed = TRUE;
 746                                 remove (self);
 747                                 return;
 748                         }
 749                 }
 750
 751                 if(self.notq3a)
 752                 {
 753                         // We aren't TA or something like that, so we keep the Q3A entities
 754                         print("removed non-Q3A ", self.classname, "\n");
 755                         startitem_failed = TRUE;
 756                         remove (self);
 757                         return;
 758                 }
 759
 760                 /*
 761                  * can't do it that way, as it would break maps
 762                  * TODO make a target_give like entity another way, that perhaps has
 763                  * the weapon name in a key
 764                 if(self.targetname)
 765                 {
 766                         // target_give not yet supported; maybe later
 767                         print("removed targeted ", self.classname, "\n");
 768                         startitem_failed = TRUE;
 769                         remove (self);
 770                         return;
 771                 }
 772                 */
 773
 774                 if(cvar("spawn_debug") >= 2)
 775                 {
 776                         entity otheritem;
 777                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 778                         {
 779                                 if(otheritem.is_item)
 780                                 {
 781                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 782                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 783                                         error("Mapper sucks.");
 784                                 }
 785                         }
 786                         self.is_item = TRUE;
 787                 }
 788
 789                 weaponsInMap |= weaponid;
 790
 791                 if(g_lms || g_ca)
 792                 {
 793                         startitem_failed = TRUE;
 794                         remove(self);
 795                         return;
 796                 }
 797                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 798                 {
 799                         startitem_failed = TRUE;
 800                         remove(self);
 801                         return;
 802                 }
 803                 else if (g_minstagib)
 804                 {
 805                         // don't remove dropped items and powerups
 806                         if (self.classname != "minstagib")
 807                         {
 808                                 startitem_failed = TRUE;
 809                                 remove (self);
 810                                 return;
 811                         }
 812                 }
 813                 else if (g_nixnex)
 814                 {
 815                         local float rm;
 816
 817                         rm = 1;
 818                         switch (itemid)
 819                         {
 820                                 case IT_HEALTH:
 821                                 case IT_5HP:
 822                                 case IT_25HP:
 823                                 case IT_ARMOR:
 824                                 case IT_ARMOR_SHARD:
 825                                         if (cvar("g_nixnex_with_healtharmor"))
 826                                                 rm = 0;
 827                                         break;
 828                                 case IT_STRENGTH:
 829                                 case IT_INVINCIBLE:
 830                                         if (cvar("g_nixnex_with_powerups"))
 831                                                 rm = 0;
 832                                         break;
 833                         }
 834
 835                         if(rm)
 836                         {
 837                                 startitem_failed = TRUE;
 838                                 remove (self);
 839                                 return;
 840                         }
 841                 }
 842                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 843                 {
 844                         startitem_failed = TRUE;
 845                         remove (self);
 846                         return;
 847                 }
 848
 849                 precache_model (itemmodel);
 850                 precache_sound (pickupsound);
 851                 precache_sound ("misc/itemrespawn.wav");
 852                 precache_sound ("misc/itemrespawncountdown.wav");
 853
 854                 if(itemid == IT_STRENGTH)
 855                         precache_sound ("misc/strength_respawn.wav");
 856                 if(itemid == IT_INVINCIBLE)
 857                         precache_sound ("misc/shield_respawn.wav");
 858
 859                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 860                         self.target = "###item###"; // for finding the nearest item using find()
 861         }
 862
 863         self.bot_pickup = TRUE;
 864         self.bot_pickupevalfunc = pickupevalfunc;
 865         self.bot_pickupbasevalue = pickupbasevalue;
 866         self.mdl = itemmodel;
 867         self.item_pickupsound = pickupsound;
 868         // let mappers override respawntime
 869         if(!self.respawntime) // both set
 870         {
 871                 self.respawntime = defaultrespawntime;
 872                 self.respawntimejitter = defaultrespawntimejitter;
 873         }
 874         self.netname = itemname;
 875         self.items = itemid;
 876         self.weapons = weaponid;
 877         self.flags = FL_ITEM | itemflags;
 878         self.touch = Item_Touch;
 879         setmodel (self, self.mdl); // precision set below
 880         self.effects |= EF_LOWPRECISION;
 881         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 882                 setsize (self, '-16 -16 0', '16 16 48');
 883         else
 884                 setsize (self, '-16 -16 0', '16 16 32');
 885         if(itemflags & FL_WEAPON)
 886                 self.modelflags |= MF_ROTATE;
 887
 888         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 889         if (itemflags & FL_WEAPON)
 890         {
 891                 // neutral team color for pickup weapons
 892                 self.colormap = 1024; // color shirt=0 pants=0 grey
 893         }
 894
 895         Item_Show(self, 1);
 896         self.state = 0;
 897         if(self.team)
 898         {
 899                 if(!self.cnt)
 900                         self.cnt = 1; // item probability weight
 901                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 902                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 903         }
 904         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 905                 Item_ScheduleInitialRespawn(self);
 906 }
 907
 908 /* replace items in minstagib
 909  * IT_STRENGTH   = invisibility
 910  * IT_NAILS      = extra lives
 911  * IT_INVINCIBLE = speed
 912  */
 913 void minstagib_items (float itemid)
 914 {
 915         // we don't want to replace dropped weapons ;)
 916         if (self.classname == "droppedweapon")
 917         {
 918                 self.ammo_cells = 25;
 919                 StartItem ("models/weapons/g_nex.md3",
 920                         "weapons/weaponpickup.wav", 15, 0,
 921                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 922                 return;
 923         }
 924
 925         local float rnd;
 926         self.classname = "minstagib";
 927
 928         // replace rocket launchers and nex guns with ammo cells
 929         if (itemid == IT_CELLS)
 930         {
 931                 self.ammo_cells = 1;
 932                 StartItem ("models/items/a_cells.md3",
 933                         "misc/itempickup.wav", 45, 0,
 934                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 935                 return;
 936         }
 937
 938         // randomize
 939         rnd = random() * 3;
 940         if (rnd <= 1)
 941                 itemid = IT_STRENGTH;
 942         else if (rnd <= 2)
 943                 itemid = IT_NAILS;
 944         else
 945                 itemid = IT_INVINCIBLE;
 946
 947         // replace with invis
 948         if (itemid == IT_STRENGTH)
 949         {
 950                 self.strength_finished = 30;
 951                 StartItem ("models/items/g_strength.md3",
 952                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 953                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 954         }
 955         // replace with extra lives
 956         if (itemid == IT_NAILS)
 957         {
 958                 self.max_health = 1;
 959                 StartItem ("models/items/g_h100.md3",
 960                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 961                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 962
 963         }
 964         // replace with speed
 965         if (itemid == IT_INVINCIBLE)
 966         {
 967                 self.invincible_finished = 30;
 968                 StartItem ("models/items/g_invincible.md3",
 969                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 970                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 971         }
 972
 973 }
 974
 975 float minst_no_auto_cells;
 976 void minst_remove_item (void) {
 977         if(minst_no_auto_cells)
 978                 remove(self);
 979 }
 980
 981 float weaponswapping;
 982 float internalteam;
 983
 984 void weapon_defaultspawnfunc(float wpn)
 985 {
 986         entity e;
 987         float t;
 988         var .float ammofield;
 989         string s;
 990         entity oldself;
 991         float i, j;
 992
 993         // set the respawntime in advance (so replaced weapons can copy it)
 994
 995         if(!self.respawntime)
 996         {
 997                 e = get_weaponinfo(wpn);
 998                 if(e.items == IT_SUPERWEAPON)
 999                 {
1000                         self.respawntime = g_pickup_respawntime_powerup;
1001                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
1002                 }
1003                 else
1004                 {
1005                         self.respawntime = g_pickup_respawntime_weapon;
1006                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1007                 }
1008         }
1009
1010         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1011         {
1012                 e = get_weaponinfo(wpn);
1013                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1014                 if(s == "0")
1015                 {
1016                         remove(self);
1017                         startitem_failed = TRUE;
1018                         return;
1019                 }
1020                 t = tokenize_console(s);
1021                 if(t >= 2)
1022                 {
1023                         self.team = --internalteam;
1024                         oldself = self;
1025                         for(i = 1; i < t; ++i)
1026                         {
1027                                 s = argv(i);
1028                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1029                                 {
1030                                         e = get_weaponinfo(j);
1031                                         if(e.netname == s)
1032                                         {
1033                                                 self = spawn();
1034                                                 copyentity(oldself, self);
1035                                                 self.classname = "replacedweapon";
1036                                                 weapon_defaultspawnfunc(j);
1037                                                 break;
1038                                         }
1039                                 }
1040                                 if(j > WEP_LAST)
1041                                 {
1042                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1043                                 }
1044                         }
1045                         self = oldself;
1046                 }
1047                 if(t >= 1)
1048                 {
1049                         s = argv(0);
1050                         wpn = 0;
1051                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1052                         {
1053                                 e = get_weaponinfo(j);
1054                                 if(e.netname == s)
1055                                 {
1056                                         wpn = j;
1057                                         break;
1058                                 }
1059                         }
1060                         if(j > WEP_LAST)
1061                         {
1062                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1063                         }
1064                 }
1065                 if(wpn == 0)
1066                 {
1067                         remove(self);
1068                         startitem_failed = TRUE;
1069                         return;
1070                 }
1071         }
1072
1073         e = get_weaponinfo(wpn);
1074
1075         if(e.items && e.items != IT_SUPERWEAPON)
1076         {
1077                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1078                 {
1079                         if(e.items & j)
1080                         {
1081                                 ammofield = Item_CounterField(j);
1082                                 if(!self.ammofield)
1083                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1084                         }
1085                 }
1086         }
1087         else
1088         {
1089                 self.flags |= FL_NO_WEAPON_STAY;
1090         }
1091
1092         // weapon stay isn't supported for teamed weapons
1093         if(self.team)
1094                 self.flags |= FL_NO_WEAPON_STAY;
1095
1096         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1097         {
1098                 self.ammo_shells = 0;
1099                 self.ammo_nails = 0;
1100                 self.ammo_cells = 0;
1101                 self.ammo_rockets = 0;
1102                 // weapon stay 2: don't use ammo on weapon pickups; instead
1103                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1104         }
1105
1106         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1107         if (self.modelindex) // don't precache if self was removed
1108                 weapon_action(e.weapon, WR_PRECACHE);
1109 }
1110
1111 void spawnfunc_weapon_shotgun (void);
1112 void spawnfunc_weapon_uzi (void) {
1113         if(q3acompat_machineshotgunswap)
1114         if(self.classname != "droppedweapon")
1115         {
1116                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1117                 return;
1118         }
1119         weapon_defaultspawnfunc(WEP_UZI);
1120 }
1121
1122 void spawnfunc_weapon_shotgun (void) {
1123         if(q3acompat_machineshotgunswap)
1124         if(self.classname != "droppedweapon")
1125         {
1126                 weapon_defaultspawnfunc(WEP_UZI);
1127                 return;
1128         }
1129         weapon_defaultspawnfunc(WEP_SHOTGUN);
1130 }
1131
1132 void spawnfunc_weapon_nex (void)
1133 {
1134         if (g_minstagib)
1135         {
1136                 minstagib_items(IT_CELLS);
1137                 self.think = minst_remove_item;
1138                 self.nextthink = time;
1139                 return;
1140         }
1141         weapon_defaultspawnfunc(WEP_NEX);
1142 }
1143
1144 void spawnfunc_weapon_minstanex (void)
1145 {
1146         if (g_minstagib)
1147         {
1148                 minstagib_items(IT_CELLS);
1149                 self.think = minst_remove_item;
1150                 self.nextthink = time;
1151                 return;
1152         }
1153         weapon_defaultspawnfunc(WEP_MINSTANEX);
1154 }
1155
1156 void spawnfunc_weapon_rocketlauncher (void)
1157 {
1158         if (g_minstagib)
1159         {
1160                 minstagib_items(IT_CELLS);
1161                 self.think = minst_remove_item;
1162                 self.nextthink = time;
1163                 return;
1164         }
1165         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1166 }
1167
1168 void spawnfunc_item_rockets (void) {
1169         if(!self.ammo_rockets)
1170                 self.ammo_rockets = g_pickup_rockets;
1171         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1172 }
1173
1174 void spawnfunc_item_shells (void);
1175 void spawnfunc_item_bullets (void) {
1176         if(!weaponswapping)
1177         if(q3acompat_machineshotgunswap)
1178         if(self.classname != "droppedweapon")
1179         {
1180                 weaponswapping = TRUE;
1181                 spawnfunc_item_shells();
1182                 weaponswapping = FALSE;
1183                 return;
1184         }
1185
1186         if(!self.ammo_nails)
1187                 self.ammo_nails = g_pickup_nails;
1188         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1189 }
1190
1191 void spawnfunc_item_cells (void) {
1192         if(!self.ammo_cells)
1193                 self.ammo_cells = g_pickup_cells;
1194         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1195 }
1196
1197 void spawnfunc_item_shells (void) {
1198         if(!weaponswapping)
1199         if(q3acompat_machineshotgunswap)
1200         if(self.classname != "droppedweapon")
1201         {
1202                 weaponswapping = TRUE;
1203                 spawnfunc_item_bullets();
1204                 weaponswapping = FALSE;
1205                 return;
1206         }
1207
1208         if(!self.ammo_shells)
1209                 self.ammo_shells = g_pickup_shells;
1210         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1211 }
1212
1213 void spawnfunc_item_armor_small (void) {
1214         if(!self.armorvalue)
1215                 self.armorvalue = g_pickup_armorsmall;
1216         if(!self.max_armorvalue)
1217                 self.max_armorvalue = g_pickup_armorsmall_max;
1218         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1219 }
1220
1221 void spawnfunc_item_armor_medium (void) {
1222         if(!self.armorvalue)
1223                 self.armorvalue = g_pickup_armormedium;
1224         if(!self.max_armorvalue)
1225                 self.max_armorvalue = g_pickup_armormedium_max;
1226         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1227 }
1228
1229 void spawnfunc_item_armor_big (void) {
1230         if(!self.armorvalue)
1231                 self.armorvalue = g_pickup_armorbig;
1232         if(!self.max_armorvalue)
1233                 self.max_armorvalue = g_pickup_armorbig_max;
1234         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1235 }
1236
1237 void spawnfunc_item_armor_large (void) {
1238         if(!self.armorvalue)
1239                 self.armorvalue = g_pickup_armorlarge;
1240         if(!self.max_armorvalue)
1241                 self.max_armorvalue = g_pickup_armorlarge_max;
1242         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1243 }
1244
1245 void spawnfunc_item_health_small (void) {
1246         if(!self.max_health)
1247                 self.max_health = g_pickup_healthsmall_max;
1248         if(!self.health)
1249                 self.health = g_pickup_healthsmall;
1250         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1251 }
1252
1253 void spawnfunc_item_health_medium (void) {
1254         if(!self.max_health)
1255                 self.max_health = g_pickup_healthmedium_max;
1256         if(!self.health)
1257                 self.health = g_pickup_healthmedium;
1258         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1259 }
1260
1261 void spawnfunc_item_health_large (void) {
1262         if(!self.max_health)
1263                 self.max_health = g_pickup_healthlarge_max;
1264         if(!self.health)
1265                 self.health = g_pickup_healthlarge;
1266         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1267 }
1268
1269 void spawnfunc_item_health_mega (void) {
1270         if(!cvar("g_powerup_superhealth"))
1271                 return;
1272
1273         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1274                 return;
1275
1276         if(g_minstagib) {
1277                 minstagib_items(IT_NAILS);
1278         } else {
1279                 if(!self.max_health)
1280                         self.max_health = g_pickup_healthmega_max;
1281                 if(!self.health)
1282                         self.health = g_pickup_healthmega;
1283                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1284         }
1285 }
1286
1287 // support old misnamed entities
1288 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1289 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1290 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1291 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1292 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1293
1294 void spawnfunc_item_strength (void) {
1295         if(!cvar("g_powerup_strength"))
1296                 return;
1297
1298         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1299                 return;
1300
1301         if(g_minstagib) {
1302                 minstagib_items(IT_STRENGTH);
1303         } else {
1304                 precache_sound("weapons/strength_fire.wav");
1305                 self.strength_finished = 30;
1306                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1307         }
1308 }
1309
1310 void spawnfunc_item_invincible (void) {
1311         if(!cvar("g_powerup_shield"))
1312                 return;
1313
1314         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1315                 return;
1316
1317         if(g_minstagib) {
1318                 minstagib_items(IT_INVINCIBLE);
1319         } else {
1320                 self.invincible_finished = 30;
1321                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1322         }
1323 }
1324
1325 void spawnfunc_item_minst_cells (void) {
1326         if (g_minstagib)
1327         {
1328                 minst_no_auto_cells = 1;
1329                 minstagib_items(IT_CELLS);
1330         }
1331         else
1332                 remove(self);
1333 }
1334
1335 // compatibility:
1336 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1337
1338 float target_item_func_set(float a, float b)
1339 {
1340         if(b == 0)
1341                 return a;
1342         else if(b < 0)
1343                 return 0;
1344         else
1345                 return b;
1346 }
1347
1348 float target_item_func_min(float a, float b)
1349 {
1350         if(b == 0)
1351                 return a;
1352         else if(b < 0)
1353                 return 0;
1354         else
1355                 return min(a, b);
1356 }
1357
1358 float target_item_func_max(float a, float b)
1359 {
1360         return max(a, b);
1361 }
1362
1363 float target_item_func_bitset(float a, float b)
1364 {
1365         return b;
1366 }
1367
1368 float target_item_func_and(float a, float b)
1369 {
1370         return a & b;
1371 }
1372
1373 float target_item_func_itembitset(float a, float b)
1374 {
1375         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1376 }
1377
1378 float target_item_func_itemand(float a, float b)
1379 {
1380         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1381 }
1382
1383 float target_item_func_or(float a, float b)
1384 {
1385         return a | b;
1386 }
1387
1388 float target_item_func_andnot(float a, float b)
1389 {
1390         return a - (a & b);
1391 }
1392
1393 float target_item_changed;
1394 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1395 {
1396         float n, d;
1397         n = func(activator.field, self.field);
1398
1399         if(binary)
1400         {
1401                 d = n & activator.field;
1402                 if(d != n) // bits added?
1403                         d = +1;
1404                 else if(d != activator.field) // bits removed?
1405                         d = -1;
1406                 else
1407                         d = 0;
1408         }
1409         else
1410                 d = n - activator.field;
1411
1412         if(d < 0)
1413         {
1414                 if(sound_decrease != "")
1415                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1416                 target_item_changed = 1;
1417         }
1418         else if(d > 0)
1419         {
1420                 if(sound_increase != "")
1421                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1422                 target_item_changed = 1;
1423         }
1424         activator.field = n;
1425 }
1426
1427 void target_items_use (void)
1428 {
1429         float h0, a0, f0;
1430
1431         if(activator.classname == "droppedweapon")
1432         {
1433                 EXACTTRIGGER_TOUCH;
1434                 remove(activator);
1435                 return;
1436         }
1437
1438         if(activator.classname != "player")
1439                 return;
1440         if(activator.deadflag != DEAD_NO)
1441                 return;
1442         EXACTTRIGGER_TOUCH;
1443
1444         entity e;
1445         for(e = world; (e = find(e, classname, "droppedweapon")); )
1446                 if(e.enemy == activator)
1447                         remove(e);
1448
1449         float _switchweapon;
1450         _switchweapon = FALSE;
1451         if (activator.autoswitch)
1452                 if (activator.switchweapon == w_getbestweapon(activator))
1453                         _switchweapon = TRUE;
1454
1455         a0 = activator.armorvalue;
1456         h0 = activator.health;
1457         f0 = activator.ammo_fuel;
1458         target_item_changed = 0;
1459
1460         if(self.spawnflags == 0) // SET
1461         {
1462                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1463                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1464                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1465                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1466                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1467                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1468                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1469                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1470                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1471
1472                 if((self.items & activator.items) & IT_STRENGTH)
1473                         activator.strength_finished = time + self.strength_finished;
1474                 if((self.items & activator.items) & IT_INVINCIBLE)
1475                         activator.invincible_finished = time + self.invincible_finished;
1476         }
1477         else if(self.spawnflags == 1) // AND/MIN
1478         {
1479                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1480                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1481                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1482                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1483                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1484                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1485                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1486                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1487                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1488
1489                 if((self.items & activator.items) & IT_STRENGTH)
1490                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1491                 if((self.items & activator.items) & IT_INVINCIBLE)
1492                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1493         }
1494         else if(self.spawnflags == 2) // OR/MAX
1495         {
1496                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1497                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1498                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1499                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1500                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1501                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1502                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1503                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1504                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1505
1506                 if((self.items & activator.items) & IT_STRENGTH)
1507                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1508                 if((self.items & activator.items) & IT_INVINCIBLE)
1509                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1510         }
1511         else if(self.spawnflags == 4) // ANDNOT/MIN
1512         {
1513                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1514                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1515                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1516                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1517                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1518                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1519                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1520                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1521                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1522
1523                 if((self.items & activator.items) & IT_STRENGTH)
1524                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1525                 if((self.items & activator.items) & IT_INVINCIBLE)
1526                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1527         }
1528
1529         if not(activator.items & IT_STRENGTH)
1530                 activator.strength_finished = 0;
1531         if not(activator.items & IT_INVINCIBLE)
1532                 activator.invincible_finished = 0;
1533
1534         if(activator.health > h0)
1535                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1536         else if(activator.health < h0)
1537                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1538
1539         if(activator.ammo_fuel > f0)
1540                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1541         else if(activator.ammo_fuel < f0)
1542                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1543
1544         if(activator.armorvalue > a0)
1545                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1546
1547         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1548                 _switchweapon = TRUE;
1549         if(_switchweapon)
1550                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1551
1552         if(target_item_changed)
1553                 centerprint(activator, self.message);
1554 }
1555
1556 void spawnfunc_target_items (void)
1557 {
1558         float n, i, j;
1559         entity e;
1560
1561         if(g_nixnex)
1562         {
1563                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1564                 remove(self);
1565                 return;
1566         }
1567
1568         self.use = target_items_use;
1569         if(!self.strength_finished)
1570                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1571         if(!self.invincible_finished)
1572                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1573
1574         precache_sound("misc/itempickup.wav");
1575         precache_sound("misc/itempickup.wav");
1576         precache_sound("misc/itempickup.wav");
1577         precache_sound("misc/itempickup.wav");
1578         precache_sound("misc/megahealth.wav");
1579         precache_sound("misc/armor25.wav");
1580         precache_sound("misc/powerup.wav");
1581         precache_sound("misc/poweroff.wav");
1582         precache_sound("weapons/weaponpickup.wav");
1583
1584         n = tokenize_console(self.netname);
1585         for(i = 0; i < n; ++i)
1586         {
1587                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1588                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1589                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1590                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1591                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1592                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1593                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1594                 else
1595                 {
1596                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1597                         {
1598                                 e = get_weaponinfo(j);
1599                                 if(argv(i) == e.netname)
1600                                 {
1601                                         self.weapons |= e.weapons;
1602                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1603                                                 weapon_action(e.weapon, WR_PRECACHE);
1604                                         break;
1605                                 }
1606                         }
1607                         if(j > WEP_LAST)
1608                                 print("target_items: invalid item ", argv(i), "\n");
1609                 }
1610         }
1611 }
1612
1613 void spawnfunc_item_fuel(void)
1614 {
1615         if(!self.ammo_fuel)
1616                 self.ammo_fuel = g_pickup_fuel;
1617         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1618 }
1619
1620 void spawnfunc_item_fuel_regen(void)
1621 {
1622         if(start_items & IT_FUEL_REGEN)
1623         {
1624                 spawnfunc_item_fuel();
1625                 return;
1626         }
1627         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1628 }
1629
1630 void spawnfunc_item_jetpack(void)
1631 {
1632         if(g_grappling_hook)
1633                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1634         if(!self.ammo_fuel)
1635                 self.ammo_fuel = g_pickup_fuel_jetpack;
1636         if(start_items & IT_JETPACK)
1637         {
1638                 spawnfunc_item_fuel();
1639                 return;
1640         }
1641         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1642 }
1643
1644 // we no longer have the seeker
1645 void spawnfunc_weapon_seeker()
1646 {
1647         spawnfunc_weapon_fireball();
1648 }