data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 float Item_Customize()
  45 {
  46         if(self.spawnshieldtime)
  47                 return TRUE;
  48         if(self.weapons != (self.weapons & other.weapons))
  49         {
  50                 self.colormod = self.glowmod = stov(cvar_string("g_ghost_items_color"));
  51                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  52                 return TRUE;
  53         }
  54         else
  55         {
  56                 if(g_ghost_items)
  57                 {
  58                         self.colormod = self.glowmod = stov(cvar_string("g_ghost_items_color"));
  59                         self.alpha = g_ghost_items;
  60                         return TRUE;
  61                 }
  62                 else
  63                         return FALSE;
  64         }
  65 }
  66
  67 void Item_Show (entity e, float mode)
  68 {
  69         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
  70         if (mode > 0)
  71         {
  72                 // make the item look normal, and be touchable
  73                 e.model = e.mdl;
  74                 e.solid = SOLID_TRIGGER;
  75                 e.colormod = e.glowmod = '0 0 0';
  76                 e.alpha = 0;
  77                 e.customizeentityforclient = func_null;
  78
  79                 e.spawnshieldtime = 1;
  80         }
  81         else if (mode < 0)
  82         {
  83                 // hide the item completely
  84                 e.model = string_null;
  85                 e.solid = SOLID_NOT;
  86                 //e.colormod = '0 0 0';
  87                 e.alpha = 0;
  88                 e.customizeentityforclient = func_null;
  89
  90                 e.spawnshieldtime = 1;
  91         }
  92         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  93         {
  94                 // make the item translucent green and not touchable
  95                 e.model = e.mdl;
  96                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
  97                 e.effects |= EF_STARDUST;
  98                 //e.colormod = '0.2 1 0.2';
  99                 //e.alpha = 0.5; // will be overridden by CEFC though...
 100                 e.customizeentityforclient = Item_Customize;
 101
 102                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 103         }
 104         else if(g_ghost_items)
 105         {
 106                 // make the item translucent green and not touchable
 107                 e.model = e.mdl;
 108                 e.solid = SOLID_NOT;
 109                 e.colormod = e.glowmod = stov(cvar_string("g_ghost_items_color"));
 110                 e.alpha = g_ghost_items;
 111                 e.customizeentityforclient = func_null;
 112
 113                 e.spawnshieldtime = 1;
 114         }
 115         else
 116         {
 117                 // hide the item completely
 118                 e.model = string_null;
 119                 e.solid = SOLID_NOT;
 120                 //e.colormod = '0 0 0';
 121                 e.alpha = 0;
 122                 e.customizeentityforclient = func_null;
 123
 124                 e.spawnshieldtime = 1;
 125         }
 126
 127         if (e.strength_finished || e.invincible_finished)
 128                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 129         if (cvar("g_nodepthtestitems"))
 130                 e.effects |= EF_NODEPTHTEST;
 131         if (cvar("g_fullbrightitems"))
 132                 e.effects |= EF_FULLBRIGHT;
 133
 134         // relink entity (because solid may have changed)
 135         setorigin(e, e.origin);
 136 }
 137
 138 void Item_Respawn (void)
 139 {
 140         Item_Show(self, 1);
 141         if(!g_minstagib && self.items == IT_STRENGTH)
 142                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 143         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 144                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 145         else
 146                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 147         setorigin (self, self.origin);
 148
 149         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 150         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 151 }
 152
 153 void Item_RespawnCountdown (void)
 154 {
 155         if(self.count >= ITEM_RESPAWN_TICKS)
 156         {
 157                 if(self.waypointsprite_attached)
 158                         WaypointSprite_Kill(self.waypointsprite_attached);
 159                 Item_Respawn();
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 self.count += 1;
 165                 if(self.count == 1)
 166                 {
 167                         string name;
 168                         vector rgb;
 169                         name = string_null;
 170                         if(g_minstagib)
 171                         {
 172                                 switch(self.items)
 173                                 {
 174                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 175                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 176                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 177                                 }
 178                         }
 179                         else
 180                         {
 181                                 switch(self.items)
 182                                 {
 183                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 184                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 185                                 }
 186                         }
 187                         switch(self.items)
 188                         {
 189                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 190                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 191                         }
 192                         if(name)
 193                         {
 194                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 195                                 if(self.waypointsprite_attached)
 196                                 {
 197                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 198                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 199                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 200                                 }
 201                         }
 202                 }
 203                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 204                 if(self.waypointsprite_attached)
 205                 {
 206                         WaypointSprite_Ping(self.waypointsprite_attached);
 207                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 208                 }
 209         }
 210 }
 211
 212 void Item_ScheduleRespawnIn(entity e, float t)
 213 {
 214         if(e.flags & FL_POWERUP)
 215         {
 216                 e.think = Item_RespawnCountdown;
 217                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 218                 e.count = 0;
 219         }
 220         else
 221         {
 222                 e.think = Item_Respawn;
 223                 e.nextthink = time + t;
 224         }
 225 }
 226
 227 void Item_ScheduleRespawn(entity e)
 228 {
 229         Item_Show(e, 0);
 230         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 231 }
 232
 233 void Item_ScheduleInitialRespawn(entity e)
 234 {
 235         Item_Show(e, 0);
 236         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 237 }
 238
 239 float Item_GiveTo(entity item, entity player)
 240 {
 241         float _switchweapon;
 242         float pickedup;
 243         float it;
 244         float i;
 245         entity e;
 246
 247         // if nothing happens to player, just return without taking the item
 248         pickedup = FALSE;
 249         _switchweapon = FALSE;
 250
 251         if (g_minstagib)
 252         {
 253                 if(item.spawnshieldtime)
 254                 {
 255                         if (item.ammo_fuel)
 256                         if (player.ammo_fuel < g_pickup_fuel_max)
 257                         {
 258                                 pickedup = TRUE;
 259                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 260                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 261                         }
 262                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 263                         {
 264                                 pickedup = TRUE;
 265                                 player.items |= it;
 266                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 267                         }
 268
 269                         _switchweapon = TRUE;
 270                         if (item.ammo_cells)
 271                         {
 272                                 pickedup = TRUE;
 273                                 // play some cool sounds ;)
 274                                 centerprint(player, "\n");
 275                                 if (clienttype(player) == CLIENTTYPE_REAL)
 276                                 {
 277                                         if(player.health <= 5)
 278                                                 AnnounceTo(player, "lastsecond");
 279                                         else if(player.health < 50)
 280                                                 AnnounceTo(player, "narrowly");
 281                                 }
 282                                 // sound not available
 283                                 // else if(item.items == IT_CELLS)
 284                                 //      AnnounceTo(player, "ammo");
 285
 286                                 if (item.weapons & WEPBIT_MINSTANEX)
 287                                         W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 288                                 if (item.ammo_cells)
 289                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 290                                 player.health = 100;
 291                         }
 292
 293                         // extralife powerup
 294                         if (item.max_health)
 295                         {
 296                                 pickedup = TRUE;
 297                                 // sound not available
 298                                 // AnnounceTo(player, "_lives");
 299                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 300                                 sprint(player, "^3You picked up some extra lives\n");
 301                         }
 302
 303                         // invis powerup
 304                         if (item.strength_finished)
 305                         {
 306                                 pickedup = TRUE;
 307                                 // sound not available
 308                                 // AnnounceTo(player, "invisible");
 309                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 310                         }
 311
 312                         // speed powerup
 313                         if (item.invincible_finished)
 314                         {
 315                                 pickedup = TRUE;
 316                                 // sound not available
 317                                 // AnnounceTo(player, "speed");
 318                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 319                         }
 320
 321                         if (item.ammo_fuel)
 322                         if (player.ammo_fuel < g_pickup_fuel_max)
 323                         {
 324                                 pickedup = TRUE;
 325                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 326                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 327                         }
 328                 }
 329         }
 330         else
 331         {
 332                 if (g_weapon_stay == 1)
 333                 if not(item.flags & FL_NO_WEAPON_STAY)
 334                 if (item.flags & FL_WEAPON)
 335                 {
 336                         if(item.classname == "droppedweapon")
 337                         {
 338                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 339                                         goto skip;
 340                         }
 341                         else
 342                         {
 343                                 if (player.weapons & item.weapons)
 344                                         goto skip;
 345                         }
 346                 }
 347
 348                 // in case the player has autoswitch enabled do the following:
 349                 // if the player is using their best weapon before items are given, they
 350                 // probably want to switch to an even better weapon after items are given
 351                 if (player.autoswitch)
 352                 if (player.switchweapon == w_getbestweapon(player))
 353                         _switchweapon = TRUE;
 354
 355                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 356                         _switchweapon = TRUE;
 357
 358                 if(item.spawnshieldtime)
 359                 {
 360                         if (item.ammo_shells)
 361                         if (player.ammo_shells < g_pickup_shells_max)
 362                         {
 363                                 pickedup = TRUE;
 364                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 365                         }
 366                         if (item.ammo_nails)
 367                         if (player.ammo_nails < g_pickup_nails_max)
 368                         {
 369                                 pickedup = TRUE;
 370                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 371                         }
 372                         if (item.ammo_rockets)
 373                         if (player.ammo_rockets < g_pickup_rockets_max)
 374                         {
 375                                 pickedup = TRUE;
 376                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 377                         }
 378                         if (item.ammo_cells)
 379                         if (player.ammo_cells < g_pickup_cells_max)
 380                         {
 381                                 pickedup = TRUE;
 382                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 383                         }
 384                         if (item.ammo_fuel)
 385                         if (player.ammo_fuel < g_pickup_fuel_max)
 386                         {
 387                                 pickedup = TRUE;
 388                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 389                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 390                         }
 391                 }
 392
 393                 if (item.flags & FL_WEAPON)
 394                 if ((it = item.weapons - (item.weapons & player.weapons)))
 395                 {
 396                         pickedup = TRUE;
 397                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 398                         {
 399                                 e = get_weaponinfo(i);
 400                                 if(it & e.weapons)
 401                                         W_GiveWeapon (player, e.weapon, item.netname);
 402                         }
 403                 }
 404
 405                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 406                 {
 407                         pickedup = TRUE;
 408                         player.items |= it;
 409                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 410                 }
 411
 412                 if(item.spawnshieldtime)
 413                 {
 414                         if (item.strength_finished)
 415                         {
 416                                 pickedup = TRUE;
 417                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 418                         }
 419                         if (item.invincible_finished)
 420                         {
 421                                 pickedup = TRUE;
 422                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 423                         }
 424
 425                         if (item.health)
 426                         if (player.health < item.max_health)
 427                         {
 428                                 pickedup = TRUE;
 429                                 player.health = min(player.health + item.health, item.max_health);
 430                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 431                         }
 432                         if (item.armorvalue)
 433                         if (player.armorvalue < item.max_armorvalue)
 434                         {
 435                                 pickedup = TRUE;
 436                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 437                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 438                         }
 439                 }
 440         }
 441
 442 :skip
 443         // always eat teamed entities
 444         if(item.team)
 445                 pickedup = TRUE;
 446
 447         if (!pickedup)
 448                 return 0;
 449
 450         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 451         if (_switchweapon)
 452                 if (player.switchweapon != w_getbestweapon(player))
 453                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 454
 455         return 1;
 456 }
 457
 458 void Item_Touch (void)
 459 {
 460         entity e, head;
 461
 462         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 463         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 464         {
 465                 remove(self);
 466                 return;
 467         }
 468         if (other.classname != "player")
 469                 return;
 470         if (other.deadflag)
 471                 return;
 472         if (self.solid != SOLID_TRIGGER)
 473                 return;
 474         if (self.owner == other)
 475                 return;
 476
 477         if(!Item_GiveTo(self, other))
 478                 return;
 479
 480         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 481
 482         if (self.classname == "droppedweapon")
 483                 remove (self);
 484         else if not(self.spawnshieldtime)
 485                 return;
 486         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 487                 return;
 488         else
 489         {
 490                 if(self.team)
 491                 {
 492                         RandomSelection_Init();
 493                         for(head = world; (head = findfloat(head, team, self.team)); )
 494                         {
 495                                 if(head.flags & FL_ITEM)
 496                                 {
 497                                         Item_Show(head, -1);
 498                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 499                                 }
 500                         }
 501                         e = RandomSelection_chosen_ent;
 502                 }
 503                 else
 504                         e = self;
 505                 Item_ScheduleRespawn(e);
 506         }
 507 }
 508
 509 void Item_FindTeam()
 510 {
 511         entity head, e;
 512
 513         if(self.effects & EF_NODRAW)
 514         {
 515                 // marker for item team search
 516                 dprint("Initializing item team ", ftos(self.team), "\n");
 517                 RandomSelection_Init();
 518                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 519                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 520                 e = RandomSelection_chosen_ent;
 521                 e.state = 0;
 522                 Item_Show(e, 1);
 523
 524                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 525                 {
 526                         if(head != e)
 527                         {
 528                                 // make it a non-spawned item
 529                                 Item_Show(head, -1);
 530                                 head.state = 1; // state 1 = initially hidden item
 531                         }
 532                         head.effects &~= EF_NODRAW;
 533                 }
 534
 535                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 536                         Item_ScheduleInitialRespawn(e);
 537         }
 538 }
 539
 540 void Item_Reset()
 541 {
 542         Item_Show(self, !self.state);
 543         setorigin (self, self.origin);
 544         self.think = SUB_Null;
 545         self.nextthink = 0;
 546
 547         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 548                 Item_ScheduleInitialRespawn(self);
 549 }
 550
 551 // Savage: used for item garbage-collection
 552 // TODO: perhaps nice special effect?
 553 void RemoveItem(void)
 554 {
 555         remove(self);
 556 }
 557
 558 // pickup evaluation functions
 559 // these functions decide how desirable an item is to the bots
 560
 561 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 562
 563 float weapon_pickupevalfunc(entity player, entity item)
 564 {
 565         float c, i, j, position;
 566
 567         // See if I have it already
 568         if(player.weapons & item.weapons == item.weapons)
 569         {
 570                 // If I can pick it up
 571                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 572                         c = 0;
 573                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 574                 {
 575                         // Skilled bots will grab more
 576                         c = bound(0, skill / 10, 1) * 0.5;
 577                 }
 578                 else
 579                         c = 0;
 580         }
 581         else
 582                 c = 1;
 583
 584         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 585         if( bot_custom_weapon && c )
 586         {
 587                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 588                 {
 589                         // Find weapon
 590                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 591                                 continue;
 592
 593                         // Find the highest position on any range
 594                         position = -1;
 595                         for(j = 0; j < WEP_LAST ; ++j){
 596                                 if(
 597                                                 bot_weapons_far[j] == i ||
 598                                                 bot_weapons_mid[j] == i ||
 599                                                 bot_weapons_close[j] == i
 600                                   )
 601                                 {
 602                                         position = j;
 603                                         break;
 604                                 }
 605                         }
 606
 607                         // Rate it
 608                         if (position >= 0 )
 609                         {
 610                                 position = WEP_LAST - position;
 611                                 // item.bot_pickupbasevalue is overwritten here
 612                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 613                         }
 614                 }
 615         }
 616
 617         return item.bot_pickupbasevalue * c;
 618 };
 619
 620 float commodity_pickupevalfunc(entity player, entity item)
 621 {
 622         float c, i, need_shells, need_nails, need_rockets, need_cells;
 623         entity wi;
 624         c = 0;
 625
 626         // Detect needed ammo
 627         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 628         {
 629                 wi = get_weaponinfo(i);
 630
 631                 if not(wi.weapons & player.weapons)
 632                         continue;
 633
 634                 if(wi.items & IT_SHELLS)
 635                         need_shells = TRUE;
 636                 else if(wi.items & IT_NAILS)
 637                         need_nails = TRUE;
 638                 else if(wi.items & IT_ROCKETS)
 639                         need_rockets = TRUE;
 640                 else if(wi.items & IT_CELLS)
 641                         need_cells = TRUE;
 642         }
 643
 644         // TODO: figure out if the player even has the weapon this ammo is for?
 645         // may not affect strategy much though...
 646         // find out how much more ammo/armor/health the player can hold
 647         if (need_shells)
 648         if (item.ammo_shells)
 649         if (player.ammo_shells < g_pickup_shells_max)
 650                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 651         if (need_nails)
 652         if (item.ammo_nails)
 653         if (player.ammo_nails < g_pickup_nails_max)
 654                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 655         if (need_rockets)
 656         if (item.ammo_rockets)
 657         if (player.ammo_rockets < g_pickup_rockets_max)
 658                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 659         if (need_cells)
 660         if (item.ammo_cells)
 661         if (player.ammo_cells < g_pickup_cells_max)
 662                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 663         if (item.armorvalue)
 664         if (player.armorvalue < item.max_armorvalue)
 665                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 666         if (item.health)
 667         if (player.health < item.max_health)
 668                 c = c + max(0, 1 - player.health / item.max_health);
 669
 670         return item.bot_pickupbasevalue * c;
 671 };
 672
 673
 674 .float is_item;
 675 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 676 {
 677         startitem_failed = FALSE;
 678
 679         // is it a dropped weapon?
 680         if (self.classname == "droppedweapon")
 681         {
 682                 self.reset = SUB_Remove;
 683                 // it's a dropped weapon
 684                 self.movetype = MOVETYPE_TOSS;
 685                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 686                 self.think = RemoveItem;
 687                 self.nextthink = time + 60;
 688                 // don't drop if in a NODROP zone (such as lava)
 689                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 690                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 691                 {
 692                         startitem_failed = TRUE;
 693                         remove(self);
 694                         return;
 695                 }
 696         }
 697         else
 698         {
 699                 self.reset = Item_Reset;
 700                 // it's a level item
 701                 if(self.spawnflags & 1)
 702                         self.noalign = 1;
 703                 if (self.noalign)
 704                         self.movetype = MOVETYPE_NONE;
 705                 else
 706                         self.movetype = MOVETYPE_TOSS;
 707                 // do item filtering according to game mode and other things
 708                 if (!self.noalign)
 709                 {
 710                         // first nudge it off the floor a little bit to avoid math errors
 711                         setorigin(self, self.origin + '0 0 1');
 712                         // set item size before we spawn a spawnfunc_waypoint
 713                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 714                                 setsize (self, '-16 -16 0', '16 16 48');
 715                         else
 716                                 setsize (self, '-16 -16 0', '16 16 32');
 717                         // note droptofloor returns FALSE if stuck/or would fall too far
 718                         droptofloor();
 719                         waypoint_spawnforitem(self);
 720                 }
 721
 722                 if(teams_matter)
 723                 {
 724                         if(self.notteam)
 725                         {
 726                                 print("removed non-teamplay ", self.classname, "\n");
 727                                 startitem_failed = TRUE;
 728                                 remove (self);
 729                                 return;
 730                         }
 731                 }
 732                 else
 733                 {
 734                         if(self.notfree)
 735                         {
 736                                 print("removed non-FFA ", self.classname, "\n");
 737                                 startitem_failed = TRUE;
 738                                 remove (self);
 739                                 return;
 740                         }
 741                 }
 742
 743                 if(self.notq3a)
 744                 {
 745                         // We aren't TA or something like that, so we keep the Q3A entities
 746                         print("removed non-Q3A ", self.classname, "\n");
 747                         startitem_failed = TRUE;
 748                         remove (self);
 749                         return;
 750                 }
 751
 752                 /*
 753                  * can't do it that way, as it would break maps
 754                  * TODO make a target_give like entity another way, that perhaps has
 755                  * the weapon name in a key
 756                 if(self.targetname)
 757                 {
 758                         // target_give not yet supported; maybe later
 759                         print("removed targeted ", self.classname, "\n");
 760                         startitem_failed = TRUE;
 761                         remove (self);
 762                         return;
 763                 }
 764                 */
 765
 766                 if(cvar("spawn_debug") >= 2)
 767                 {
 768                         entity otheritem;
 769                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 770                         {
 771                                 if(otheritem.is_item)
 772                                 {
 773                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 774                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 775                                         error("Mapper sucks.");
 776                                 }
 777                         }
 778                         self.is_item = TRUE;
 779                 }
 780
 781                 weaponsInMap |= weaponid;
 782
 783                 if(g_lms || g_ca)
 784                 {
 785                         startitem_failed = TRUE;
 786                         remove(self);
 787                         return;
 788                 }
 789                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 790                 {
 791                         startitem_failed = TRUE;
 792                         remove(self);
 793                         return;
 794                 }
 795                 else if (g_minstagib)
 796                 {
 797                         // don't remove dropped items and powerups
 798                         if (self.classname != "minstagib")
 799                         {
 800                                 startitem_failed = TRUE;
 801                                 remove (self);
 802                                 return;
 803                         }
 804                 }
 805                 else if (g_nixnex)
 806                 {
 807                         local float rm;
 808
 809                         rm = 1;
 810                         switch (itemid)
 811                         {
 812                                 case IT_HEALTH:
 813                                 case IT_5HP:
 814                                 case IT_25HP:
 815                                 case IT_ARMOR:
 816                                 case IT_ARMOR_SHARD:
 817                                         if (cvar("g_nixnex_with_healtharmor"))
 818                                                 rm = 0;
 819                                         break;
 820                                 case IT_STRENGTH:
 821                                 case IT_INVINCIBLE:
 822                                         if (cvar("g_nixnex_with_powerups"))
 823                                                 rm = 0;
 824                                         break;
 825                         }
 826
 827                         if(rm)
 828                         {
 829                                 startitem_failed = TRUE;
 830                                 remove (self);
 831                                 return;
 832                         }
 833                 }
 834                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 835                 {
 836                         startitem_failed = TRUE;
 837                         remove (self);
 838                         return;
 839                 }
 840
 841                 precache_model (itemmodel);
 842                 precache_sound (pickupsound);
 843                 precache_sound ("misc/itemrespawn.wav");
 844                 precache_sound ("misc/itemrespawncountdown.wav");
 845
 846                 if(itemid == IT_STRENGTH)
 847                         precache_sound ("misc/strength_respawn.wav");
 848                 if(itemid == IT_INVINCIBLE)
 849                         precache_sound ("misc/shield_respawn.wav");
 850
 851                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 852                         self.target = "###item###"; // for finding the nearest item using find()
 853         }
 854
 855         self.bot_pickup = TRUE;
 856         self.bot_pickupevalfunc = pickupevalfunc;
 857         self.bot_pickupbasevalue = pickupbasevalue;
 858         self.mdl = itemmodel;
 859         self.item_pickupsound = pickupsound;
 860         // let mappers override respawntime
 861         if(!self.respawntime) // both set
 862         {
 863                 self.respawntime = defaultrespawntime;
 864                 self.respawntimejitter = defaultrespawntimejitter;
 865         }
 866         self.netname = itemname;
 867         self.items = itemid;
 868         self.weapons = weaponid;
 869         self.flags = FL_ITEM | itemflags;
 870         self.touch = Item_Touch;
 871         setmodel (self, self.mdl); // precision set below
 872         self.effects |= EF_LOWPRECISION;
 873         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 874                 setsize (self, '-16 -16 0', '16 16 48');
 875         else
 876                 setsize (self, '-16 -16 0', '16 16 32');
 877         if(itemflags & FL_WEAPON)
 878                 self.modelflags |= MF_ROTATE;
 879
 880         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 881         if (itemflags & FL_WEAPON)
 882         {
 883                 // neutral team color for pickup weapons
 884                 self.colormap = 1024; // color shirt=0 pants=0 grey
 885         }
 886
 887         Item_Show(self, 1);
 888         self.state = 0;
 889         if(self.team)
 890         {
 891                 if(!self.cnt)
 892                         self.cnt = 1; // item probability weight
 893                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 894                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 895         }
 896         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 897                 Item_ScheduleInitialRespawn(self);
 898 }
 899
 900 /* replace items in minstagib
 901  * IT_STRENGTH   = invisibility
 902  * IT_NAILS      = extra lives
 903  * IT_INVINCIBLE = speed
 904  */
 905 void minstagib_items (float itemid)
 906 {
 907         // we don't want to replace dropped weapons ;)
 908         if (self.classname == "droppedweapon")
 909         {
 910                 self.ammo_cells = 25;
 911                 StartItem ("models/weapons/g_nex.md3",
 912                         "weapons/weaponpickup.wav", 15, 0,
 913                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 914                 return;
 915         }
 916
 917         local float rnd;
 918         self.classname = "minstagib";
 919
 920         // replace rocket launchers and nex guns with ammo cells
 921         if (itemid == IT_CELLS)
 922         {
 923                 self.ammo_cells = 1;
 924                 StartItem ("models/items/a_cells.md3",
 925                         "misc/itempickup.wav", 45, 0,
 926                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 927                 return;
 928         }
 929
 930         // randomize
 931         rnd = random() * 3;
 932         if (rnd <= 1)
 933                 itemid = IT_STRENGTH;
 934         else if (rnd <= 2)
 935                 itemid = IT_NAILS;
 936         else
 937                 itemid = IT_INVINCIBLE;
 938
 939         // replace with invis
 940         if (itemid == IT_STRENGTH)
 941         {
 942                 self.strength_finished = 30;
 943                 StartItem ("models/items/g_strength.md3",
 944                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 945                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 946         }
 947         // replace with extra lives
 948         if (itemid == IT_NAILS)
 949         {
 950                 self.max_health = 1;
 951                 StartItem ("models/items/g_h100.md3",
 952                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 953                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 954
 955         }
 956         // replace with speed
 957         if (itemid == IT_INVINCIBLE)
 958         {
 959                 self.invincible_finished = 30;
 960                 StartItem ("models/items/g_invincible.md3",
 961                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 962                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 963         }
 964
 965 }
 966
 967 float minst_no_auto_cells;
 968 void minst_remove_item (void) {
 969         if(minst_no_auto_cells)
 970                 remove(self);
 971 }
 972
 973 float weaponswapping;
 974 float internalteam;
 975
 976 void weapon_defaultspawnfunc(float wpn)
 977 {
 978         entity e;
 979         float t;
 980         var .float ammofield;
 981         string s;
 982         entity oldself;
 983         float i, j;
 984
 985         // set the respawntime in advance (so replaced weapons can copy it)
 986
 987         if(!self.respawntime)
 988         {
 989                 e = get_weaponinfo(wpn);
 990                 if(e.items == IT_SUPERWEAPON)
 991                 {
 992                         self.respawntime = g_pickup_respawntime_powerup;
 993                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 994                 }
 995                 else
 996                 {
 997                         self.respawntime = g_pickup_respawntime_weapon;
 998                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 999                 }
1000         }
1001
1002         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1003         {
1004                 e = get_weaponinfo(wpn);
1005                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1006                 if(s == "0")
1007                 {
1008                         remove(self);
1009                         startitem_failed = TRUE;
1010                         return;
1011                 }
1012                 t = tokenize_console(s);
1013                 if(t >= 2)
1014                 {
1015                         self.team = --internalteam;
1016                         oldself = self;
1017                         for(i = 1; i < t; ++i)
1018                         {
1019                                 s = argv(i);
1020                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1021                                 {
1022                                         e = get_weaponinfo(j);
1023                                         if(e.netname == s)
1024                                         {
1025                                                 self = spawn();
1026                                                 copyentity(oldself, self);
1027                                                 self.classname = "replacedweapon";
1028                                                 weapon_defaultspawnfunc(j);
1029                                                 break;
1030                                         }
1031                                 }
1032                                 if(j > WEP_LAST)
1033                                 {
1034                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1035                                 }
1036                         }
1037                         self = oldself;
1038                 }
1039                 if(t >= 1)
1040                 {
1041                         s = argv(0);
1042                         wpn = 0;
1043                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1044                         {
1045                                 e = get_weaponinfo(j);
1046                                 if(e.netname == s)
1047                                 {
1048                                         wpn = j;
1049                                         break;
1050                                 }
1051                         }
1052                         if(j > WEP_LAST)
1053                         {
1054                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1055                         }
1056                 }
1057                 if(wpn == 0)
1058                 {
1059                         remove(self);
1060                         startitem_failed = TRUE;
1061                         return;
1062                 }
1063         }
1064
1065         e = get_weaponinfo(wpn);
1066
1067         if(e.items && e.items != IT_SUPERWEAPON)
1068         {
1069                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1070                 {
1071                         if(e.items & j)
1072                         {
1073                                 ammofield = Item_CounterField(j);
1074                                 if(!self.ammofield)
1075                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1076                         }
1077                 }
1078         }
1079         else
1080         {
1081                 self.flags |= FL_NO_WEAPON_STAY;
1082         }
1083
1084         // weapon stay isn't supported for teamed weapons
1085         if(self.team)
1086                 self.flags |= FL_NO_WEAPON_STAY;
1087
1088         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1089         {
1090                 self.ammo_shells = 0;
1091                 self.ammo_nails = 0;
1092                 self.ammo_cells = 0;
1093                 self.ammo_rockets = 0;
1094                 // weapon stay 2: don't use ammo on weapon pickups; instead
1095                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1096         }
1097
1098         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1099         if (self.modelindex) // don't precache if self was removed
1100                 weapon_action(e.weapon, WR_PRECACHE);
1101 }
1102
1103 void spawnfunc_weapon_shotgun (void);
1104 void spawnfunc_weapon_uzi (void) {
1105         if(q3acompat_machineshotgunswap)
1106         if(self.classname != "droppedweapon")
1107         {
1108                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1109                 return;
1110         }
1111         weapon_defaultspawnfunc(WEP_UZI);
1112 }
1113
1114 void spawnfunc_weapon_shotgun (void) {
1115         if(q3acompat_machineshotgunswap)
1116         if(self.classname != "droppedweapon")
1117         {
1118                 weapon_defaultspawnfunc(WEP_UZI);
1119                 return;
1120         }
1121         weapon_defaultspawnfunc(WEP_SHOTGUN);
1122 }
1123
1124 void spawnfunc_weapon_nex (void)
1125 {
1126         if (g_minstagib)
1127         {
1128                 minstagib_items(IT_CELLS);
1129                 self.think = minst_remove_item;
1130                 self.nextthink = time;
1131                 return;
1132         }
1133         weapon_defaultspawnfunc(WEP_NEX);
1134 }
1135
1136 void spawnfunc_weapon_minstanex (void)
1137 {
1138         if (g_minstagib)
1139         {
1140                 minstagib_items(IT_CELLS);
1141                 self.think = minst_remove_item;
1142                 self.nextthink = time;
1143                 return;
1144         }
1145         weapon_defaultspawnfunc(WEP_MINSTANEX);
1146 }
1147
1148 void spawnfunc_weapon_rocketlauncher (void)
1149 {
1150         if (g_minstagib)
1151         {
1152                 minstagib_items(IT_CELLS);
1153                 self.think = minst_remove_item;
1154                 self.nextthink = time;
1155                 return;
1156         }
1157         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1158 }
1159
1160 void spawnfunc_item_rockets (void) {
1161         if(!self.ammo_rockets)
1162                 self.ammo_rockets = g_pickup_rockets;
1163         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1164 }
1165
1166 void spawnfunc_item_shells (void);
1167 void spawnfunc_item_bullets (void) {
1168         if(!weaponswapping)
1169         if(q3acompat_machineshotgunswap)
1170         if(self.classname != "droppedweapon")
1171         {
1172                 weaponswapping = TRUE;
1173                 spawnfunc_item_shells();
1174                 weaponswapping = FALSE;
1175                 return;
1176         }
1177
1178         if(!self.ammo_nails)
1179                 self.ammo_nails = g_pickup_nails;
1180         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1181 }
1182
1183 void spawnfunc_item_cells (void) {
1184         if(!self.ammo_cells)
1185                 self.ammo_cells = g_pickup_cells;
1186         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1187 }
1188
1189 void spawnfunc_item_shells (void) {
1190         if(!weaponswapping)
1191         if(q3acompat_machineshotgunswap)
1192         if(self.classname != "droppedweapon")
1193         {
1194                 weaponswapping = TRUE;
1195                 spawnfunc_item_bullets();
1196                 weaponswapping = FALSE;
1197                 return;
1198         }
1199
1200         if(!self.ammo_shells)
1201                 self.ammo_shells = g_pickup_shells;
1202         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1203 }
1204
1205 void spawnfunc_item_armor_small (void) {
1206         if(!self.armorvalue)
1207                 self.armorvalue = g_pickup_armorsmall;
1208         if(!self.max_armorvalue)
1209                 self.max_armorvalue = g_pickup_armorsmall_max;
1210         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1211 }
1212
1213 void spawnfunc_item_armor_medium (void) {
1214         if(!self.armorvalue)
1215                 self.armorvalue = g_pickup_armormedium;
1216         if(!self.max_armorvalue)
1217                 self.max_armorvalue = g_pickup_armormedium_max;
1218         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1219 }
1220
1221 void spawnfunc_item_armor_big (void) {
1222         if(!self.armorvalue)
1223                 self.armorvalue = g_pickup_armorbig;
1224         if(!self.max_armorvalue)
1225                 self.max_armorvalue = g_pickup_armorbig_max;
1226         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1227 }
1228
1229 void spawnfunc_item_armor_large (void) {
1230         if(!self.armorvalue)
1231                 self.armorvalue = g_pickup_armorlarge;
1232         if(!self.max_armorvalue)
1233                 self.max_armorvalue = g_pickup_armorlarge_max;
1234         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1235 }
1236
1237 void spawnfunc_item_health_small (void) {
1238         if(!self.max_health)
1239                 self.max_health = g_pickup_healthsmall_max;
1240         if(!self.health)
1241                 self.health = g_pickup_healthsmall;
1242         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1243 }
1244
1245 void spawnfunc_item_health_medium (void) {
1246         if(!self.max_health)
1247                 self.max_health = g_pickup_healthmedium_max;
1248         if(!self.health)
1249                 self.health = g_pickup_healthmedium;
1250         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1251 }
1252
1253 void spawnfunc_item_health_large (void) {
1254         if(!self.max_health)
1255                 self.max_health = g_pickup_healthlarge_max;
1256         if(!self.health)
1257                 self.health = g_pickup_healthlarge;
1258         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1259 }
1260
1261 void spawnfunc_item_health_mega (void) {
1262         if(!cvar("g_powerup_superhealth"))
1263                 return;
1264
1265         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1266                 return;
1267
1268         if(g_minstagib) {
1269                 minstagib_items(IT_NAILS);
1270         } else {
1271                 if(!self.max_health)
1272                         self.max_health = g_pickup_healthmega_max;
1273                 if(!self.health)
1274                         self.health = g_pickup_healthmega;
1275                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1276         }
1277 }
1278
1279 // support old misnamed entities
1280 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1281 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1282 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1283 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1284 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1285
1286 void spawnfunc_item_strength (void) {
1287         if(!cvar("g_powerup_strength"))
1288                 return;
1289
1290         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1291                 return;
1292
1293         if(g_minstagib) {
1294                 minstagib_items(IT_STRENGTH);
1295         } else {
1296                 precache_sound("weapons/strength_fire.wav");
1297                 self.strength_finished = 30;
1298                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1299         }
1300 }
1301
1302 void spawnfunc_item_invincible (void) {
1303         if(!cvar("g_powerup_shield"))
1304                 return;
1305
1306         if((g_arena || g_ca) && !cvar("g_arena_powerups"))
1307                 return;
1308
1309         if(g_minstagib) {
1310                 minstagib_items(IT_INVINCIBLE);
1311         } else {
1312                 self.invincible_finished = 30;
1313                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1314         }
1315 }
1316
1317 void spawnfunc_item_minst_cells (void) {
1318         if (g_minstagib)
1319         {
1320                 minst_no_auto_cells = 1;
1321                 minstagib_items(IT_CELLS);
1322         }
1323         else
1324                 remove(self);
1325 }
1326
1327 // compatibility:
1328 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1329
1330 float GiveItems(entity e, float beginarg, float endarg);
1331 void target_items_use (void)
1332 {
1333         if(activator.classname == "droppedweapon")
1334         {
1335                 EXACTTRIGGER_TOUCH;
1336                 remove(activator);
1337                 return;
1338         }
1339
1340         if(activator.classname != "player")
1341                 return;
1342         if(activator.deadflag != DEAD_NO)
1343                 return;
1344         EXACTTRIGGER_TOUCH;
1345
1346         entity e;
1347         for(e = world; (e = find(e, classname, "droppedweapon")); )
1348                 if(e.enemy == activator)
1349                         remove(e);
1350
1351         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1352                 centerprint(activator, self.message);
1353 }
1354
1355 void spawnfunc_target_items (void)
1356 {
1357         float n, i, j;
1358         entity e;
1359
1360         if(g_nixnex)
1361         {
1362                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1363                 remove(self);
1364                 return;
1365         }
1366
1367         self.use = target_items_use;
1368         if(!self.strength_finished)
1369                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1370         if(!self.invincible_finished)
1371                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1372
1373         precache_sound("misc/itempickup.wav");
1374         precache_sound("misc/itempickup.wav");
1375         precache_sound("misc/itempickup.wav");
1376         precache_sound("misc/itempickup.wav");
1377         precache_sound("misc/megahealth.wav");
1378         precache_sound("misc/armor25.wav");
1379         precache_sound("misc/powerup.wav");
1380         precache_sound("misc/poweroff.wav");
1381         precache_sound("weapons/weaponpickup.wav");
1382
1383         n = tokenize_console(self.netname);
1384         if(argv(0) == "give")
1385         {
1386                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1387         }
1388         else
1389         {
1390                 for(i = 0; i < n; ++i)
1391                 {
1392                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1393                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1394                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1395                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1396                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1397                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1398                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1399                         else
1400                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1401                         {
1402                                 e = get_weaponinfo(j);
1403                                 if(argv(i) == e.netname)
1404                                 {
1405                                         self.weapons |= e.weapons;
1406                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1407                                                 weapon_action(e.weapon, WR_PRECACHE);
1408                                         break;
1409                                 }
1410                         }
1411                         if(j > WEP_LAST)
1412                                 print("target_items: invalid item ", argv(i), "\n");
1413                 }
1414
1415                 string itemprefix, valueprefix;
1416                 if(self.spawnflags == 0)
1417                 {
1418                         itemprefix = "";
1419                         valueprefix = "";
1420                 }
1421                 else if(self.spawnflags == 1)
1422                 {
1423                         itemprefix = "max ";
1424                         valueprefix = "max ";
1425                 }
1426                 else if(self.spawnflags == 2)
1427                 {
1428                         itemprefix = "min ";
1429                         valueprefix = "min ";
1430                 }
1431                 else if(self.spawnflags == 4)
1432                 {
1433                         itemprefix = "minus ";
1434                         valueprefix = "max ";
1435                 }
1436                 else
1437                         error("invalid spawnflags");
1438
1439                 self.netname = "";
1440                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1441                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1442                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1443                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1444                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1445                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1446                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1447                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1448                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1449                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1450                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1451                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1452                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1453                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1454                 {
1455                         e = get_weaponinfo(j);
1456                         if(e.weapons)
1457                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1458                 }
1459         }
1460         self.netname = strzone(self.netname);
1461         //print(self.netname, "\n");
1462
1463         n = tokenize_console(self.netname);
1464         for(i = 0; i < n; ++i)
1465         {
1466                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1467                 {
1468                         e = get_weaponinfo(j);
1469                         if(argv(i) == e.netname)
1470                         {
1471                                 weapon_action(e.weapon, WR_PRECACHE);
1472                                 break;
1473                         }
1474                 }
1475         }
1476 }
1477
1478 void spawnfunc_item_fuel(void)
1479 {
1480         if(!self.ammo_fuel)
1481                 self.ammo_fuel = g_pickup_fuel;
1482         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1483 }
1484
1485 void spawnfunc_item_fuel_regen(void)
1486 {
1487         if(start_items & IT_FUEL_REGEN)
1488         {
1489                 spawnfunc_item_fuel();
1490                 return;
1491         }
1492         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1493 }
1494
1495 void spawnfunc_item_jetpack(void)
1496 {
1497         if(g_grappling_hook)
1498                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1499         if(!self.ammo_fuel)
1500                 self.ammo_fuel = g_pickup_fuel_jetpack;
1501         if(start_items & IT_JETPACK)
1502         {
1503                 spawnfunc_item_fuel();
1504                 return;
1505         }
1506         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1507 }
1508
1509 // we no longer have the seeker
1510 void spawnfunc_weapon_seeker()
1511 {
1512         spawnfunc_weapon_fireball();
1513 }
1514
1515
1516 #define OP_SET 0
1517 #define OP_MIN 1
1518 #define OP_MAX 2
1519 #define OP_PLUS 3
1520 #define OP_MINUS 4
1521
1522 float GiveBit(entity e, .float fld, float bit, float op, float val)
1523 {
1524         float v0, v1;
1525         v0 = (e.fld & bit);
1526         switch(op)
1527         {
1528                 case OP_SET:
1529                         if(val > 0)
1530                                 e.fld |= bit;
1531                         else
1532                                 e.fld &~= bit;
1533                         break;
1534                 case OP_MIN:
1535                 case OP_PLUS:
1536                         if(val > 0)
1537                                 e.fld |= bit;
1538                         break;
1539                 case OP_MAX:
1540                         if(val <= 0)
1541                                 e.fld &~= bit;
1542                         break;
1543                 case OP_MINUS:
1544                         if(val > 0)
1545                                 e.fld &~= bit;
1546                         break;
1547         }
1548         v1 = (e.fld & bit);
1549         return (v0 != v1);
1550 }
1551
1552 float GiveValue(entity e, .float fld, float op, float val)
1553 {
1554         float v0, v1;
1555         v0 = e.fld;
1556         switch(op)
1557         {
1558                 case OP_SET:
1559                         e.fld = val;
1560                         break;
1561                 case OP_MIN:
1562                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1563                         break;
1564                 case OP_MAX:
1565                         e.fld = min(e.fld, val);
1566                         break;
1567                 case OP_PLUS:
1568                         e.fld += val;
1569                         break;
1570                 case OP_MINUS:
1571                         e.fld -= val;
1572                         break;
1573         }
1574         v1 = e.fld;
1575         return (v0 != v1);
1576 }
1577
1578 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1579 {
1580         if(v1 == v0)
1581                 return;
1582         if(v1 <= v0 - t)
1583         {
1584                 if(snd_decr != "")
1585                         sound (e, CHAN_AUTO, snd_decr, VOL_BASE, ATTN_NORM);
1586         }
1587         else if(v0 >= v0 + t)
1588         {
1589                 if(snd_incr != "")
1590                         sound (e, CHAN_AUTO, snd_incr, VOL_BASE, ATTN_NORM);
1591         }
1592 }
1593
1594 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1595 {
1596         if(v0 < v1)
1597                 e.rotfield = max(e.rotfield, time + rottime);
1598         else if(v0 > v1)
1599                 e.regenfield = max(e.regenfield, time + regentime);
1600 }
1601
1602 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1603 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1604 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1605 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1606
1607 float GiveItems(entity e, float beginarg, float endarg)
1608 {
1609         float got, i, j, val, op;
1610         float _switchweapon;
1611         entity wi;
1612         string cmd;
1613
1614         val = 999;
1615         op = OP_SET;
1616
1617         got = 0;
1618
1619         _switchweapon = FALSE;
1620         if (e.autoswitch)
1621                 if (e.switchweapon == w_getbestweapon(e))
1622                         _switchweapon = TRUE;
1623
1624         e.strength_finished = max(0, e.strength_finished - time);
1625         e.invincible_finished = max(0, e.invincible_finished - time);
1626
1627         PREGIVE(e, items);
1628         PREGIVE(e, weapons);
1629         PREGIVE(e, strength_finished);
1630         PREGIVE(e, invincible_finished);
1631         PREGIVE(e, ammo_nails);
1632         PREGIVE(e, ammo_cells);
1633         PREGIVE(e, ammo_shells);
1634         PREGIVE(e, ammo_rockets);
1635         PREGIVE(e, ammo_fuel);
1636         PREGIVE(e, armorvalue);
1637         PREGIVE(e, health);
1638
1639         for(i = beginarg; i < endarg; ++i)
1640         {
1641                 cmd = argv(i);
1642
1643                 if(cmd == "0" || stof(cmd))
1644                 {
1645                         val = stof(cmd);
1646                         continue;
1647                 }
1648                 switch(cmd)
1649                 {
1650                         case "no":
1651                                 op = OP_MAX;
1652                                 val = 0;
1653                                 continue;
1654                         case "max":
1655                                 op = OP_MAX;
1656                                 continue;
1657                         case "min":
1658                                 op = OP_MIN;
1659                                 continue;
1660                         case "plus":
1661                                 op = OP_PLUS;
1662                                 continue;
1663                         case "minus":
1664                                 op = OP_MINUS;
1665                                 continue;
1666                         case "ALL":
1667                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1668                                 got += GiveValue(e, strength_finished, op, time + val);
1669                                 got += GiveValue(e, invincible_finished, op, time + val);
1670                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1671                         case "all":
1672                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1673                                 got += GiveValue(e, health, op, val);
1674                                 got += GiveValue(e, armorvalue, op, val);
1675                         case "allweapons":
1676                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1677                                 {
1678                                         wi = get_weaponinfo(j);
1679                                         if(wi.weapons)
1680                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1681                                 }
1682                         case "allammo":
1683                                 got += GiveValue(e, ammo_cells, op, val);
1684                                 got += GiveValue(e, ammo_shells, op, val);
1685                                 got += GiveValue(e, ammo_nails, op, val);
1686                                 got += GiveValue(e, ammo_rockets, op, val);
1687                                 got += GiveValue(e, ammo_fuel, op, val);
1688                                 break;
1689                         case "unlimited_ammo":
1690                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1691                                 break;
1692                         case "unlimited_weapon_ammo":
1693                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1694                                 break;
1695                         case "unlimited_superweapons":
1696                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1697                                 break;
1698                         case "jetpack":
1699                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1700                                 break;
1701                         case "fuel_regen":
1702                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1703                                 break;
1704                         case "strength":
1705                                 got += GiveValue(e, strength_finished, op, val);
1706                                 break;
1707                         case "invincible":
1708                                 got += GiveValue(e, invincible_finished, op, val);
1709                                 break;
1710                         case "cells":
1711                                 got += GiveValue(e, ammo_cells, op, val);
1712                                 break;
1713                         case "shells":
1714                                 got += GiveValue(e, ammo_shells, op, val);
1715                                 break;
1716                         case "nails":
1717                         case "bullets":
1718                                 got += GiveValue(e, ammo_nails, op, val);
1719                                 break;
1720                         case "rockets":
1721                                 got += GiveValue(e, ammo_rockets, op, val);
1722                                 break;
1723                         case "health":
1724                                 got += GiveValue(e, health, op, val);
1725                                 break;
1726                         case "armor":
1727                                 got += GiveValue(e, armorvalue, op, val);
1728                                 break;
1729                         case "fuel":
1730                                 got += GiveValue(e, ammo_fuel, op, val);
1731                                 break;
1732                         default:
1733                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1734                                 {
1735                                         wi = get_weaponinfo(j);
1736                                         if(cmd == wi.netname)
1737                                         {
1738                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1739                                                 break;
1740                                         }
1741                                 }
1742                                 if(j > WEP_LAST)
1743                                         print("give: invalid item ", cmd, "\n");
1744                                 break;
1745                 }
1746                 val = 999;
1747                 op = OP_SET;
1748         }
1749
1750         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1751         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1752         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1753         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1754         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1755         {
1756                 wi = get_weaponinfo(j);
1757                 if(wi.weapons)
1758                 {
1759                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1760                         if not(save_weapons & wi.weapons)
1761                                 if(e.weapons & wi.weapons)
1762                                         weapon_action(wi.weapon, WR_PRECACHE);
1763                 }
1764         }
1765         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1766         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1767         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1768         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1769         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1770         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1771         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, cvar("g_balance_pause_fuel_rot"), pauseregen_finished, cvar("g_balance_pause_fuel_regen"), "misc/itempickup.wav", string_null);
1772         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, cvar("g_balance_pause_armor_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/armor25.wav", string_null);
1773         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, cvar("g_balance_pause_health_rot"), pauseregen_finished, cvar("g_balance_pause_health_regen"), "misc/megahealth.wav", string_null);
1774
1775         if(e.strength_finished <= 0)
1776                 e.strength_finished = 0;
1777         else
1778                 e.strength_finished += time;
1779         if(e.invincible_finished <= 0)
1780                 e.invincible_finished = 0;
1781         else
1782                 e.invincible_finished += time;
1783
1784         if not(e.weapons & W_WeaponBit(e.switchweapon))
1785                 _switchweapon = TRUE;
1786         if(_switchweapon)
1787                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1788
1789         return got;
1790 }