data/qcsrc/server/t_items.qc

   1
   2 .float max_armorvalue;
   3
   4 void Item_Respawn (void)
   5 {
   6         self.model = self.mdl;          // restore original model
   7         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   8         sound (self, CHAN_VOICE, "misc/itemrespawn.wav", 1, ATTN_NORM); // play respawn sound
   9         setorigin (self, self.origin);
  10
  11         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  12         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  13 }
  14
  15 void Item_Touch (void)
  16 {
  17         local entity oldself;
  18         local float _switchweapon;
  19         local float pickedup;
  20         local float it;
  21
  22         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  23         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  24         {
  25                 remove(self);
  26                 return;
  27         }
  28         if (other.classname != "player")
  29                 return;
  30         if (other.deadflag)
  31                 return;
  32         if (self.solid != SOLID_TRIGGER)
  33                 return;
  34         if (self.owner == other)
  35                 return;
  36
  37         // if nothing happens to other, just return without taking the item
  38         pickedup = FALSE;
  39         _switchweapon = FALSE;
  40
  41         if (g_minstagib)
  42         {
  43                 _switchweapon = TRUE;
  44                 if (self.ammo_cells)
  45                 {
  46                         pickedup = TRUE;
  47                         // play some cool sounds ;)
  48                         centerprint(other, "\n");
  49                         if(other.health <= 5)
  50                                 announce(other, "announcer/robotic/lastsecond.ogg");
  51                         else if(other.health < 50)
  52                                 announce(other, "announcer/robotic/narrowly.ogg");
  53                         // sound not available
  54                         // else if(self.items == IT_CELLS)
  55                         //      play2(other, "announce/robotic/ammo.ogg");
  56
  57                         if (self.items & IT_NEX)
  58                                 W_GiveWeapon (other, IT_NEX, "Nex");
  59                         if (self.ammo_cells)
  60                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  61                         other.health = 100;
  62                 }
  63
  64                 // extralife powerup
  65                 if (self.max_health)
  66                 {
  67                         pickedup = TRUE;
  68                         // sound not available
  69                         // play2(other, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg");
  70                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  71                         sprint(other, "^3You picked up some extra lives\n");
  72                 }
  73
  74                 // invis powerup
  75                 if (self.strength_finished)
  76                 {
  77                         pickedup = TRUE;
  78                         // sound not available
  79                         // play2(other, "announce/robotic/invisible.ogg");
  80                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  81                 }
  82
  83                 // speed powerup
  84                 if (self.invincible_finished)
  85                 {
  86                         pickedup = TRUE;
  87                         // sound not available
  88                         // play2(other, "announce/robotic/speed.ogg");
  89                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  90                 }
  91         }
  92         else
  93         {
  94                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
  95                 {
  96                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
  97                                 return;
  98                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
  99                                 return;
 100                 }
 101
 102                 // in case the player has autoswitch enabled do the following:
 103                 // if the player is using their best weapon before items are given, they
 104                 // probably want to switch to an even better weapon after items are given
 105                 if (other.autoswitch)
 106                 if (other.switchweapon == w_getbestweapon(other))
 107                         _switchweapon = TRUE;
 108
 109                 if (self.ammo_shells)
 110                 if (other.ammo_shells < g_pickup_shells_max)
 111                 {
 112                         pickedup = TRUE;
 113                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, g_pickup_shells_max);
 114                 }
 115                 if (self.ammo_nails)
 116                 if (other.ammo_nails < g_pickup_nails_max)
 117                 {
 118                         pickedup = TRUE;
 119                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, g_pickup_nails_max);
 120                 }
 121                 if (self.ammo_rockets)
 122                 if (other.ammo_rockets < g_pickup_rockets_max)
 123                 {
 124                         pickedup = TRUE;
 125                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, g_pickup_rockets_max);
 126                 }
 127                 if (self.ammo_cells)
 128                 if (other.ammo_cells < g_pickup_cells_max)
 129                 {
 130                         pickedup = TRUE;
 131                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, g_pickup_cells_max);
 132                 }
 133
 134                 if (self.flags & FL_WEAPON)
 135                 if ((it = self.items - (self.items & other.items)))
 136                 {
 137                         pickedup = TRUE;
 138                         if (it & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 139                         if (it & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 140                         if (it & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 141                         if (it & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 142                         if (it & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 143                         if (it & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 144                         if (it & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 145                         if (it & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 146                 }
 147
 148                 if (self.strength_finished)
 149                 {
 150                         pickedup = TRUE;
 151                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 152                 }
 153                 if (self.invincible_finished)
 154                 {
 155                         pickedup = TRUE;
 156                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 157                 }
 158                 //if (self.speed_finished)
 159                 //{
 160                 //      pickedup = TRUE;
 161                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 162                 //}
 163                 //if (self.slowmo_finished)
 164                 //{
 165                 //      pickedup = TRUE;
 166                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 167                 //}
 168
 169                 if (self.health)
 170                 if (other.health < self.max_health)
 171                 {
 172                         pickedup = TRUE;
 173                         other.health = min(other.health + self.health, self.max_health);
 174                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 175                 }
 176                 if (self.armorvalue)
 177                 if (other.armorvalue < self.max_armorvalue)
 178                 {
 179                         pickedup = TRUE;
 180                         other.armorvalue = min(other.armorvalue + self.armorvalue, self.max_armorvalue);
 181                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 182                 }
 183         }
 184
 185         if (!pickedup)
 186                 return;
 187
 188         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
 189         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 190
 191         oldself = self;
 192         self = other;
 193
 194         if (_switchweapon)
 195                 self.switchweapon = w_getbestweapon(self);
 196         if (self.switchweapon != self.weapon)
 197                 self.cnt = self.weapon;
 198
 199         self = oldself;
 200
 201         if (self.classname == "droppedweapon")
 202                 remove (self);
 203         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 204                 return;
 205         else
 206         {
 207                 self.solid = SOLID_NOT;
 208                 self.model = string_null;
 209                 self.nextthink = time + self.respawntime;
 210                 self.think = Item_Respawn;
 211                 setorigin (self, self.origin);
 212         }
 213 }
 214
 215 // Savage: used for item garbage-collection
 216 // TODO: perhaps nice special effect?
 217 void RemoveItem(void) = {
 218         remove(self);
 219 }
 220
 221 // pickup evaluation functions
 222 // these functions decide how desirable an item is to the bots
 223
 224 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 225
 226 float(entity player, entity item) weapon_pickupevalfunc =
 227 {
 228         // if we already have the weapon, rate it 1/5th normal value
 229         if ((player.items & item.items) == item.items)
 230                 return item.bot_pickupbasevalue * 0.2;
 231         return item.bot_pickupbasevalue;
 232 };
 233
 234 float(entity player, entity item) commodity_pickupevalfunc =
 235 {
 236         float c;
 237         c = 0;
 238         // TODO: figure out if the player even has the weapon this ammo is for?
 239         // may not affect strategy much though...
 240         // find out how much more ammo/armor/health the player can hold
 241         if (item.ammo_shells)
 242         if (player.ammo_shells < g_pickup_shells_max)
 243                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 244         if (item.ammo_nails)
 245         if (player.ammo_nails < g_pickup_nails_max)
 246                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 247         if (item.ammo_rockets)
 248         if (player.ammo_rockets < g_pickup_rockets_max)
 249                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 250         if (item.ammo_cells)
 251         if (player.ammo_cells < g_pickup_cells_max)
 252                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 253         if (item.armorvalue)
 254         if (player.armorvalue < item.max_armorvalue)
 255                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 256         if (item.health)
 257         if (player.health < item.max_health)
 258                 c = c + max(0, 1 - player.health / item.max_health);
 259
 260         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 261         if (item.flags & FL_WEAPON)
 262         if (self.items & item.items)
 263         if (item.classname != "droppedweapon")
 264                 c = 0;
 265
 266         return item.bot_pickupbasevalue * c;
 267 };
 268
 269
 270 .float is_item;
 271 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 272 {
 273         startitem_failed = FALSE;
 274
 275         // is it a dropped weapon?
 276         if (self.classname == "droppedweapon")
 277         {
 278                 // it's a dropped weapon
 279                 self.movetype = MOVETYPE_TOSS;
 280                 self.solid = SOLID_TRIGGER;
 281                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 282                 self.think = RemoveItem;
 283                 self.nextthink = time + 60;
 284                 // don't drop if in a NODROP zone (such as lava)
 285                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 286                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 287                 {
 288                         startitem_failed = TRUE;
 289                         remove(self);
 290                         return;
 291                 }
 292         }
 293         else
 294         {
 295                 // it's a level item
 296                 if(self.spawnflags & 1)
 297                         self.noalign = 1;
 298                 if (self.noalign)
 299                         self.movetype = MOVETYPE_NONE;
 300                 else
 301                         self.movetype = MOVETYPE_TOSS;
 302                 self.solid = SOLID_TRIGGER;
 303                 // do item filtering according to game mode and other things
 304                 if (!self.noalign)
 305                 {
 306                         // first nudge it off the floor a little bit to avoid math errors
 307                         setorigin(self, self.origin + '0 0 1');
 308                         // set item size before we spawn a waypoint
 309                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 310                                 setsize (self, '-16 -16 0', '16 16 48');
 311                         else
 312                                 setsize (self, '-16 -16 0', '16 16 32');
 313                         // note droptofloor returns FALSE if stuck/or would fall too far
 314                         droptofloor();
 315                         waypoint_spawnforitem(self);
 316                 }
 317
 318                 if(teams_matter)
 319                 {
 320                         if(self.notteam)
 321                         {
 322                                 print("removed non-teamplay ", self.classname, "\n");
 323                                 startitem_failed = TRUE;
 324                                 remove (self);
 325                                 return;
 326                         }
 327                 }
 328                 else
 329                 {
 330                         if(self.notfree)
 331                         {
 332                                 print("removed non-FFA ", self.classname, "\n");
 333                                 startitem_failed = TRUE;
 334                                 remove (self);
 335                                 return;
 336                         }
 337                 }
 338
 339                 if(self.notq3a)
 340                 {
 341                         // We aren't TA or something like that, so we keep the Q3A entities
 342                         print("removed non-Q3A ", self.classname, "\n");
 343                         startitem_failed = TRUE;
 344                         remove (self);
 345                         return;
 346                 }
 347
 348                 /*
 349                  * can't do it that way, as it would break maps
 350                  * TODO make a target_give like entity another way, that perhaps has
 351                  * the weapon name in a key
 352                 if(self.targetname)
 353                 {
 354                         // target_give not yet supported; maybe later
 355                         print("removed targeted ", self.classname, "\n");
 356                         startitem_failed = TRUE;
 357                         remove (self);
 358                         return;
 359                 }
 360                 */
 361
 362                 if(cvar("spawn_debug") >= 2)
 363                 {
 364                         entity otheritem;
 365                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 366                         {
 367                                 if(otheritem.is_item)
 368                                 {
 369                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 370                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 371                                         error("Mapper sucks.");
 372                                 }
 373                         }
 374                         self.is_item = TRUE;
 375                 }
 376
 377                 itemsInMap |= itemid;
 378
 379                 if(g_lms || g_instagib || g_rocketarena)
 380                 {
 381                         startitem_failed = TRUE;
 382                         remove(self);
 383                         return;
 384                 }
 385                 else if (g_minstagib)
 386                 {
 387                         // don't remove dropped items and powerups
 388                         if (self.classname != "minstagib")
 389                         {
 390                                 startitem_failed = TRUE;
 391                                 remove (self);
 392                                 return;
 393                         }
 394                 }
 395                 else if ((!cvar("g_pickup_items") || g_nixnex) && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 396                 {
 397                         startitem_failed = TRUE;
 398                         remove (self);
 399                         return;
 400                 }
 401
 402                 precache_model (itemmodel);
 403                 precache_sound (pickupsound);
 404                 precache_sound ("misc/itemrespawn.wav");
 405
 406                 if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 407                                         IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 408                                         IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER))
 409                         self.target = "###item###"; // for finding the nearest item using find()
 410         }
 411
 412         self.bot_pickup = TRUE;
 413         self.bot_pickupevalfunc = pickupevalfunc;
 414         self.bot_pickupbasevalue = pickupbasevalue;
 415         self.mdl = itemmodel;
 416         //self.noise = pickupsound;
 417         self.item_pickupsound = pickupsound;
 418         // let mappers override respawntime
 419         if (!self.respawntime)
 420                 self.respawntime = defaultrespawntime;
 421         self.netname = itemname;
 422         self.items = itemid;
 423         self.flags = FL_ITEM | itemflags;
 424         self.touch = Item_Touch;
 425         setmodel (self, self.mdl); // precision set below
 426         self.effects |= EF_LOWPRECISION;
 427         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 428                 setsize (self, '-16 -16 0', '16 16 48');
 429         else
 430                 setsize (self, '-16 -16 0', '16 16 32');
 431         if (itemflags & FL_WEAPON)
 432         {
 433                 // neutral team color for pickup weapons
 434                 self.colormap = 160 * 1024 + 160;
 435         }
 436
 437         if (cvar("g_fullbrightitems"))
 438                 self.effects = self.effects | EF_FULLBRIGHT;
 439 }
 440
 441 /* replace items in minstagib
 442  * IT_STRENGTH   = invisibility
 443  * IT_NAILS      = extra lives
 444  * IT_INVINCIBLE = speed
 445  */
 446 void minstagib_items (float itemid)
 447 {
 448         // we don't want to replace dropped weapons ;)
 449         if (self.classname == "droppedweapon")
 450         {
 451                 self.ammo_cells = 25;
 452                 StartItem ("models/weapons/g_nex.md3",
 453                         "weapons/weaponpickup.wav", 15,
 454                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 455                 return;
 456         }
 457
 458         local float rnd;
 459         self.classname = "minstagib";
 460
 461         // replace rocket launchers and nex guns with ammo cells
 462         if (itemid == IT_CELLS)
 463         {
 464                 self.ammo_cells = 1;
 465                 StartItem ("models/items/a_cells.md3",
 466                         "misc/itempickup.wav", 45,
 467                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 468                 return;
 469         }
 470
 471         // randomize
 472         rnd = random() * 3;
 473         if (rnd <= 1)
 474                 itemid = IT_STRENGTH;
 475         else if (rnd <= 2)
 476                 itemid = IT_NAILS;
 477         else
 478                 itemid = IT_INVINCIBLE;
 479
 480         // replace with invis
 481         if (itemid == IT_STRENGTH)
 482         {
 483                 self.effects = EF_ADDITIVE;
 484                 self.strength_finished = 30;
 485                 StartItem ("models/items/g_strength.md3",
 486                         "misc/powerup.wav", 120,
 487                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 488         }
 489         // replace with extra lives
 490         if (itemid == IT_NAILS)
 491         {
 492                 self.max_health = 1;
 493                 StartItem ("models/items/g_h100.md3",
 494                         "misc/megahealth.wav", 120,
 495                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 496
 497         }
 498         // replace with speed
 499         if (itemid == IT_INVINCIBLE)
 500         {
 501                 self.effects = EF_ADDITIVE;
 502                 self.invincible_finished = 30;
 503                 StartItem ("models/items/g_invincible.md3",
 504                         "misc/powerup_shield.wav", 120,
 505                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 506         }
 507
 508 }
 509
 510 float minst_no_auto_cells;
 511 void minst_remove_item (void) {
 512         if(minst_no_auto_cells)
 513                 remove(self);
 514 }
 515
 516 float weaponswapping;
 517
 518 void weapon_shotgun (void);
 519 void weapon_uzi (void) {
 520         if(!weaponswapping)
 521         if(q3acompat_machineshotgunswap)
 522         if(self.classname != "droppedweapon")
 523         {
 524                 weaponswapping = TRUE;
 525                 weapon_shotgun();
 526                 weaponswapping = FALSE;
 527                 return;
 528         }
 529
 530         if(!self.ammo_nails)
 531                 self.ammo_nails = cvar("g_pickup_nails");
 532         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 5000);
 533         if (self.modelindex) // don't precache if self was removed
 534                 weapon_action(WEP_UZI, WR_PRECACHE);
 535 }
 536
 537 void weapon_shotgun (void) {
 538         if(!weaponswapping)
 539         if(q3acompat_machineshotgunswap)
 540         if(self.classname != "droppedweapon")
 541         {
 542                 weaponswapping = TRUE;
 543                 weapon_uzi();
 544                 weaponswapping = FALSE;
 545                 return;
 546         }
 547
 548         if(!self.ammo_shells)
 549                 self.ammo_shells = cvar("g_pickup_shells");
 550         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 2500);
 551         if (self.modelindex) // don't precache if self was removed
 552                 weapon_action(WEP_SHOTGUN, WR_PRECACHE);
 553 }
 554
 555 void weapon_grenadelauncher (void)
 556 {
 557         if(!self.ammo_rockets)
 558                 self.ammo_rockets = cvar("g_pickup_rockets");
 559         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 5000);
 560         if (self.modelindex) // don't precache if self was removed
 561                 weapon_action(WEP_GRENADE_LAUNCHER, WR_PRECACHE);
 562 }
 563
 564 void weapon_electro (void)
 565 {
 566         if(!self.ammo_cells)
 567                 self.ammo_cells = cvar("g_pickup_cells");
 568         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 5000);
 569         if (self.modelindex) // don't precache if self was removed
 570                 weapon_action(WEP_ELECTRO, WR_PRECACHE);
 571 }
 572
 573 void weapon_crylink (void)
 574 {
 575         if(!self.ammo_cells)
 576                 self.ammo_cells = cvar("g_pickup_cells");
 577         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 2500);
 578         if (self.modelindex) // don't precache if self was removed
 579                 weapon_action(WEP_CRYLINK, WR_PRECACHE);
 580 }
 581
 582 void weapon_nex (void)
 583 {
 584         float nextime;
 585         if (g_minstagib)
 586         {
 587                 minstagib_items(IT_CELLS);
 588                 self.think = minst_remove_item;
 589                 self.nextthink = time + cvar("sys_ticrate");
 590                 return;
 591         }
 592         if(!self.ammo_cells)
 593                 self.ammo_cells = cvar("g_pickup_cells");
 594         nextime = cvar("g_balance_nex_respawntime_modifier");
 595         if(nextime)
 596                 nextime = 15 * nextime;
 597         else
 598                 nextime = 15;
 599         StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.wav", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 10000);
 600         if (self.modelindex) // don't precache if self was removed
 601                 weapon_action(WEP_NEX, WR_PRECACHE);
 602 }
 603
 604 void weapon_hagar (void)
 605 {
 606         if(!self.ammo_rockets)
 607                 self.ammo_rockets = cvar("g_pickup_rockets");
 608         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 5000);
 609         if (self.modelindex) // don't precache if self was removed
 610                 weapon_action(WEP_HAGAR, WR_PRECACHE);
 611 }
 612
 613 void weapon_rocketlauncher (void)
 614 {
 615         if (g_minstagib)
 616         {
 617                 minstagib_items(IT_CELLS);
 618                 self.think = minst_remove_item;
 619                 self.nextthink = time + cvar("sys_ticrate");
 620                 return;
 621         }
 622         if(!self.ammo_rockets)
 623                 self.ammo_rockets = g_pickup_rockets;
 624         StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.wav", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 10000);
 625         if (self.modelindex) // don't precache if self was removed
 626                 weapon_action(WEP_ROCKET_LAUNCHER, WR_PRECACHE);
 627 }
 628
 629 void item_rockets (void) {
 630         if(!self.ammo_rockets)
 631                 self.ammo_rockets = g_pickup_rockets;
 632         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 3000);
 633 }
 634
 635 void item_shells (void);
 636 void item_bullets (void) {
 637         if(!weaponswapping)
 638         if(q3acompat_machineshotgunswap)
 639         if(self.classname != "droppedweapon")
 640         {
 641                 weaponswapping = TRUE;
 642                 item_shells();
 643                 weaponswapping = FALSE;
 644                 return;
 645         }
 646
 647         if(!self.ammo_nails)
 648                 self.ammo_nails = g_pickup_nails;
 649         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 2000);
 650 }
 651
 652 void item_cells (void) {
 653         if(!self.ammo_cells)
 654                 self.ammo_cells = g_pickup_cells;
 655         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 2000);
 656 }
 657
 658 void item_shells (void) {
 659         if(!weaponswapping)
 660         if(q3acompat_machineshotgunswap)
 661         if(self.classname != "droppedweapon")
 662         {
 663                 weaponswapping = TRUE;
 664                 item_bullets();
 665                 weaponswapping = FALSE;
 666                 return;
 667         }
 668
 669         if(!self.ammo_shells)
 670                 self.ammo_shells = g_pickup_shells;
 671         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 500);
 672 }
 673
 674 void item_armor_small (void) {
 675         if(!self.armorvalue)
 676                 self.armorvalue = g_pickup_armorsmall;
 677         if(!self.max_armorvalue)
 678                 self.max_armorvalue = g_pickup_armorsmall_max;
 679         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "5 Armor", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 1000);
 680 }
 681
 682 void item_armor_medium (void) {
 683         if(!self.armorvalue)
 684                 self.armorvalue = g_pickup_armormedium;
 685         if(!self.max_armorvalue)
 686                 self.max_armorvalue = g_pickup_armormedium_max;
 687         StartItem ("models/items/g_armormedium.md3", "misc/armor1.wav", 30, "25 Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 20000);
 688 }
 689
 690 void item_armor_large (void) {
 691         if(!self.armorvalue)
 692                 self.armorvalue = g_pickup_armorlarge;
 693         if(!self.max_armorvalue)
 694                 self.max_armorvalue = g_pickup_armorlarge_max;
 695         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "100 Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 20000);
 696 }
 697
 698 void item_health_small (void) {
 699         if(!self.max_health)
 700                 self.max_health = g_pickup_healthsmall_max;
 701         if(!self.health)
 702                 self.health = g_pickup_healthsmall;
 703         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 20000);
 704 }
 705
 706 void item_health_medium (void) {
 707         if(!self.max_health)
 708                 self.max_health = g_pickup_healthmedium_max;
 709         if(!self.health)
 710                 self.health = g_pickup_healthmedium;
 711         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 20000);
 712 }
 713
 714 void item_health_large (void) {
 715         if(!self.max_health)
 716                 self.max_health = g_pickup_healthlarge_max;
 717         if(!self.health)
 718                 self.health = g_pickup_healthlarge;
 719         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", 15, "50 Health", IT_25HP, 0, commodity_pickupevalfunc, 20000);
 720 }
 721
 722 void item_health_mega (void) {
 723         if(!cvar("g_powerup_superhealth"))
 724                 return;
 725
 726         if(g_arena && !cvar("g_arena_powerups"))
 727                 return;
 728
 729         if(g_minstagib) {
 730                 minstagib_items(IT_NAILS);
 731         } else {
 732                 if(!self.max_health)
 733                         self.max_health = g_pickup_healthmega_max;
 734                 if(!self.health)
 735                         self.health = g_pickup_healthmega;
 736                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 20000);
 737         }
 738 }
 739
 740 // support old misnamed entities
 741 void item_armor1() { item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
 742 void item_armor25() { item_armor_large(); }
 743 void item_health1() { item_health_small(); }
 744 void item_health25() { item_health_medium(); }
 745 void item_health100() { item_health_mega(); }
 746
 747 void item_strength (void) {
 748         if(!cvar("g_powerup_strength"))
 749                 return;
 750
 751         if(g_arena && !cvar("g_arena_powerups"))
 752                 return;
 753
 754         if(g_minstagib) {
 755                 minstagib_items(IT_STRENGTH);
 756         } else {
 757                 precache_sound("weapons/strength_fire.wav");
 758                 self.strength_finished = 30;
 759                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.wav", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 100000);
 760         }
 761 }
 762
 763 void item_invincible (void) {
 764         if(!cvar("g_powerup_shield"))
 765                 return;
 766
 767         if(g_arena && !cvar("g_arena_powerups"))
 768                 return;
 769
 770         if(g_minstagib) {
 771                 minstagib_items(IT_INVINCIBLE);
 772         } else {
 773                 self.invincible_finished = 30;
 774                 self.effects = EF_ADDITIVE;
 775                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 100000);
 776         }
 777 }
 778 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 779 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 780
 781 void item_minst_cells (void) {
 782         if (g_minstagib)
 783         {
 784                 minst_no_auto_cells = 1;
 785                 minstagib_items(IT_CELLS);
 786         }
 787         else
 788                 remove(self);
 789 }
 790
 791 // compatibility:
 792 void item_quad (void) {self.classname = "item_strength";item_strength();}
 793
 794 void misc_models (void)
 795 {
 796         precache_model (self.model);
 797         setmodel (self, self.model); // precision set by mapper
 798         setsize (self, self.mins, self.maxs);
 799 }
 800
 801 void func_wall_use (void)
 802 {
 803         if(teams_matter)
 804         {
 805                 if(activator.team)
 806                         self.colormap = (activator.team - 1) * 0x11;
 807                 else
 808                         self.colormap = 0x00;
 809         }
 810         else
 811                 self.colormap = ceil(random() * 256) - 1;
 812         self.colormap |= 1024; // RENDER_COLORMAPPED
 813 }
 814
 815 void func_wall (void)
 816 {
 817         precache_model (self.model);
 818         setmodel (self, self.model); // precision set by mapper
 819         setsize (self, self.mins, self.maxs);
 820         self.solid = SOLID_BSP;
 821         self.use = func_wall_use;
 822 }
 823
 824 floatfield Item_CounterField(float it)
 825 {
 826         switch(it)
 827         {
 828                 case IT_SHELLS:      return ammo_shells;
 829                 case IT_NAILS:       return ammo_nails;
 830                 case IT_ROCKETS:     return ammo_rockets;
 831                 case IT_CELLS:       return ammo_cells;
 832                 case IT_5HP:         return health;
 833                 case IT_25HP:        return health;
 834                 case IT_HEALTH:      return health;
 835                 case IT_ARMOR_SHARD: return armorvalue;
 836                 case IT_ARMOR:       return armorvalue;
 837                 // add more things here (health, armor)
 838                 default:             error("requested item has no counter field");
 839         }
 840 }
 841
 842 float Item_WeaponCode(float it)
 843 {
 844         switch(it)
 845         {
 846                 case IT_LASER:            return WEP_LASER;
 847                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 848                 case IT_UZI:              return WEP_UZI;
 849                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 850                 case IT_ELECTRO:          return WEP_ELECTRO;
 851                 case IT_CRYLINK:          return WEP_CRYLINK;
 852                 case IT_NEX:              return WEP_NEX;
 853                 case IT_HAGAR:            return WEP_HAGAR;
 854                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 855                 default:                  return 0;
 856         }
 857 }
 858
 859 void Item_SpawnByItemCode(float it)
 860 {
 861         switch(it)
 862         {
 863                 case IT_SHOTGUN:          weapon_shotgun(); break;
 864                 case IT_UZI:              weapon_uzi(); break;
 865                 case IT_GRENADE_LAUNCHER: weapon_grenadelauncher(); break;
 866                 case IT_ELECTRO:          weapon_electro(); break;
 867                 case IT_CRYLINK:          weapon_crylink(); break;
 868                 case IT_NEX:              weapon_nex(); break;
 869                 case IT_HAGAR:            weapon_hagar(); break;
 870                 case IT_ROCKET_LAUNCHER:  weapon_rocketlauncher(); break;
 871                 // add all other item spawn functions here
 872                 default:
 873                         error("requested item can't be spawned");
 874         }
 875 }